t/06_mail_handling.t

   1 # -*- mode: cperl;-*-
   2 # $Id: 05_mail.t,v 1.1 2005/08/17 21:46:17 don Exp $
   3
   4 use Test::More tests => 31;
   5
   6 use warnings;
   7 use strict;
   8
   9 # Here, we're going to shoot messages through a set of things that can
  10 # happen.
  11
  12 # First, we're going to send mesages to receive.
  13 # To do so, we'll first send a message to submit,
  14 # then send messages to the newly created bugnumber.
  15
  16 use IO::File;
  17 use File::Temp qw(tempdir);
  18 use Cwd qw(getcwd);
  19 use Debbugs::MIME qw(create_mime_message);
  20 use File::Basename qw(dirname basename);
  21 # The test functions are placed here to make things easier
  22 use lib qw(t/lib);
  23 use DebbugsTest qw(:all);
  24 use Data::Dumper;
  25
  26 # HTTP::Server:::Simple defines a SIG{CHLD} handler that breaks system; undef it here.
  27 $SIG{CHLD} = sub {};
  28 my %config;
  29 eval {
  30      %config = create_debbugs_configuration(debug => exists $ENV{DEBUG}?$ENV{DEBUG}:0);
  31 };
  32 if ($@) {
  33      BAIL_OUT($@);
  34 }
  35
  36 my $sendmail_dir = $config{sendmail_dir};
  37 my $spool_dir = $config{spool_dir};
  38 my $config_dir = $config{config_dir};
  39
  40 END{
  41      if ($ENV{DEBUG}) {
  42           diag("spool_dir:   $spool_dir\n");
  43           diag("config_dir:   $config_dir\n");
  44           diag("sendmail_dir: $sendmail_dir\n");
  45      }
  46 }
  47
  48 # We're going to use create mime message to create these messages, and
  49 # then just send them to receive.
  50
  51 send_message(to=>'submit@bugs.something',
  52              headers => [To   => 'submit@bugs.something',
  53                          From => 'foo@bugs.something',
  54                          Subject => 'Submiting a bug',
  55                         ],
  56              body => <<EOF) or fail('Unable to send message');
  57 Package: foo
  58 Severity: normal
  59
  60 This is a silly bug
  61 EOF
  62
  63 # now we check to see that we have a bug, and nextnumber has been incremented
  64 ok(-e "$spool_dir/db-h/01/1.log",'log file created');
  65 ok(-e "$spool_dir/db-h/01/1.summary",'sumary file created');
  66 ok(-e "$spool_dir/db-h/01/1.status",'status file created');
  67 ok(-e "$spool_dir/db-h/01/1.report",'report file created');
  68
  69 # next, we check to see that (at least) the proper messages have been
  70 # sent out. 1) ack to submitter 2) mail to maintainer
  71
  72 # This keeps track of the previous size of the sendmail directory
  73 my $SD_SIZE_PREV = 0;
  74 my $SD_SIZE_NOW = dirsize($sendmail_dir);
  75 ok($SD_SIZE_NOW-$SD_SIZE_PREV >= 2,'submit messages appear to have been sent out properly');
  76 $SD_SIZE_PREV=$SD_SIZE_NOW;
  77
  78 # now send a message to the bug
  79
  80 send_message(to => '1@bugs.something',
  81              headers => [To   => '1@bugs.something',
  82                          From => 'foo@bugs.something',
  83                          Subject => 'Sending a message to a bug',
  84                         ],
  85              body => <<EOF) or fail('sending message to 1@bugs.someting failed');
  86 Package: foo
  87 Severity: normal
  88
  89 This is a silly bug
  90 EOF
  91
  92 $SD_SIZE_NOW = dirsize($sendmail_dir);
  93 ok($SD_SIZE_NOW-$SD_SIZE_PREV >= 2,'1@bugs.something messages appear to have been sent out properly');
  94 $SD_SIZE_PREV=$SD_SIZE_NOW;
  95
  96 # just check to see that control doesn't explode
  97 send_message(to => 'control@bugs.something',
  98              headers => [To   => 'control@bugs.something',
  99                          From => 'foo@bugs.something',
 100                          Subject => 'Munging a bug',
 101                         ],
 102              body => <<EOF) or fail 'message to control@bugs.something failed';
 103 severity 1 wishlist
 104 retitle 1 new title
 105 thanks
 106 EOF
 107
 108 $SD_SIZE_NOW = dirsize($sendmail_dir);
 109 ok($SD_SIZE_NOW-$SD_SIZE_PREV >= 1,'control@bugs.something messages appear to have been sent out properly');
 110 $SD_SIZE_PREV=$SD_SIZE_NOW;
 111 # now we need to check to make sure the control message was processed without errors
 112 ok(system('sh','-c','find '.$sendmail_dir.q( -type f | xargs grep -q "Subject: Processed: Munging a bug")) == 0,
 113    'control@bugs.something message was parsed without errors');
 114 # now we need to check to make sure that the control message actually did anything
 115 # This is an eval because $ENV{DEBBUGS_CONFIG_FILE} isn't set at BEGIN{} time
 116 eval "use Debbugs::Status qw(read_bug);";
 117 my $status = read_bug(bug=>1);
 118 ok($status->{subject} eq 'new title','bug 1 retitled');
 119 ok($status->{severity} eq 'wishlist','bug 1 wishlisted');
 120
 121 # now we're going to go through and methododically test all of the control commands.
 122 my @control_commands =
 123      (severity_wishlist => {command => 'severity',
 124                             value   => 'wishlist',
 125                             status_key => 'severity',
 126                             status_value => 'wishlist',
 127                            },
 128       'found_1.0'        => {command => 'found',
 129                              value   => '1.0',
 130                              status_key => 'found_versions',
 131                              status_value => ['1.0'],
 132                             },
 133       'notfound_1.0'     => {command => 'notfound',
 134                              value   => '1.0',
 135                              status_key => 'found_versions',
 136                              status_value => [],
 137                             },
 138       submitter_foo      => {command => 'submitter',
 139                              value   => 'foo@bar.com',
 140                              status_key => 'originator',
 141                              status_value => 'foo@bar.com',
 142                             },
 143
 144       forwarded_foo      => {command => 'forwarded',
 145                              value   => 'foo@bar.com',
 146                              status_key => 'forwarded',
 147                              status_value => 'foo@bar.com',
 148                             },
 149       owner_foo          => {command => 'owner',
 150                              value   => 'foo@bar.com',
 151                              status_key => 'owner',
 152                              status_value => 'foo@bar.com',
 153                             },
 154       noowner      => {command => 'noowner',
 155                        value   => '',
 156                        status_key => 'owner',
 157                        status_value => '',
 158                       },
 159
 160      );
 161
 162 while (my ($command,$control_command) = splice(@control_commands,0,2)) {
 163      # just check to see that control doesn't explode
 164      $control_command->{value} = " $control_command->{value}" if length $control_command->{value}
 165           and $control_command->{value} !~ /^\s/;
 166      send_message(to => 'control@bugs.something',
 167                   headers => [To   => 'control@bugs.something',
 168                               From => 'foo@bugs.something',
 169                               Subject => "Munging a bug with $command",
 170                              ],
 171                   body => <<EOF) or fail 'message to control@bugs.something failed';
 172 $control_command->{command} 1$control_command->{value}
 173 thanks
 174 EOF
 175                                   ;
 176      $SD_SIZE_NOW = dirsize($sendmail_dir);
 177      ok($SD_SIZE_NOW-$SD_SIZE_PREV >= 1,'control@bugs.something messages appear to have been sent out properly');
 178      $SD_SIZE_PREV=$SD_SIZE_NOW;
 179      # now we need to check to make sure the control message was processed without errors
 180      ok(system('sh','-c','find '.$sendmail_dir.q( -type f | xargs grep -q "Subject: Processed: Munging a bug with $command")) == 0,
 181         'control@bugs.something'. "$command message was parsed without errors");
 182      # now we need to check to make sure that the control message actually did anything
 183      my $status = read_bug(bug=>1);
 184      is_deeply($status->{$control_command->{status_key}},$control_command->{status_value},"bug 1 $command")
 185           or fail(Dumper($status));
 186 }