Debbugs/Config.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later
   3 # version at your option.
   4 # See the file README and COPYING for more information.
   5 #
   6 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
   7
   8 package Debbugs::Config;
   9
  10 =head1 NAME
  11
  12 Debbugs::Config -- Configuration information for debbugs
  13
  14 =head1 SYNOPSIS
  15
  16  use Debbugs::Config;
  17
  18 # to get the compatiblity interface
  19
  20  use Debbugs::Config qw(:globals);
  21
  22 =head1 DESCRIPTION
  23
  24 This module provides configuration variables for all of debbugs.
  25
  26 =head1 CONFIGURATION FILES
  27
  28 The default configuration file location is /etc/debbugs/config; this
  29 configuration file location can be set by modifying the
  30 DEBBUGS_CONFIG_FILE env variable to point at a different location.
  31
  32 =cut
  33
  34 use warnings;
  35 use strict;
  36 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT $USING_GLOBALS %config);
  37 use base qw(Exporter);
  38
  39 BEGIN {
  40      # set the version for version checking
  41      $VERSION     = 1.00;
  42      $DEBUG = 0 unless defined $DEBUG;
  43      $USING_GLOBALS = 0;
  44
  45      @EXPORT = ();
  46      %EXPORT_TAGS = (globals => [qw($gEmailDomain $gListDomain $gWebHost $gWebHostBugDir),
  47                                  qw($gWebDomain $gHTMLSuffix $gCGIDomain $gMirrors),
  48                                  qw($gPackagePages $gSubscriptionDomain $gProject $gProjectTitle),
  49                                  qw($gMaintainer $gMaintainerWebpage $gMaintainerEmail $gUnknownMaintainerEmail),
  50                                  qw($gSubmitList $gMaintList $gQuietList $gForwardList),
  51                                  qw($gDoneList $gRequestList $gSubmitterList $gControlList),
  52                                  qw($gStrongList),
  53                                  qw($gPackageVersionRe),
  54                                  qw($gSummaryList $gMirrorList $gMailer $gBug),
  55                                  qw($gBugs $gRemoveAge $gSaveOldBugs $gDefaultSeverity),
  56                                  qw($gShowSeverities $gBounceFroms $gConfigDir $gSpoolDir),
  57                                  qw($gIncomingDir $gWebDir $gDocDir $gMaintainerFile),
  58                                  qw($gMaintainerFileOverride $gPseudoMaintFile $gPseudoDescFile $gPackageSource),
  59                                  qw($gVersionPackagesDir $gVersionIndex $gBinarySourceMap $gSourceBinaryMap),
  60                                  qw($gVersionTimeIndex),
  61                                  qw($gSendmail $gLibPath $gSpamScan @gExcludeFromControl),
  62                                  qw(%gSeverityDisplay @gTags @gSeverityList @gStrongSeverities),
  63                                  qw(%gSearchEstraier),
  64                                  qw(%gDistributionAliases),
  65                                  qw(@gPostProcessall @gRemovalDefaultDistributionTags @gRemovalDistributionTags @gRemovalArchitectures),
  66                                  qw(@gRemovalStrongSeverityDefaultDistributionTags),
  67                                  qw(@gDefaultArchitectures),
  68                                  qw($gTemplateDir),
  69                                  qw($gDefaultPackage),
  70                                 ],
  71                      text     => [qw($gBadEmailPrefix $gHTMLTail $gHTMLExpireNote),
  72                                  ],
  73                      config   => [qw(%config)],
  74                     );
  75      @EXPORT_OK = ();
  76      Exporter::export_ok_tags(qw(globals text config));
  77      $EXPORT_TAGS{all} = [@EXPORT_OK];
  78 }
  79
  80 use File::Basename qw(dirname);
  81 use IO::File;
  82 use Safe;
  83
  84 =head1 CONFIGURATION VARIABLES
  85
  86 =head2 General Configuration
  87
  88 =over
  89
  90 =cut
  91
  92 # read in the files;
  93 %config = ();
  94 # untaint $ENV{DEBBUGS_CONFIG_FILE} if it's owned by us
  95 # This enables us to test things that are -T.
  96 if (exists $ENV{DEBBUGS_CONFIG_FILE}) {
  97      if (${[stat($ENV{DEBBUGS_CONFIG_FILE})]}[4] = $<) {
  98           $ENV{DEBBUGS_CONFIG_FILE} =~ /(.+)/;
  99           $ENV{DEBBUGS_CONFIG_FILE} = $1;
 100      }
 101      else {
 102           die "Environmental variable DEBBUGS_CONFIG_FILE set, and $ENV{DEBBUGS_CONFIG_FILE} is not owned by the user running this script.";
 103      }
 104 }
 105 read_config(exists $ENV{DEBBUGS_CONFIG_FILE}?$ENV{DEBBUGS_CONFIG_FILE}:'/etc/debbugs/config');
 106
 107 =item email_domain $gEmailDomain
 108
 109 The email domain of the bts
 110
 111 =cut
 112
 113 set_default(\%config,'email_domain','bugs.something');
 114
 115 =item list_domain $gListDomain
 116
 117 The list domain of the bts, defaults to the email domain
 118
 119 =cut
 120
 121 set_default(\%config,'list_domain',$config{email_domain});
 122
 123 =item web_host $gWebHost
 124
 125 The web host of the bts; defaults to the email domain
 126
 127 =cut
 128
 129 set_default(\%config,'web_host',$config{email_domain});
 130
 131 =item web_host_bug_dir $gWebHostDir
 132
 133 The directory of the web host on which bugs are kept, defaults to C<''>
 134
 135 =cut
 136
 137 set_default(\%config,'web_host_bug_dir','');
 138
 139 =item web_domain $gWebDomain
 140
 141 Full path of the web domain where bugs are kept, defaults to the
 142 concatenation of L</web_host> and L</web_host_bug_dir>
 143
 144 =cut
 145
 146 set_default(\%config,'web_domain',$config{web_host}.($config{web_host}=~m{/$}?'':'/').$config{web_host_bug_dir});
 147
 148 =item html_suffix $gHTMLSuffix
 149
 150 Suffix of html pages, defaults to .html
 151
 152 =cut
 153
 154 set_default(\%config,'html_suffix','.html');
 155
 156 =item cgi_domain $gCGIDomain
 157
 158 Full path of the web domain where cgi scripts are kept. Defaults to
 159 the concatentation of L</web_host> and cgi.
 160
 161 =cut
 162
 163 set_default(\%config,'cgi_domain',$config{web_domain}.($config{web_domain}=~m{/$}?'':'/').'cgi');
 164
 165 =item mirrors @gMirrors
 166
 167 List of mirrors [What these mirrors are used for, no one knows.]
 168
 169 =cut
 170
 171
 172 set_default(\%config,'mirrors',[]);
 173
 174 =item package_pages  $gPackagePages
 175
 176 Domain where the package pages are kept; links should work in a
 177 package_pages/foopackage manner. Defaults to undef, which means that
 178 package links will not be made.
 179
 180 =cut
 181
 182
 183 set_default(\%config,'package_pages',undef);
 184
 185 =item package_pages  $gUsertagPackageDomain
 186
 187 Domain where where usertags of packages belong; defaults to $gPackagePages
 188
 189 =cut
 190
 191 set_default(\%config,'usertag_package_domain',$config{package_pages});
 192
 193
 194 =item subscription_domain $gSubscriptionDomain
 195
 196 Domain where subscriptions to package lists happen
 197
 198 =cut
 199
 200
 201 set_default(\%config,'subscription_domain',undef);
 202
 203 =back
 204
 205 =cut
 206
 207
 208 =head2 Project Identification
 209
 210 =over
 211
 212 =item project $gProject
 213
 214 Name of the project
 215
 216 Default: 'Something'
 217
 218 =cut
 219
 220 set_default(\%config,'project','Something');
 221
 222 =item project_title $gProjectTitle
 223
 224 Name of this install of Debbugs, defaults to "L</project> Debbugs Install"
 225
 226 Default: "$config{project} Debbugs Install"
 227
 228 =cut
 229
 230 set_default(\%config,'project_title',"$config{project} Debbugs Install");
 231
 232 =item maintainer $gMaintainer
 233
 234 Name of the maintainer of this debbugs install
 235
 236 Default: 'Local DebBugs Owner's
 237
 238 =cut
 239
 240 set_default(\%config,'maintainer','Local DebBugs Owner');
 241
 242 =item maintainer_webpage $gMaintainerWebpage
 243
 244 Webpage of the maintainer of this install of debbugs
 245
 246 Default: "$config{web_domain}/~owner"
 247
 248 =cut
 249
 250 set_default(\%config,'maintainer_webpage',"$config{web_domain}/~owner");
 251
 252 =item maintainer_email $gMaintainerEmail
 253
 254 Email address of the maintainer of this Debbugs install
 255
 256 Default: 'root@'.$config{email_domain}
 257
 258 =cut
 259
 260 set_default(\%config,'maintainer_email','root@'.$config{email_domain});
 261
 262 =item unknown_maintainer_email
 263
 264 Email address where packages with an unknown maintainer will be sent
 265
 266 Default: $config{maintainer_email}
 267
 268 =back
 269
 270 =cut
 271
 272 set_default(\%config,'unknown_maintainer_email',$config{maintainer_email});
 273
 274 =head2 BTS Mailing Lists
 275
 276
 277 =over
 278
 279 =item submit_list
 280
 281 =item maint_list
 282
 283 =item forward_list
 284
 285 =item done_list
 286
 287 =item request_list
 288
 289 =item submitter_list
 290
 291 =item control_list
 292
 293 =item summary_list
 294
 295 =item mirror_list
 296
 297 =back
 298
 299 =cut
 300
 301 set_default(\%config,   'submit_list',   'bug-submit-list');
 302 set_default(\%config,    'maint_list',    'bug-maint-list');
 303 set_default(\%config,    'quiet_list',    'bug-quiet-list');
 304 set_default(\%config,  'forward_list',  'bug-forward-list');
 305 set_default(\%config,     'done_list',     'bug-done-list');
 306 set_default(\%config,  'request_list',  'bug-request-list');
 307 set_default(\%config,'submitter_list','bug-submitter-list');
 308 set_default(\%config,  'control_list',  'bug-control-list');
 309 set_default(\%config,  'summary_list',  'bug-summary-list');
 310 set_default(\%config,   'mirror_list',   'bug-mirror-list');
 311 set_default(\%config,   'strong_list',   'bug-strong-list');
 312
 313 =head2 Misc Options
 314
 315 =over
 316
 317 =cut
 318
 319 set_default(\%config,'mailer','exim');
 320 set_default(\%config,'bug','bug');
 321 set_default(\%config,'bugs','bugs');
 322
 323 =item remove_age
 324
 325 Age at which bugs are archived/removed
 326
 327 Default: 28
 328
 329 =cut
 330
 331 set_default(\%config,'remove_age',28);
 332
 333 =item save_old_bugs
 334
 335 Whether old bugs are saved or deleted
 336
 337 Default: 1
 338
 339 =cut
 340
 341 set_default(\%config,'save_old_bugs',1);
 342
 343 =item distribution_aliases
 344
 345 Map of distribution aliases to the distribution name
 346
 347 Default:
 348          {experimental => 'experimental',
 349           unstable     => 'unstable',
 350           testing      => 'testing',
 351           stable       => 'stable',
 352           oldstable    => 'oldstable',
 353           sid          => 'unstable',
 354           lenny        => 'testing',
 355           etch         => 'stable',
 356           sarge        => 'oldstable',
 357          }
 358
 359 =cut
 360
 361 set_default(\%config,'distribution_aliases',
 362             {experimental => 'experimental',
 363              unstable     => 'unstable',
 364              testing      => 'testing',
 365              stable       => 'stable',
 366              oldstable    => 'oldstable',
 367              sid          => 'unstable',
 368              lenny        => 'testing',
 369              etch         => 'stable',
 370              sarge        => 'oldstable',
 371             },
 372            );
 373
 374
 375
 376 =item distributions
 377
 378 List of valid distributions
 379
 380 Default: The values of the distribution aliases map.
 381
 382 =cut
 383
 384 my %_distributions_default;
 385 @_distributions_default{values %{$config{distribution_aliases}}} = values %{$config{distribution_aliases}};
 386 set_default(\%config,'distributions',[keys %_distributions_default]);
 387
 388
 389 =item default_architectures
 390
 391 List of default architectures to use when architecture(s) are not
 392 specified
 393
 394 Default: i386 amd64 arm ppc sparc alpha
 395
 396 =cut
 397
 398 set_default(\%config,'default_architectures',
 399             [qw(i386 amd64 arm powerpc sparc alpha)]
 400            );
 401
 402 =item removal_distribution_tags
 403
 404 Tags which specifiy distributions to check
 405
 406 Default: @{$config{distributions}}
 407
 408 =cut
 409
 410 set_default(\%config,'removal_distribution_tags',
 411             [@{$config{distributions}}]);
 412
 413 =item removal_default_distribution_tags
 414
 415 For removal/archival purposes, all bugs are assumed to have these tags
 416 set.
 417
 418 Default: qw(unstable testing);
 419
 420 =cut
 421
 422 set_default(\%config,'removal_default_distribution_tags',
 423             [qw(unstable testing)]
 424            );
 425
 426 =item removal_strong_severity_default_distribution_tags
 427
 428 For removal/archival purposes, all bugs with strong severity are
 429 assumed to have these tags set.
 430
 431 Default: qw(unstable testing stable);
 432
 433 =cut
 434
 435 set_default(\%config,'removal_strong_severity_default_distribution_tags',
 436             [qw(unstable testing stable)]
 437            );
 438
 439
 440 =item removal_architectures
 441
 442 For removal/archival purposes, these architectures are consulted if
 443 there is more than one architecture applicable. If the bug is in a
 444 package not in any of these architectures, the architecture actually
 445 checked is undefined.
 446
 447 Default: value of default_architectures
 448
 449 =cut
 450
 451 set_default(\%config,'removal_architectures',
 452             $config{default_architectures},
 453            );
 454
 455
 456 =item package_name_re
 457
 458 The regex which will match a package name
 459
 460 Default: '[a-z0-9][a-z0-9\.+-]+'
 461
 462 =cut
 463
 464 set_default(\%config,'package_name_re',
 465             '[a-z0-9][a-z0-9\.+-]+');
 466
 467 =item package_version_re
 468
 469 The regex which will match a package version
 470
 471 Default: '[A-Za-z0-9:+\.-]+'
 472
 473 =cut
 474
 475
 476 set_default(\%config,'package_version_re',
 477             '[A-Za-z0-9:+\.~-]+');
 478
 479
 480 =item default_package
 481
 482 This is the name of the default package. If set, bugs assigned to
 483 packages without a maintainer and bugs missing a Package: psuedoheader
 484 will be assigned to this package instead.
 485
 486 Defaults to unset, which is the traditional debbugs behavoir
 487
 488 =cut
 489
 490 set_default(\%config,'default_package',
 491             undef
 492            );
 493
 494
 495 =item control_internal_requester
 496
 497 This address is used by Debbugs::Control as the request address which
 498 sent a control request for faked log messages.
 499
 500 Default:"Debbugs Internal Request <$config{maintainer_email}>"
 501
 502 =cut
 503
 504 set_default(\%config,'control_internal_requester',
 505             "Debbugs Internal Request <$config{maintainer_email}>",
 506            );
 507
 508 =item control_internal_request_addr
 509
 510 This address is used by Debbugs::Control as the address to which a
 511 faked log message request was sent.
 512
 513 Default: "internal_control\@$config{email_domain}";
 514
 515 =cut
 516
 517 set_default(\%config,'control_internal_request_addr',
 518             'internal_control@'.$config{email_domain},
 519            );
 520
 521
 522 =item exclude_from_control
 523
 524 Addresses which are not allowed to send messages to control
 525
 526 =cut
 527
 528 set_default(\%config,'exclude_from_control',[]);
 529
 530
 531
 532
 533 set_default(\%config,'default_severity','normal');
 534 set_default(\%config,'show_severities','critical, grave, normal, minor, wishlist');
 535 set_default(\%config,'strong_severities',[qw(critical grave)]);
 536 set_default(\%config,'severity_list',[qw(critical grave normal wishlist)]);
 537 set_default(\%config,'severity_display',{critical => "Critical $config{bugs}",
 538                                          grave    => "Grave $config{bugs}",
 539                                          normal   => "Normal $config{bugs}",
 540                                          wishlist => "Wishlist $config{bugs}",
 541                                         });
 542
 543 set_default(\%config,'tags',[qw(patch wontfix moreinfo unreproducible fixed),
 544                              @{$config{distributions}}
 545                             ]);
 546
 547 set_default(\%config,'bounce_froms','^mailer|^da?emon|^post.*mast|^root|^wpuser|^mmdf|^smt.*|'.
 548             '^mrgate|^vmmail|^mail.*system|^uucp|-maiser-|^mal\@|'.
 549             '^mail.*agent|^tcpmail|^bitmail|^mailman');
 550
 551 set_default(\%config,'config_dir',dirname(exists $ENV{DEBBUGS_CONFIG_FILE}?$ENV{DEBBUGS_CONFIG_FILE}:'/etc/debbugs/config'));
 552 set_default(\%config,'spool_dir','/var/lib/debbugs/spool');
 553 set_default(\%config,'incoming_dir','incoming');
 554 set_default(\%config,'web_dir','/var/lib/debbugs/www');
 555 set_default(\%config,'doc_dir','/var/lib/debbugs/www/txt');
 556 set_default(\%config,'lib_path','/usr/lib/debbugs');
 557
 558
 559 =item template_dir
 560
 561 directory of templates; defaults to /usr/share/debbugs/templates.
 562
 563 =cut
 564
 565 set_default(\%config,'template_dir','/usr/share/debbugs/templates');
 566
 567
 568 set_default(\%config,'maintainer_file',$config{config_dir}.'/Maintainers');
 569 set_default(\%config,'maintainer_file_override',$config{config_dir}.'/Maintainers.override');
 570 set_default(\%config,'pseudo_maint_file',$config{config_dir}.'/pseudo-packages.maint');
 571 set_default(\%config,'pseudo_desc_file',$config{config_dir}.'/pseudo-packages.description');
 572 set_default(\%config,'package_source',$config{config_dir}.'/indices/sources');
 573
 574
 575 =item version_packages_dir
 576
 577 Location where the version package information is kept; defaults to
 578 spool_dir/../versions/pkg
 579
 580 =cut
 581
 582 set_default(\%config,'version_packages_dir',$config{spool_dir}.'/../versions/pkg');
 583
 584 =item version_time_index
 585
 586 Location of the version/time index file. Defaults to
 587 spool_dir/../versions/idx/versions_time.idx if spool_dir/../versions
 588 exists; otherwise defaults to undef.
 589
 590 =cut
 591
 592
 593 set_default(\%config,'version_time_index', -d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/versions_time.idx' : undef);
 594
 595 =item version_index
 596
 597 Location of the version index file. Defaults to
 598 spool_dir/../versions/indices/versions.idx if spool_dir/../versions
 599 exists; otherwise defaults to undef.
 600
 601 =cut
 602
 603 set_default(\%config,'version_index',-d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/versions.idx' : undef);
 604
 605 =item binary_source_map
 606
 607 Location of the binary -> source map. Defaults to
 608 spool_dir/../versions/indices/bin2src.idx if spool_dir/../versions
 609 exists; otherwise defaults to undef.
 610
 611 =cut
 612
 613 set_default(\%config,'binary_source_map',-d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/binsrc.idx' : undef);
 614
 615 =item source_binary_map
 616
 617 Location of the source -> binary map. Defaults to
 618 spool_dir/../versions/indices/src2bin.idx if spool_dir/../versions
 619 exists; otherwise defaults to undef.
 620
 621 =cut
 622
 623 set_default(\%config,'source_binary_map',-d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/srcbin.idx' : undef);
 624
 625
 626
 627 set_default(\%config,'post_processall',[]);
 628
 629 =item sendmail
 630
 631 Sets the sendmail binary to execute; defaults to /usr/lib/sendmail
 632
 633 =cut
 634
 635 set_default(\%config,'sendmail','/usr/lib/sendmail');
 636
 637 =item spam_scan
 638
 639 Whether or not spamscan is being used; defaults to 0 (not being used
 640
 641 =cut
 642
 643 set_default(\%config,'spam_scan',0);
 644
 645
 646 =back
 647
 648
 649 =head2 Text Fields
 650
 651 The following are the only text fields in general use in the scripts;
 652 a few additional text fields are defined in text.in, but are only used
 653 in db2html and a few other specialty scripts.
 654
 655 Earlier versions of debbugs defined these values in /etc/debbugs/text,
 656 but now they are required to be in the configuration file. [Eventually
 657 the longer ones will move out into a fully fledged template system.]
 658
 659 =cut
 660
 661 =over
 662
 663 =item bad_email_prefix
 664
 665 This prefixes the text of all lines in a bad e-mail message ack.
 666
 667 =cut
 668
 669 set_default(\%config,'bad_email_prefix','');
 670
 671
 672 =item text_instructions
 673
 674 This gives more information about bad e-mails to receive.in
 675
 676 =cut
 677
 678 set_default(\%config,'text_instructions',$config{bad_email_prefix});
 679
 680 =item html_tail
 681
 682 This shows up at the end of (most) html pages
 683
 684 =cut
 685
 686 set_default(\%config,'html_tail',<<END);
 687  <ADDRESS>$config{maintainer} &lt;<A HREF=\"mailto:$config{maintainer_email}\">$config{maintainer_email}</A>&gt;.
 688  Last modified:
 689  <!--timestamp-->
 690  SUBSTITUTE_DTIME
 691  <!--timestamp-->
 692  <P>
 693  <A HREF=\"http://$config{web_domain}/\">Debian $config{bug} tracking system</A><BR>
 694  Copyright (C) 1999 Darren O. Benham,
 695  1997,2003 nCipher Corporation Ltd,
 696  1994-97 Ian Jackson.
 697  </ADDRESS>
 698 END
 699
 700
 701 =item html_expire_note
 702
 703 This message explains what happens to archive/remove-able bugs
 704
 705 =cut
 706
 707 set_default(\%config,'html_expire_note',
 708             "(Closed $config{bugs} are archived $config{remove_age} days after the last related message is received.)");
 709
 710 =back
 711
 712 =cut
 713
 714
 715 sub read_config{
 716      my ($conf_file) = @_;
 717      # first, figure out what type of file we're reading in.
 718      my $fh = new IO::File $conf_file,'r'
 719           or die "Unable to open configuration file $conf_file for reading: $!";
 720      # A new version configuration file must have a comment as its first line
 721      my $first_line = <$fh>;
 722      my ($version) = defined $first_line?$first_line =~ /VERSION:\s*(\d+)/i:undef;
 723      if (defined $version) {
 724           if ($version == 1) {
 725                # Do something here;
 726                die "Version 1 configuration files not implemented yet";
 727           }
 728           else {
 729                die "Version $version configuration files are not supported";
 730           }
 731      }
 732      else {
 733           # Ugh. Old configuration file
 734           # What we do here is we create a new Safe compartment
 735           # so fucked up crap in the config file doesn't sink us.
 736           my $cpt = new Safe or die "Unable to create safe compartment";
 737           # perldoc Opcode; for details
 738           $cpt->permit('require',':filesys_read','entereval','caller','pack','unpack','dofile');
 739           $cpt->reval(qq(require '$conf_file';));
 740           die "Error in configuration file: $@" if $@;
 741           # Now what we do is check out the contents of %EXPORT_TAGS to see exactly which variables
 742           # we want to glob in from the configuration file
 743           for my $variable (@{$EXPORT_TAGS{globals}}) {
 744                my ($hash_name,$glob_name,$glob_type) = __convert_name($variable);
 745                my $var_glob = $cpt->varglob($glob_name);
 746                my $value; #= $cpt->reval("return $variable");
 747                # print STDERR "$variable $value",qq(\n);
 748                if (defined $var_glob) {{
 749                     no strict 'refs';
 750                     if ($glob_type eq '%') {
 751                          $value = {%{*{$var_glob}}} if defined *{$var_glob}{HASH};
 752                     }
 753                     elsif ($glob_type eq '@') {
 754                          $value = [@{*{$var_glob}}] if defined *{$var_glob}{ARRAY};
 755                     }
 756                     else {
 757                          $value = ${*{$var_glob}};
 758                     }
 759                     # We punt here, because we can't tell if the value was
 760                     # defined intentionally, or if it was just left alone;
 761                     # this tries to set sane defaults.
 762                     set_default(\%config,$hash_name,$value) if defined $value;
 763                }}
 764           }
 765      }
 766 }
 767
 768 sub __convert_name{
 769      my ($variable) = @_;
 770      my $hash_name = $variable;
 771      $hash_name =~ s/^([\$\%\@])g//;
 772      my $glob_type = $1;
 773      my $glob_name = 'g'.$hash_name;
 774      $hash_name =~ s/(HTML|CGI)/ucfirst(lc($1))/ge;
 775      $hash_name =~ s/^([A-Z]+)/lc($1)/e;
 776      $hash_name =~ s/([A-Z]+)/'_'.lc($1)/ge;
 777      return $hash_name unless wantarray;
 778      return ($hash_name,$glob_name,$glob_type);
 779 }
 780
 781 # set_default
 782
 783 # sets the configuration hash to the default value if it's not set,
 784 # otherwise doesn't do anything
 785 # If $USING_GLOBALS, then sets an appropriate global.
 786
 787 sub set_default{
 788      my ($config,$option,$value) = @_;
 789      my $varname;
 790      if ($USING_GLOBALS) {
 791           # fix up the variable name
 792           $varname = 'g'.join('',map {ucfirst $_} split /_/, $option);
 793           # Fix stupid HTML names
 794           $varname =~ s/(Html|Cgi)/uc($1)/ge;
 795      }
 796      # update the configuration value
 797      if (not $USING_GLOBALS and not exists $config->{$option}) {
 798           $config->{$option} = $value;
 799      }
 800      elsif ($USING_GLOBALS) {{
 801           no strict 'refs';
 802           # Need to check if a value has already been set in a global
 803           if (defined *{"Debbugs::Config::${varname}"}) {
 804                $config->{$option} = *{"Debbugs::Config::${varname}"};
 805           }
 806           else {
 807                $config->{$option} = $value;
 808           }
 809      }}
 810      if ($USING_GLOBALS) {{
 811           no strict 'refs';
 812           *{"Debbugs::Config::${varname}"} = $config->{$option};
 813      }}
 814 }
 815
 816
 817 ### import magick
 818
 819 # All we care about here is whether we've been called with the globals or text option;
 820 # if so, then we need to export some symbols back up.
 821 # In any event, we call exporter.
 822
 823 sub import {
 824      if (grep /^:(?:text|globals)$/, @_) {
 825           $USING_GLOBALS=1;
 826           for my $variable (map {@$_} @EXPORT_TAGS{map{(/^:(text|globals)$/?($1):())} @_}) {
 827                my $tmp = $variable;
 828                no strict 'refs';
 829                # Yes, I don't care if these are only used once
 830                no warnings 'once';
 831                # No, it doesn't bother me that I'm assigning an undefined value to a typeglob
 832                no warnings 'misc';
 833                my ($hash_name,$glob_name,$glob_type) = __convert_name($variable);
 834                $tmp =~ s/^[\%\$\@]//;
 835                *{"Debbugs::Config::${tmp}"} = ref($config{$hash_name})?$config{$hash_name}:\$config{$hash_name};
 836           }
 837      }
 838      Debbugs::Config->export_to_level(1,@_);
 839 }
 840
 841
 842 1;