src/Modules/BZFlag.pl

   1 #!/usr/bin/perl
   2 #
   3 # BZFlag
   4 # Copyright (c) 1993 - 2002 Tim Riker
   5 #
   6 # This package is free software;  you can redistribute it and/or
   7 # modify it under the terms of the license found in the file
   8 # named LICENSE that should have accompanied this file.
   9 #
  10 # THIS PACKAGE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR
  11 # IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED
  12 # WARRANTIES OF MERCHANTIBILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  13
  14 package BZFlag;
  15 use strict;
  16
  17 my $no_BZFlag;
  18
  19 BEGIN {
  20         $no_BZFlag = 0;
  21         eval "use Socket";
  22         eval "use LWP::UserAgent";
  23         $no_BZFlag++ if ($@);
  24 }
  25
  26 sub BZFlag::BZFlag {
  27         my ($message) = @_;
  28   my ($retval);
  29         if ($no_BZFlag) {
  30                 &main::status("BZFlag module requires Socket.");
  31                 return 'BZFlag module not active';
  32         }
  33         if ($message =~ /^bzfquery\s+([^:]*)(?::([0-9]*))?$/xi) {
  34                 $retval = &query($1,$2);
  35         } elsif ($message =~ /^bzflist$/xi) {
  36                 $retval = &list();
  37   } else {
  38                 $retval = "BZFlag: unhandled command \"$message\"";
  39         }
  40         &::performStrictReply($retval);
  41 }
  42
  43 sub BZFlag::list {
  44         my ($response);
  45         my $ua = new LWP::UserAgent;
  46
  47         $ua->timeout(5);
  48
  49         my $req = HTTP::Request->new('GET', 'http://list.bzflag.org:5156/');
  50         my $res = $ua->request($req);
  51         for my $line (split("\n",$res->content)) {
  52                 my ($serverport, $version, $flags, $ip, $comments) = split(" ",$line,5);
  53                 # not "(A4)18" to handle old dumb perl
  54                 my ($style,$maxPlayers,$maxShots,
  55                                 $rogueSize,$redSize,$greenSize,$blueSize,$purpleSize,
  56                                 $rogueMax,$redMax,$greenMax,$blueMax,$purpleMax,
  57                                 $shakeWins,$shakeTimeout,
  58                                 $maxPlayerScore,$maxTeamScore,$maxTime) =
  59                                 unpack("A4A4A4A4A4A4A4A4A4A4A4A4A4A4A4A4A4A4", $flags);
  60                 my $playerSize = hex($rogueSize) + hex($redSize) + hex($greenSize)
  61                                 + hex($blueSize) + hex($purpleSize);
  62                 if ($playerSize > 0) {
  63                         $response .= "$serverport($playerSize) ";
  64                 }
  65         }
  66         &::performStrictReply($response);
  67         return;
  68 }
  69
  70 sub BZFlag::querytext {
  71         my ($servernameport) = @_;
  72         my ($servername,$port) = split(":",$servernameport);
  73         if ($no_BZFlag) {
  74                 &main::status("BZFlag module requires Socket.");
  75                 return 'BZFlag module not active';
  76         }
  77         #my @teamName = ("Rogue", "Red", "Green", "Blue", "Purple");
  78         my @teamName = ("X", "R", "G", "B", "P");
  79         my ($message, $server, $response);
  80         $port = 5155 unless $port;
  81
  82         # socket define
  83         my $sockaddr = 'S n a4 x8';
  84
  85         # port to port number
  86         my ($name,$aliases,$proto) = getprotobyname('tcp');
  87         ($name,$aliases,$port)  = getservbyname($port,'tcp') unless $port =~ /^\d+$/;
  88
  89         # get server address
  90         my ($type,$len,$serveraddr);
  91         ($name,$aliases,$type,$len,$serveraddr) = gethostbyname($servername);
  92         $server = pack($sockaddr, AF_INET, $port, $serveraddr);
  93
  94         # connect
  95         return 'socket() error' unless socket(S1, AF_INET, SOCK_STREAM, $proto);
  96         return "could not connect to $servername:$port" unless connect(S1, $server);
  97
  98         # don't buffer
  99         select(S1); $| = 1; select(STDOUT);
 100
 101         # get hello
 102         my $buffer;
 103         return 'read error' unless sysread(S1, $buffer, 10) == 10;
 104
 105         # parse reply
 106         my ($magic,$major,$minor,$revision);
 107         ($magic,$major,$minor,$revision,$port) = unpack("a4 a1 a2 a1 n", $buffer);
 108
 109         # quit if version isn't valid
 110         return 'not a bzflag server' if ($magic ne "BZFS");
 111         return 'incompatible version' if ($major < 1);
 112         return 'incompatible version' if ($major == 1 && $minor < 7);
 113         return 'incompatible version' if ($major == 1 && $minor == 7 && $revision eq "b");
 114
 115         # quit if rejected
 116         return 'rejected by server' if ($port == 0);
 117
 118         # reconnect on new port
 119         $server = pack($sockaddr, AF_INET, $port, $serveraddr);
 120         return 'socket() error on reconnect' unless socket(S, AF_INET, SOCK_STREAM, $proto);
 121         return "could not reconnect to $servername:$port" unless connect(S, $server);
 122         select(S); $| = 1; select(STDOUT);
 123
 124         # close first socket
 125         close(S1);
 126
 127         # send game request
 128         print S pack("n2", 0, 0x7167);
 129
 130         # get reply
 131         return 'server read error' unless sysread(S, $buffer, 40) == 40;
 132         my ($infolen,$infocode,$style,$maxPlayers,$maxShots,
 133                 $rogueSize,$redSize,$greenSize,$blueSize,$purpleSize,
 134                 $rogueMax,$redMax,$greenMax,$blueMax,$purpleMax,
 135                 $shakeWins,$shakeTimeout,
 136                 $maxPlayerScore,$maxTeamScore,$maxTime) = unpack("n20", $buffer);
 137         return 'bad server data' unless $infocode == 0x7167;
 138
 139         # send players request
 140         print S pack("n2", 0, 0x7170);
 141
 142         # get number of teams and players we'll be receiving
 143         return 'count read error' unless sysread(S, $buffer, 8) == 8;
 144         my ($countlen,$countcode,$numTeams,$numPlayers) = unpack("n4", $buffer);
 145         return 'bad count data' unless $countcode == 0x7170;
 146
 147         # get the teams
 148         for (1..$numTeams) {
 149                 return 'team read error' unless sysread(S, $buffer, 14) == 14;
 150                 my ($teamlen,$teamcode,$team,$size,$aSize,$won,$lost) = unpack("n7", $buffer);
 151                 return 'bad team data' unless $teamcode == 0x7475;
 152                 if ($size > 0) {
 153                         my $score = $won - $lost;
 154                         $response .= "$teamName[$team]:$score($won-$lost) ";
 155                 }
 156         }
 157
 158         # get the players
 159         for (1..$numPlayers) {
 160                 last unless sysread(S, $buffer, 180) == 180;
 161                 my ($playerlen,$playercode,$pAddr,$pPort,$pNum,$type,$team,$won,$lost,$sign,$email) =
 162                                 unpack("n2Nn2 n4A32A128", $buffer);
 163                 return 'bad player data' unless $playercode == 0x6170;
 164                 my $score = $won - $lost;
 165                 $response .= " $sign($teamName[$team]";
 166                 $response .= ":$email" if ($email);
 167                 $response .= ")$score($won-$lost)";
 168         }
 169         $response .= "No Players" if ($numPlayers <= 1);
 170
 171         # close socket
 172         close(S);
 173
 174         return $response;
 175 }
 176
 177 sub BZFlag::query {
 178         my ($servernameport) = @_;
 179         &::performStrictReply(&querytext($servernameport));
 180   return;
 181 }
 182
 183 1;
 184 # vim: ts=2 sw=2