Debbugs/MIME.pm

   1 package Debbugs::MIME;
   2
   3 use strict;
   4
   5 use base qw(Exporter);
   6 use vars qw($VERSION @EXPORT_OK);
   7
   8 BEGIN {
   9     $VERSION = 1.00;
  10
  11     @EXPORT_OK = qw(parse decode_rfc1522 encode_rfc1522 convert_to_utf8 create_mime_message);
  12 }
  13
  14 use File::Path;
  15 use MIME::Parser;
  16
  17 # for decode_rfc1522
  18 use MIME::WordDecoder qw();
  19 use Encode qw(decode encode encode_utf8 decode_utf8 is_utf8);
  20
  21 # for encode_rfc1522
  22 use MIME::Words qw();
  23
  24 sub getmailbody ($);
  25 sub getmailbody ($)
  26 {
  27     my $entity = shift;
  28     my $type = $entity->effective_type;
  29     if ($type eq 'text/plain' or
  30             ($type =~ m#text/# and $type ne 'text/html') or
  31             $type eq 'application/pgp') {
  32         return $entity->bodyhandle;
  33     } elsif ($type eq 'multipart/alternative') {
  34         # RFC 2046 says we should use the last part we recognize.
  35         for my $part (reverse $entity->parts) {
  36             my $ret = getmailbody($part);
  37             return $ret if $ret;
  38         }
  39     } else {
  40         # For other multipart types, we just pretend they're
  41         # multipart/mixed and run through in order.
  42         for my $part ($entity->parts) {
  43             my $ret = getmailbody($part);
  44             return $ret if $ret;
  45         }
  46     }
  47     return undef;
  48 }
  49
  50 sub parse ($)
  51 {
  52     # header and decoded body respectively
  53     my (@headerlines, @bodylines);
  54
  55     my $parser = new MIME::Parser;
  56     mkdir "mime.tmp.$$", 0777;
  57     $parser->output_under("mime.tmp.$$");
  58     my $entity = eval { $parser->parse_data($_[0]) };
  59
  60     if ($entity and $entity->head->tags) {
  61         @headerlines = @{$entity->head->header};
  62         chomp @headerlines;
  63
  64         my $entity_body = getmailbody($entity);
  65         @bodylines = $entity_body ? $entity_body->as_lines() : ();
  66         chomp @bodylines;
  67     } else {
  68         # Legacy pre-MIME code, kept around in case MIME::Parser fails.
  69         my @msg = split /\n/, $_[0];
  70         my $i;
  71
  72         for ($i = 0; $i <= $#msg; ++$i) {
  73             $_ = $msg[$i];
  74             last unless length;
  75             while ($msg[$i + 1] =~ /^\s/) {
  76                 ++$i;
  77                 $_ .= "\n" . $msg[$i];
  78             }
  79             push @headerlines, $_;
  80         }
  81
  82         @bodylines = @msg[$i .. $#msg];
  83     }
  84
  85     rmtree "mime.tmp.$$", 0, 1;
  86
  87     # Remove blank lines.
  88     shift @bodylines while @bodylines and $bodylines[0] !~ /\S/;
  89
  90     # Strip off RFC2440-style PGP clearsigning.
  91     if (@bodylines and $bodylines[0] =~ /^-----BEGIN PGP SIGNED/) {
  92         shift @bodylines while @bodylines and length $bodylines[0];
  93         shift @bodylines while @bodylines and $bodylines[0] !~ /\S/;
  94         for my $findsig (0 .. $#bodylines) {
  95             if ($bodylines[$findsig] =~ /^-----BEGIN PGP SIGNATURE/) {
  96                 $#bodylines = $findsig - 1;
  97                 last;
  98             }
  99         }
 100         map { s/^- // } @bodylines;
 101     }
 102
 103     return { header => [@headerlines], body => [@bodylines]};
 104 }
 105
 106 =head2 create_mime_message
 107
 108      create_mime_message([To=>'don@debian.org'],$body,[$attach1, $attach2]);
 109
 110 Creates a MIME encoded message with headers given by the first
 111 argument, and a message given by the second.
 112
 113 Optional attachments can be specified in the third arrayref argument.
 114
 115 Headers are passed directly to MIME::Entity::build, the message is the
 116 first attachment.
 117
 118 Each of the elements of the attachment arrayref is attached as an
 119 rfc822 message if it is a scalar or an arrayref; otherwise if it is a
 120 hashref, the contents are passed as an argument to
 121 MIME::Entity::attach
 122
 123 =cut
 124
 125 sub create_mime_message{
 126      my ($headers,$body,$attachments) = @_;
 127      $attachments = [] if not defined $attachments;
 128
 129      die "The first argument to create_mime_message must be an arrayref" unless ref($headers) eq 'ARRAY';
 130      die "The third argument to create_mime_message must be an arrayref" unless ref($attachments) eq 'ARRAY';
 131
 132      # Build the message
 133      my $msg = MIME::Entity->build(@{$headers},
 134                                    Data    => $body
 135                                   );
 136
 137      # Attach the attachments
 138      for my $attachment (@{$attachments}) {
 139           if (ref($attachment) eq 'HASH') {
 140                $msg->attach(%{$attachment});
 141           }
 142           else {
 143                # This is *craptacular*, but because various MTAs
 144                # (sendmail and exim4, at least) appear to eat From
 145                # lines in message/rfc822 attachments, we need to make
 146                # sure the From line is the first thing in the
 147                # attachement, not the second, so if it gets eaten, the
 148                # headers don't collide into the body.
 149                if (ref($attachment) eq 'ARRAY' and $attachment->[1] =~ /^From /) {
 150                     # make a copy so that we don't screw up anything
 151                     # that is expecting this arrayref to stay constant
 152                     $attachment = [@{$attachment}];
 153                     # flip the From and Received lines around
 154                     @{$attachment}[qw(1 0)] = @{$attachment}[qw(0 1)];
 155                }
 156                elsif (not ref($attachment)) {
 157                     # It's a scalar
 158                     $attachment =~ s/^(Received:[^\n]+\n)(From [^\n]+\n)/$2$1/s;
 159                }
 160                $msg->attach(Type => 'message/rfc822',
 161                             Data => $attachment,
 162                             Encoding => '7bit',
 163                            );
 164           }
 165      }
 166      print STDERR $msg->as_string;
 167      return $msg->as_string;
 168 }
 169
 170
 171 # Bug #61342 et al.
 172
 173 sub convert_to_utf8 {
 174      my ($data, $charset) = @_;
 175      # raw data just gets returned (that's the charset WordDecorder
 176      # uses when it doesn't know what to do)
 177      return $data if $charset eq 'raw' or is_utf8($data,1);
 178      my $result;
 179      eval {
 180           # this encode/decode madness is to make sure that the data
 181           # really is valid utf8 and that the is_utf8 flag is off.
 182           $result = encode("utf8",decode($charset,$data))
 183      };
 184      if ($@) {
 185           warn "Unable to decode charset; '$charset' and '$data': $@";
 186           return $data;
 187      }
 188      return $result;
 189 }
 190
 191
 192 =head2 decode_rfc1522
 193
 194     decode_rfc1522('=?iso-8859-1?Q?D=F6n_Armstr=F3ng?= <don@donarmstrong.com>')
 195
 196 Turn RFC-1522 names into the UTF-8 equivalent.
 197
 198 =cut
 199
 200 BEGIN {
 201     # Set up the default RFC1522 decoder, which turns all charsets that
 202     # are supported into the appropriate UTF-8 charset.
 203     MIME::WordDecoder->default(new MIME::WordDecoder(
 204         ['*' => \&convert_to_utf8,
 205         ]));
 206 }
 207
 208 sub decode_rfc1522 ($)
 209 {
 210     my ($string) = @_;
 211
 212     # unmime calls the default MIME::WordDecoder handler set up at
 213     # initialization time.
 214     return MIME::WordDecoder::unmime($string);
 215 }
 216
 217 =head2 encode_rfc1522
 218
 219      encode_rfc1522('Dön Armströng <don@donarmstrong.com>')
 220
 221 Encodes headers according to the RFC1522 standard by calling
 222 MIME::Words::encode_mimeword on distinct words as appropriate.
 223
 224 =cut
 225
 226 # We cannot use MIME::Words::encode_mimewords because that function
 227 # does not handle spaces properly at all.
 228
 229 sub encode_rfc1522 ($) {
 230      my ($rawstr) = @_;
 231
 232      # We process words in reverse so we can preserve spacing between
 233      # encoded words. This regex splits on word|nonword boundaries and
 234      # nonword|nonword boundaries.
 235      my @words = reverse split /(?:(?<=[\s\n])|(?=[\s\n]))/m, $rawstr;
 236
 237      my $previous_word_encoded = 0;
 238      my $string = '';
 239      for my $word (@words) {
 240           if ($word !~ m#[\x00-\x1F\x7F-\xFF]#o and $word ne ' ') {
 241                $string = $word.$string;
 242                $previous_word_encoded=0;
 243           }
 244           elsif ($word =~ /^[\s\n]$/) {
 245                $string = $word.$string;
 246                $previous_word_encoded = 0 if $word eq "\n";
 247           }
 248           else {
 249                my $encoded = MIME::Words::encode_mimeword($word, 'q', 'UTF-8');
 250                # RFC 1522 mandates that segments be at most 76 characters
 251                # long. If that's the case, we split the word up into 10
 252                # character pieces and encode it. We must use the Encode
 253                # magic here to avoid breaking on bit boundaries here.
 254                if (length $encoded > 75) {
 255                     # Turn utf8 into the internal perl representation
 256                     # so . is a character, not a byte.
 257                     my $tempstr = decode_utf8($word,Encode::FB_DEFAULT);
 258                     my @encoded;
 259                     # Strip it into 10 character long segments, and encode
 260                     # the segments
 261                     # XXX It's possible that these segments are > 76 characters
 262                     while ($tempstr =~ s/(.{1,10})$//) {
 263                          # turn the character back into the utf8 representation.
 264                          my $tempword = encode_utf8($1);
 265                          # It may actually be better to eventually use
 266                          # the base64 encoding here, but I'm not sure
 267                          # if that's as widely supported as quoted
 268                          # printable.
 269                          unshift @encoded, MIME::Words::encode_mimeword($tempword,'q','UTF-8');
 270                     }
 271                     $encoded = join(" ",@encoded);
 272                     # If the previous word was encoded, we must
 273                     # include a trailing _ that gets encoded as a
 274                     # space.
 275                     $encoded =~ s/\?\=$/_\?\=/ if $previous_word_encoded;
 276                     $string = $encoded.$string;
 277                }
 278                else {
 279                     # If the previous word was encoded, we must
 280                     # include a trailing _ that gets encoded as a
 281                     # space.
 282                     $encoded =~ s/\?\=$/_\?\=/ if $previous_word_encoded;
 283                     $string = $encoded.$string;
 284                }
 285                $previous_word_encoded = 1;
 286           }
 287      }
 288      return $string;
 289 }
 290
 291 1;