bin/add_bug_to_estraier

   1 #!/usr/bin/perl
   2 # add_bug_to_estraier adds a log for a bug to the estaier db, and is
   3 # released under the terms of the GPL version 2, or any later version,
   4 # at your option. See the file README and COPYING for more
   5 # information.
   6 # Copyright 2006 by Don Armstrong <don@debian.org>.
   7
   8
   9
  10 use warnings;
  11 use strict;
  12
  13
  14 use Getopt::Long;
  15 use Pod::Usage;
  16
  17 =head1 NAME
  18
  19 add_bug_to_estraier
  20
  21 =head1 SYNOPSIS
  22
  23 add_bug_to_estraier [options] < list_of_bugs_to_add
  24
  25  Options:
  26   --debug, -d debugging level (Default 0)
  27   --help, -h display this help
  28   --man, -m display manual
  29
  30 =head1 OPTIONS
  31
  32 =over
  33
  34 =item B<--url, -u>
  35
  36 Url to the estraier node
  37
  38 =item B<--user,-U>
  39
  40 User to log onto the estraier node
  41
  42 =item B<--pass,-P>
  43
  44 Password to log onto the estraier node
  45
  46 =item B<--spool,-s>
  47
  48 Spool location; if not set defaults to /etc/debbugs/config
  49
  50 =item B<--conf,-C>
  51
  52 Configuration file; a set of key = value pairs separated by newlines;
  53 the long name of any option is the name that the configuration file
  54 takes
  55
  56 =item B<--cron>
  57
  58 Descend through the spool and add all of the bugs to estraier
  59
  60 =item B<--timestamp>
  61
  62 Use the timestamp file to only add new bugs; will lock the timestamp
  63 file to avoid racing with other invocations
  64
  65 =item B<--debug, -d>
  66
  67 Debug verbosity. (Default 0)
  68
  69 =item B<--help, -h>
  70
  71 Display brief useage information.
  72
  73 =item B<--man, -m>
  74
  75 Display this manual.
  76
  77 =back
  78
  79
  80 =head1 EXAMPLES
  81
  82   test_bts --bug 7 --host donbugs.donarmstrong.com
  83
  84
  85 =cut
  86
  87
  88 use Debbugs::Mail qw(send_mail_message);
  89 use Debbugs::MIME qw(create_mime_message);
  90
  91 use Search::Estraier;
  92 use Debbugs::Estraier qw(:add);
  93 use File::Find;
  94 use File::stat;
  95
  96 use vars qw($DEBUG $VERBOSE);
  97
  98 # XXX parse config file
  99
 100 my %options = (debug           => 0,
 101                help            => 0,
 102                man             => 0,
 103                url             => undef,
 104                user            => undef,
 105                passwd          => undef,
 106                spool           => undef,
 107                conf            => undef,
 108                cron            => 0,
 109                timestamp       => undef,
 110               );
 111
 112 GetOptions(\%options,'url|u=s','user|U=s','passwd|P=s',
 113            'spool|s=s','conf|C=s','cron!','timestamp=s',
 114            'debug|d+','help|h|?','man|m');
 115
 116 my $ERRORS = '';
 117
 118 if (not defined $options{conf}) {
 119      $ERRORS .= "--url must be set\n" if not defined $options{url};
 120      $ERRORS .= "--user must be set\n" if not defined $options{user};
 121      $ERRORS .= "--passwd must be set\n" if not defined $options{passwd};
 122 }
 123 else {
 124      # Read the conf file
 125      my $conf_fh = new IO::File $options{conf},'r'
 126           or die "Unable to open $options{conf} for reading";
 127      while (<$conf_fh>) {
 128           chomp;
 129           next if /^\s*\#/;
 130           my ($key,$value) = split /\s*[:=]\s*/,$_,2;
 131           $options{$key} = $value if defined $key and not defined $options{$key};
 132      }
 133      $ERRORS .= "url must be set\n" if not defined $options{url};
 134      $ERRORS .= "user must be set\n" if not defined $options{user};
 135      $ERRORS .= "passwd must be set\n" if not defined $options{passwd};
 136 }
 137 $ERRORS .= "--spool must be set if --cron is used\n" if
 138      not defined $options{spool} and $options{cron};
 139 pod2usage($ERRORS) if length $ERRORS;
 140
 141 pod2usage() if $options{help};
 142 pod2usage({verbose=>2}) if $options{man};
 143
 144
 145 $DEBUG = $options{debug};
 146
 147 $Debbugs::Estraier::DEBUG = $DEBUG;
 148 $VERBOSE = 0;
 149
 150 my $node =  new Search::Estraier::Node (url    => $options{url},
 151                                         user   => $options{user},
 152                                         passwd => $options{passwd},
 153                                        );
 154 $Debbugs::Config::gSpoolDir = $options{spool} if defined $options{spool};
 155
 156 if ($options{cron}) {
 157      my %timestamps;
 158      my $start_time = time;
 159      my $unlink = 0;
 160      my %seen_dirs;
 161      check_pid($options{timestamp});
 162      # read timestamp file
 163      if (defined $options{timestamp}) {
 164           my $timestamp_fh = new IO::File $options{timestamp},'r' or
 165                die "Unable to open timestamp $options{timestamp}: $!";
 166           while (<$timestamp_fh>) {
 167                chomp;
 168                my ($key,$value) = split /\s+/,$_,2;
 169                $timestamps{$key} = $value;
 170           }
 171      }
 172      for my $hash (map {sprintf '%02d',$_ } 0..99) {
 173           find(sub {
 174                     print STDERR "Examining $_\n" if $DEBUG > 1;
 175                     return if not /^(\d+)\.log$/;
 176                     my $bug_num = $1;
 177                     my $stat = stat $_ or next;
 178                     return unless -f _;
 179                     return if exists $timestamps{$File::Find::dir} and
 180                          ($timestamps{$File::Find::dir} > $stat->mtime);
 181                     $seen_dirs{$File::Find::dir} = $start_time;
 182                     print STDERR "Adding $bug_num\n" if $DEBUG;
 183                     eval{
 184                          add_bug_log($node,$bug_num);
 185                     };
 186                     if ($@) {
 187                          print STDERR "Adding $bug_num failed with $@\n";
 188                     }
 189                },
 190                map {(-d "$options{spool}/$_/$hash")?
 191                          "$options{spool}/$_/$hash":()}
 192                qw(db-h archive),
 193               );
 194           # write timestamp file
 195           if (defined $options{timestamp}) {
 196                %timestamps = (%timestamps,%seen_dirs);
 197                my $timestamp_fh = new IO::File $options{timestamp},'w' or
 198                     die "Unable to open timestamp $options{timestamp}: $!";
 199                foreach my $key (keys %timestamps) {
 200                     print {$timestamp_fh} $key,' ',
 201                          $timestamps{$key}||'',qq(\n);
 202                }
 203           }
 204      }
 205      unlink("$options{timestamp}.pid");
 206 }
 207 else {
 208      while (my $bug_num = <STDIN>) {
 209           chomp $bug_num;
 210           add_bug_log($node,$bug_num);
 211      }
 212 }
 213
 214
 215 sub check_pid{
 216      my ($timestamp) = @_;
 217      if (-e "${timestamp}.pid") {
 218           my $time_fh = new IO::File  "${timestamp}.pid", 'r' or die "Unable to read pidfile";
 219           local $/;
 220           my $pid = <$time_fh>;
 221           if (kill(0,$pid)) {
 222                print STDERR "Another cron is running" and exit 0;
 223           }
 224      }
 225      my $time_fh = new IO::File  "${timestamp}.pid", 'w' or
 226           die "Unable to read pidfile";
 227      print {$time_fh} $$;
 228 }
 229
 230
 231 __END__