Debbugs/DB/Load.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 # Copyright 2013 by Don Armstrong <don@donarmstrong.com>.
   5
   6 package Debbugs::DB::Load;
   7
   8 =head1 NAME
   9
  10 Debbugs::DB::Load -- Utility routines for loading the database
  11
  12 =head1 SYNOPSIS
  13
  14
  15 =head1 DESCRIPTION
  16
  17
  18 =head1 BUGS
  19
  20 None known.
  21
  22 =cut
  23
  24 use warnings;
  25 use strict;
  26 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  27 use base qw(Exporter);
  28
  29 BEGIN{
  30      ($VERSION) = q$Revision$ =~ /^Revision:\s+([^\s+])/;
  31      $DEBUG = 0 unless defined $DEBUG;
  32
  33      @EXPORT = ();
  34      %EXPORT_TAGS = (load_bug    => [qw(load_bug handle_load_bug_queue load_bug_log)],
  35                      load_debinfo => [qw(load_debinfo)],
  36                      load_package => [qw(load_packages)],
  37                      load_suite => [qw(load_suite)],
  38                     );
  39      @EXPORT_OK = ();
  40      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  41      $EXPORT_TAGS{all} = [@EXPORT_OK];
  42 }
  43
  44 use Params::Validate qw(validate_with :types);
  45 use List::MoreUtils qw(natatime);
  46
  47 use Debbugs::Status qw(read_bug split_status_fields);
  48 use Debbugs::DB;
  49 use DateTime;
  50 use Debbugs::Common qw(make_list getparsedaddrs);
  51 use Debbugs::Config qw(:config);
  52 use Debbugs::MIME qw(parse_to_mime_entity decode_rfc1522);
  53 use DateTime::Format::Mail;
  54 use Carp;
  55
  56 =head2 Bug loading
  57
  58 Routines to load bug; exported with :load_bug
  59
  60 =over
  61
  62 =item load_bug
  63
  64      load_bug(db => $schema,
  65               data => split_status_fields($data),
  66               tags => \%tags,
  67               queue => \%queue);
  68
  69 Loads a bug's metadata into the database. (Does not load any messages)
  70
  71 =over
  72
  73 =item db -- Debbugs::DB object
  74
  75 =item data -- Bug data (from read_bug) which has been split with split_status_fields
  76
  77 =item tags -- tag cache (hashref); optional
  78
  79 =item queue -- queue of operations to perform after bug is loaded; optional.
  80
  81 =back
  82
  83 =cut
  84
  85 sub load_bug {
  86     my %param = validate_with(params => \@_,
  87                               spec => {db => {type => OBJECT,
  88                                              },
  89                                        data => {type => HASHREF,
  90                                                 optional => 1,
  91                                                },
  92                                        bug => {type => SCALAR,
  93                                                optional => 1,
  94                                               },
  95                                        tags => {type => HASHREF,
  96                                                 default => sub {return {}},
  97                                                 optional => 1},
  98                                        severities => {type => HASHREF,
  99                                                       default => sub {return {}},
 100                                                       optional => 1,
 101                                                      },
 102                                        queue => {type => HASHREF,
 103                                                  optional => 1},
 104                                       });
 105     my $s = $param{db};
 106     if (not exists $param{data} and not exists $param{bug}) {
 107         croak "One of data or bug must be provided to load_bug";
 108     }
 109     if (not exists $param{data}) {
 110         $param{data} = read_bug(bug => $param{bug});
 111     }
 112     my $data = $param{data};
 113     my $tags = $param{tags};
 114     my $queue = $param{queue};
 115     my $severities = $param{severities};
 116     my $can_queue = 1;
 117     if (not defined $queue) {
 118         $can_queue = 0;
 119         $queue = {};
 120     }
 121     my %tags;
 122     my $s_data = split_status_fields($data);
 123     for my $tag (make_list($s_data->{keywords})) {
 124         next unless defined $tag and length $tag;
 125         # this allows for invalid tags. But we'll use this to try to
 126         # find those bugs and clean them up
 127         if (not exists $tags->{$tag}) {
 128             $tags->{$tag} = $s->resultset('Tag')->
 129             find_or_create({tag => $tag});
 130         }
 131         $tags{$tag} = $tags->{$tag};
 132     }
 133     my $severity = length($data->{severity}) ? $data->{severity} :
 134         $config{default_severity};
 135     if (not exists $severities->{$severity}) {
 136         $severities->{$severity} =
 137             $s->resultset('Severity')->
 138             find_or_create({severity => $severity},
 139                           );
 140     }
 141     $severity = $severities->{$severity};
 142     my $bug =
 143         {id => $data->{bug_num},
 144          creation => DateTime->from_epoch(epoch => $data->{date}),
 145          log_modified => DateTime->from_epoch(epoch => $data->{log_modified}),
 146          last_modified => DateTime->from_epoch(epoch => $data->{last_modified}),
 147          archived => $data->{archived},
 148          (defined $data->{unarchived} and length($data->{unarchived}))?
 149          (unarchived => DateTime->from_epoch(epoch => $data->{unarchived})):(),
 150          forwarded => $data->{forwarded} // '',
 151          summary => $data->{summary} // '',
 152          outlook => $data->{outlook} // '',
 153          subject => $data->{subject} // '',
 154          done_full => $data->{done} // '',
 155          severity => $severity,
 156          owner_full => $data->{owner} // '',
 157          submitter_full => $data->{originator} // '',
 158         };
 159     my %addr_map =
 160         (done => 'done',
 161          owner => 'owner',
 162          submitter => 'originator',
 163         );
 164     for my $addr_type (keys %addr_map) {
 165         $bug->{$addr_type} =
 166             $s->resultset('Correspondent')->
 167             get_correspondent_id($data->{$addr_map{$addr_type}})
 168     }
 169     my $b = $s->resultset('Bug')->update_or_create($bug) or
 170         die "Unable to update or create bug $bug->{id}";
 171      $s->txn_do(sub {
 172                    for my $ff (qw(found fixed)) {
 173                        my @elements = $s->resultset('BugVer')->search({bug => $data->{bug_num},
 174                                                                        found  => $ff eq 'found'?1:0,
 175                                                                       });
 176                        my %elements_to_delete = map {($elements[$_]->ver_string(),
 177                                                       $elements[$_])} 0..$#elements;
 178                        my %elements_to_add;
 179                        my @elements_to_keep;
 180                        for my $version (@{$data->{"${ff}_versions"}}) {
 181                            if (exists $elements_to_delete{$version}) {
 182                                push @elements_to_keep,$version;
 183                            } else {
 184                                $elements_to_add{$version} = 1;
 185                            }
 186                        }
 187                        for my $version (@elements_to_keep) {
 188                            delete $elements_to_delete{$version};
 189                        }
 190                        for my $element (keys %elements_to_delete) {
 191                            $elements_to_delete{$element}->delete();
 192                        }
 193                        for my $element (keys %elements_to_add) {
 194                            # find source package and source version id
 195                            my $ne = $s->resultset('BugVer')->new_result({bug => $data->{bug_num},
 196                                                                          ver_string => $element,
 197                                                                          found => $ff eq 'found'?1:0,
 198                                                                         }
 199                                                                        );
 200                            if (my ($src_pkg,$src_ver) = $element =~ m{^([^\/]+)/(.+)$}) {
 201                                my $src_pkg_e = $s->resultset('SrcPkg')->single({pkg => $src_pkg});
 202                                if (defined $src_pkg_e) {
 203                                    $ne->src_pkg($src_pkg_e->id());
 204                                    my $src_ver_e = $s->resultset('SrcVer')->single({src_pkg => $src_pkg_e->id(),
 205                                                                                     ver => $src_ver
 206                                                                                    });
 207                                    $ne->src_ver($src_ver_e->id()) if defined $src_ver_e;
 208                                }
 209                            }
 210                            $ne->insert();
 211                        }
 212                    }
 213                });
 214     ### set bug tags
 215     $s->txn_do(sub {$b->set_tags([values %tags ] )});
 216     # because these bugs reference other bugs which might not exist
 217     # yet, we can't handle them until we've loaded all bugs. queue
 218     # them up.
 219     for my $merge_block (qw(merged block)) {
 220         my $data_key = $merge_block;
 221         $data_key .= 'with' if $merge_block eq 'merged';
 222         if (@{$data->{$data_key}||[]}) {
 223             my $count = $s->resultset('Bug')->search({id => [@{$data->{$data_key}}]})->count();
 224             if ($count == @{$data->{$data_key}}) {
 225                 handle_load_bug_queue(db=>$s,
 226                                       queue => {$merge_block,
 227                                                {$data->{bug_num},[@{$data->{$data_key}}]}
 228                                                });
 229             } else {
 230                 $queue->{$merge_block}{$data->{bug_num}} = [@{$data->{$data_key}}];
 231             }
 232         }
 233     }
 234
 235     if (not $can_queue and keys %{$queue}) {
 236         handle_load_bug_queue(db => $s,queue => $queue);
 237     }
 238
 239     # still need to handle merges, versions, etc.
 240 }
 241
 242 =item handle_load_bug_queue
 243
 244      handle_load_bug_queue(db => $schema,queue => $queue);
 245
 246 Handles a queue of operations created by load bug. [These operations
 247 are used to handle cases where a bug referenced by a loaded bug may
 248 not exist yet. In cases where the bugs should exist, the queue is
 249 cleared automatically by load_bug if queue is undefined.
 250
 251 =cut
 252
 253 sub handle_load_bug_queue{
 254     my %param = validate_with(params => \@_,
 255                               spec => {db => {type => OBJECT,
 256                                              },
 257                                        queue => {type => HASHREF,
 258                                                 },
 259                                       });
 260     my $s = $param{db};
 261     my $queue = $param{queue};
 262     my %queue_types =
 263         (merged => {set => 'BugMerged',
 264                     columns => [qw(bug merged)],
 265                     bug => 'bug',
 266                    },
 267          blocks => {set => 'BugBlock',
 268                     columns => [qw(bug blocks)],
 269                     bug => 'bug',
 270                    },
 271         );
 272     for my $queue_type (keys %queue_types) {
 273         for my $bug (%{$queue->{$queue_type}}) {
 274             my $qt = $queue_types{$queue_type};
 275             $s->txn_do(sub {
 276                            $s->resultset($qt->{set})->search({$qt->{bug},$bug})->delete();
 277                            $s->populate($qt->{set},[[@{$qt->{columns}}],
 278                                                     map {[$bug,$_]} @{$queue->{$queue_type}{$bug}}]) if
 279                                @{$queue->{$queue_type}{$bug}//[]};
 280                        }
 281                       );
 282         }
 283     }
 284 }
 285
 286 =item load_bug_log -- load bug logs
 287
 288        load_bug_log(db  => $s,
 289                     bug => $bug);
 290
 291
 292 =over
 293
 294 =item db -- database
 295
 296 =item bug -- bug whose log should be loaded
 297
 298 =back
 299
 300 =cut
 301
 302 sub load_bug_log {
 303     my %param = validate_with(params => \@_,
 304                               spec => {db => {type => OBJECT,
 305                                              },
 306                                        bug => {type => SCALAR,
 307                                               },
 308                                        queue => {type => HASHREF,
 309                                                  optional => 1},
 310                                       });
 311     my $s = $param{db};
 312     my $msg_num=0;
 313     my %seen_msg_ids;
 314     my $log = Debbugs::Log->new(bug_num => $param{bug}) or
 315         die "Unable to open log for $param{bug} for reading: $!";
 316     while (my $record = $log->read_record()) {
 317         next unless $record->{type} eq 'incoming-recv';
 318         my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 319         next if defined $msg_id and exists $seen_msg_ids{$msg_id};
 320         $seen_msg_ids{$msg_id} = 1 if defined $msg_id;
 321         next if defined $msg_id and $msg_id =~ /handler\..+\.ack(?:info)?\@/;
 322         my $entity = parse_to_mime_entity($record);
 323         # search for a message with this message id in the database
 324         $msg_id = $entity->head->get('Message-Id:');
 325         $msg_id =~ s/^\s*\<//;
 326         $msg_id =~ s/>\s*$//;
 327         # check to see if the subject, to, and from match. if so, it's
 328         # probably the same message.
 329         my $subject = decode_rfc1522($entity->head->get('Subject:'));
 330         $subject =~ s/\n(?:(\s)\s*|\s*$)/$1/g;
 331         my $to = decode_rfc1522($entity->head->get('To:'));
 332         $to =~ s/\n(?:(\s)\s*|\s*$)/$1/g;
 333         my $from = decode_rfc1522($entity->head->get('From:'));
 334         $from =~ s/\n(?:(\s)\s*|\s*$)/$1/g;
 335         my $m = $s->resultset('Message')->
 336             find({msgid => $msg_id,
 337                   from_complete => $from,
 338                   to_complete => $to,
 339                   subject => $subject
 340                  });
 341         if (not defined $m) {
 342             # if not, create a new message
 343             $m = $s->resultset('Message')->
 344                 find_or_create({msgid => $msg_id,
 345                                 from_complete => $from,
 346                                 to_complete => $to,
 347                                 subject => $subject
 348                                });
 349             eval {
 350                 $m->sent_date(DateTime::Format::Mail->
 351                               parse_datetime($entity->head->get('Date:',0)));
 352             };
 353             my $spam = $entity->head->get('X-Spam-Status:',0);
 354             if ($spam=~ /score=([\d\.]+)/) {
 355                 $m->spam_score($1);
 356             }
 357             my %corr;
 358             @{$corr{from}} = getparsedaddrs($from);
 359             @{$corr{to}} = getparsedaddrs($to);
 360             @{$corr{cc}} = getparsedaddrs($entity->head->get('Cc:'));
 361             # add correspondents if necessary
 362             my @cors;
 363             for my $type (keys %corr) {
 364                 for my $addr (@{$corr{$type}}) {
 365                     push @cors,
 366                         {correspondent => $s->resultset('Correspondent')->
 367                          get_correspondent_id($addr),
 368                          correspondent_type => $type,
 369                         };
 370                 }
 371             }
 372             $m->update();
 373             $s->txn_do(sub {
 374                            $m->message_correspondents()->delete();
 375                            $m->add_to_message_correspondents(@cors);
 376                        }
 377                       );
 378         }
 379         my $recv;
 380         if ($entity->head->get('Received:',0)
 381             =~ /via spool by (\S+)/) {
 382             $recv = $s->resultset('Correspondent')->
 383                 get_correspondent_id($1);
 384             $m->add_to_message_correspondents({correspondent=>$recv,
 385                                                correspondent_type => 'recv'});
 386         }
 387         # link message to bugs if necessary
 388         $m->find_or_create_related('bug_messages',
 389                                   {bug=>$param{bug},
 390                                    message_number => $msg_num});
 391     }
 392
 393 }
 394
 395 =back
 396
 397 =head2 Debinfo
 398
 399 Commands to handle src and package version loading from debinfo files
 400
 401 =over
 402
 403 =item load_debinfo
 404
 405      load_debinfo($schema,$binname, $binver, $binarch, $srcname, $srcver);
 406
 407
 408
 409 =cut
 410
 411 sub load_debinfo {
 412     my ($schema,$binname, $binver, $binarch, $srcname, $srcver) = @_;
 413     my $sp = $schema->resultset('SrcPkg')->find_or_create({pkg => $srcname});
 414     my $sv = $schema->resultset('SrcVer')->find_or_create({src_pkg=>$sp->id(),
 415                                                            ver => $srcver});
 416     my $arch = $schema->resultset('Arch')->find_or_create({arch => $binarch});
 417     my $bp = $schema->resultset('BinPkg')->find_or_create({pkg => $binname});
 418     $schema->resultset('BinVer')->find_or_create({bin_pkg_id => $bp->id(),
 419                                                   src_ver_id => $sv->id(),
 420                                                   arch_id    => $arch->id(),
 421                                                   ver        => $binver,
 422                                                  });
 423 }
 424
 425
 426 =back
 427
 428 =head Packages
 429
 430 =over
 431
 432 =item load_package
 433
 434      load_package($schema,$suite,$component,$arch,$pkg)
 435
 436 =cut
 437
 438 sub load_packages {
 439     my ($schema,$suite,$pkgs,$p) = @_;
 440     my $suite_id = $schema->resultset('Suite')->
 441         find_or_create({codename => $suite})->id;
 442     my %maint_cache;
 443     my %arch_cache;
 444     my %source_cache;
 445     my $src_max_last_modified = $schema->resultset('SrcAssociation')->
 446         search_rs({suite => $suite_id},
 447                  {order_by => {-desc => ['me.modified']},
 448                   rows => 1,
 449                   page => 1
 450                  }
 451                  )->single();
 452     my $bin_max_last_modified = $schema->resultset('BinAssociation')->
 453         search_rs({suite => $suite_id},
 454                  {order_by => {-desc => ['me.modified']},
 455                   rows => 1,
 456                   page => 1
 457                  }
 458                  )->single();
 459     my %maints;
 460     my %sources;
 461     my %bins;
 462     for my $pkg_tuple (@{$pkgs}) {
 463         my ($arch,$component,$pkg) = @{$pkg_tuple};
 464         $maints{$pkg->{Maintainer}} = $pkg->{Maintainer};
 465         if ($arch eq 'source') {
 466             my $source = $pkg->{Package};
 467             my $source_ver = $pkg->{Version};
 468             $sources{$source}{$source_ver} = $pkg->{Maintainer};
 469         } else {
 470             my $source = $pkg->{Source} // $pkg->{Package};
 471             my $source_ver = $pkg->{Version};
 472             if ($source =~ /^\s*(\S+) \(([^\)]+)\)\s*$/) {
 473                 ($source,$source_ver) = ($1,$2);
 474             }
 475             $sources{$source}{$source_ver} = $pkg->{Maintainer};
 476             $bins{$arch}{$pkg->{Package}} =
 477                {arch => $arch,
 478                 bin => $pkg->{Package},
 479                 bin_ver => $pkg->{Version},
 480                 src_ver => $source_ver,
 481                 source  => $source,
 482                 maint   => $pkg->{Maintainer},
 483                };
 484         }
 485     }
 486     # Retrieve and Insert new maintainers
 487     my $maints =
 488         $schema->resultset('Maintainer')->
 489         get_maintainers(keys %maints);
 490     my $archs =
 491         $schema->resultset('Arch')->
 492         get_archs(keys %bins);
 493     # We want all of the source package/versions which are in this suite to
 494     # start with
 495     my @sa_to_add;
 496     my @sa_to_del;
 497     my %included_sa;
 498     # Calculate which source packages are no longer in this suite
 499     for my $s ($schema->resultset('SrcPkg')->
 500                src_pkg_and_ver_in_suite($suite)) {
 501         if (not exists $sources{$s->{pkg}} or
 502             not exists $sources{$s->{pkg}}{$s->{src_vers}{ver}}
 503            ) {
 504             push @sa_to_del,
 505                 $s->{src_associations}{id};
 506         }
 507         $included_sa{$s->{pkg}}{$s->{src_vers}} = 1;
 508     }
 509     # Calculate which source packages are newly in this suite
 510     for my $s (keys %sources) {
 511         for my $v (keys %{$sources{$s}}) {
 512             if (not exists $included_sa{$s} and
 513                 not $included_sa{$s}{$v}) {
 514                 push @sa_to_add,
 515                     [$s,$v,$sources{$s}{$v}];
 516             } else {
 517                 $p->update() if defined $p;
 518             }
 519         }
 520     }
 521     # add new source packages
 522     my $it = natatime 100, @sa_to_add;
 523     while (my @v = $it->()) {
 524         $schema->txn_do(
 525             sub {
 526                 for my $svm (@_) {
 527                     my $s_id = $schema->resultset('SrcPkg')->
 528                         get_src_pkg_id($svm->[0]);
 529                     my $sv_id = $schema->resultset('SrcVer')->
 530                         get_src_ver_id($s_id,$svm->[1],$maints->{$svm->[2]});
 531                     $schema->resultset('SrcAssociation')->
 532                         insert_suite_src_ver_association($suite_id,$sv_id);
 533                 }
 534             },
 535                         @v
 536                        );
 537         $p->update($p->last_update()+
 538                    scalar @v) if defined $p;
 539     }
 540     # remove associations for packages not in this suite
 541     if (@sa_to_del) {
 542         $schema->resultset('SrcAssociation')->
 543             search_rs({id => \@sa_to_del})->delete();
 544     }
 545     # update packages in this suite to have a modification time of now
 546     $schema->resultset('SrcAssociation')->
 547         search_rs({suite => $suite_id})->
 548         update({modified => 'NOW()'});
 549     ## Handle binary packages
 550     my @bin_to_del;
 551     my @bin_to_add;
 552     my %included_bin;
 553     # calculate which binary packages are no longer in this suite
 554     for my $b ($schema->resultset('BinPkg')->
 555                bin_pkg_and_ver_in_suite($suite)) {
 556         if (not exists $bins{$b->{arch}{arch}} or
 557             not exists $bins{$b->{arch}{arch}}{$b->{pkg}} or
 558             ($bins{$b->{arch}{arch}}{$b->{pkg}}{bin_ver} ne
 559              $b->{bin_vers}{ver}
 560             )
 561            ) {
 562             push @bin_to_del,
 563                 $b->{bin_associations}{id};
 564         }
 565         $included_bin{$b->{arch}{arch}}{$b->{pkg}} =
 566             $b->{bin_vers}{ver};
 567     }
 568     # calculate which binary packages are newly in this suite
 569     for my $a (keys %bins) {
 570         for my $pkg (keys %{$bins{$a}}) {
 571             if (not exists $included_bin{$a} or
 572                 not exists $included_bin{$a}{$pkg} or
 573                 $bins{$a}{$pkg}{bin_ver} ne
 574                 $included_bin{$a}{$pkg}) {
 575                 push @bin_to_add,
 576                     $bins{$a}{$pkg};
 577             } else {
 578                 $p->update() if defined $p;
 579             }
 580         }
 581     }
 582     $it = natatime 100, @bin_to_add;
 583     while (my @v = $it->()) {
 584         $schema->txn_do(
 585         sub {
 586             for my $bvm (@_) {
 587                 my $s_id = $schema->resultset('SrcPkg')->
 588                     get_src_pkg_id($bvm->{source});
 589                 my $sv_id = $schema->resultset('SrcVer')->
 590                     get_src_ver_id($s_id,$bvm->{src_ver},$maints->{$bvm->{maint}});
 591                 my $b_id = $schema->resultset('BinPkg')->
 592                     get_bin_pkg_id($bvm->{bin});
 593                 my $bv_id = $schema->resultset('BinVer')->
 594                     get_bin_ver_id($b_id,$bvm->{bin_ver},
 595                                    $archs->{$bvm->{arch}},$sv_id);
 596                 $schema->resultset('BinAssociation')->
 597                     insert_suite_bin_ver_association($suite_id,$bv_id);
 598             }
 599         },
 600                         @v
 601                        );
 602         $p->update($p->last_update()+
 603                    scalar @v) if defined $p;
 604     }
 605     if (@bin_to_del) {
 606         $schema->resultset('BinAssociation')->
 607             search_rs({id => \@bin_to_del})->delete();
 608     }
 609     $schema->resultset('BinAssociation')->
 610         search_rs({suite => $suite_id})->
 611         update({modified => 'NOW()'});
 612
 613 }
 614
 615
 616 =back
 617
 618 =cut
 619
 620 =head Suites
 621
 622 =over
 623
 624 =item load_suite
 625
 626      load_suite($schema,$codename,$suite,$version,$active);
 627
 628 =cut
 629
 630 sub load_suite {
 631     my ($schema,$codename,$suite,$version,$active) = @_;
 632     if (ref($codename)) {
 633         ($codename,$suite,$version) =
 634             @{$codename}{qw(Codename Suite Version)};
 635         $active = 1;
 636     }
 637     my $s = $schema->resultset('Suite')->find_or_create({codename => $codename});
 638     $s->suite_name($suite);
 639     $s->version($version);
 640     $s->active($active);
 641     $s->update();
 642     return $s;
 643
 644 }
 645
 646 =back
 647
 648 =cut
 649
 650 1;
 651
 652
 653 __END__