cgi/pkgreport.cgi

   1 #!/usr/bin/perl -wT
   2 # This script is part of debbugs, and is released
   3 # under the terms of the GPL version 2, or any later
   4 # version at your option.
   5 # See the file README and COPYING for more information.
   6 #
   7 # [Other people have contributed to this file; their copyrights should
   8 # go here too.]
   9 # Copyright 2004-2006 by Anthony Towns <ajt@debian.org>
  10 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
  11
  12
  13 use warnings;
  14 use strict;
  15
  16 # Sanitize environent for taint
  17 BEGIN{
  18     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};
  19 }
  20
  21 binmode(STDOUT,':encoding(UTF-8)');
  22 use POSIX qw(strftime nice);
  23 use List::AllUtils qw(uniq);
  24
  25 use Debbugs::Config qw(:globals :text :config);
  26
  27 use Debbugs::User;
  28
  29 use Debbugs::Common qw(getparsedaddrs make_list getmaintainers getpseudodesc);
  30
  31 use Debbugs::Bugs qw(get_bugs bug_filter newest_bug);
  32 use Debbugs::Packages qw(getsrcpkgs getpkgsrc get_versions);
  33
  34 use Debbugs::Status qw(splitpackages);
  35
  36 use Debbugs::CGI qw(:all);
  37
  38 use Debbugs::CGI::Pkgreport qw(:all);
  39
  40 use Debbugs::Text qw(:templates);
  41
  42 use CGI::Simple;
  43 my $q = new CGI::Simple;
  44
  45 if ($q->request_method() eq 'HEAD') {
  46      print $q->header(-type => "text/html",
  47                       -charset => 'utf-8',
  48                      );
  49      exit 0;
  50 }
  51
  52 my $default_params = {ordering => 'normal',
  53                       archive  => 0,
  54                       repeatmerged => 0,
  55                       include      => [],
  56                       exclude      => [],
  57                      };
  58
  59 our %param = cgi_parameters(query => $q,
  60                             single => [qw(ordering archive repeatmerged),
  61                                        qw(bug-rev pend-rev sev-rev),
  62                                        qw(maxdays mindays version),
  63                                        qw(data which dist newest),
  64                                        qw(noaffects),
  65                                       ],
  66                             default => $default_params,
  67                            );
  68
  69 my ($form_options,$param) = ({},undef);
  70 ($form_options,$param)= form_options_and_normal_param(\%param)
  71      if $param{form_options};
  72
  73 %param = %{$param} if defined $param;
  74
  75 if (exists $param{form_options} and defined $param{form_options}) {
  76      delete $param{form_options};
  77      delete $param{submit} if exists $param{submit};
  78      for my $default (keys %{$default_params}) {
  79           if (exists $param{$default} and
  80               not ref($default_params->{$default}) and
  81               $default_params->{$default} eq $param{$default}
  82              ) {
  83                delete $param{$default};
  84           }
  85      }
  86      for my $incexc (qw(include exclude)) {
  87           next unless exists $param{$incexc};
  88           # normalize tag to tags
  89           $param{$incexc} = [map {s/^tag:/tags:/; $_} grep /\S\:\S/, make_list($param{$incexc})];
  90      }
  91      for my $key (keys %package_search_keys) {
  92           next unless exists $param{key};
  93           $param{$key} = [map {split /\s*,\s*/} make_list($param{$key})];
  94      }
  95      # kill off keys for which empty values are meaningless
  96      for my $key (qw(package src submitter affects severity status dist)) {
  97           next unless exists $param{$key};
  98           $param{$key} = [grep {defined $_ and length $_}
  99                           make_list($param{$key})];
 100      }
 101      print $q->redirect(munge_url('pkgreport.cgi?',%param));
 102      exit 0;
 103 }
 104
 105 # normalize innclude/exclude keys; currently this is in two locations,
 106 # which is suboptimal. Closes: #567407
 107 for my $incexc (qw(include exclude)) {
 108     next unless exists $param{$incexc};
 109     # normalize tag to tags
 110     $param{$incexc} = [map {s/^tag:/tags:/; $_} make_list($param{$incexc})];
 111 }
 112
 113
 114
 115 # map from yes|no to 1|0
 116 for my $key (qw(repeatmerged bug-rev pend-rev sev-rev)) {
 117      if (exists $param{$key}){
 118           if ($param{$key} =~ /^no$/i) {
 119                $param{$key} = 0;
 120           }
 121           elsif ($param{$key}) {
 122                $param{$key} = 1;
 123           }
 124      }
 125 }
 126
 127 if (lc($param{archive}) eq 'no') {
 128      $param{archive} = 0;
 129 }
 130 elsif (lc($param{archive}) eq 'yes') {
 131      $param{archive} = 1;
 132 }
 133
 134 # fixup dist
 135 if (exists $param{dist} and $param{dist} eq '') {
 136      delete $param{dist};
 137 }
 138
 139 my $include = $param{'&include'} || $param{'include'} || "";
 140 my $exclude = $param{'&exclude'} || $param{'exclude'} || "";
 141
 142 my $users = $param{'users'} || "";
 143
 144 my $ordering = $param{'ordering'};
 145 my $raw_sort = ($param{'raw'} || "no") eq "yes";
 146 my $old_view = ($param{'oldview'} || "no") eq "yes";
 147 my $age_sort = ($param{'age'} || "no") eq "yes";
 148 unless (defined $ordering) {
 149    $ordering = "normal";
 150    $ordering = "oldview" if $old_view;
 151    $ordering = "raw" if $raw_sort;
 152    $ordering = 'age' if $age_sort;
 153 }
 154 $param{ordering} = $ordering;
 155
 156 our ($bug_order) = $ordering =~ /(age(?:rev)?)/;
 157 $bug_order = '' if not defined $bug_order;
 158
 159 my $bug_rev = ($param{'bug-rev'} || "no") eq "yes";
 160 my $pend_rev = ($param{'pend-rev'} || "no") eq "yes";
 161 my $sev_rev = ($param{'sev-rev'} || "no") eq "yes";
 162
 163 my @inc_exc_mapping = ({name   => 'pending',
 164                         incexc => 'include',
 165                         key    => 'pend-inc',
 166                        },
 167                        {name   => 'pending',
 168                         incexc => 'exclude',
 169                         key    => 'pend-exc',
 170                        },
 171                        {name   => 'severity',
 172                         incexc => 'include',
 173                         key    => 'sev-inc',
 174                        },
 175                        {name   => 'severity',
 176                         incexc => 'exclude',
 177                         key    => 'sev-exc',
 178                        },
 179                        {name   => 'subject',
 180                         incexc => 'include',
 181                         key    => 'includesubj',
 182                        },
 183                        {name   => 'subject',
 184                         incexc => 'exclude',
 185                         key    => 'excludesubj',
 186                        },
 187                       );
 188 for my $incexcmap (@inc_exc_mapping) {
 189      push @{$param{$incexcmap->{incexc}}}, map {"$incexcmap->{name}:$_"}
 190           map{split /\s*,\s*/} make_list($param{$incexcmap->{key}})
 191                if exists $param{$incexcmap->{key}};
 192      delete $param{$incexcmap->{key}};
 193 }
 194
 195
 196 my $maxdays = ($param{'maxdays'} || -1);
 197 my $mindays = ($param{'mindays'} || 0);
 198 my $version = $param{'version'} || undef;
 199
 200
 201 our %hidden = map { $_, 1 } qw(status severity classification);
 202 our %cats = (
 203     "status" => [ {
 204         "nam" => "Status",
 205         "pri" => [map { "pending=$_" }
 206             qw(pending forwarded pending-fixed fixed done absent)],
 207         "ttl" => ["Outstanding","Forwarded","Pending Upload",
 208                   "Fixed in NMU","Resolved","From other Branch"],
 209         "def" => "Unknown Pending Status",
 210         "ord" => [0,1,2,3,4,5,6],
 211     } ],
 212     "severity" => [ {
 213         "nam" => "Severity",
 214         "pri" => [map { "severity=$_" } @gSeverityList],
 215         "ttl" => [map { $gSeverityDisplay{$_} } @gSeverityList],
 216         "def" => "Unknown Severity",
 217         "ord" => [0..@gSeverityList],
 218     } ],
 219     "classification" => [ {
 220         "nam" => "Classification",
 221         "pri" => [qw(pending=pending+tag=wontfix
 222                      pending=pending+tag=moreinfo
 223                      pending=pending+tag=patch
 224                      pending=pending+tag=confirmed
 225                      pending=pending)],
 226         "ttl" => ["Will Not Fix","More information needed",
 227                   "Patch Available","Confirmed"],
 228         "def" => "Unclassified",
 229         "ord" => [2,3,4,1,0,5],
 230     } ],
 231     "oldview" => [ qw(status severity) ],
 232              "normal" => [ qw(status severity classification) ],
 233              raw => [{nam => 'Raw',def => 'Raw'}],
 234 );
 235
 236 if (exists $param{which} and exists $param{data}) {
 237      $param{$param{which}} = [exists $param{$param{which}}?(make_list($param{$param{which}})):(),
 238                               make_list($param{data}),
 239                              ];
 240      delete $param{which};
 241      delete $param{data};
 242 }
 243
 244 if (defined $param{maintenc}) {
 245      $param{maint} = maint_decode($param{maintenc});
 246      delete $param{maintenc}
 247 }
 248
 249 if (exists $param{pkg}) {
 250      $param{package} = $param{pkg};
 251      delete $param{pkg};
 252 }
 253
 254 if (not grep {exists $param{$_}} keys %package_search_keys and exists $param{users}) {
 255      $param{usertag} = [make_list($param{users})];
 256 }
 257
 258 my %bugusertags;
 259 my %ut;
 260 my %seen_users;
 261
 262 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
 263     next unless length($user);
 264     add_user($user,\%ut,\%bugusertags,\%seen_users,\%cats,\%hidden);
 265 }
 266
 267 if (defined $param{usertag}) {
 268      for my $usertag (make_list($param{usertag})) {
 269           my %select_ut = ();
 270           my ($u, $t) = split /:/, $usertag, 2;
 271           Debbugs::User::read_usertags(\%select_ut, $u);
 272           unless (defined $t && $t ne "") {
 273                $t = join(",", keys(%select_ut));
 274           }
 275           add_user($u,\%ut,\%bugusertags,\%seen_users,\%cats,\%hidden);
 276           push @{$param{tag}}, split /,/, $t;
 277      }
 278 }
 279
 280 quitcgi("You have to choose something to select by", '400 Bad Request')
 281   unless grep {exists $param{$_}} keys %package_search_keys;
 282
 283
 284 my $Archived = $param{archive} ? " Archived" : "";
 285
 286 my $this = munge_url('pkgreport.cgi?',
 287                       %param,
 288                      );
 289
 290 my %indexentry;
 291 my %strings = ();
 292
 293 my @bugs;
 294
 295 # addusers for source and binary packages being searched for
 296 my $pkgsrc = getpkgsrc();
 297 my $srcpkg = getsrcpkgs();
 298 for my $package (# For binary packages, add the binary package
 299                  # and corresponding source package
 300                  make_list($param{package}||[]),
 301                  (map {defined $pkgsrc->{$_}?($pkgsrc->{$_}):()}
 302                   make_list($param{package}||[]),
 303                  ),
 304                  # For source packages, add the source package
 305                  # and corresponding binary packages
 306                  make_list($param{src}||[]),
 307                  (map {defined $srcpkg->{$_}?($srcpkg->{$_}):()}
 308                   make_list($param{src}||[]),
 309                  ),
 310                 ) {
 311      next unless defined $package;
 312      add_user($package.'@'.$config{usertag_package_domain},
 313               \%ut,\%bugusertags,\%seen_users,\%cats,\%hidden)
 314           if defined $config{usertag_package_domain};
 315 }
 316
 317
 318 # walk through the keys and make the right get_bugs query.
 319
 320 my $form_option_variables = {};
 321 $form_option_variables->{search_key_order} = [@package_search_key_order];
 322
 323 # Set the title sanely and clean up parameters
 324 my @title;
 325 my @temp = @package_search_key_order;
 326 while (my ($key,$value) = splice @temp, 0, 2) {
 327      next unless exists $param{$key};
 328      my @entries = ();
 329      for my $entry (make_list($param{$key})) {
 330           # we'll handle newest below
 331           next if $key eq 'newest';
 332           my $extra = '';
 333           if (exists $param{dist} and ($key eq 'package' or $key eq 'src')) {
 334                my %versions = get_versions(package => $entry,
 335                                            (exists $param{dist}?(dist => $param{dist}):()),
 336                                            (exists $param{arch}?(arch => $param{arch}):(arch => $config{default_architectures})),
 337                                            ($key eq 'src'?(arch => q(source)):()),
 338                                            no_source_arch => 1,
 339                                            return_archs => 1,
 340                                           );
 341                my $verdesc;
 342                if (keys %versions > 1) {
 343                     $verdesc = 'versions '. join(', ',
 344                                     map { $_ .' ['.join(', ',
 345                                                     sort @{$versions{$_}}
 346                                                    ).']';
 347                                    } keys %versions);
 348                }
 349                else {
 350                     $verdesc = 'version '.join(', ',
 351                                                keys %versions
 352                                               );
 353                }
 354                $extra= " ($verdesc)" if keys %versions;
 355           }
 356           if ($key eq 'maint' and $entry eq '') {
 357                push @entries, "no one (packages without maintainers)"
 358           }
 359           else {
 360                push @entries, $entry.$extra;
 361           }
 362      }
 363      push @title,$value.' '.join(' or ', @entries) if @entries;
 364 }
 365 if (defined $param{newest}) {
 366      my $newest_bug = newest_bug();
 367      @bugs = ($newest_bug - $param{newest} + 1) .. $newest_bug;
 368      push @title, 'in '.@bugs.' newest reports';
 369      $param{bugs} = [exists $param{bugs}?make_list($param{bugs}):(),
 370                      @bugs,
 371                     ];
 372 }
 373
 374 my $title = $gBugs.' '.join(' and ', map {/ or /?"($_)":$_} @title);
 375 @title = ();
 376
 377 #yeah for magick!
 378 @bugs = get_bugs((map {exists $param{$_}?($_,$param{$_}):()}
 379                   grep {$_ ne 'newest'}
 380                   keys %package_search_keys, 'archive'),
 381                  usertags => \%ut,
 382                 );
 383
 384 # shove in bugs which affect this package if there is a package or a
 385 # source given (by default), but no affects options given
 386 if (not exists $param{affects} and not exists $param{noaffects} and
 387     (exists $param{src} or
 388      exists $param{package})) {
 389     push @bugs, get_bugs((map {my $key = $_;
 390                                exists $param{$key}?($key =~ /^(?:package|src)$/?'affects':$key,
 391                                                   ($key eq 'src'?[map {"src:$_"}make_list($param{$key})]:$param{$_})):()}
 392                           grep {$_ ne 'newest'}
 393                           keys %package_search_keys, 'archive'),
 394                          usertags => \%ut,
 395                         );
 396 }
 397
 398 # filter out included or excluded bugs
 399
 400
 401 if (defined $param{version}) {
 402      $title .= " at version $param{version}";
 403 }
 404 elsif (defined $param{dist}) {
 405      $title .= " in $param{dist}";
 406 }
 407
 408 $title = html_escape($title);
 409
 410 my @names; my @prior; my @order;
 411 determine_ordering(cats => \%cats,
 412                    param => \%param,
 413                    ordering => \$ordering,
 414                    names => \@names,
 415                    prior => \@prior,
 416                    title => \@title,
 417                    order => \@order,
 418                   );
 419
 420 # strip out duplicate bugs
 421 my %bugs;
 422 @bugs{@bugs} = @bugs;
 423 @bugs = keys %bugs;
 424
 425 my $result = pkg_htmlizebugs(bugs => \@bugs,
 426                              names => \@names,
 427                              title => \@title,
 428                              order => \@order,
 429                              prior => \@prior,
 430                              ordering => $ordering,
 431                              bugusertags => \%bugusertags,
 432                              bug_rev => $bug_rev,
 433                              bug_order => $bug_order,
 434                              repeatmerged => $param{repeatmerged},
 435                              include => $include,
 436                              exclude => $exclude,
 437                              this => $this,
 438                              options => \%param,
 439                              (exists $param{dist})?(dist    => $param{dist}):(),
 440                             );
 441
 442 print "Cache-Control: public, max-age=300\n";
 443 print "Content-Type: text/html; charset=utf-8\n\n";
 444
 445 print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01 Transitional//EN\">\n";
 446 print "<HTML><HEAD>\n" .
 447     "<TITLE>$title -- $gProject$Archived $gBug report logs</TITLE>\n" .
 448     qq(<link rel="stylesheet" href="$gWebHostBugDir/css/bugs.css" type="text/css">) .
 449     "</HEAD>\n" .
 450     '<BODY onload="pagemain();">' .
 451     "\n";
 452 print qq(<DIV id="status_mask"></DIV>\n);
 453 print "<H1>" . "$gProject$Archived $gBug report logs: $title" .
 454       "</H1>\n";
 455
 456 my $showresult = 1;
 457
 458 my $pkg = $param{package} if defined $param{package};
 459 my $src = $param{src} if defined $param{src};
 460
 461 my $pseudodesc = getpseudodesc();
 462 if (defined $pseudodesc and defined $pkg and exists $pseudodesc->{$pkg}) {
 463      delete $param{dist};
 464 }
 465
 466 # output information about the packages
 467
 468 for my $package (make_list($param{package}||[])) {
 469      print generate_package_info(binary => 1,
 470                                  package => $package,
 471                                  options => \%param,
 472                                  bugs    => \@bugs,
 473                                 );
 474 }
 475 for my $package (make_list($param{src}||[])) {
 476      print generate_package_info(binary => 0,
 477                                  package => $package,
 478                                  options => \%param,
 479                                  bugs    => \@bugs,
 480                                 );
 481 }
 482
 483 if (exists $param{maint} or exists $param{maintenc}) {
 484     print "<p>Note that maintainers may use different Maintainer fields for\n";
 485     print "different packages, so there may be other reports filed under\n";
 486     print "different addresses.\n";
 487 }
 488 if (exists $param{submitter}) {
 489     print "<p>Note that people may use different email accounts for\n";
 490     print "different bugs, so there may be other reports filed under\n";
 491     print "different addresses.\n";
 492 }
 493
 494 print $result;
 495
 496 print fill_in_template(template=>'cgi/pkgreport_javascript');
 497
 498 print qq(<h2 class="outstanding"><!--<a class="options" href="javascript:toggle(1)">-->Options<!--</a>--></h2>\n);
 499
 500 $param{orderings} =
 501     [uniq((grep {!$hidden{$_}} keys %cats),
 502           $param{ordering})];
 503 print option_form(template => 'cgi/pkgreport_options',
 504                   param    => \%param,
 505                   form_options => $form_options,
 506                   variables => $form_option_variables,
 507                  );
 508
 509 print "<hr>\n";
 510 print fill_in_template(template=>'html/html_tail',
 511                        hole_var => {'&strftime' => \&POSIX::strftime,
 512                                    },
 513                       );
 514 print "</body></html>\n";
 515