scripts/service

   1 #!/usr/bin/perl
   2 # $Id: service.in,v 1.118 2005/10/19 01:22:14 don Exp $
   3 #
   4 # Usage: service <code>.nn
   5 # Temps:  incoming/P<code>.nn
   6
   7 use warnings;
   8 use strict;
   9
  10 use locale;
  11 use POSIX qw(strftime locale_h);
  12 setlocale(LC_TIME, "C");
  13
  14 use Debbugs::Config qw(:globals :config);
  15
  16 use File::Copy;
  17 use MIME::Parser;
  18
  19 use Params::Validate qw(:types validate_with);
  20
  21 use Debbugs::Common qw(:util :quit :misc :lock);
  22
  23 use Debbugs::Status qw(:read :status :write :versions :hook);
  24 use Debbugs::Packages qw(binary_to_source);
  25
  26 use Debbugs::MIME qw(decode_rfc1522 encode_rfc1522 create_mime_message);
  27 use Debbugs::Mail qw(send_mail_message);
  28 use Debbugs::User;
  29 use Debbugs::Recipients qw(:all);
  30 use HTML::Entities qw(encode_entities);
  31 use Debbugs::Versions::Dpkg;
  32
  33 use Debbugs::Status qw(splitpackages);
  34
  35 use Debbugs::CGI qw(html_escape);
  36 use Debbugs::Control qw(:all);
  37 use Debbugs::Control::Service qw(:all);
  38 use Debbugs::Log qw(:misc);
  39 use Debbugs::Text qw(:templates);
  40
  41 use Scalar::Util qw(looks_like_number);
  42
  43 use List::Util qw(first);
  44
  45 use Mail::RFC822::Address;
  46 use Encode qw(decode encode);
  47
  48 chdir($config{spool_dir}) or
  49      die "Unable to chdir to spool_dir '$config{spool_dir}': $!";
  50
  51 my $debug = 0;
  52 umask(002);
  53
  54 my ($nn,$control) = $ARGV[0] =~ m/^(([RC])\.\d+)$/;
  55 if (not defined $control or not defined $nn) {
  56      die "Bad argument to service.in";
  57 }
  58 if (!rename("incoming/G$nn","incoming/P$nn")) {
  59     defined $! and $! =~ m/no such file or directory/i and exit 0;
  60     die "Failed to rename incoming/G$nn to incoming/P$nn: $!";
  61 }
  62
  63 my $log_fh = IO::File->new("incoming/P$nn",'r') or
  64      die "Unable to open incoming/P$nn for reading: $!";
  65 my @log=<$log_fh>;
  66 my @msg=@log;
  67 close($log_fh);
  68
  69 chomp @msg;
  70
  71 print "###\n",join("##\n",@msg),"\n###\n" if $debug;
  72
  73 # Bug numbers to send e-mail to, hash so that we don't send to the
  74 # same bug twice.
  75 my (%bug_affected);
  76
  77 my (@headerlines,@bodylines);
  78
  79 my $parse_output = Debbugs::MIME::parse(join('',@log));
  80 @headerlines = @{$parse_output->{header}};
  81 @bodylines = @{$parse_output->{body}};
  82
  83 my %header;
  84 for (@headerlines) {
  85     $_ = decode_rfc1522($_);
  86     s/\n\s/ /g;
  87     print ">$_<\n" if $debug;
  88     if (s/^(\S+):\s*//) {
  89         my $v = lc $1;
  90         print ">$v=$_<\n" if $debug;
  91         $header{$v} = $_;
  92     } else {
  93         print "!>$_<\n" if $debug;
  94     }
  95 }
  96 $header{'message-id'} ||= '';
  97 $header{subject} ||= '';
  98
  99 grep(s/\s+$//,@bodylines);
 100
 101 print "***\n",join("\n",@bodylines),"\n***\n" if $debug;
 102
 103 if (defined $header{'resent-from'} && !defined $header{'from'}) {
 104     $header{'from'} = $header{'resent-from'};
 105 }
 106
 107 defined($header{'from'}) || die "no From header";
 108
 109 delete $header{'reply-to'}
 110         if ( defined($header{'reply-to'}) && $header{'reply-to'} =~ m/^\s*$/ );
 111
 112 my $replyto;
 113 if ( defined($header{'reply-to'}) && $header{'reply-to'} ne "" ) {
 114     $replyto = $header{'reply-to'};
 115 } else {
 116     $replyto = $header{'from'};
 117 }
 118
 119 # This is an error counter which should be incremented every time there is an error.
 120 my $errors = 0;
 121 my $controlrequestaddr= ($control ? 'control' : 'request').'@'.$config{email_domain};
 122 my $transcript_scalar = '';
 123 open my $transcript, ">:scalar:utf8", \$transcript_scalar or
 124      die "Unable to create transcript scalar: $!";
 125 print {$transcript} "Processing commands for $controlrequestaddr:\n\n";
 126
 127
 128 my $dl = 0;
 129 my %affected_packages;
 130 my %recipients;
 131 # this is the hashref which is passed to all control calls
 132 my %limit = ();
 133
 134
 135 my @common_control_options =
 136     (transcript        => $transcript,
 137      requester         => $header{from},
 138      request_addr      => $controlrequestaddr,
 139      request_msgid     => $header{'message-id'},
 140      request_subject   => $header{subject},
 141      request_nn        => $nn,
 142      request_replyto   => $replyto,
 143      message           => \@log,
 144      affected_bugs     => \%bug_affected,
 145      affected_packages => \%affected_packages,
 146      recipients        => \%recipients,
 147      limit             => \%limit,
 148     );
 149
 150 my $state= 'idle';
 151 my $lowstate= 'idle';
 152 my $mergelowstate= 'idle';
 153 my $midix=0;
 154
 155 my $user = $replyto;
 156 $user =~ s/,.*//;
 157 $user =~ s/^.*<(.*)>.*$/$1/;
 158 $user =~ s/[(].*[)]//;
 159 $user =~ s/^\s*(\S+)\s+.*$/$1/;
 160 $user = "" unless (Debbugs::User::is_valid_user($user));
 161 my $indicated_user = 0;
 162
 163 my $quickabort = 0;
 164
 165
 166 if (@gExcludeFromControl and grep {$replyto =~ m/\Q$_\E/} @gExcludeFromControl) {
 167         print {$transcript} fill_template('mail/excluded_from_control');
 168         $quickabort = 1;
 169 }
 170
 171 my %limit_pkgs = ();
 172 my %clonebugs = ();
 173 my %bcc = ();
 174
 175
 176 our $data;
 177 our $message;
 178 our $extramessage;
 179 our $ref;
 180
 181 our $mismatch;
 182 our $action;
 183
 184
 185 my $ok = 0;
 186 my $unknowns = 0;
 187 my $procline=0;
 188 for ($procline=0; $procline<=$#bodylines; $procline++) {
 189     my $noriginator;
 190     my $newsubmitter;
 191     my $oldsubmitter;
 192     my $newowner;
 193     $state eq 'idle' || print "state: $state ?\n";
 194     $lowstate eq 'idle' || print "lowstate: $lowstate ?\n";
 195     $mergelowstate eq 'idle' || print "mergelowstate: $mergelowstate ?\n";
 196     if ($quickabort) {
 197          print {$transcript} "Stopping processing here.\n\n";
 198          last;
 199     }
 200     $_= $bodylines[$procline]; s/\s+$//;
 201     # Remove BOM markers from UTF-8 strings
 202     # Fixes #488554
 203     s/\xef\xbb\xbf//g;
 204     next unless m/\S/;
 205     eval {
 206         my $temp = decode("utf8",$_,Encode::FB_CROAK);
 207         $_ = $temp;
 208     };
 209     print {$transcript} "> $_\n";
 210     next if m/^\s*\#/;
 211     $action= '';
 212     if (m/^(?:stop|quit|--|thank(?:s|\s*you)?|kthxbye)\.*\s*$/i) {
 213         print {$transcript} "Stopping processing here.\n\n";
 214         last;
 215     } elsif (m/^debug\s+(\d+)$/i && $1 >= 0 && $1 <= 1000) {
 216         $dl= $1+0;
 217         if ($dl > 0 and not grep /debug/,@common_control_options) {
 218             push @common_control_options,(debug => $transcript);
 219         }
 220         print {$transcript} "Debug level $dl.\n\n";
 221     } elsif (m/^(send|get)\s+\#?(\d{2,})$/i) {
 222         $ref= $2+0;
 223         &sendlynxdoc("bugreport.cgi?bug=$ref","logs for $gBug#$ref");
 224     } elsif (m/^send-detail\s+\#?(\d{2,})$/i) {
 225         $ref= $1+0;
 226         &sendlynxdoc("bugreport.cgi?bug=$ref&boring=yes",
 227                      "detailed logs for $gBug#$ref");
 228     } elsif (m/^index(\s+full)?$/i) {
 229         print {$transcript} "This BTS function is currently disabled, sorry.\n\n";
 230         $errors++;
 231         $ok++; # well, it's not really ok, but it fixes #81224 :)
 232     } elsif (m/^index-summary\s+by-package$/i) {
 233         print {$transcript} "This BTS function is currently disabled, sorry.\n\n";
 234         $errors++;
 235         $ok++; # well, it's not really ok, but it fixes #81224 :)
 236     } elsif (m/^index-summary(\s+by-number)?$/i) {
 237         print {$transcript} "This BTS function is currently disabled, sorry.\n\n";
 238         $errors++;
 239         $ok++; # well, it's not really ok, but it fixes #81224 :)
 240     } elsif (m/^index(\s+|-)pack(age)?s?$/i) {
 241         &sendlynxdoc("pkgindex.cgi?indexon=pkg",'index of packages');
 242     } elsif (m/^index(\s+|-)maints?$/i) {
 243         &sendlynxdoc("pkgindex.cgi?indexon=maint",'index of maintainers');
 244     } elsif (m/^index(\s+|-)maint\s+(\S+)$/i) {
 245         my $maint = $2;
 246         &sendlynxdoc("pkgreport.cgi?maint=" . urlsanit($maint),
 247                      "$gBug list for maintainer \`$maint'");
 248         $ok++;
 249     } elsif (m/^index(\s+|-)pack(age)?s?\s+(\S.*\S)$/i) {
 250         my $package = $+;
 251         &sendlynxdoc("pkgreport.cgi?pkg=" . urlsanit($package),
 252                      "$gBug list for package $package");
 253         $ok++;
 254     } elsif (m/^send-unmatched(\s+this|\s+-?0)?$/i) {
 255         print {$transcript} "This BTS function is currently disabled, sorry.\n\n";
 256         $errors++;
 257         $ok++; # well, it's not really ok, but it fixes #81224 :)
 258     } elsif (m/^send-unmatched\s+(last|-1)$/i) {
 259         print {$transcript} "This BTS function is currently disabled, sorry.\n\n";
 260         $errors++;
 261         $ok++; # well, it's not really ok, but it fixes #81224 :)
 262     } elsif (m/^send-unmatched\s+(old|-2)$/i) {
 263         print {$transcript} "This BTS function is currently disabled, sorry.\n\n";
 264         $errors++;
 265         $ok++; # well, it's not really ok, but it fixes #81224 :)
 266     } elsif (m/^getinfo\s+([\w.-]+)$/i) {
 267         # the following is basically a Debian-specific kludge, but who cares
 268         my $req = $1;
 269         if ($req =~ /^maintainers$/i && -f "$gConfigDir/Maintainers") {
 270             &sendinfo("local", "$gConfigDir/Maintainers", "Maintainers file");
 271         } elsif ($req =~ /^override\.(\w+)\.([\w.-]+)$/i) {
 272             $req =~ s/.gz$//;
 273             &sendinfo("ftp.d.o", "$req", "override file for $2 part of $1 distribution");
 274         } elsif ($req =~ /^pseudo-packages\.(description|maintainers)$/i && -f "$gConfigDir/$req") {
 275             &sendinfo("local", "$gConfigDir/$req", "$req file");
 276         } else {
 277             print {$transcript} "Info file $req does not exist.\n\n";
 278         }
 279     } elsif (m/^help/i) {
 280         &sendhelp;
 281         print {$transcript} "\n";
 282         $ok++;
 283     } elsif (m/^refcard/i) {
 284         &sendtxthelp("bug-mailserver-refcard.txt","mail servers' reference card");
 285     } elsif (m/^subscribe/i) {
 286         print {$transcript} <<END;
 287 There is no $gProject $gBug mailing list.  If you wish to review bug reports
 288 please do so via http://$gWebDomain/ or ask this mail server
 289 to send them to you.
 290 soon: MAILINGLISTS_TEXT
 291 END
 292     } elsif (m/^unsubscribe/i) {
 293         print {$transcript} <<END;
 294 soon: UNSUBSCRIBE_TEXT
 295 soon: MAILINGLISTS_TEXT
 296 END
 297     } elsif (m/^user\s+(\S+)\s*$/i) {
 298         my $newuser = $1;
 299         if (Debbugs::User::is_valid_user($newuser)) {
 300             my $olduser = ($user ne "" ? " (was $user)" : "");
 301             print {$transcript} "Setting user to $newuser$olduser.\n";
 302             $user = $newuser;
 303             $indicated_user = 1;
 304         } else {
 305             print {$transcript} "Selected user id ($newuser) invalid, sorry\n";
 306             $errors++;
 307             $user = "";
 308             $indicated_user = 1;
 309         }
 310     } elsif (m/^usercategory\s+(\S+)(\s+\[hidden\])?\s*$/i) {
 311         $ok++;
 312         my $catname = $1;
 313         my $hidden = (defined $2 and $2 ne "");
 314
 315         my $prefix = "";
 316         my @cats;
 317         my $bad = 0;
 318         my $catsec = 0;
 319         if ($user eq "") {
 320             print {$transcript} "No valid user selected\n";
 321             $errors++;
 322             next;
 323         }
 324         if (not $indicated_user and defined $user) {
 325              print {$transcript} "User is $user\n";
 326              $indicated_user = 1;
 327         }
 328         my @ords = ();
 329         while (++$procline <= $#bodylines) {
 330             unless ($bodylines[$procline] =~ m/^\s*([*+])\s*(\S.*)$/) {
 331                 $procline--;
 332                 last;
 333             }
 334             print {$transcript} "> $bodylines[$procline]\n";
 335             next if $bad;
 336             my ($o, $txt) = ($1, $2);
 337             if ($#cats == -1 && $o eq "+") {
 338                 print {$transcript} "User defined category specification must start with a category name. Skipping.\n\n";
 339                 $errors++;
 340                 $bad = 1;
 341                 next;
 342             }
 343             if ($o eq "+") {
 344                 unless (ref($cats[-1]) eq "HASH") {
 345                     $cats[-1] = { "nam" => $cats[-1],
 346                                   "pri" => [], "ttl" => [] };
 347                 }
 348                 $catsec++;
 349                 my ($desc, $ord, $op);
 350                 if ($txt =~ m/^(.*\S)\s*\[((\d+):\s*)?\]\s*$/) {
 351                     $desc = $1; $ord = $3; $op = "";
 352                 } elsif ($txt =~ m/^(.*\S)\s*\[((\d+):\s*)?(\S+)\]\s*$/) {
 353                     $desc = $1; $ord = $3; $op = $4;
 354                 } elsif ($txt =~ m/^([^[\s]+)\s*$/) {
 355                     $desc = ""; $op = $1;
 356                 } else {
 357                     print {$transcript} "Unrecognised syntax for category section. Skipping.\n\n";
 358                     $errors++;
 359                     $bad = 1;
 360                     next;
 361                 }
 362                 $ord = 999 unless defined $ord;
 363
 364                 if ($op) {
 365                     push @{$cats[-1]->{"pri"}}, $prefix . $op;
 366                     push @{$cats[-1]->{"ttl"}}, $desc;
 367                     push @ords, "$ord $catsec";
 368                 } else {
 369                     $cats[-1]->{"def"} = $desc;
 370                     push @ords, "$ord DEF";
 371                     $catsec--;
 372                 }
 373                 @ords = sort {
 374                     my ($a1, $a2, $b1, $b2) = split / /, "$a $b";
 375                     ((looks_like_number($a1) and looks_like_number($a2))?$a1 <=> $b1:$a1 cmp $b1) ||
 376                     ((looks_like_number($a2) and looks_like_number($b2))?$a2 <=> $b2:$a2 cmp $b2);
 377                 } @ords;
 378                 $cats[-1]->{"ord"} = [map { m/^.* (\S+)/; $1 eq "DEF" ? $catsec + 1 : $1 } @ords];
 379             } elsif ($o eq "*") {
 380                 $catsec = 0;
 381                 my ($name);
 382                 if ($txt =~ m/^(.*\S)(\s*\[(\S+)\])\s*$/) {
 383                     $name = $1; $prefix = $3;
 384                 } else {
 385                     $name = $txt; $prefix = "";
 386                 }
 387                 push @cats, $name;
 388             }
 389         }
 390         # XXX: got @cats, now do something with it
 391         my $u = Debbugs::User::get_user($user);
 392         if (@cats) {
 393             print {$transcript} "Added usercategory $catname.\n\n";
 394             $u->{"categories"}->{$catname} = [ @cats ];
 395             if (not $hidden) {
 396                  push @{$u->{visible_cats}},$catname;
 397             }
 398         } else {
 399             print {$transcript} "Removed usercategory $catname.\n\n";
 400             delete $u->{"categories"}->{$catname};
 401             @{$u->{visible_cats}} = grep {$_ ne $catname} @{$u->{visible_cats}};
 402         }
 403         $u->write();
 404     } elsif (m/^usertags?\s+\#?(-?\d+)\s+(([=+-])\s*)?(\S.*)?$/i) {
 405         $ok++;
 406         $ref = $1;
 407         my $addsubcode = $3 || "+";
 408         my $tags = $4;
 409         if ($ref =~ m/^-\d+$/ && defined $clonebugs{$ref}) {
 410              $ref = $clonebugs{$ref};
 411         }
 412         if ($user eq "") {
 413             print {$transcript} "No valid user selected\n";
 414             $errors++;
 415             $indicated_user = 1;
 416         } elsif (check_limit(data => read_bug(bug => $ref),
 417                              limit => \%limit,
 418                              transcript => $transcript)) {
 419             if (not $indicated_user and defined $user) {
 420                  print {$transcript} "User is $user\n";
 421                  $indicated_user = 1;
 422             }
 423             my %ut;
 424             Debbugs::User::read_usertags(\%ut, $user);
 425             my @oldtags = (); my @newtags = (); my @badtags = ();
 426             my %chtags;
 427             if (defined $tags and length $tags) {
 428                  for my $t (split /[,\s]+/, $tags) {
 429                       if ($t =~ m/^[a-zA-Z0-9.+\@-]+$/) {
 430                            $chtags{$t} = 1;
 431                       } else {
 432                            push @badtags, $t;
 433                       }
 434                  }
 435             }
 436             if (@badtags) {
 437                 print {$transcript} "Ignoring illegal tag/s: ".join(', ', @badtags).".\nPlease use only alphanumerics, at, dot, plus and dash.\n";
 438                 $errors++;
 439             }
 440             for my $t (keys %chtags) {
 441                 $ut{$t} = [] unless defined $ut{$t};
 442             }
 443             for my $t (keys %ut) {
 444                 my %res = map { ($_, 1) } @{$ut{$t}};
 445                 push @oldtags, $t if defined $res{$ref};
 446                 my $addop = ($addsubcode eq "+" or $addsubcode eq "=");
 447                 my $del = (defined $chtags{$t} ? $addsubcode eq "-"
 448                                                : $addsubcode eq "=");
 449                 $res{$ref} = 1 if ($addop && defined $chtags{$t});
 450                 delete $res{$ref} if ($del);
 451                 push @newtags, $t if defined $res{$ref};
 452                 $ut{$t} = [ sort { $a <=> $b } (keys %res) ];
 453             }
 454             if (@oldtags == 0) {
 455                 print {$transcript} "There were no usertags set.\n";
 456             } else {
 457                 print {$transcript} "Usertags were: " . join(" ", @oldtags) . ".\n";
 458             }
 459             print {$transcript} "Usertags are now: " . join(" ", @newtags) . ".\n";
 460             Debbugs::User::write_usertags(\%ut, $user);
 461         }
 462     } elsif (!$control) {
 463         print {$transcript} <<END;
 464 Unknown command or malformed arguments to command.
 465 (Use control\@$gEmailDomain to manipulate reports.)
 466
 467 END
 468         #### "developer only" ones start here
 469     } elsif (defined valid_control($_)) {
 470         my ($new_errors,$terminate_control) =
 471             control_line(line => $_,
 472                          clonebugs => \%clonebugs,
 473                          limit => \%limit,
 474                          common_control_options => \@common_control_options,
 475                          errors => \$errors,
 476                          transcript => $transcript,
 477                          debug => $debug,
 478                          ok => \$ok,
 479                          replyto => $replyto,
 480                         );
 481         if ($terminate_control) {
 482             last;
 483         }
 484     } else {
 485         $errors++;
 486         if (++$unknowns >= 5) {
 487             print {$transcript} "Too many unknown commands, stopping here.\n\n";
 488             last;
 489         }
 490     }
 491 }
 492 if ($procline>$#bodylines) {
 493     print {$transcript} ">\nEnd of message, stopping processing here.\n\n";
 494 }
 495 if (!$ok && !$quickabort) {
 496     $errors++;
 497     print {$transcript} "No commands successfully parsed; sending the help text(s).\n";
 498     &sendhelp;
 499     print {$transcript} "\n";
 500 }
 501
 502 my @maintccs = determine_recipients(recipients => \%recipients,
 503                                     address_only => 1,
 504                                     cc => 1,
 505                                    );
 506 if (!defined $header{'subject'} || $header{'subject'} eq "") {
 507   $header{'subject'} = "your mail";
 508 }
 509
 510 # Error text here advertises how many errors there were
 511 my $error_text = $errors > 0 ? " (with $errors errors)":'';
 512
 513 my @common_headers;
 514 push @common_headers, 'X-Loop',$gMaintainerEmail;
 515
 516 my $temp_transcript = $transcript_scalar;
 517 eval{
 518     $temp_transcript = decode("utf8",$temp_transcript,Encode::FB_CROAK);
 519 };
 520 my $reply =
 521     create_mime_message([From          => "$gMaintainerEmail ($gProject $gBug Tracking System)",
 522                          To            => $replyto,
 523                          @maintccs ? (Cc => join(', ',@maintccs)):(),
 524                          Subject       => "Processed${error_text}: $header{subject}",
 525                          'Message-ID'  => "<handler.s.$nn.transcript\@$gEmailDomain>",
 526                          'In-Reply-To' => $header{'message-id'},
 527                          References    => join(' ',grep {defined $_} $header{'message-id'},$data->{msgid}),
 528                          Precedence    => 'bulk',
 529                          keys %affected_packages ?("X-${gProject}-PR-Package" => join(' ',keys %affected_packages)):(),
 530                          keys %affected_packages ?("X-${gProject}-PR-Source" =>
 531                                                    join(' ',
 532                                                         map {defined $_ ?(ref($_)?@{$_}:$_):()}
 533                                                         binary_to_source(binary => [keys %affected_packages],
 534                                                                          source_only => 1))):(),
 535                          "X-$gProject-PR-Message" => 'transcript',
 536                          @common_headers,
 537                         ],
 538                         fill_template('mail/message_body',
 539                                       {body => "${temp_transcript}Please contact me if you need assistance."},
 540                                      ));
 541
 542 my $repliedshow= join(', ',$replyto,
 543                       determine_recipients(recipients => \%recipients,
 544                                            cc => 1,
 545                                            address_only => 1,
 546                                           )
 547                      );
 548
 549 utime(time,time,"db-h");
 550
 551 &sendmailmessage($reply,
 552                  exists $header{'x-debbugs-no-ack'}?():$replyto,
 553                  make_list(values %{{determine_recipients(recipients => \%recipients,
 554                                                           address_only => 1,
 555                                                          )}}
 556                           ),
 557                 );
 558
 559 unlink("incoming/P$nn") || die "unlinking incoming/P$nn: $!";
 560
 561 sub sendmailmessage {
 562     my ($message,@recips) = @_;
 563     $message = "X-Loop: $gMaintainerEmail\n" . $message;
 564     send_mail_message(message    => $message,
 565                       recipients => \@recips,
 566                      );
 567     $midix++;
 568 }
 569
 570 sub fill_template{
 571      my ($template,$extra_var) = @_;
 572      $extra_var ||={};
 573      my $variables = {config => \%config,
 574                       defined($ref)?(ref    => $ref):(),
 575                       defined($data)?(data  => $data):(),
 576                       refs => [map {exists $clonebugs{$_}?$clonebugs{$_}:$_} keys %bug_affected],
 577                       %{$extra_var},
 578                      };
 579      my $hole_var = {'&bugurl' =>
 580                      sub{"$_[0]: ".
 581                               'http://'.$config{cgi_domain}.'/'.
 582                                    Debbugs::CGI::bug_links(bug=>$_[0],
 583                                                            links_only => 1,
 584                                                           );
 585                     }
 586                     };
 587      return fill_in_template(template => $template,
 588                              variables => $variables,
 589                              hole_var  => $hole_var,
 590                             );
 591 }
 592
 593 =head2 message_body_template
 594
 595      message_body_template('mail/ack',{ref=>'foo'});
 596
 597 Creates a message body using a template
 598
 599 =cut
 600
 601 sub message_body_template{
 602      my ($template,$extra_var) = @_;
 603      $extra_var ||={};
 604      my $body = fill_template($template,$extra_var);
 605      return fill_template('mail/message_body',
 606                           {%{$extra_var},
 607                            body => $body,
 608                           },
 609                          );
 610 }
 611
 612 sub sendhelp {
 613      if ($control) {
 614           &sendtxthelpraw("bug-maint-mailcontrol.txt","instructions for control\@$gEmailDomain")
 615      }
 616      else {
 617           &sendtxthelpraw("bug-log-mailserver.txt","instructions for request\@$gEmailDomain");
 618      }
 619 }
 620
 621 #sub unimplemented {
 622 #    print {$transcript} "Sorry, command $_[0] not yet implemented.\n\n";
 623 #}
 624 our %checkmatch_values;
 625 sub checkmatch {
 626     my ($string,$mvarname,$svarvalue,@newmergelist) = @_;
 627     my ($mvarvalue);
 628     if (@newmergelist) {
 629         $mvarvalue = $checkmatch_values{$mvarname};
 630         print {$transcript} "D| checkmatch \`$string' /$mvarname/$mvarvalue/$svarvalue/\n"
 631             if $dl;
 632         $mismatch .=
 633             "Values for \`$string' don't match:\n".
 634             " #$newmergelist[0] has \`$mvarvalue';\n".
 635             " #$ref has \`$svarvalue'\n"
 636             if $mvarvalue ne $svarvalue;
 637     } else {
 638          print {$transcript} "D| setupmatch \`$string' /$mvarname/$svarvalue/\n"
 639               if $dl;
 640          $checkmatch_values{$mvarname} = $svarvalue;
 641     }
 642 }
 643
 644 sub checkpkglimit {
 645     if (keys %limit_pkgs and not defined $limit_pkgs{$data->{package}}) {
 646         print {$transcript} "$gBug number $ref belongs to package $data->{package}, skipping.\n\n";
 647         $errors++;
 648         return 0;
 649     }
 650     return 1;
 651 }
 652
 653 sub manipset {
 654     my $list = shift;
 655     my $elt = shift;
 656     my $add = shift;
 657
 658     my %h = map { $_ => 1 } split ' ', $list;
 659     if ($add) {
 660         $h{$elt}=1;
 661     }
 662     else {
 663         delete $h{$elt};
 664     }
 665     return join ' ', sort keys %h;
 666 }
 667
 668 # High-level bug manipulation calls
 669 # Do announcements themselves
 670 #
 671 # Possible calling sequences:
 672 #    setbug (returns 0)
 673 #
 674 #    setbug (returns 1)
 675 #    &transcript(something)
 676 #    nochangebug
 677 #
 678 #    setbug (returns 1)
 679 #    $action= (something)
 680 #    do {
 681 #      (modify s_* variables)
 682 #    } while (getnextbug);
 683
 684 our $manybugs;
 685
 686 sub nochangebug {
 687     &dlen("nochangebug");
 688     $state eq 'single' || $state eq 'multiple' || die "$state ?";
 689     &cancelbug;
 690     &endmerge if $manybugs;
 691     $state= 'idle';
 692     &dlex("nochangebug");
 693 }
 694
 695 our $sref;
 696 our @thisbugmergelist;
 697
 698 sub setbug {
 699     &dlen("setbug $ref");
 700     if ($ref =~ m/^-\d+/) {
 701         if (!defined $clonebugs{$ref}) {
 702             &notfoundbug;
 703             &dlex("setbug => noclone");
 704             return 0;
 705         }
 706         $ref = $clonebugs{$ref};
 707     }
 708     $state eq 'idle' || die "$state ?";
 709     if (!&getbug) {
 710         &notfoundbug;
 711         &dlex("setbug => 0s");
 712         return 0;
 713     }
 714
 715     if (!&checkpkglimit) {
 716         &cancelbug;
 717         return 0;
 718     }
 719
 720     @thisbugmergelist= split(/ /,$data->{mergedwith});
 721     if (!@thisbugmergelist) {
 722         &foundbug;
 723         $manybugs= 0;
 724         $state= 'single';
 725         $sref=$ref;
 726         &dlex("setbug => 1s");
 727         return 1;
 728     }
 729     &cancelbug;
 730     &getmerge;
 731     $manybugs= 1;
 732     if (!&getbug) {
 733         &notfoundbug;
 734         &endmerge;
 735         &dlex("setbug => 0mc");
 736         return 0;
 737     }
 738     &foundbug;
 739     $state= 'multiple'; $sref=$ref;
 740     &dlex("setbug => 1m");
 741     return 1;
 742 }
 743
 744 sub getnextbug {
 745     &dlen("getnextbug");
 746     $state eq 'single' || $state eq 'multiple' || die "$state ?";
 747     &savebug;
 748     if (!$manybugs || !@thisbugmergelist) {
 749         length($action) || die;
 750         print {$transcript} "$action\n$extramessage\n";
 751         &endmerge if $manybugs;
 752         $state= 'idle';
 753         &dlex("getnextbug => 0");
 754         return 0;
 755     }
 756     $ref= shift(@thisbugmergelist);
 757     &getbug || die "bug $ref disappeared";
 758     &foundbug;
 759     &dlex("getnextbug => 1");
 760     return 1;
 761 }
 762
 763 # Low-level bug-manipulation calls
 764 # Do no announcements
 765 #
 766 #    getbug (returns 0)
 767 #
 768 #    getbug (returns 1)
 769 #    cancelbug
 770 #
 771 #    getmerge
 772 #    $action= (something)
 773 #    getbug (returns 1)
 774 #    savebug/cancelbug
 775 #    getbug (returns 1)
 776 #    savebug/cancelbug
 777 #    [getbug (returns 0)]
 778 #    &transcript("$action\n\n")
 779 #    endmerge
 780
 781 sub notfoundbug { print {$transcript} "$gBug number $ref not found. (Is it archived?)\n\n"; }
 782 sub foundbug { print {$transcript} "$gBug#$ref: $data->{subject}\n"; }
 783
 784 sub getmerge {
 785     &dlen("getmerge");
 786     $mergelowstate eq 'idle' || die "$mergelowstate ?";
 787     &filelock('lock/merge');
 788     $mergelowstate='locked';
 789     &dlex("getmerge");
 790 }
 791
 792 sub endmerge {
 793     &dlen("endmerge");
 794     $mergelowstate eq 'locked' || die "$mergelowstate ?";
 795     &unfilelock;
 796     $mergelowstate='idle';
 797     &dlex("endmerge");
 798 }
 799
 800 sub getbug {
 801     &dlen("getbug $ref");
 802     $lowstate eq 'idle' || die "$state ?";
 803     # Only use unmerged bugs here
 804     if (($data = &lockreadbug($ref,'db-h'))) {
 805         $sref= $ref;
 806         $lowstate= "open";
 807         &dlex("getbug => 1");
 808         $extramessage='';
 809         return 1;
 810     }
 811     $lowstate= 'idle';
 812     &dlex("getbug => 0");
 813     return 0;
 814 }
 815
 816 sub cancelbug {
 817     &dlen("cancelbug");
 818     $lowstate eq 'open' || die "$state ?";
 819     &unfilelock;
 820     $lowstate= 'idle';
 821     &dlex("cancelbug");
 822 }
 823
 824 sub savebug {
 825     &dlen("savebug $ref");
 826     $lowstate eq 'open' || die "$lowstate ?";
 827     length($action) || die;
 828     $ref == $sref || die "read $sref but saving $ref ?";
 829     append_action_to_log(bug => $ref,
 830                          action => $action,
 831                          requester => $header{from},
 832                          request_addr => $controlrequestaddr,
 833                          message => \@log,
 834                          get_lock => 0,
 835                         );
 836     unlockwritebug($ref, $data);
 837     $lowstate= "idle";
 838     &dlex("savebug");
 839 }
 840
 841 sub dlen {
 842     return if !$dl;
 843     print {$transcript} "C> @_ ($state $lowstate $mergelowstate)\n";
 844 }
 845
 846 sub dlex {
 847     return if !$dl;
 848     print {$transcript} "R> @_ ($state $lowstate $mergelowstate)\n";
 849 }
 850
 851 sub urlsanit {
 852     my $url = shift;
 853     $url =~ s/%/%25/g;
 854     $url =~ s/\+/%2b/g;
 855     my %saniarray = ('<','lt', '>','gt', '&','amp', '"','quot');
 856     $url =~ s/([<>&"])/\&$saniarray{$1};/g;
 857     return $url;
 858 }
 859
 860 sub sendlynxdoc {
 861     &sendlynxdocraw;
 862     print {$transcript} "\n";
 863     $ok++;
 864 }
 865
 866 sub sendtxthelp {
 867     &sendtxthelpraw;
 868     print {$transcript} "\n";
 869     $ok++;
 870 }
 871
 872
 873 our $doc;
 874 sub sendtxthelpraw {
 875     my ($relpath,$description) = @_;
 876     $doc='';
 877     if (not -e "$gDocDir/$relpath") {
 878         print {$transcript} "Unfortunatly, the help text doesn't exist, so it wasn't sent.\n";
 879         warn "Help text $gDocDir/$relpath not found";
 880         return;
 881     }
 882     open(D,"$gDocDir/$relpath") || die "open doc file $relpath: $!";
 883     while(<D>) { $doc.=$_; }
 884     close(D);
 885     print {$transcript} "Sending $description in separate message.\n";
 886     &sendmailmessage(<<END.$doc,$replyto);
 887 From: $gMaintainerEmail ($gProject $gBug Tracking System)
 888 To: $replyto
 889 Subject: $gProject $gBug help: $description
 890 References: $header{'message-id'}
 891 In-Reply-To: $header{'message-id'}
 892 Message-ID: <handler.s.$nn.help.$midix\@$gEmailDomain>
 893 Precedence: bulk
 894 X-$gProject-PR-Message: doc-text $relpath
 895
 896 END
 897     $ok++;
 898 }
 899
 900 sub sendlynxdocraw {
 901     my ($relpath,$description) = @_;
 902     $doc='';
 903     open(L,"lynx -nolist -dump http://$gCGIDomain/\Q$relpath\E 2>&1 |") || die "fork for lynx: $!";
 904     while(<L>) { $doc.=$_; }
 905     $!=0; close(L);
 906     if ($? == 255 && $doc =~ m/^\n*lynx: Can\'t access start file/) {
 907         print {$transcript} "Information ($description) is not available -\n".
 908              "perhaps the $gBug does not exist or is not on the WWW yet.\n";
 909          $ok++;
 910     } elsif ($?) {
 911         print {$transcript} "Error getting $description (code $? $!):\n$doc\n";
 912     } else {
 913         print {$transcript} "Sending $description.\n";
 914         &sendmailmessage(<<END.$doc,$replyto);
 915 From: $gMaintainerEmail ($gProject $gBug Tracking System)
 916 To: $replyto
 917 Subject: $gProject $gBugs information: $description
 918 References: $header{'message-id'}
 919 In-Reply-To: $header{'message-id'}
 920 Message-ID: <handler.s.$nn.info.$midix\@$gEmailDomain>
 921 Precedence: bulk
 922 X-$gProject-PR-Message: doc-html $relpath
 923
 924 END
 925          $ok++;
 926     }
 927 }
 928
 929
 930 sub sendinfo {
 931     my ($wherefrom,$path,$description) = @_;
 932     if ($wherefrom eq "ftp.d.o") {
 933       $doc = `lynx -nolist -dump http://ftp.debian.org/debian/indices/$path.gz 2>&1 | gunzip -cf` or die "fork for lynx/gunzip: $!";
 934       $! = 0;
 935       if ($? == 255 && $doc =~ m/^\n*lynx: Can\'t access start file/) {
 936           print {$transcript} "$description is not available.\n";
 937           $ok++; return;
 938       } elsif ($?) {
 939           print {$transcript} "Error getting $description (code $? $!):\n$doc\n";
 940           return;
 941       }
 942     } elsif ($wherefrom eq "local") {
 943       open P, "$path";
 944       $doc = do { local $/; <P> };
 945       close P;
 946     } else {
 947       print {$transcript} "internal errror: info files location unknown.\n";
 948       $ok++; return;
 949     }
 950     print {$transcript} "Sending $description.\n";
 951     &sendmailmessage(<<END.$doc,$replyto);
 952 From: $gMaintainerEmail ($gProject $gBug Tracking System)
 953 To: $replyto
 954 Subject: $gProject $gBugs information: $description
 955 References: $header{'message-id'}
 956 In-Reply-To: $header{'message-id'}
 957 Message-ID: <handler.s.$nn.info.$midix\@$gEmailDomain>
 958 Precedence: bulk
 959 X-$gProject-PR-Message: getinfo
 960
 961 $description follows:
 962
 963 END
 964     $ok++;
 965     print {$transcript} "\n";
 966 }