cgi/pkgreport.cgi

   1 #!/usr/bin/perl -wT
   2 # This script is part of debbugs, and is released
   3 # under the terms of the GPL version 2, or any later
   4 # version at your option.
   5 # See the file README and COPYING for more information.
   6 #
   7 # [Other people have contributed to this file; their copyrights should
   8 # go here too.]
   9 # Copyright 2004-2006 by Anthony Towns <ajt@debian.org>
  10 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
  11
  12
  13 use warnings;
  14 use strict;
  15
  16 # Sanitize environent for taint
  17 BEGIN{
  18     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};
  19 }
  20
  21 binmode(STDOUT,':encoding(UTF-8)');
  22 use POSIX qw(strftime nice);
  23 use List::AllUtils qw(uniq);
  24
  25 use Debbugs::Config qw(:globals :text :config);
  26
  27 use Debbugs::User;
  28
  29 use Debbugs::Common qw(getparsedaddrs make_list getmaintainers getpseudodesc);
  30
  31 use Debbugs::Bugs qw(get_bugs bug_filter newest_bug);
  32 use Debbugs::Packages qw(getsrcpkgs getpkgsrc get_versions);
  33
  34 use Debbugs::Status qw(splitpackages);
  35
  36 use Debbugs::CGI qw(:all);
  37
  38 use Debbugs::CGI::Pkgreport qw(:all);
  39
  40 use Debbugs::Text qw(:templates);
  41
  42 use Debbugs::DB;
  43
  44 my $s;
  45 if (defined $config{database}) {
  46     $s = Debbugs::DB->connect($config{database}) or
  47         die "Unable to connect to DB";
  48 }
  49
  50 use CGI::Simple;
  51 my $q = new CGI::Simple;
  52
  53 if ($q->request_method() eq 'HEAD') {
  54      print $q->header(-type => "text/html",
  55                       -charset => 'utf-8',
  56                      );
  57      exit 0;
  58 }
  59
  60 my $default_params = {ordering => 'normal',
  61                       archive  => 0,
  62                       repeatmerged => 0,
  63                       include      => [],
  64                       exclude      => [],
  65                      };
  66
  67 our %param = cgi_parameters(query => $q,
  68                             single => [qw(ordering archive repeatmerged),
  69                                        qw(bug-rev pend-rev sev-rev),
  70                                        qw(maxdays mindays version),
  71                                        qw(data which dist newest),
  72                                        qw(noaffects),
  73                                       ],
  74                             default => $default_params,
  75                            );
  76
  77 my ($form_options,$param) = ({},undef);
  78 ($form_options,$param)= form_options_and_normal_param(\%param)
  79      if $param{form_options};
  80
  81 %param = %{$param} if defined $param;
  82
  83 if (exists $param{form_options} and defined $param{form_options}) {
  84      delete $param{form_options};
  85      delete $param{submit} if exists $param{submit};
  86      for my $default (keys %{$default_params}) {
  87           if (exists $param{$default} and
  88               not ref($default_params->{$default}) and
  89               $default_params->{$default} eq $param{$default}
  90              ) {
  91                delete $param{$default};
  92           }
  93      }
  94      for my $incexc (qw(include exclude)) {
  95           next unless exists $param{$incexc};
  96           # normalize tag to tags
  97           $param{$incexc} = [map {s/^tag:/tags:/; $_} grep /\S\:\S/, make_list($param{$incexc})];
  98      }
  99      for my $key (keys %package_search_keys) {
 100           next unless exists $param{key};
 101           $param{$key} = [map {split /\s*,\s*/} make_list($param{$key})];
 102      }
 103      # kill off keys for which empty values are meaningless
 104      for my $key (qw(package src submitter affects severity status dist)) {
 105           next unless exists $param{$key};
 106           $param{$key} = [grep {defined $_ and length $_}
 107                           make_list($param{$key})];
 108      }
 109      print $q->redirect(munge_url('pkgreport.cgi?',%param));
 110      exit 0;
 111 }
 112
 113 # normalize innclude/exclude keys; currently this is in two locations,
 114 # which is suboptimal. Closes: #567407
 115 for my $incexc (qw(include exclude)) {
 116     next unless exists $param{$incexc};
 117     # normalize tag to tags
 118     $param{$incexc} = [map {s/^tag:/tags:/; $_} make_list($param{$incexc})];
 119 }
 120
 121
 122
 123 # map from yes|no to 1|0
 124 for my $key (qw(repeatmerged bug-rev pend-rev sev-rev)) {
 125      if (exists $param{$key}){
 126           if ($param{$key} =~ /^no$/i) {
 127                $param{$key} = 0;
 128           }
 129           elsif ($param{$key}) {
 130                $param{$key} = 1;
 131           }
 132      }
 133 }
 134
 135 if (lc($param{archive}) eq 'no') {
 136      $param{archive} = 0;
 137 }
 138 elsif (lc($param{archive}) eq 'yes') {
 139      $param{archive} = 1;
 140 }
 141
 142 # fixup dist
 143 if (exists $param{dist} and $param{dist} eq '') {
 144      delete $param{dist};
 145 }
 146
 147 my $include = $param{'&include'} || $param{'include'} || "";
 148 my $exclude = $param{'&exclude'} || $param{'exclude'} || "";
 149
 150 my $users = $param{'users'} || "";
 151
 152 my $ordering = $param{'ordering'};
 153 my $raw_sort = ($param{'raw'} || "no") eq "yes";
 154 my $old_view = ($param{'oldview'} || "no") eq "yes";
 155 my $age_sort = ($param{'age'} || "no") eq "yes";
 156 unless (defined $ordering) {
 157    $ordering = "normal";
 158    $ordering = "oldview" if $old_view;
 159    $ordering = "raw" if $raw_sort;
 160    $ordering = 'age' if $age_sort;
 161 }
 162 $param{ordering} = $ordering;
 163
 164 our ($bug_order) = $ordering =~ /(age(?:rev)?)/;
 165 $bug_order = '' if not defined $bug_order;
 166
 167 my $bug_rev = ($param{'bug-rev'} || "no") eq "yes";
 168 my $pend_rev = ($param{'pend-rev'} || "no") eq "yes";
 169 my $sev_rev = ($param{'sev-rev'} || "no") eq "yes";
 170
 171 my @inc_exc_mapping = ({name   => 'pending',
 172                         incexc => 'include',
 173                         key    => 'pend-inc',
 174                        },
 175                        {name   => 'pending',
 176                         incexc => 'exclude',
 177                         key    => 'pend-exc',
 178                        },
 179                        {name   => 'severity',
 180                         incexc => 'include',
 181                         key    => 'sev-inc',
 182                        },
 183                        {name   => 'severity',
 184                         incexc => 'exclude',
 185                         key    => 'sev-exc',
 186                        },
 187                        {name   => 'subject',
 188                         incexc => 'include',
 189                         key    => 'includesubj',
 190                        },
 191                        {name   => 'subject',
 192                         incexc => 'exclude',
 193                         key    => 'excludesubj',
 194                        },
 195                       );
 196 for my $incexcmap (@inc_exc_mapping) {
 197      push @{$param{$incexcmap->{incexc}}}, map {"$incexcmap->{name}:$_"}
 198           map{split /\s*,\s*/} make_list($param{$incexcmap->{key}})
 199                if exists $param{$incexcmap->{key}};
 200      delete $param{$incexcmap->{key}};
 201 }
 202
 203
 204 my $maxdays = ($param{'maxdays'} || -1);
 205 my $mindays = ($param{'mindays'} || 0);
 206 my $version = $param{'version'} || undef;
 207
 208
 209 our %hidden = map { $_, 1 } qw(status severity classification);
 210 our %cats = (
 211     "status" => [ {
 212         "nam" => "Status",
 213         "pri" => [map { "pending=$_" }
 214             qw(pending forwarded pending-fixed fixed done absent)],
 215         "ttl" => ["Outstanding","Forwarded","Pending Upload",
 216                   "Fixed in NMU","Resolved","From other Branch"],
 217         "def" => "Unknown Pending Status",
 218         "ord" => [0,1,2,3,4,5,6],
 219     } ],
 220     "severity" => [ {
 221         "nam" => "Severity",
 222         "pri" => [map { "severity=$_" } @gSeverityList],
 223         "ttl" => [map { $gSeverityDisplay{$_} } @gSeverityList],
 224         "def" => "Unknown Severity",
 225         "ord" => [0..@gSeverityList],
 226     } ],
 227     "classification" => [ {
 228         "nam" => "Classification",
 229         "pri" => [qw(pending=pending+tag=wontfix
 230                      pending=pending+tag=moreinfo
 231                      pending=pending+tag=patch
 232                      pending=pending+tag=confirmed
 233                      pending=pending)],
 234         "ttl" => ["Will Not Fix","More information needed",
 235                   "Patch Available","Confirmed"],
 236         "def" => "Unclassified",
 237         "ord" => [2,3,4,1,0,5],
 238     } ],
 239     "oldview" => [ qw(status severity) ],
 240              "normal" => [ qw(status severity classification) ],
 241              raw => [{nam => 'Raw',def => 'Raw'}],
 242 );
 243
 244 if (exists $param{which} and exists $param{data}) {
 245      $param{$param{which}} = [exists $param{$param{which}}?(make_list($param{$param{which}})):(),
 246                               make_list($param{data}),
 247                              ];
 248      delete $param{which};
 249      delete $param{data};
 250 }
 251
 252 if (defined $param{maintenc}) {
 253      $param{maint} = maint_decode($param{maintenc});
 254      delete $param{maintenc}
 255 }
 256
 257 if (exists $param{pkg}) {
 258      $param{package} = $param{pkg};
 259      delete $param{pkg};
 260 }
 261
 262 if (not grep {exists $param{$_}} keys %package_search_keys and exists $param{users}) {
 263      $param{usertag} = [make_list($param{users})];
 264 }
 265
 266 my %bugusertags;
 267 my %ut;
 268 my %seen_users;
 269
 270 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
 271     next unless length($user);
 272     add_user($user,\%ut,\%bugusertags,\%seen_users,\%cats,\%hidden);
 273 }
 274
 275 if (defined $param{usertag}) {
 276      for my $usertag (make_list($param{usertag})) {
 277           my %select_ut = ();
 278           my ($u, $t) = split /:/, $usertag, 2;
 279           Debbugs::User::read_usertags(\%select_ut, $u);
 280           unless (defined $t && $t ne "") {
 281                $t = join(",", keys(%select_ut));
 282           }
 283           add_user($u,\%ut,\%bugusertags,\%seen_users,\%cats,\%hidden);
 284           push @{$param{tag}}, split /,/, $t;
 285      }
 286 }
 287
 288 quitcgi("You have to choose something to select by", '400 Bad Request')
 289   unless grep {exists $param{$_}} keys %package_search_keys;
 290
 291
 292 my $Archived = $param{archive} ? " Archived" : "";
 293
 294 my $this = munge_url('pkgreport.cgi?',
 295                       %param,
 296                      );
 297
 298 my %indexentry;
 299 my %strings = ();
 300
 301 my @bugs;
 302
 303 # addusers for source and binary packages being searched for
 304 my $pkgsrc = getpkgsrc();
 305 my $srcpkg = getsrcpkgs();
 306 for my $package (# For binary packages, add the binary package
 307                  # and corresponding source package
 308                  make_list($param{package}||[]),
 309                  (map {defined $pkgsrc->{$_}?($pkgsrc->{$_}):()}
 310                   make_list($param{package}||[]),
 311                  ),
 312                  # For source packages, add the source package
 313                  # and corresponding binary packages
 314                  make_list($param{src}||[]),
 315                  (map {defined $srcpkg->{$_}?($srcpkg->{$_}):()}
 316                   make_list($param{src}||[]),
 317                  ),
 318                 ) {
 319      next unless defined $package;
 320      add_user($package.'@'.$config{usertag_package_domain},
 321               \%ut,\%bugusertags,\%seen_users,\%cats,\%hidden)
 322           if defined $config{usertag_package_domain};
 323 }
 324
 325
 326 # walk through the keys and make the right get_bugs query.
 327
 328 my $form_option_variables = {};
 329 $form_option_variables->{search_key_order} = [@package_search_key_order];
 330
 331 # Set the title sanely and clean up parameters
 332 my @title;
 333 my @temp = @package_search_key_order;
 334 while (my ($key,$value) = splice @temp, 0, 2) {
 335      next unless exists $param{$key};
 336      my @entries = ();
 337      for my $entry (make_list($param{$key})) {
 338           # we'll handle newest below
 339           next if $key eq 'newest';
 340           my $extra = '';
 341           if (exists $param{dist} and ($key eq 'package' or $key eq 'src')) {
 342                my %versions = get_versions(package => $entry,
 343                                            (exists $param{dist}?(dist => $param{dist}):()),
 344                                            (exists $param{arch}?(arch => $param{arch}):(arch => $config{default_architectures})),
 345                                            ($key eq 'src'?(arch => q(source)):()),
 346                                            no_source_arch => 1,
 347                                            return_archs => 1,
 348                                           );
 349                my $verdesc;
 350                if (keys %versions > 1) {
 351                     $verdesc = 'versions '. join(', ',
 352                                     map { $_ .' ['.join(', ',
 353                                                     sort @{$versions{$_}}
 354                                                    ).']';
 355                                    } keys %versions);
 356                }
 357                else {
 358                     $verdesc = 'version '.join(', ',
 359                                                keys %versions
 360                                               );
 361                }
 362                $extra= " ($verdesc)" if keys %versions;
 363           }
 364           if ($key eq 'maint' and $entry eq '') {
 365                push @entries, "no one (packages without maintainers)"
 366           }
 367           else {
 368                push @entries, $entry.$extra;
 369           }
 370      }
 371      push @title,$value.' '.join(' or ', @entries) if @entries;
 372 }
 373 if (defined $param{newest}) {
 374      my $newest_bug = newest_bug();
 375      @bugs = ($newest_bug - $param{newest} + 1) .. $newest_bug;
 376      push @title, 'in '.@bugs.' newest reports';
 377      $param{bugs} = [exists $param{bugs}?make_list($param{bugs}):(),
 378                      @bugs,
 379                     ];
 380 }
 381
 382 my $title = $gBugs.' '.join(' and ', map {/ or /?"($_)":$_} @title);
 383 @title = ();
 384
 385 #yeah for magick!
 386 @bugs = get_bugs((map {exists $param{$_}?($_,$param{$_}):()}
 387                   grep {$_ ne 'newest'}
 388                   keys %package_search_keys, 'archive'),
 389                  usertags => \%ut,
 390                  defined $s?(schema => $s):(),
 391                 );
 392
 393 # shove in bugs which affect this package if there is a package or a
 394 # source given (by default), but no affects options given
 395 if (not exists $param{affects} and not exists $param{noaffects} and
 396     (exists $param{src} or
 397      exists $param{package})) {
 398     push @bugs, get_bugs((map {my $key = $_;
 399                                exists $param{$key}?($key =~ /^(?:package|src)$/?'affects':$key,
 400                                                   ($key eq 'src'?[map {"src:$_"}make_list($param{$key})]:$param{$_})):()}
 401                           grep {$_ ne 'newest'}
 402                           keys %package_search_keys, 'archive'),
 403                          usertags => \%ut,
 404                          defined $s?(schema => $s):(),
 405                         );
 406 }
 407
 408 # filter out included or excluded bugs
 409
 410
 411 if (defined $param{version}) {
 412      $title .= " at version $param{version}";
 413 }
 414 elsif (defined $param{dist}) {
 415      $title .= " in $param{dist}";
 416 }
 417
 418 $title = html_escape($title);
 419
 420 my @names; my @prior; my @order;
 421 determine_ordering(cats => \%cats,
 422                    param => \%param,
 423                    ordering => \$ordering,
 424                    names => \@names,
 425                    prior => \@prior,
 426                    title => \@title,
 427                    order => \@order,
 428                   );
 429
 430 # strip out duplicate bugs
 431 my %bugs;
 432 @bugs{@bugs} = @bugs;
 433 @bugs = keys %bugs;
 434
 435 my $result = pkg_htmlizebugs(bugs => \@bugs,
 436                              names => \@names,
 437                              title => \@title,
 438                              order => \@order,
 439                              prior => \@prior,
 440                              ordering => $ordering,
 441                              bugusertags => \%bugusertags,
 442                              bug_rev => $bug_rev,
 443                              bug_order => $bug_order,
 444                              repeatmerged => $param{repeatmerged},
 445                              include => $include,
 446                              exclude => $exclude,
 447                              this => $this,
 448                              options => \%param,
 449                              defined $s?(schema => $s):(),
 450                              (exists $param{dist})?(dist    => $param{dist}):(),
 451                             );
 452
 453 print "Cache-Control: public, max-age=300\n";
 454 print "Content-Type: text/html; charset=utf-8\n\n";
 455
 456 print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01 Transitional//EN\">\n";
 457 print "<HTML><HEAD>\n" .
 458     "<TITLE>$title -- $gProject$Archived $gBug report logs</TITLE>\n" .
 459     qq(<link rel="stylesheet" href="$gWebHostBugDir/css/bugs.css" type="text/css">) .
 460     "</HEAD>\n" .
 461     '<BODY onload="pagemain();">' .
 462     "\n";
 463 print qq(<DIV id="status_mask"></DIV>\n);
 464 print "<H1>" . "$gProject$Archived $gBug report logs: $title" .
 465       "</H1>\n";
 466
 467 my $showresult = 1;
 468
 469 my $pkg = $param{package} if defined $param{package};
 470 my $src = $param{src} if defined $param{src};
 471
 472 my $pseudodesc = getpseudodesc();
 473 if (defined $pseudodesc and defined $pkg and exists $pseudodesc->{$pkg}) {
 474      delete $param{dist};
 475 }
 476
 477 # output information about the packages
 478
 479 for my $package (make_list($param{package}||[])) {
 480      print generate_package_info(binary => 1,
 481                                  package => $package,
 482                                  options => \%param,
 483                                  bugs    => \@bugs,
 484                                 );
 485 }
 486 for my $package (make_list($param{src}||[])) {
 487      print generate_package_info(binary => 0,
 488                                  package => $package,
 489                                  options => \%param,
 490                                  bugs    => \@bugs,
 491                                 );
 492 }
 493
 494 if (exists $param{maint} or exists $param{maintenc}) {
 495     print "<p>Note that maintainers may use different Maintainer fields for\n";
 496     print "different packages, so there may be other reports filed under\n";
 497     print "different addresses.\n";
 498 }
 499 if (exists $param{submitter}) {
 500     print "<p>Note that people may use different email accounts for\n";
 501     print "different bugs, so there may be other reports filed under\n";
 502     print "different addresses.\n";
 503 }
 504
 505 print $result;
 506
 507 print fill_in_template(template=>'cgi/pkgreport_javascript');
 508
 509 print qq(<h2 class="outstanding"><!--<a class="options" href="javascript:toggle(1)">-->Options<!--</a>--></h2>\n);
 510
 511 $param{orderings} =
 512     [uniq((grep {!$hidden{$_}} keys %cats),
 513           $param{ordering})];
 514 print option_form(template => 'cgi/pkgreport_options',
 515                   param    => \%param,
 516                   form_options => $form_options,
 517                   variables => $form_option_variables,
 518                  );
 519
 520 print "<hr>\n";
 521 print fill_in_template(template=>'html/html_tail',
 522                        hole_var => {'&strftime' => \&POSIX::strftime,
 523                                    },
 524                       );
 525 print "</body></html>\n";
 526