Debbugs/DB/Load.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 # Copyright 2013 by Don Armstrong <don@donarmstrong.com>.
   5
   6 package Debbugs::DB::Load;
   7
   8 =head1 NAME
   9
  10 Debbugs::DB::Load -- Utility routines for loading the database
  11
  12 =head1 SYNOPSIS
  13
  14
  15 =head1 DESCRIPTION
  16
  17
  18 =head1 BUGS
  19
  20 None known.
  21
  22 =cut
  23
  24 use warnings;
  25 use strict;
  26 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  27 use base qw(Exporter);
  28
  29 BEGIN{
  30      ($VERSION) = q$Revision$ =~ /^Revision:\s+([^\s+])/;
  31      $DEBUG = 0 unless defined $DEBUG;
  32
  33      @EXPORT = ();
  34      %EXPORT_TAGS = (load_bug    => [qw(load_bug handle_load_bug_queue load_bug_log)],
  35                      load_debinfo => [qw(load_debinfo)],
  36                      load_package => [qw(load_packages)],
  37                      load_suite => [qw(load_suite)],
  38                     );
  39      @EXPORT_OK = ();
  40      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  41      $EXPORT_TAGS{all} = [@EXPORT_OK];
  42 }
  43
  44 use Params::Validate qw(validate_with :types);
  45 use List::MoreUtils qw(natatime);
  46
  47 use Debbugs::Status qw(read_bug split_status_fields);
  48 use Debbugs::DB;
  49 use DateTime;
  50 use Debbugs::Common qw(make_list getparsedaddrs);
  51 use Debbugs::Config qw(:config);
  52 use Debbugs::MIME qw(parse_to_mime_entity decode_rfc1522);
  53 use DateTime::Format::Mail;
  54 use Carp;
  55
  56 =head2 Bug loading
  57
  58 Routines to load bug; exported with :load_bug
  59
  60 =over
  61
  62 =item load_bug
  63
  64      load_bug(db => $schema,
  65               data => split_status_fields($data),
  66               tags => \%tags,
  67               queue => \%queue);
  68
  69 Loads a bug's metadata into the database. (Does not load any messages)
  70
  71 =over
  72
  73 =item db -- Debbugs::DB object
  74
  75 =item data -- Bug data (from read_bug) which has been split with split_status_fields
  76
  77 =item tags -- tag cache (hashref); optional
  78
  79 =item queue -- queue of operations to perform after bug is loaded; optional.
  80
  81 =back
  82
  83 =cut
  84
  85 sub load_bug {
  86     my %param = validate_with(params => \@_,
  87                               spec => {db => {type => OBJECT,
  88                                              },
  89                                        data => {type => HASHREF,
  90                                                 optional => 1,
  91                                                },
  92                                        bug => {type => SCALAR,
  93                                                optional => 1,
  94                                               },
  95                                        tags => {type => HASHREF,
  96                                                 default => sub {return {}},
  97                                                 optional => 1},
  98                                        severities => {type => HASHREF,
  99                                                       default => sub {return {}},
 100                                                       optional => 1,
 101                                                      },
 102                                        queue => {type => HASHREF,
 103                                                  optional => 1},
 104                                        packages => {type => HASHREF,
 105                                                     default => sub {return {}},
 106                                                     optional => 1,
 107                                                    },
 108                                       });
 109     my $s = $param{db};
 110     if (not exists $param{data} and not exists $param{bug}) {
 111         croak "One of data or bug must be provided to load_bug";
 112     }
 113     if (not exists $param{data}) {
 114         $param{data} = read_bug(bug => $param{bug});
 115     }
 116     my $data = $param{data};
 117     my $tags = $param{tags};
 118     my $queue = $param{queue};
 119     my $severities = $param{severities};
 120     my $can_queue = 1;
 121     if (not defined $queue) {
 122         $can_queue = 0;
 123         $queue = {};
 124     }
 125     my %tags;
 126     $data = split_status_fields($data);
 127     for my $tag (make_list($data->{keywords})) {
 128         next unless defined $tag and length $tag;
 129         # this allows for invalid tags. But we'll use this to try to
 130         # find those bugs and clean them up
 131         if (not exists $tags->{$tag}) {
 132             $tags->{$tag} = $s->resultset('Tag')->
 133             find_or_create({tag => $tag});
 134         }
 135         $tags{$tag} = $tags->{$tag};
 136     }
 137     my $severity = length($data->{severity}) ? $data->{severity} :
 138         $config{default_severity};
 139     if (not exists $severities->{$severity}) {
 140         $severities->{$severity} =
 141             $s->resultset('Severity')->
 142             find_or_create({severity => $severity},
 143                           );
 144     }
 145     $severity = $severities->{$severity};
 146     my $bug =
 147         {id => $data->{bug_num},
 148          creation => DateTime->from_epoch(epoch => $data->{date}),
 149          log_modified => DateTime->from_epoch(epoch => $data->{log_modified}),
 150          last_modified => DateTime->from_epoch(epoch => $data->{last_modified}),
 151          archived => $data->{archived},
 152          (defined $data->{unarchived} and length($data->{unarchived}))?
 153          (unarchived => DateTime->from_epoch(epoch => $data->{unarchived})):(),
 154          forwarded => $data->{forwarded} // '',
 155          summary => $data->{summary} // '',
 156          outlook => $data->{outlook} // '',
 157          subject => $data->{subject} // '',
 158          done_full => $data->{done} // '',
 159          severity => $severity,
 160          owner_full => $data->{owner} // '',
 161          submitter_full => $data->{originator} // '',
 162         };
 163     my %addr_map =
 164         (done => 'done',
 165          owner => 'owner',
 166          submitter => 'originator',
 167         );
 168     for my $addr_type (keys %addr_map) {
 169         $bug->{$addr_type} = undef;
 170         next unless defined $data->{$addr_map{$addr_type}} and
 171             length($data->{$addr_map{$addr_type}});
 172         $bug->{$addr_type} =
 173             $s->resultset('Correspondent')->
 174             get_correspondent_id($data->{$addr_map{$addr_type}})
 175     }
 176     my $b = $s->resultset('Bug')->update_or_create($bug) or
 177         die "Unable to update or create bug $bug->{id}";
 178     $s->txn_do(sub {
 179                  $b->set_related_packages('binpackages',
 180                                           [grep {defined $_ and
 181                                                    length $_ and $_ !~ /^src:/}
 182                                            make_list($data->{package})],
 183                                           $param{packages},
 184                                          );
 185                  $b->set_related_packages('srcpackages',
 186                                           [map {s/src://;
 187                                                 $_}
 188                                            grep {defined $_ and
 189                                                    $_ =~ /^src:/}
 190                                            make_list($data->{package})],
 191                                           $param{packages},
 192                                          );
 193                  $b->set_related_packages('affects_binpackages',
 194                                           [grep {defined $_ and
 195                                                    length $_ and $_ !~ /^src:/}
 196                                            make_list($data->{affects})
 197                                           ],
 198                                           $param{packages},
 199                                          );
 200                  $b->set_related_packages('affects_srcpackages',
 201                                           [map {s/src://;
 202                                                 $_}
 203                                            grep {defined $_ and
 204                                                    $_ =~ /^src:/}
 205                                            make_list($data->{affects})],
 206                                           $param{packages},
 207                                          );
 208                  for my $ff (qw(found fixed)) {
 209                        my @elements = $s->resultset('BugVer')->search({bug => $data->{bug_num},
 210                                                                        found  => $ff eq 'found'?1:0,
 211                                                                       });
 212                        my %elements_to_delete = map {($elements[$_]->ver_string(),
 213                                                       $elements[$_])} 0..$#elements;
 214                        my %elements_to_add;
 215                        my @elements_to_keep;
 216                        for my $version (@{$data->{"${ff}_versions"}}) {
 217                            if (exists $elements_to_delete{$version}) {
 218                                push @elements_to_keep,$version;
 219                            } else {
 220                                $elements_to_add{$version} = 1;
 221                            }
 222                        }
 223                        for my $version (@elements_to_keep) {
 224                            delete $elements_to_delete{$version};
 225                        }
 226                        for my $element (keys %elements_to_delete) {
 227                            $elements_to_delete{$element}->delete();
 228                        }
 229                        for my $element (keys %elements_to_add) {
 230                            # find source package and source version id
 231                            my $ne = $s->resultset('BugVer')->new_result({bug => $data->{bug_num},
 232                                                                          ver_string => $element,
 233                                                                          found => $ff eq 'found'?1:0,
 234                                                                         }
 235                                                                        );
 236                            if (my ($src_pkg,$src_ver) = $element =~ m{^([^\/]+)/(.+)$}) {
 237                                my $src_pkg_e = $s->resultset('SrcPkg')->single({pkg => $src_pkg});
 238                                if (defined $src_pkg_e) {
 239                                    $ne->src_pkg($src_pkg_e->id());
 240                                    my $src_ver_e = $s->resultset('SrcVer')->single({src_pkg => $src_pkg_e->id(),
 241                                                                                     ver => $src_ver
 242                                                                                    });
 243                                    $ne->src_ver($src_ver_e->id()) if defined $src_ver_e;
 244                                }
 245                            }
 246                            $ne->insert();
 247                        }
 248                    }
 249                });
 250     ### set bug tags
 251     $s->txn_do(sub {$b->set_tags([values %tags ] )});
 252     # because these bugs reference other bugs which might not exist
 253     # yet, we can't handle them until we've loaded all bugs. queue
 254     # them up.
 255     for my $merge_block (qw(merged block)) {
 256         my $data_key = $merge_block;
 257         $data_key .= 'with' if $merge_block eq 'merged';
 258         if (@{$data->{$data_key}||[]}) {
 259             my $count = $s->resultset('Bug')->search({id => [@{$data->{$data_key}}]})->count();
 260             if ($count == @{$data->{$data_key}}) {
 261                 handle_load_bug_queue(db=>$s,
 262                                       queue => {$merge_block,
 263                                                {$data->{bug_num},[@{$data->{$data_key}}]}
 264                                                });
 265             } else {
 266                 $queue->{$merge_block}{$data->{bug_num}} = [@{$data->{$data_key}}];
 267             }
 268         }
 269     }
 270
 271     if (not $can_queue and keys %{$queue}) {
 272         handle_load_bug_queue(db => $s,queue => $queue);
 273     }
 274
 275     # still need to handle merges, versions, etc.
 276 }
 277
 278 =item handle_load_bug_queue
 279
 280      handle_load_bug_queue(db => $schema,queue => $queue);
 281
 282 Handles a queue of operations created by load bug. [These operations
 283 are used to handle cases where a bug referenced by a loaded bug may
 284 not exist yet. In cases where the bugs should exist, the queue is
 285 cleared automatically by load_bug if queue is undefined.
 286
 287 =cut
 288
 289 sub handle_load_bug_queue{
 290     my %param = validate_with(params => \@_,
 291                               spec => {db => {type => OBJECT,
 292                                              },
 293                                        queue => {type => HASHREF,
 294                                                 },
 295                                       });
 296     my $s = $param{db};
 297     my $queue = $param{queue};
 298     my %queue_types =
 299         (merged => {set => 'BugMerged',
 300                     columns => [qw(bug merged)],
 301                     bug => 'bug',
 302                    },
 303          blocks => {set => 'BugBlock',
 304                     columns => [qw(bug blocks)],
 305                     bug => 'bug',
 306                    },
 307         );
 308     for my $queue_type (keys %queue_types) {
 309         for my $bug (%{$queue->{$queue_type}}) {
 310             my $qt = $queue_types{$queue_type};
 311             $s->txn_do(sub {
 312                            $s->resultset($qt->{set})->search({$qt->{bug},$bug})->delete();
 313                            $s->populate($qt->{set},[[@{$qt->{columns}}],
 314                                                     map {[$bug,$_]} @{$queue->{$queue_type}{$bug}}]) if
 315                                @{$queue->{$queue_type}{$bug}//[]};
 316                        }
 317                       );
 318         }
 319     }
 320 }
 321
 322 =item load_bug_log -- load bug logs
 323
 324        load_bug_log(db  => $s,
 325                     bug => $bug);
 326
 327
 328 =over
 329
 330 =item db -- database
 331
 332 =item bug -- bug whose log should be loaded
 333
 334 =back
 335
 336 =cut
 337
 338 sub load_bug_log {
 339     my %param = validate_with(params => \@_,
 340                               spec => {db => {type => OBJECT,
 341                                              },
 342                                        bug => {type => SCALAR,
 343                                               },
 344                                        queue => {type => HASHREF,
 345                                                  optional => 1},
 346                                       });
 347     my $s = $param{db};
 348     my $msg_num=0;
 349     my %seen_msg_ids;
 350     my $log = Debbugs::Log->new(bug_num => $param{bug}) or
 351         die "Unable to open log for $param{bug} for reading: $!";
 352     while (my $record = $log->read_record()) {
 353         next unless $record->{type} eq 'incoming-recv';
 354         my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 355         next if defined $msg_id and exists $seen_msg_ids{$msg_id};
 356         $seen_msg_ids{$msg_id} = 1 if defined $msg_id;
 357         next if defined $msg_id and $msg_id =~ /handler\..+\.ack(?:info)?\@/;
 358         my $entity = parse_to_mime_entity($record);
 359         # search for a message with this message id in the database
 360         $msg_id = $entity->head->get('Message-Id:');
 361         $msg_id =~ s/^\s*\<//;
 362         $msg_id =~ s/>\s*$//;
 363         # check to see if the subject, to, and from match. if so, it's
 364         # probably the same message.
 365         my $subject = decode_rfc1522($entity->head->get('Subject:'));
 366         $subject =~ s/\n(?:(\s)\s*|\s*$)/$1/g;
 367         my $to = decode_rfc1522($entity->head->get('To:'));
 368         $to =~ s/\n(?:(\s)\s*|\s*$)/$1/g;
 369         my $from = decode_rfc1522($entity->head->get('From:'));
 370         $from =~ s/\n(?:(\s)\s*|\s*$)/$1/g;
 371         my $m = $s->resultset('Message')->
 372             find({msgid => $msg_id,
 373                   from_complete => $from,
 374                   to_complete => $to,
 375                   subject => $subject
 376                  });
 377         if (not defined $m) {
 378             # if not, create a new message
 379             $m = $s->resultset('Message')->
 380                 find_or_create({msgid => $msg_id,
 381                                 from_complete => $from,
 382                                 to_complete => $to,
 383                                 subject => $subject
 384                                });
 385             eval {
 386                 $m->sent_date(DateTime::Format::Mail->
 387                               parse_datetime($entity->head->get('Date:',0)));
 388             };
 389             my $spam = $entity->head->get('X-Spam-Status:',0);
 390             if ($spam=~ /score=([\d\.]+)/) {
 391                 $m->spam_score($1);
 392             }
 393             my %corr;
 394             @{$corr{from}} = getparsedaddrs($from);
 395             @{$corr{to}} = getparsedaddrs($to);
 396             @{$corr{cc}} = getparsedaddrs($entity->head->get('Cc:'));
 397             # add correspondents if necessary
 398             my @cors;
 399             for my $type (keys %corr) {
 400                 for my $addr (@{$corr{$type}}) {
 401                     push @cors,
 402                         {correspondent => $s->resultset('Correspondent')->
 403                          get_correspondent_id($addr),
 404                          correspondent_type => $type,
 405                         };
 406                 }
 407             }
 408             $m->update();
 409             $s->txn_do(sub {
 410                            $m->message_correspondents()->delete();
 411                            $m->add_to_message_correspondents(@cors);
 412                        }
 413                       );
 414         }
 415         my $recv;
 416         if ($entity->head->get('Received:',0)
 417             =~ /via spool by (\S+)/) {
 418             $recv = $s->resultset('Correspondent')->
 419                 get_correspondent_id($1);
 420             $m->add_to_message_correspondents({correspondent=>$recv,
 421                                                correspondent_type => 'recv'});
 422         }
 423         # link message to bugs if necessary
 424         $m->find_or_create_related('bug_messages',
 425                                   {bug=>$param{bug},
 426                                    message_number => $msg_num});
 427     }
 428
 429 }
 430
 431 =back
 432
 433 =head2 Debinfo
 434
 435 Commands to handle src and package version loading from debinfo files
 436
 437 =over
 438
 439 =item load_debinfo
 440
 441      load_debinfo($schema,$binname, $binver, $binarch, $srcname, $srcver);
 442
 443
 444
 445 =cut
 446
 447 sub load_debinfo {
 448     my ($s,$binname, $binver, $binarch, $srcname, $srcver,$ct_date,$cache) = @_;
 449     $cache //= {};
 450     my $sp;
 451     if (not defined $cache->{sp}{$srcname}) {
 452         $cache->{sp}{$srcname} =
 453             $s->resultset('SrcPkg')->find_or_create({pkg => $srcname});
 454     }
 455     $sp = $cache->{sp}{$srcname};
 456     # update the creation date if the data we have is earlier
 457     if (defined $ct_date and
 458         (not defined $sp->creation or
 459          $ct_date < $sp->creation)) {
 460         $sp->creation($ct_date);
 461         $sp->last_modified(DateTime->now);
 462         $sp->update;
 463     }
 464     my $sv;
 465     if (not defined $cache->{sv}{$srcname}{$srcver}) {
 466         $cache->{sv}{$srcname}{$srcver} =
 467             $s->resultset('SrcVer')->
 468             find_or_create({src_pkg =>$sp->id(),
 469                             ver => $srcver});
 470     }
 471     $sv = $cache->{sv}{$srcname}{$srcver};
 472     if (defined $ct_date and
 473         (not defined $sv->upload_date() or $ct_date < $sv->upload_date())) {
 474         $sv->upload_date($ct_date);
 475         $sv->update;
 476     }
 477     my $arch;
 478     if (not defined $cache->{arch}{$binarch}) {
 479         $cache->{arch}{$binarch} =
 480             $s->resultset('Arch')->
 481             find_or_create({arch => $binarch},
 482                           )->id();
 483     }
 484     $arch = $cache->{arch}{$binarch};
 485     my $bp;
 486     if (not defined $cache->{bp}{$binname}) {
 487         $cache->{bp}{$binname} =
 488             $s->resultset('BinPkg')->
 489             get_bin_pkg_id($binname);
 490     }
 491     $bp = $cache->{bp}{$binname};
 492     $s->resultset('BinVer')->
 493         get_bin_ver_id($bp,$binver,$arch,$sv->id());
 494 }
 495
 496
 497 =back
 498
 499 =head2 Packages
 500
 501 =over
 502
 503 =item load_package
 504
 505      load_package($schema,$suite,$component,$arch,$pkg)
 506
 507 =cut
 508
 509 sub load_packages {
 510     my ($schema,$suite,$pkgs,$p) = @_;
 511     my $suite_id = $schema->resultset('Suite')->
 512         find_or_create({codename => $suite})->id;
 513     my %maint_cache;
 514     my %arch_cache;
 515     my %source_cache;
 516     my $src_max_last_modified = $schema->resultset('SrcAssociation')->
 517         search_rs({suite => $suite_id},
 518                  {order_by => {-desc => ['me.modified']},
 519                   rows => 1,
 520                   page => 1
 521                  }
 522                  )->single();
 523     my $bin_max_last_modified = $schema->resultset('BinAssociation')->
 524         search_rs({suite => $suite_id},
 525                  {order_by => {-desc => ['me.modified']},
 526                   rows => 1,
 527                   page => 1
 528                  }
 529                  )->single();
 530     my %maints;
 531     my %sources;
 532     my %bins;
 533     for my $pkg_tuple (@{$pkgs}) {
 534         my ($arch,$component,$pkg) = @{$pkg_tuple};
 535         $maints{$pkg->{Maintainer}} = $pkg->{Maintainer};
 536         if ($arch eq 'source') {
 537             my $source = $pkg->{Package};
 538             my $source_ver = $pkg->{Version};
 539             $sources{$source}{$source_ver} = $pkg->{Maintainer};
 540         } else {
 541             my $source = $pkg->{Source} // $pkg->{Package};
 542             my $source_ver = $pkg->{Version};
 543             if ($source =~ /^\s*(\S+) \(([^\)]+)\)\s*$/) {
 544                 ($source,$source_ver) = ($1,$2);
 545             }
 546             $sources{$source}{$source_ver} = $pkg->{Maintainer};
 547             $bins{$arch}{$pkg->{Package}} =
 548                {arch => $arch,
 549                 bin => $pkg->{Package},
 550                 bin_ver => $pkg->{Version},
 551                 src_ver => $source_ver,
 552                 source  => $source,
 553                 maint   => $pkg->{Maintainer},
 554                };
 555         }
 556     }
 557     # Retrieve and Insert new maintainers
 558     my $maints =
 559         $schema->resultset('Maintainer')->
 560         get_maintainers(keys %maints);
 561     my $archs =
 562         $schema->resultset('Arch')->
 563         get_archs(keys %bins);
 564     # We want all of the source package/versions which are in this suite to
 565     # start with
 566     my @sa_to_add;
 567     my @sa_to_del;
 568     my %included_sa;
 569     # Calculate which source packages are no longer in this suite
 570     for my $s ($schema->resultset('SrcPkg')->
 571                src_pkg_and_ver_in_suite($suite)) {
 572         if (not exists $sources{$s->{pkg}} or
 573             not exists $sources{$s->{pkg}}{$s->{src_vers}{ver}}
 574            ) {
 575             push @sa_to_del,
 576                 $s->{src_associations}{id};
 577         }
 578         $included_sa{$s->{pkg}}{$s->{src_vers}} = 1;
 579     }
 580     # Calculate which source packages are newly in this suite
 581     for my $s (keys %sources) {
 582         for my $v (keys %{$sources{$s}}) {
 583             if (not exists $included_sa{$s} and
 584                 not $included_sa{$s}{$v}) {
 585                 push @sa_to_add,
 586                     [$s,$v,$sources{$s}{$v}];
 587             } else {
 588                 $p->update() if defined $p;
 589             }
 590         }
 591     }
 592     # add new source packages
 593     my $it = natatime 100, @sa_to_add;
 594     while (my @v = $it->()) {
 595         $schema->txn_do(
 596             sub {
 597                 for my $svm (@_) {
 598                     my $s_id = $schema->resultset('SrcPkg')->
 599                         get_src_pkg_id($svm->[0]);
 600                     my $sv_id = $schema->resultset('SrcVer')->
 601                         get_src_ver_id($s_id,$svm->[1],$maints->{$svm->[2]});
 602                     $schema->resultset('SrcAssociation')->
 603                         insert_suite_src_ver_association($suite_id,$sv_id);
 604                 }
 605             },
 606                         @v
 607                        );
 608         $p->update($p->last_update()+
 609                    scalar @v) if defined $p;
 610     }
 611     # remove associations for packages not in this suite
 612     if (@sa_to_del) {
 613         $it = natatime 1000, @sa_to_del;
 614         while (my @v = $it->()) {
 615             $schema->
 616                 txn_do(sub {
 617                            $schema->resultset('SrcAssociation')->
 618                                search_rs({id => \@v})->
 619                                delete();
 620                        });
 621         }
 622     }
 623     # update packages in this suite to have a modification time of now
 624     $schema->resultset('SrcAssociation')->
 625         search_rs({suite => $suite_id})->
 626         update({modified => 'NOW()'});
 627     ## Handle binary packages
 628     my @bin_to_del;
 629     my @bin_to_add;
 630     my %included_bin;
 631     # calculate which binary packages are no longer in this suite
 632     for my $b ($schema->resultset('BinPkg')->
 633                bin_pkg_and_ver_in_suite($suite)) {
 634         if (not exists $bins{$b->{arch}{arch}} or
 635             not exists $bins{$b->{arch}{arch}}{$b->{pkg}} or
 636             ($bins{$b->{arch}{arch}}{$b->{pkg}}{bin_ver} ne
 637              $b->{bin_vers}{ver}
 638             )
 639            ) {
 640             push @bin_to_del,
 641                 $b->{bin_associations}{id};
 642         }
 643         $included_bin{$b->{arch}{arch}}{$b->{pkg}} =
 644             $b->{bin_vers}{ver};
 645     }
 646     # calculate which binary packages are newly in this suite
 647     for my $a (keys %bins) {
 648         for my $pkg (keys %{$bins{$a}}) {
 649             if (not exists $included_bin{$a} or
 650                 not exists $included_bin{$a}{$pkg} or
 651                 $bins{$a}{$pkg}{bin_ver} ne
 652                 $included_bin{$a}{$pkg}) {
 653                 push @bin_to_add,
 654                     $bins{$a}{$pkg};
 655             } else {
 656                 $p->update() if defined $p;
 657             }
 658         }
 659     }
 660     $it = natatime 100, @bin_to_add;
 661     while (my @v = $it->()) {
 662         $schema->txn_do(
 663         sub {
 664             for my $bvm (@_) {
 665                 my $s_id = $schema->resultset('SrcPkg')->
 666                     get_src_pkg_id($bvm->{source});
 667                 my $sv_id = $schema->resultset('SrcVer')->
 668                     get_src_ver_id($s_id,$bvm->{src_ver},$maints->{$bvm->{maint}});
 669                 my $b_id = $schema->resultset('BinPkg')->
 670                     get_bin_pkg_id($bvm->{bin});
 671                 my $bv_id = $schema->resultset('BinVer')->
 672                     get_bin_ver_id($b_id,$bvm->{bin_ver},
 673                                    $archs->{$bvm->{arch}},$sv_id);
 674                 $schema->resultset('BinAssociation')->
 675                     insert_suite_bin_ver_association($suite_id,$bv_id);
 676             }
 677         },
 678                         @v
 679                        );
 680         $p->update($p->last_update()+
 681                    scalar @v) if defined $p;
 682     }
 683     if (@bin_to_del) {
 684         $it = natatime 1000, @bin_to_del;
 685         while (my @v = $it->()) {
 686             $schema->
 687                 txn_do(sub {
 688                            $schema->resultset('BinAssociation')->
 689                                search_rs({id => \@v})->
 690                                delete();
 691                        });
 692         }
 693     }
 694     $schema->resultset('BinAssociation')->
 695         search_rs({suite => $suite_id})->
 696         update({modified => 'NOW()'});
 697
 698 }
 699
 700
 701 =back
 702
 703 =cut
 704
 705 =head2 Suites
 706
 707 =over
 708
 709 =item load_suite
 710
 711      load_suite($schema,$codename,$suite,$version,$active);
 712
 713 =cut
 714
 715 sub load_suite {
 716     my ($schema,$codename,$suite,$version,$active) = @_;
 717     if (ref($codename)) {
 718         ($codename,$suite,$version) =
 719             @{$codename}{qw(Codename Suite Version)};
 720         $active = 1;
 721     }
 722     my $s = $schema->resultset('Suite')->find_or_create({codename => $codename});
 723     $s->suite_name($suite);
 724     $s->version($version);
 725     $s->active($active);
 726     $s->update();
 727     return $s;
 728
 729 }
 730
 731 =back
 732
 733 =cut
 734
 735 1;
 736
 737
 738 __END__
 739 # Local Variables:
 740 # indent-tabs-mode: nil
 741 # cperl-indent-level: 4
 742 # End: