Bootloader/CMakeLists.txt

   1 ###| CMAKE Kiibohd Controller Bootloader |###
   2 #
   3 # Jacob Alexander 2011-2014
   4 # Due to this file's usefulness:
   5 #
   6 # Released into the Public Domain
   7 #
   8 # This bootloader is based upon the MCHCK dfu-usb bootloader.
   9 # DO NOT USE with Teensy based microcontrollers.
  10 #
  11 ###
  12
  13
  14
  15 ###
  16 # Chip Selection
  17 #
  18
  19 #| You _MUST_ set this to match the microcontroller you are trying to compile for
  20 #| You _MUST_ clean the build directory if you change this value
  21 #|
  22 set( CHIP
  23         #"mk20dx128vlf5"    # McHCK       mk20dx128vlf5
  24         "mk20dx256vlh7"    # Kiibohd-dfu mk20dx256vlh7
  25         CACHE STRING "Chip"
  26 )
  27
  28
  29
  30 ###
  31 # Compiler Selection
  32 #
  33
  34 #| *** EXPERIMENTAL ***
  35 #| Stick with gcc unless you know what you're doing
  36 #| Currently only arm is supported with clang
  37 set( COMPILER
  38         "gcc"   # arm-none-eabi-gcc / avr-gcc - Default
  39 #       "clang" # arm-none-eabi
  40         CACHE STRING "Compiler Type"
  41 )
  42
  43
  44
  45 ###
  46 # Bootloader Configuration
  47 #
  48 set ( BOOTLOADER 1 )
  49
  50
  51
  52 ###
  53 # Compiler Intialization
  54 #
  55 set ( CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_SOURCE_DIR}/../Lib/CMake )
  56 include( initialize )
  57
  58
  59
  60 ##
  61 # Source Defines
  62 #
  63 set( SRCS
  64         main.c
  65         dfu.c
  66         dfu.desc.c
  67         flash.c
  68         kinetis.c
  69         usb.c
  70 )
  71
  72 # Only compile in if necessary
  73 if( CHIP STREQUAL "mk20dx256vlh7" )
  74         set( SRCS ${SRCS}
  75                 debug.c
  76         )
  77 endif()
  78
  79
  80 message( STATUS "Bootloader Source Files:" )
  81 message( "${SRCS}" )
  82
  83 #| Add Lib sources to main list
  84 foreach( SRC_FILE ${COMPILER_SRCS} )
  85         set( SRCS ${SRCS} ${CMAKE_SOURCE_DIR}/../${SRC_FILE} )
  86 endforeach()
  87
  88
  89
  90
  91 ###
  92 # Directory Includes
  93 #
  94 include_directories( ${CMAKE_SOURCE_DIR}/../Lib )
  95
  96
  97
  98 ###
  99 # Project Description
 100 #
 101
 102 #| Project
 103 project( kiibohd_bootloader )
 104
 105 #| Target Name (output name)
 106 set( TARGET kiibohd_bootloader )
 107
 108 #| General Settings
 109 cmake_minimum_required( VERSION 2.8 )
 110
 111
 112
 113 ###
 114 # Generate Header Files
 115 #
 116 configure_file( _buildvars.h buildvars.h )
 117 include_directories( ${CMAKE_BINARY_DIR} )
 118
 119
 120
 121 ###
 122 # CMake Module Checking
 123 #
 124 find_package( Git REQUIRED )
 125 find_package( Ctags ) # Optional
 126
 127
 128
 129 ###
 130 # ctag Generation
 131 #
 132 if( CTAGS_EXECUTABLE )
 133         # Generate the ctags
 134         execute_process( COMMAND ctags ${SRCS}
 135                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 136         )
 137 endif()
 138
 139
 140
 141 ###
 142 # Disable -Wl,-search_paths_first for OSX (not supported by arm-none-eabi-gcc)
 143 #
 144
 145 if ( APPLE )
 146         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_C_LINK_FLAGS ${CMAKE_C_LINK_FLAGS} )
 147         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_CXX_LINK_FLAGS ${CMAKE_CXX_LINK_FLAGS} )
 148
 149         message ( AUTHOR_WARNING "Bootloader binary may not fit on device (must be less than 4096 bytes). Macports arm-none-eabi-gcc 4.7.3 doesn't seem to work properly with -flto. However, even disabling it doesn't shrink the binary enough... 4.9.1 is known to work on Arch Linux." )
 150 endif ()
 151
 152
 153
 154 ###
 155 # Build Targets
 156 #
 157
 158 #| Create the .ELF file
 159 set( TARGET_ELF ${TARGET}.elf )
 160 add_executable( ${TARGET_ELF} ${SRCS} )
 161
 162
 163 #| .ELF Properties
 164 set_target_properties( ${TARGET_ELF} PROPERTIES
 165         LINK_FLAGS ${LINKER_FLAGS}
 166         SUFFIX ""                               # XXX Force Windows to keep the .exe off
 167 )
 168
 169
 170 #| Convert the .ELF into a .bin to load onto the McHCK
 171 set( TARGET_BIN ${TARGET}.bin )
 172 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
 173         COMMAND ${CMAKE_OBJCOPY} ${BIN_FLAGS} ${TARGET_ELF} ${TARGET_BIN}
 174         COMMENT "Creating binary file to load:  ${TARGET_BIN}"
 175 )
 176
 177
 178 #| Generate the Extended .LSS
 179 set( TARGET_LSS ${TARGET}.lss )
 180 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
 181         COMMAND ${CMAKE_OBJDUMP} ${LSS_FLAGS} ${TARGET_ELF} > ${TARGET_LSS}
 182         COMMENT "Creating Extended Listing:     ${TARGET_LSS}"
 183 )
 184
 185
 186 #| Generate the Symbol Table .SYM
 187 set( TARGET_SYM ${TARGET}.sym )
 188 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
 189         COMMAND ${CMAKE_NM} -n ${TARGET_ELF} > ${TARGET_SYM}
 190         COMMENT "Creating Symbol Table:         ${TARGET_SYM}"
 191 )
 192
 193
 194 #| Compiler Selection Record
 195 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
 196         COMMAND ${CMAKE_SOURCE_DIR}/../Lib/CMake/writer compiler ${COMPILER_FAMILY}
 197 )
 198
 199
 200
 201 ###
 202 # Size Information
 203 #
 204
 205 #| After Changes Size Information
 206 add_custom_target( SizeAfter ALL
 207         COMMAND ${CMAKE_SOURCE_DIR}/../Lib/CMake/sizeCalculator ${CMAKE_SIZE} ram   ${TARGET_ELF} ${SIZE_RAM}   " SRAM"
 208         COMMAND ${CMAKE_SOURCE_DIR}/../Lib/CMake/sizeCalculator ${CMAKE_SIZE} flash ${TARGET_ELF} ${SIZE_FLASH} "Flash"
 209         DEPENDS ${TARGET_ELF}
 210         COMMENT "Chip usage for ${CHIP}"
 211 )
 212