Debbugs/DB/Load.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 # Copyright 2013 by Don Armstrong <don@donarmstrong.com>.
   5
   6 package Debbugs::DB::Load;
   7
   8 =head1 NAME
   9
  10 Debbugs::DB::Load -- Utility routines for loading the database
  11
  12 =head1 SYNOPSIS
  13
  14
  15 =head1 DESCRIPTION
  16
  17
  18 =head1 BUGS
  19
  20 None known.
  21
  22 =cut
  23
  24 use warnings;
  25 use strict;
  26 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  27 use base qw(Exporter);
  28
  29 BEGIN{
  30      ($VERSION) = q$Revision$ =~ /^Revision:\s+([^\s+])/;
  31      $DEBUG = 0 unless defined $DEBUG;
  32
  33      @EXPORT = ();
  34      %EXPORT_TAGS = (load_bug    => [qw(load_bug handle_load_bug_queue)],
  35                     );
  36      @EXPORT_OK = ();
  37      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  38      $EXPORT_TAGS{all} = [@EXPORT_OK];
  39 }
  40
  41 use Params::Validate qw(validate_with :types);
  42
  43 use Debbugs::Status qw(read_bug split_status_fields);
  44 use Debbugs::DB;
  45 use DateTime;
  46 use Debbugs::Common qw(make_list getparsedaddrs);
  47 use Debbugs::Config qw(:config);
  48
  49 =head2 Bug loading
  50
  51 Routines to load bug; exported with :load_bug
  52
  53 =over
  54
  55 =item load_bug
  56
  57      load_bug(db => $schema,
  58               data => split_status_fields($data),
  59               tags => \%tags,
  60               queue => \%queue);
  61
  62 Loads a bug's metadata into the database. (Does not load any messages)
  63
  64 =over
  65
  66 =item db -- Debbugs::DB object
  67
  68 =item data -- Bug data (from read_bug) which has been split with split_status_fields
  69
  70 =item tags -- tag cache (hashref); optional
  71
  72 =item queue -- queue of operations to perform after bug is loaded; optional.
  73
  74 =back
  75
  76 =cut
  77
  78 sub load_bug {
  79     my %param = validate_with(params => \@_,
  80                               spec => {db => {type => OBJECT,
  81                                              },
  82                                        data => {type => HASHREF},
  83                                        tags => {type => HASHREF,
  84                                                 default => sub {return {}},
  85                                                 optional => 1},
  86                                        severities => {type => HASHREF,
  87                                                       default => sub {return {}},
  88                                                       optional => 1,
  89                                                      },
  90                                        queue => {type => HASHREF,
  91                                                  optional => 1},
  92                                       });
  93     my $s = $param{db};
  94     my $data = $param{data};
  95     my $tags = $param{tags};
  96     my $queue = $param{queue};
  97     my $severities = $param{severities};
  98     my $can_queue = 1;
  99     if (not defined $queue) {
 100         $can_queue = 0;
 101         $queue = {};
 102     }
 103     my %tags;
 104     my $s_data = split_status_fields($data);
 105     for my $tag (make_list($s_data->{keywords})) {
 106         next unless defined $tag and length $tag;
 107         # this allows for invalid tags. But we'll use this to try to
 108         # find those bugs and clean them up
 109         if (not exists $tags->{$tag}) {
 110             $tags->{$tag} = $s->resultset('Tag')->
 111             find_or_create({tag => $tag});
 112         }
 113         $tags{$tag} = $tags->{$tag};
 114     }
 115     my $severity = length($data->{severity}) ? $data->{severity} : $config{default_severity};
 116     if (exists $severities->{$severity}) {
 117         $severity = $severities->{$severity};
 118     } else {
 119         $severity = $s->resultset('Severity')->
 120             find_or_create({severity => $severity});
 121     }
 122     my $bug =
 123         {id => $data->{bug_num},
 124          creation => DateTime->from_epoch(epoch => $data->{date}),
 125          log_modified => DateTime->from_epoch(epoch => $data->{log_modified}),
 126          last_modified => DateTime->from_epoch(epoch => $data->{last_modified}),
 127          archived => $data->{archived},
 128          (defined $data->{unarchived} and length($data->{unarchived}))?(unarchived => DateTime->from_epoch(epoch => $data->{unarchived})):(),
 129          forwarded => $data->{forwarded} // '',
 130          summary => $data->{summary} // '',
 131          outlook => $data->{outlook} // '',
 132          subject => $data->{subject} // '',
 133          done_full => $data->{done} // '',
 134          severity => $severity,
 135          owner_full => $data->{owner} // '',
 136          submitter_full => $data->{originator} // '',
 137         };
 138     my %addr_map =
 139         (done => 'done',
 140          owner => 'owner',
 141          submitter => 'originator',
 142         );
 143     for my $addr_type (keys %addr_map) {
 144         my @addrs = getparsedaddrs($data->{$addr_map{$addr_type}} // '');
 145         next unless @addrs;
 146         $bug->{$addr_type} = $s->resultset('Correspondent')->find_or_create({addr => $addrs[0]->address()});
 147         # insert the full name as well
 148         my $full_name = $addrs[0]->phrase();
 149         $full_name =~ s/^\"|\"$//g;
 150         $full_name =~ s/^\s+|\s+$//g;
 151         $bug->{$addr_type}->update_or_create_related('correspondent_full_names',{full_name=>$full_name}) if length $full_name;
 152     }
 153      my $b = $s->resultset('Bug')->update_or_create($bug) or
 154          die "Unable to update or create bug $bug->{id}";
 155      $s->txn_do(sub {
 156                    for my $ff (qw(found fixed)) {
 157                        my @elements = $s->resultset('BugVer')->search({bug => $data->{bug_num},
 158                                                                        found  => $ff eq 'found'?1:0,
 159                                                                       });
 160                        my %elements_to_delete = map {($elements[$_]->ver_string(),$elements[$_])} 0..$#elements;
 161                        my %elements_to_add;
 162                        my @elements_to_keep;
 163                        for my $version (@{$data->{"${ff}_versions"}}) {
 164                            if (exists $elements_to_delete{$version}) {
 165                                push @elements_to_keep,$version;
 166                            } else {
 167                                $elements_to_add{$version} = 1;
 168                            }
 169                        }
 170                        for my $version (@elements_to_keep) {
 171                            delete $elements_to_delete{$version};
 172                        }
 173                        for my $element (keys %elements_to_delete) {
 174                            $elements_to_delete{$element}->delete();
 175                        }
 176                        for my $element (keys %elements_to_add) {
 177                            # find source package and source version id
 178                            my $ne = $s->resultset('BugVer')->new_result({bug => $data->{bug_num},
 179                                                                          ver_string => $element,
 180                                                                          found => $ff eq 'found'?1:0,
 181                                                                         }
 182                                                                        );
 183                            if (my ($src_pkg,$src_ver) = $element =~ m{^([^\/]+)/(.+)$}) {
 184                                my $src_pkg_e = $s->resultset('SrcPkg')->single({pkg => $src_pkg});
 185                                if (defined $src_pkg_e) {
 186                                    $ne->src_pkg_id($src_pkg_e->id());
 187                                    my $src_ver_e = $s->resultset('SrcVer')->single({src_pkg_id => $src_pkg_e->id(),
 188                                                                                     ver => $src_ver
 189                                                                                    });
 190                                    $ne->src_ver_id($src_ver_e->id()) if defined $src_ver_e;
 191                                }
 192                            }
 193                            $ne->insert();
 194                        }
 195                    }
 196                });
 197     $s->txn_do(sub {
 198                    my $t = $s->resultset('BugTag')->search({bug => $data->{bug_num}});
 199                    $t->delete() if defined $t;
 200                    $s->populate(BugTag => [[qw(bug tag)], map {[$data->{bug_num}, $_->id()]} values %tags]);
 201                });
 202     # because these bugs reference other bugs which might not exist
 203     # yet, we can't handle them until we've loaded all bugs. queue
 204     # them up.
 205     $queue->{merged}{$data->{bug_num}} = [@{$data->{mergedwith}}];
 206     $queue->{blocks}{$data->{bug_num}} = [@{$data->{blocks}}];
 207
 208     if (not $can_queue) {
 209         handle_load_bug_queue(db => $s,queue => $queue);
 210     }
 211
 212     # still need to handle merges, versions, etc.
 213 }
 214
 215 =item handle_load_bug_queue
 216
 217      handle_load_bug_queue(db => $schema,queue => $queue);
 218
 219 Handles a queue of operations created by load bug. [These operations
 220 are used to handle cases where a bug referenced by a loaded bug may
 221 not exist yet. In cases where the bugs should exist, the queue is
 222 cleared automatically by load_bug if queue is undefined.
 223
 224 =cut
 225
 226 sub handle_load_bug_queue{
 227     my %param = validate_with(params => \@_,
 228                               spec => {db => {type => OBJECT,
 229                                              },
 230                                        queue => {type => HASHREF,
 231                                                 },
 232                                       });
 233     my $s = $param{db};
 234     my $queue = $param{queue};
 235     my %queue_types =
 236         (merged => {set => 'BugMerged',
 237                     columns => [qw(bug_id merged)],
 238                     bug_id => 'bug_id',
 239                    },
 240          blocks => {set => 'BugBlock',
 241                     columns => [qw(bug_id blocks)],
 242                     bug_id => 'bug_id',
 243                    },
 244         );
 245     for my $queue_type (keys %queue_types) {
 246         for my $bug (%{$queue->{$queue_type}}) {
 247             my $qt = $queue_types{$queue_type};
 248             $s->txn_do(sub {
 249                            $s->resultset($qt->{set})->search({$qt->{bug_id},$bug})->delete();
 250                            $s->populate($qt->{set},[[@{$qt->{columns}}],
 251                                                     map {[$bug,$_]} @{$queue->{$queue_type}{$bug}}]) if
 252                                @{$queue->{$queue_type}{$bug}//[]};
 253                        }
 254                       );
 255         }
 256     }
 257 }
 258
 259 =back
 260
 261 =head2 Debinfo
 262
 263 Commands to handle src and package version loading from debinfo files
 264
 265 =item load_debinfo
 266
 267      load_debinfo($schema,$binname, $binver, $binarch, $srcname, $srcver);
 268
 269
 270
 271 =cut
 272
 273 sub load_debinfo {
 274     my ($schema,$binname, $binver, $binarch, $srcname, $srcver) = @_;
 275     my $sp = $schema->resultset('SrcPkg')->find_or_create({pkg => $srcname});
 276     my $sv = $schema->resultset('SrcVer')->find_or_create({src_pkg_id=>$sp->id(),
 277                                                            ver => $srcver});
 278     my $arch = $schema->resultset('Arch')->find_or_create({arch => $binarch});
 279     my $bp = $schema->resultset('BinPkg')->find_or_create({pkg => $binname});
 280     $schema->resultset('BinVer')->find_or_create({bin_pkg_id => $bp->id(),
 281                                                   src_ver_id => $sv->id(),
 282                                                   arch_id    => $arch->id(),
 283                                                   ver        => $binver,
 284                                                  });
 285 }
 286
 287 1;
 288
 289
 290 __END__