Debbugs/DB/ResultSet/SrcPkg.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 # Copyright 2017 by Don Armstrong <don@donarmstrong.com>.
   5 use utf8;
   6 package Debbugs::DB::ResultSet::SrcPkg;
   7
   8 =head1 NAME
   9
  10 Debbugs::DB::ResultSet::SrcPkg - Source Package
  11
  12 =head1 SYNOPSIS
  13
  14
  15
  16 =head1 DESCRIPTION
  17
  18
  19
  20 =cut
  21
  22 use strict;
  23 use warnings;
  24
  25 use base 'DBIx::Class::ResultSet';
  26
  27 use Debbugs::DB::Util qw(select_one);
  28
  29 sub src_pkg_and_ver_in_suite {
  30     my ($self,$suite) = @_;
  31     if (ref($suite)) {
  32         if (ref($suite) eq 'HASH') {
  33             $suite = $suite->{id}
  34         } else {
  35            $suite = $suite->id();
  36         }
  37     } else {
  38         if ($suite !~ /^\d+$/) {
  39             $suite = $self->result_source->schema->
  40                 resultset('Suite')->
  41                 search_rs({codename => $suite},
  42                          {result_class => 'DBIx::Class::ResultClass::HashRefInflator',
  43                          })->first();
  44             if (defined $suite) {
  45                 $suite = $suite->{id};
  46             }
  47         }
  48     }
  49     return
  50         $self->search_rs({'src_associations.suite' => $suite,
  51                          },
  52                         {join => {src_vers => 'src_associations'},
  53                          result_class => 'DBIx::Class::ResultClass::HashRefInflator',
  54                          columns => [qw(me.pkg src_vers.ver src_associations.id)]
  55                         },
  56                         )->all;
  57 }
  58
  59
  60 sub get_src_pkg_id {
  61     my ($self,$source) = @_;
  62     return $self->result_source->schema->storage->
  63         dbh_do(sub {
  64                    my ($s,$dbh,$src_pkg) = @_;
  65                    return select_one($dbh,<<'SQL',$src_pkg);
  66 SELECT id FROM src_pkg where pkg = ?;
  67 SQL
  68                },
  69                $source
  70               );
  71 }
  72
  73 sub get_or_create_src_pkg_id {
  74     my ($self,$source) = @_;
  75     return $self->result_source->schema->storage->
  76         dbh_do(sub {
  77                    my ($s,$dbh,$source) = @_;
  78                    return select_one($dbh,<<'SQL',$source,$source);
  79 WITH ins AS (
  80 INSERT INTO src_pkg (pkg)
  81    VALUES (?) ON CONFLICT (pkg,disabled) DO NOTHING RETURNING id
  82 )
  83 SELECT id FROM ins
  84 UNION ALL
  85 SELECT id FROM src_pkg where pkg = ? AND disabled = 'infinity'::timestamptz
  86 LIMIT 1;
  87 SQL
  88                },
  89                $source
  90               );
  91 }
  92
  93 1;
  94
  95 __END__