Debbugs/DB/Load.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 # Copyright 2013 by Don Armstrong <don@donarmstrong.com>.
   5
   6 package Debbugs::DB::Load;
   7
   8 =head1 NAME
   9
  10 Debbugs::DB::Load -- Utility routines for loading the database
  11
  12 =head1 SYNOPSIS
  13
  14
  15 =head1 DESCRIPTION
  16
  17
  18 =head1 BUGS
  19
  20 None known.
  21
  22 =cut
  23
  24 use warnings;
  25 use strict;
  26 use v5.10;
  27 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  28 use base qw(Exporter);
  29
  30 BEGIN{
  31      ($VERSION) = q$Revision$ =~ /^Revision:\s+([^\s+])/;
  32      $DEBUG = 0 unless defined $DEBUG;
  33
  34      @EXPORT = ();
  35      %EXPORT_TAGS = (load_bug    => [qw(load_bug handle_load_bug_queue load_bug_log)],
  36                      load_debinfo => [qw(load_debinfo)],
  37                      load_package => [qw(load_packages)],
  38                      load_suite => [qw(load_suite)],
  39                     );
  40      @EXPORT_OK = ();
  41      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  42      $EXPORT_TAGS{all} = [@EXPORT_OK];
  43 }
  44
  45 use Params::Validate qw(validate_with :types);
  46 use List::AllUtils qw(natatime);
  47
  48 use Debbugs::Status qw(read_bug split_status_fields);
  49 use Debbugs::DB;
  50 use DateTime;
  51 use Debbugs::Common qw(make_list getparsedaddrs);
  52 use Debbugs::Config qw(:config);
  53 use Debbugs::MIME qw(parse_to_mime_entity decode_rfc1522);
  54 use DateTime::Format::Mail;
  55 use Carp;
  56
  57 =head2 Bug loading
  58
  59 Routines to load bug; exported with :load_bug
  60
  61 =over
  62
  63 =item load_bug
  64
  65      load_bug(db => $schema,
  66               data => split_status_fields($data),
  67               tags => \%tags,
  68               queue => \%queue);
  69
  70 Loads a bug's metadata into the database. (Does not load any messages)
  71
  72 =over
  73
  74 =item db -- Debbugs::DB object
  75
  76 =item data -- Bug data (from read_bug) which has been split with split_status_fields
  77
  78 =item tags -- tag cache (hashref); optional
  79
  80 =item queue -- queue of operations to perform after bug is loaded; optional.
  81
  82 =back
  83
  84 =cut
  85
  86 sub load_bug {
  87     my %param = validate_with(params => \@_,
  88                               spec => {db => {type => OBJECT,
  89                                              },
  90                                        data => {type => HASHREF,
  91                                                 optional => 1,
  92                                                },
  93                                        bug => {type => SCALAR,
  94                                                optional => 1,
  95                                               },
  96                                        tags => {type => HASHREF,
  97                                                 default => sub {return {}},
  98                                                 optional => 1},
  99                                        severities => {type => HASHREF,
 100                                                       default => sub {return {}},
 101                                                       optional => 1,
 102                                                      },
 103                                        queue => {type => HASHREF,
 104                                                  optional => 1},
 105                                        packages => {type => HASHREF,
 106                                                     default => sub {return {}},
 107                                                     optional => 1,
 108                                                    },
 109                                       });
 110     my $s = $param{db};
 111     if (not exists $param{data} and not exists $param{bug}) {
 112         croak "One of data or bug must be provided to load_bug";
 113     }
 114     if (not exists $param{data}) {
 115         $param{data} = read_bug(bug => $param{bug});
 116     }
 117     my $data = $param{data};
 118     my $tags = $param{tags};
 119     my $queue = $param{queue};
 120     my $severities = $param{severities};
 121     my $can_queue = 1;
 122     if (not defined $queue) {
 123         $can_queue = 0;
 124         $queue = {};
 125     }
 126     my %tags;
 127     $data = split_status_fields($data);
 128     for my $tag (make_list($data->{keywords})) {
 129         next unless defined $tag and length $tag;
 130         # this allows for invalid tags. But we'll use this to try to
 131         # find those bugs and clean them up
 132         if (not exists $tags->{$tag}) {
 133             $tags->{$tag} = $s->resultset('Tag')->
 134             find_or_create({tag => $tag});
 135         }
 136         $tags{$tag} = $tags->{$tag};
 137     }
 138     my $severity = length($data->{severity}) ? $data->{severity} :
 139         $config{default_severity};
 140     if (not exists $severities->{$severity}) {
 141         $severities->{$severity} =
 142             $s->resultset('Severity')->
 143             find_or_create({severity => $severity},
 144                           );
 145     }
 146     $severity = $severities->{$severity};
 147     my $bug =
 148         {id => $data->{bug_num},
 149          creation => DateTime->from_epoch(epoch => $data->{date}),
 150          log_modified => DateTime->from_epoch(epoch => $data->{log_modified}),
 151          last_modified => DateTime->from_epoch(epoch => $data->{last_modified}),
 152          archived => $data->{archived},
 153          (defined $data->{unarchived} and length($data->{unarchived}))?
 154          (unarchived => DateTime->from_epoch(epoch => $data->{unarchived})):(),
 155          forwarded => $data->{forwarded} // '',
 156          summary => $data->{summary} // '',
 157          outlook => $data->{outlook} // '',
 158          subject => $data->{subject} // '',
 159          done_full => $data->{done} // '',
 160          severity => $severity,
 161          owner_full => $data->{owner} // '',
 162          submitter_full => $data->{originator} // '',
 163         };
 164     my %addr_map =
 165         (done => 'done',
 166          owner => 'owner',
 167          submitter => 'originator',
 168         );
 169     for my $addr_type (keys %addr_map) {
 170         $bug->{$addr_type} = undef;
 171         next unless defined $data->{$addr_map{$addr_type}} and
 172             length($data->{$addr_map{$addr_type}});
 173         $bug->{$addr_type} =
 174             $s->resultset('Correspondent')->
 175             get_correspondent_id($data->{$addr_map{$addr_type}})
 176     }
 177     my $b = $s->resultset('Bug')->update_or_create($bug) or
 178         die "Unable to update or create bug $bug->{id}";
 179     $s->txn_do(sub {
 180                  $b->set_related_packages('binpackages',
 181                                           [grep {defined $_ and
 182                                                    length $_ and $_ !~ /^src:/}
 183                                            make_list($data->{package})],
 184                                           $param{packages},
 185                                          );
 186                  $b->set_related_packages('srcpackages',
 187                                           [map {s/src://;
 188                                                 $_}
 189                                            grep {defined $_ and
 190                                                    $_ =~ /^src:/}
 191                                            make_list($data->{package})],
 192                                           $param{packages},
 193                                          );
 194                  $b->set_related_packages('affects_binpackages',
 195                                           [grep {defined $_ and
 196                                                    length $_ and $_ !~ /^src:/}
 197                                            make_list($data->{affects})
 198                                           ],
 199                                           $param{packages},
 200                                          );
 201                  $b->set_related_packages('affects_srcpackages',
 202                                           [map {s/src://;
 203                                                 $_}
 204                                            grep {defined $_ and
 205                                                    $_ =~ /^src:/}
 206                                            make_list($data->{affects})],
 207                                           $param{packages},
 208                                          );
 209                  for my $ff (qw(found fixed)) {
 210                        my @elements = $s->resultset('BugVer')->search({bug => $data->{bug_num},
 211                                                                        found  => $ff eq 'found'?1:0,
 212                                                                       });
 213                        my %elements_to_delete = map {($elements[$_]->ver_string(),
 214                                                       $elements[$_])} 0..$#elements;
 215                        my %elements_to_add;
 216                        my @elements_to_keep;
 217                        for my $version (@{$data->{"${ff}_versions"}}) {
 218                            if (exists $elements_to_delete{$version}) {
 219                                push @elements_to_keep,$version;
 220                            } else {
 221                                $elements_to_add{$version} = 1;
 222                            }
 223                        }
 224                        for my $version (@elements_to_keep) {
 225                            delete $elements_to_delete{$version};
 226                        }
 227                        for my $element (keys %elements_to_delete) {
 228                            $elements_to_delete{$element}->delete();
 229                        }
 230                        for my $element (keys %elements_to_add) {
 231                            # find source package and source version id
 232                            my $ne = $s->resultset('BugVer')->new_result({bug => $data->{bug_num},
 233                                                                          ver_string => $element,
 234                                                                          found => $ff eq 'found'?1:0,
 235                                                                         }
 236                                                                        );
 237                            if (my ($src_pkg,$src_ver) = $element =~ m{^([^\/]+)/(.+)$}) {
 238                                my $src_pkg_e = $s->resultset('SrcPkg')->single({pkg => $src_pkg});
 239                                if (defined $src_pkg_e) {
 240                                    $ne->src_pkg($src_pkg_e->id());
 241                                    my $src_ver_e = $s->resultset('SrcVer')->single({src_pkg => $src_pkg_e->id(),
 242                                                                                     ver => $src_ver
 243                                                                                    });
 244                                    $ne->src_ver($src_ver_e->id()) if defined $src_ver_e;
 245                                }
 246                            }
 247                            $ne->insert();
 248                        }
 249                    }
 250                });
 251     ### set bug tags
 252     $s->txn_do(sub {$b->set_tags([values %tags ] )});
 253     # because these bugs reference other bugs which might not exist
 254     # yet, we can't handle them until we've loaded all bugs. queue
 255     # them up.
 256     for my $merge_block (qw(mergedwith blocks)) {
 257         my $count = 0;
 258         if (@{$data->{$merge_block}}) {
 259             $count =
 260                 $s->resultset('Bug')->
 261                 search({id => [@{$data->{$merge_block}}]})->
 262                 count();
 263         }
 264         # if all of the bugs exist, immediately fix the merge/blocks
 265         if ($count == @{$data->{$merge_block}}) {
 266             handle_load_bug_queue(db=>$s,
 267                                   queue => {$merge_block,
 268                                            {$data->{bug_num},[@{$data->{$merge_block}}]}
 269                                            });
 270         } else {
 271             $queue->{$merge_block}{$data->{bug_num}} = [@{$data->{$merge_block}}];
 272         }
 273     }
 274
 275     if (not $can_queue and keys %{$queue}) {
 276         handle_load_bug_queue(db => $s,queue => $queue);
 277     }
 278
 279     # still need to handle merges, versions, etc.
 280 }
 281
 282 =item handle_load_bug_queue
 283
 284      handle_load_bug_queue(db => $schema,queue => $queue);
 285
 286 Handles a queue of operations created by load bug. [These operations
 287 are used to handle cases where a bug referenced by a loaded bug may
 288 not exist yet. In cases where the bugs should exist, the queue is
 289 cleared automatically by load_bug if queue is undefined.
 290
 291 =cut
 292
 293 sub handle_load_bug_queue{
 294     my %param = validate_with(params => \@_,
 295                               spec => {db => {type => OBJECT,
 296                                              },
 297                                        queue => {type => HASHREF,
 298                                                 },
 299                                       });
 300     my $s = $param{db};
 301     my $queue = $param{queue};
 302     my %queue_types =
 303         (mergedwith => {set => 'BugMerged',
 304                         columns => [qw(bug merged)],
 305                         bug => 'bug',
 306                        },
 307          blocks => {set => 'BugBlock',
 308                     columns => [qw(bug blocks)],
 309                     bug => 'bug',
 310                    },
 311         );
 312     for my $queue_type (keys %queue_types) {
 313         my $qt = $queue_types{$queue_type};
 314         my @bugs = keys %{$queue->{$queue_type}};
 315         next unless @bugs;
 316         my @entries;
 317         for my $bug (@bugs) {
 318             push @entries,
 319                 map {[$bug,$_]}
 320                 @{$queue->{$queue_type}{$bug}};
 321         }
 322         $s->txn_do(sub {
 323                        $s->resultset($qt->{set})->
 324                            search({$qt->{bug}=>\@bugs})->delete();
 325                        $s->resultset($qt->{set})->
 326                            populate([[@{$qt->{columns}}],
 327                                      @entries]) if @entries;
 328                        }
 329                   );
 330     }
 331 }
 332
 333 =item load_bug_log -- load bug logs
 334
 335        load_bug_log(db  => $s,
 336                     bug => $bug);
 337
 338
 339 =over
 340
 341 =item db -- database
 342
 343 =item bug -- bug whose log should be loaded
 344
 345 =back
 346
 347 =cut
 348
 349 sub load_bug_log {
 350     my %param = validate_with(params => \@_,
 351                               spec => {db => {type => OBJECT,
 352                                              },
 353                                        bug => {type => SCALAR,
 354                                               },
 355                                        queue => {type => HASHREF,
 356                                                  optional => 1},
 357                                       });
 358     my $s = $param{db};
 359     my $msg_num=0;
 360     my %seen_msg_ids;
 361     my $log = Debbugs::Log->new(bug_num => $param{bug}) or
 362         die "Unable to open log for $param{bug} for reading: $!";
 363     while (my $record = $log->read_record()) {
 364         next unless $record->{type} eq 'incoming-recv';
 365         my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 366         next if defined $msg_id and exists $seen_msg_ids{$msg_id};
 367         $seen_msg_ids{$msg_id} = 1 if defined $msg_id;
 368         next if defined $msg_id and $msg_id =~ /handler\..+\.ack(?:info)?\@/;
 369         my $entity = parse_to_mime_entity($record);
 370         # search for a message with this message id in the database
 371         $msg_id = $entity->head->get('Message-Id') //
 372             $entity->head->get('Resent-Message-ID') //
 373             '';
 374         $msg_id =~ s/^\s*\<//;
 375         $msg_id =~ s/>\s*$//;
 376         # check to see if the subject, to, and from match. if so, it's
 377         # probably the same message.
 378         my $subject = decode_rfc1522($entity->head->get('Subject')//'');
 379         $subject =~ s/\n(?:(\s)\s*|\s*$)//g;
 380         my $to = decode_rfc1522($entity->head->get('To')//'');
 381         $to =~ s/\n(?:(\s)\s*|\s*$)//g;
 382         my $from = decode_rfc1522($entity->head->get('From')//'');
 383         $from =~ s/\n(?:(\s)\s*|\s*$)//g;
 384         my $m = $s->resultset('Message')->
 385             find({msgid => $msg_id,
 386                   from_complete => $from,
 387                   to_complete => $to,
 388                   subject => $subject
 389                  });
 390         if (not defined $m) {
 391             # if not, create a new message
 392             $m = $s->resultset('Message')->
 393                 find_or_create({msgid => $msg_id,
 394                                 from_complete => $from,
 395                                 to_complete => $to,
 396                                 subject => $subject
 397                                });
 398             eval {
 399                 my $date = DateTime::Format::Mail->
 400                     parse_datetime($entity->head->get('Date',0));
 401                 if (abs($date->offset) >= 60 * 60 * 12) {
 402                     $date = $date->set_time_zone('UTC');
 403                 }
 404                 $m->sent_date($date);
 405             };
 406             my $spam = $entity->head->get('X-Spam-Status',0)//'';
 407             if ($spam=~ /score=([\d\.]+)/) {
 408                 $m->spam_score($1);
 409             }
 410             my %corr;
 411             @{$corr{from}} = getparsedaddrs($from);
 412             @{$corr{to}} = getparsedaddrs($to);
 413             @{$corr{cc}} = getparsedaddrs($entity->head->get('Cc'));
 414             # add correspondents if necessary
 415             my @cors;
 416             for my $type (keys %corr) {
 417                 for my $addr (@{$corr{$type}}) {
 418                     my $cor = $s->resultset('Correspondent')->
 419                         get_correspondent_id($addr);
 420                     next unless defined $cor;
 421                     push @cors,
 422                         {correspondent => $cor,
 423                          correspondent_type => $type,
 424                         };
 425                 }
 426             }
 427             $m->update();
 428             $s->txn_do(sub {
 429                            $m->message_correspondents()->delete();
 430                            $m->add_to_message_correspondents(@cors) if
 431                                @cors;
 432                        }
 433                       );
 434         }
 435         my $recv;
 436         if ($entity->head->get('Received',0)
 437             =~ /via spool by (\S+)/) {
 438             $recv = $s->resultset('Correspondent')->
 439                 get_correspondent_id($1);
 440             $m->add_to_message_correspondents({correspondent=>$recv,
 441                                                correspondent_type => 'recv'});
 442         }
 443         # link message to bugs if necessary
 444         $m->find_or_create_related('bug_messages',
 445                                   {bug=>$param{bug},
 446                                    message_number => $msg_num});
 447     }
 448
 449 }
 450
 451 =back
 452
 453 =head2 Debinfo
 454
 455 Commands to handle src and package version loading from debinfo files
 456
 457 =over
 458
 459 =item load_debinfo
 460
 461      load_debinfo($schema,$binname, $binver, $binarch, $srcname, $srcver);
 462
 463
 464
 465 =cut
 466
 467 sub load_debinfo {
 468     my ($s,$binname, $binver, $binarch, $srcname, $srcver,$ct_date,$cache) = @_;
 469     $cache //= {};
 470     my $sp;
 471     if (not defined $cache->{sp}{$srcname}) {
 472         $cache->{sp}{$srcname} =
 473             $s->resultset('SrcPkg')->find_or_create({pkg => $srcname});
 474     }
 475     $sp = $cache->{sp}{$srcname};
 476     # update the creation date if the data we have is earlier
 477     if (defined $ct_date and
 478         (not defined $sp->creation or
 479          $ct_date < $sp->creation)) {
 480         $sp->creation($ct_date);
 481         $sp->last_modified(DateTime->now);
 482         $sp->update;
 483     }
 484     my $sv;
 485     if (not defined $cache->{sv}{$srcname}{$srcver}) {
 486         $cache->{sv}{$srcname}{$srcver} =
 487             $s->resultset('SrcVer')->
 488             find_or_create({src_pkg =>$sp->id(),
 489                             ver => $srcver});
 490     }
 491     $sv = $cache->{sv}{$srcname}{$srcver};
 492     if (defined $ct_date and
 493         (not defined $sv->upload_date() or $ct_date < $sv->upload_date())) {
 494         $sv->upload_date($ct_date);
 495         $sv->update;
 496     }
 497     my $arch;
 498     if (not defined $cache->{arch}{$binarch}) {
 499         $cache->{arch}{$binarch} =
 500             $s->resultset('Arch')->
 501             find_or_create({arch => $binarch},
 502                           )->id();
 503     }
 504     $arch = $cache->{arch}{$binarch};
 505     my $bp;
 506     if (not defined $cache->{bp}{$binname}) {
 507         $cache->{bp}{$binname} =
 508             $s->resultset('BinPkg')->
 509             get_bin_pkg_id($binname);
 510     }
 511     $bp = $cache->{bp}{$binname};
 512     $s->resultset('BinVer')->
 513         get_bin_ver_id($bp,$binver,$arch,$sv->id());
 514 }
 515
 516
 517 =back
 518
 519 =head2 Packages
 520
 521 =over
 522
 523 =item load_package
 524
 525      load_package($schema,$suite,$component,$arch,$pkg)
 526
 527 =cut
 528
 529 sub load_packages {
 530     my ($schema,$suite,$pkgs,$p) = @_;
 531     my $suite_id = $schema->resultset('Suite')->
 532         find_or_create({codename => $suite})->id;
 533     my %maint_cache;
 534     my %arch_cache;
 535     my %source_cache;
 536     my $src_max_last_modified = $schema->resultset('SrcAssociation')->
 537         search_rs({suite => $suite_id},
 538                  {order_by => {-desc => ['me.modified']},
 539                   rows => 1,
 540                   page => 1
 541                  }
 542                  )->single();
 543     my $bin_max_last_modified = $schema->resultset('BinAssociation')->
 544         search_rs({suite => $suite_id},
 545                  {order_by => {-desc => ['me.modified']},
 546                   rows => 1,
 547                   page => 1
 548                  }
 549                  )->single();
 550     my %maints;
 551     my %sources;
 552     my %bins;
 553     for my $pkg_tuple (@{$pkgs}) {
 554         my ($arch,$component,$pkg) = @{$pkg_tuple};
 555         $maints{$pkg->{Maintainer}} = $pkg->{Maintainer};
 556         if ($arch eq 'source') {
 557             my $source = $pkg->{Package};
 558             my $source_ver = $pkg->{Version};
 559             $sources{$source}{$source_ver} = $pkg->{Maintainer};
 560         } else {
 561             my $source = $pkg->{Source} // $pkg->{Package};
 562             my $source_ver = $pkg->{Version};
 563             if ($source =~ /^\s*(\S+) \(([^\)]+)\)\s*$/) {
 564                 ($source,$source_ver) = ($1,$2);
 565             }
 566             $sources{$source}{$source_ver} = $pkg->{Maintainer};
 567             $bins{$arch}{$pkg->{Package}} =
 568                {arch => $arch,
 569                 bin => $pkg->{Package},
 570                 bin_ver => $pkg->{Version},
 571                 src_ver => $source_ver,
 572                 source  => $source,
 573                 maint   => $pkg->{Maintainer},
 574                };
 575         }
 576     }
 577     # Retrieve and Insert new maintainers
 578     my $maints =
 579         $schema->resultset('Maintainer')->
 580         get_maintainers(keys %maints);
 581     my $archs =
 582         $schema->resultset('Arch')->
 583         get_archs(keys %bins);
 584     # We want all of the source package/versions which are in this suite to
 585     # start with
 586     my @sa_to_add;
 587     my @sa_to_del;
 588     my %included_sa;
 589     # Calculate which source packages are no longer in this suite
 590     for my $s ($schema->resultset('SrcPkg')->
 591                src_pkg_and_ver_in_suite($suite)) {
 592         if (not exists $sources{$s->{pkg}} or
 593             not exists $sources{$s->{pkg}}{$s->{src_vers}{ver}}
 594            ) {
 595             push @sa_to_del,
 596                 $s->{src_associations}{id};
 597         }
 598         $included_sa{$s->{pkg}}{$s->{src_vers}} = 1;
 599     }
 600     # Calculate which source packages are newly in this suite
 601     for my $s (keys %sources) {
 602         for my $v (keys %{$sources{$s}}) {
 603             if (not exists $included_sa{$s} and
 604                 not $included_sa{$s}{$v}) {
 605                 push @sa_to_add,
 606                     [$s,$v,$sources{$s}{$v}];
 607             } else {
 608                 $p->update() if defined $p;
 609             }
 610         }
 611     }
 612     # add new source packages
 613     my $it = natatime 100, @sa_to_add;
 614     while (my @v = $it->()) {
 615         $schema->txn_do(
 616             sub {
 617                 for my $svm (@_) {
 618                     my $s_id = $schema->resultset('SrcPkg')->
 619                         get_src_pkg_id($svm->[0]);
 620                     my $sv_id = $schema->resultset('SrcVer')->
 621                         get_src_ver_id($s_id,$svm->[1],$maints->{$svm->[2]});
 622                     $schema->resultset('SrcAssociation')->
 623                         insert_suite_src_ver_association($suite_id,$sv_id);
 624                 }
 625             },
 626                         @v
 627                        );
 628         $p->update($p->last_update()+
 629                    scalar @v) if defined $p;
 630     }
 631     # remove associations for packages not in this suite
 632     if (@sa_to_del) {
 633         $it = natatime 1000, @sa_to_del;
 634         while (my @v = $it->()) {
 635             $schema->
 636                 txn_do(sub {
 637                            $schema->resultset('SrcAssociation')->
 638                                search_rs({id => \@v})->
 639                                delete();
 640                        });
 641         }
 642     }
 643     # update packages in this suite to have a modification time of now
 644     $schema->resultset('SrcAssociation')->
 645         search_rs({suite => $suite_id})->
 646         update({modified => 'NOW()'});
 647     ## Handle binary packages
 648     my @bin_to_del;
 649     my @bin_to_add;
 650     my %included_bin;
 651     # calculate which binary packages are no longer in this suite
 652     for my $b ($schema->resultset('BinPkg')->
 653                bin_pkg_and_ver_in_suite($suite)) {
 654         if (not exists $bins{$b->{arch}{arch}} or
 655             not exists $bins{$b->{arch}{arch}}{$b->{pkg}} or
 656             ($bins{$b->{arch}{arch}}{$b->{pkg}}{bin_ver} ne
 657              $b->{bin_vers}{ver}
 658             )
 659            ) {
 660             push @bin_to_del,
 661                 $b->{bin_associations}{id};
 662         }
 663         $included_bin{$b->{arch}{arch}}{$b->{pkg}} =
 664             $b->{bin_vers}{ver};
 665     }
 666     # calculate which binary packages are newly in this suite
 667     for my $a (keys %bins) {
 668         for my $pkg (keys %{$bins{$a}}) {
 669             if (not exists $included_bin{$a} or
 670                 not exists $included_bin{$a}{$pkg} or
 671                 $bins{$a}{$pkg}{bin_ver} ne
 672                 $included_bin{$a}{$pkg}) {
 673                 push @bin_to_add,
 674                     $bins{$a}{$pkg};
 675             } else {
 676                 $p->update() if defined $p;
 677             }
 678         }
 679     }
 680     $it = natatime 100, @bin_to_add;
 681     while (my @v = $it->()) {
 682         $schema->txn_do(
 683         sub {
 684             for my $bvm (@_) {
 685                 my $s_id = $schema->resultset('SrcPkg')->
 686                     get_src_pkg_id($bvm->{source});
 687                 my $sv_id = $schema->resultset('SrcVer')->
 688                     get_src_ver_id($s_id,$bvm->{src_ver},$maints->{$bvm->{maint}});
 689                 my $b_id = $schema->resultset('BinPkg')->
 690                     get_bin_pkg_id($bvm->{bin});
 691                 my $bv_id = $schema->resultset('BinVer')->
 692                     get_bin_ver_id($b_id,$bvm->{bin_ver},
 693                                    $archs->{$bvm->{arch}},$sv_id);
 694                 $schema->resultset('BinAssociation')->
 695                     insert_suite_bin_ver_association($suite_id,$bv_id);
 696             }
 697         },
 698                         @v
 699                        );
 700         $p->update($p->last_update()+
 701                    scalar @v) if defined $p;
 702     }
 703     if (@bin_to_del) {
 704         $it = natatime 1000, @bin_to_del;
 705         while (my @v = $it->()) {
 706             $schema->
 707                 txn_do(sub {
 708                            $schema->resultset('BinAssociation')->
 709                                search_rs({id => \@v})->
 710                                delete();
 711                        });
 712         }
 713     }
 714     $schema->resultset('BinAssociation')->
 715         search_rs({suite => $suite_id})->
 716         update({modified => 'NOW()'});
 717
 718 }
 719
 720
 721 =back
 722
 723 =cut
 724
 725 =head2 Suites
 726
 727 =over
 728
 729 =item load_suite
 730
 731      load_suite($schema,$codename,$suite,$version,$active);
 732
 733 =cut
 734
 735 sub load_suite {
 736     my ($schema,$codename,$suite,$version,$active) = @_;
 737     if (ref($codename)) {
 738         ($codename,$suite,$version) =
 739             @{$codename}{qw(Codename Suite Version)};
 740         $active = 1;
 741     }
 742     my $s = $schema->resultset('Suite')->find_or_create({codename => $codename});
 743     $s->suite_name($suite);
 744     $s->version($version);
 745     $s->active($active);
 746     $s->update();
 747     return $s;
 748
 749 }
 750
 751 =back
 752
 753 =cut
 754
 755 1;
 756
 757
 758 __END__
 759 # Local Variables:
 760 # indent-tabs-mode: nil
 761 # cperl-indent-level: 4
 762 # End: