Debbugs/Config.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later
   3 # version at your option.
   4 # See the file README and COPYING for more information.
   5 #
   6 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
   7
   8 package Debbugs::Config;
   9
  10 =head1 NAME
  11
  12 Debbugs::Config -- Configuration information for debbugs
  13
  14 =head1 SYNOPSIS
  15
  16  use Debbugs::Config;
  17
  18 # to get the compatiblity interface
  19
  20  use Debbugs::Config qw(:globals);
  21
  22 =head1 DESCRIPTION
  23
  24 This module provides configuration variables for all of debbugs.
  25
  26 =head1 CONFIGURATION FILES
  27
  28 The default configuration file location is /etc/debbugs/config; this
  29 configuration file location can be set by modifying the
  30 DEBBUGS_CONFIG_FILE env variable to point at a different location.
  31
  32 =cut
  33
  34 use warnings;
  35 use strict;
  36 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT $USING_GLOBALS %config);
  37 use base qw(Exporter);
  38
  39 BEGIN {
  40      # set the version for version checking
  41      $VERSION     = 1.00;
  42      $DEBUG = 0 unless defined $DEBUG;
  43      $USING_GLOBALS = 0;
  44
  45      @EXPORT = ();
  46      %EXPORT_TAGS = (globals => [qw($gEmailDomain $gListDomain $gWebHost $gWebHostBugDir),
  47                                  qw($gWebDomain $gHTMLSuffix $gCGIDomain $gMirrors),
  48                                  qw($gPackagePages $gSubscriptionDomain $gProject $gProjectTitle),
  49                                  qw($gMaintainer $gMaintainerWebpage $gMaintainerEmail $gUnknownMaintainerEmail),
  50                                  qw($gSubmitList $gMaintList $gQuietList $gForwardList),
  51                                  qw($gDoneList $gRequestList $gSubmitterList $gControlList),
  52                                  qw($gStrongList),
  53                                  qw($gPackageVersionRe),
  54                                  qw($gSummaryList $gMirrorList $gMailer $gBug),
  55                                  qw($gBugs $gRemoveAge $gSaveOldBugs $gDefaultSeverity),
  56                                  qw($gShowSeverities $gBounceFroms $gConfigDir $gSpoolDir),
  57                                  qw($gIncomingDir $gWebDir $gDocDir $gMaintainerFile),
  58                                  qw($gMaintainerFileOverride $gPseudoMaintFile $gPseudoDescFile $gPackageSource),
  59                                  qw($gVersionPackagesDir $gVersionIndex $gBinarySourceMap $gSourceBinaryMap),
  60                                  qw($gVersionTimeIndex),
  61                                  qw($gSendmail $gLibPath $gSpamScan @gExcludeFromControl),
  62                                  qw(%gSeverityDisplay @gTags @gSeverityList @gStrongSeverities),
  63                                  qw(%gSearchEstraier),
  64                                  qw(%gDistributionAliases),
  65                                  qw(@gPostProcessall @gRemovalDefaultDistributionTags @gRemovalDistributionTags @gRemovalArchitectures),
  66                                  qw(@gRemovalStrongSeverityDefaultDistributionTags),
  67                                  qw(@gDefaultArchitectures),
  68                                  qw($gTemplateDir),
  69                                  qw($gDefaultPackage),
  70                                  qw($gSpamMaxThreads $gSpamSpamsPerThread $gSpamKeepRunning $gSpamScan $gSpamCrossassassinDb)
  71                                 ],
  72                      text     => [qw($gBadEmailPrefix $gHTMLTail $gHTMLExpireNote),
  73                                  ],
  74                      config   => [qw(%config)],
  75                     );
  76      @EXPORT_OK = ();
  77      Exporter::export_ok_tags(qw(globals text config));
  78      $EXPORT_TAGS{all} = [@EXPORT_OK];
  79 }
  80
  81 use File::Basename qw(dirname);
  82 use IO::File;
  83 use Safe;
  84
  85 =head1 CONFIGURATION VARIABLES
  86
  87 =head2 General Configuration
  88
  89 =over
  90
  91 =cut
  92
  93 # read in the files;
  94 %config = ();
  95 # untaint $ENV{DEBBUGS_CONFIG_FILE} if it's owned by us
  96 # This enables us to test things that are -T.
  97 if (exists $ENV{DEBBUGS_CONFIG_FILE}) {
  98      if (${[stat($ENV{DEBBUGS_CONFIG_FILE})]}[4] = $<) {
  99           $ENV{DEBBUGS_CONFIG_FILE} =~ /(.+)/;
 100           $ENV{DEBBUGS_CONFIG_FILE} = $1;
 101      }
 102      else {
 103           die "Environmental variable DEBBUGS_CONFIG_FILE set, and $ENV{DEBBUGS_CONFIG_FILE} is not owned by the user running this script.";
 104      }
 105 }
 106 read_config(exists $ENV{DEBBUGS_CONFIG_FILE}?$ENV{DEBBUGS_CONFIG_FILE}:'/etc/debbugs/config');
 107
 108 =item email_domain $gEmailDomain
 109
 110 The email domain of the bts
 111
 112 =cut
 113
 114 set_default(\%config,'email_domain','bugs.something');
 115
 116 =item list_domain $gListDomain
 117
 118 The list domain of the bts, defaults to the email domain
 119
 120 =cut
 121
 122 set_default(\%config,'list_domain',$config{email_domain});
 123
 124 =item web_host $gWebHost
 125
 126 The web host of the bts; defaults to the email domain
 127
 128 =cut
 129
 130 set_default(\%config,'web_host',$config{email_domain});
 131
 132 =item web_host_bug_dir $gWebHostDir
 133
 134 The directory of the web host on which bugs are kept, defaults to C<''>
 135
 136 =cut
 137
 138 set_default(\%config,'web_host_bug_dir','');
 139
 140 =item web_domain $gWebDomain
 141
 142 Full path of the web domain where bugs are kept, defaults to the
 143 concatenation of L</web_host> and L</web_host_bug_dir>
 144
 145 =cut
 146
 147 set_default(\%config,'web_domain',$config{web_host}.($config{web_host}=~m{/$}?'':'/').$config{web_host_bug_dir});
 148
 149 =item html_suffix $gHTMLSuffix
 150
 151 Suffix of html pages, defaults to .html
 152
 153 =cut
 154
 155 set_default(\%config,'html_suffix','.html');
 156
 157 =item cgi_domain $gCGIDomain
 158
 159 Full path of the web domain where cgi scripts are kept. Defaults to
 160 the concatentation of L</web_host> and cgi.
 161
 162 =cut
 163
 164 set_default(\%config,'cgi_domain',$config{web_domain}.($config{web_domain}=~m{/$}?'':'/').'cgi');
 165
 166 =item mirrors @gMirrors
 167
 168 List of mirrors [What these mirrors are used for, no one knows.]
 169
 170 =cut
 171
 172
 173 set_default(\%config,'mirrors',[]);
 174
 175 =item package_pages  $gPackagePages
 176
 177 Domain where the package pages are kept; links should work in a
 178 package_pages/foopackage manner. Defaults to undef, which means that
 179 package links will not be made.
 180
 181 =cut
 182
 183
 184 set_default(\%config,'package_pages',undef);
 185
 186 =item package_pages  $gUsertagPackageDomain
 187
 188 Domain where where usertags of packages belong; defaults to $gPackagePages
 189
 190 =cut
 191
 192 set_default(\%config,'usertag_package_domain',$config{package_pages});
 193
 194
 195 =item subscription_domain $gSubscriptionDomain
 196
 197 Domain where subscriptions to package lists happen
 198
 199 =cut
 200
 201
 202 set_default(\%config,'subscription_domain',undef);
 203
 204 =back
 205
 206 =cut
 207
 208
 209 =head2 Project Identification
 210
 211 =over
 212
 213 =item project $gProject
 214
 215 Name of the project
 216
 217 Default: 'Something'
 218
 219 =cut
 220
 221 set_default(\%config,'project','Something');
 222
 223 =item project_title $gProjectTitle
 224
 225 Name of this install of Debbugs, defaults to "L</project> Debbugs Install"
 226
 227 Default: "$config{project} Debbugs Install"
 228
 229 =cut
 230
 231 set_default(\%config,'project_title',"$config{project} Debbugs Install");
 232
 233 =item maintainer $gMaintainer
 234
 235 Name of the maintainer of this debbugs install
 236
 237 Default: 'Local DebBugs Owner's
 238
 239 =cut
 240
 241 set_default(\%config,'maintainer','Local DebBugs Owner');
 242
 243 =item maintainer_webpage $gMaintainerWebpage
 244
 245 Webpage of the maintainer of this install of debbugs
 246
 247 Default: "$config{web_domain}/~owner"
 248
 249 =cut
 250
 251 set_default(\%config,'maintainer_webpage',"$config{web_domain}/~owner");
 252
 253 =item maintainer_email $gMaintainerEmail
 254
 255 Email address of the maintainer of this Debbugs install
 256
 257 Default: 'root@'.$config{email_domain}
 258
 259 =cut
 260
 261 set_default(\%config,'maintainer_email','root@'.$config{email_domain});
 262
 263 =item unknown_maintainer_email
 264
 265 Email address where packages with an unknown maintainer will be sent
 266
 267 Default: $config{maintainer_email}
 268
 269 =back
 270
 271 =cut
 272
 273 set_default(\%config,'unknown_maintainer_email',$config{maintainer_email});
 274
 275 =head2 BTS Mailing Lists
 276
 277
 278 =over
 279
 280 =item submit_list
 281
 282 =item maint_list
 283
 284 =item forward_list
 285
 286 =item done_list
 287
 288 =item request_list
 289
 290 =item submitter_list
 291
 292 =item control_list
 293
 294 =item summary_list
 295
 296 =item mirror_list
 297
 298 =back
 299
 300 =cut
 301
 302 set_default(\%config,   'submit_list',   'bug-submit-list');
 303 set_default(\%config,    'maint_list',    'bug-maint-list');
 304 set_default(\%config,    'quiet_list',    'bug-quiet-list');
 305 set_default(\%config,  'forward_list',  'bug-forward-list');
 306 set_default(\%config,     'done_list',     'bug-done-list');
 307 set_default(\%config,  'request_list',  'bug-request-list');
 308 set_default(\%config,'submitter_list','bug-submitter-list');
 309 set_default(\%config,  'control_list',  'bug-control-list');
 310 set_default(\%config,  'summary_list',  'bug-summary-list');
 311 set_default(\%config,   'mirror_list',   'bug-mirror-list');
 312 set_default(\%config,   'strong_list',   'bug-strong-list');
 313
 314 =head2 Misc Options
 315
 316 =over
 317
 318 =cut
 319
 320 set_default(\%config,'mailer','exim');
 321 set_default(\%config,'bug','bug');
 322 set_default(\%config,'bugs','bugs');
 323
 324 =item remove_age
 325
 326 Age at which bugs are archived/removed
 327
 328 Default: 28
 329
 330 =cut
 331
 332 set_default(\%config,'remove_age',28);
 333
 334 =item save_old_bugs
 335
 336 Whether old bugs are saved or deleted
 337
 338 Default: 1
 339
 340 =cut
 341
 342 set_default(\%config,'save_old_bugs',1);
 343
 344 =item distribution_aliases
 345
 346 Map of distribution aliases to the distribution name
 347
 348 Default:
 349          {experimental => 'experimental',
 350           unstable     => 'unstable',
 351           testing      => 'testing',
 352           stable       => 'stable',
 353           oldstable    => 'oldstable',
 354           sid          => 'unstable',
 355           lenny        => 'testing',
 356           etch         => 'stable',
 357           sarge        => 'oldstable',
 358          }
 359
 360 =cut
 361
 362 set_default(\%config,'distribution_aliases',
 363             {experimental => 'experimental',
 364              unstable     => 'unstable',
 365              testing      => 'testing',
 366              stable       => 'stable',
 367              oldstable    => 'oldstable',
 368              sid          => 'unstable',
 369              lenny        => 'testing',
 370              etch         => 'stable',
 371              sarge        => 'oldstable',
 372             },
 373            );
 374
 375
 376
 377 =item distributions
 378
 379 List of valid distributions
 380
 381 Default: The values of the distribution aliases map.
 382
 383 =cut
 384
 385 my %_distributions_default;
 386 @_distributions_default{values %{$config{distribution_aliases}}} = values %{$config{distribution_aliases}};
 387 set_default(\%config,'distributions',[keys %_distributions_default]);
 388
 389
 390 =item default_architectures
 391
 392 List of default architectures to use when architecture(s) are not
 393 specified
 394
 395 Default: i386 amd64 arm ppc sparc alpha
 396
 397 =cut
 398
 399 set_default(\%config,'default_architectures',
 400             [qw(i386 amd64 arm powerpc sparc alpha)]
 401            );
 402
 403 =item removal_distribution_tags
 404
 405 Tags which specifiy distributions to check
 406
 407 Default: @{$config{distributions}}
 408
 409 =cut
 410
 411 set_default(\%config,'removal_distribution_tags',
 412             [@{$config{distributions}}]);
 413
 414 =item removal_default_distribution_tags
 415
 416 For removal/archival purposes, all bugs are assumed to have these tags
 417 set.
 418
 419 Default: qw(unstable testing);
 420
 421 =cut
 422
 423 set_default(\%config,'removal_default_distribution_tags',
 424             [qw(unstable testing)]
 425            );
 426
 427 =item removal_strong_severity_default_distribution_tags
 428
 429 For removal/archival purposes, all bugs with strong severity are
 430 assumed to have these tags set.
 431
 432 Default: qw(unstable testing stable);
 433
 434 =cut
 435
 436 set_default(\%config,'removal_strong_severity_default_distribution_tags',
 437             [qw(unstable testing stable)]
 438            );
 439
 440
 441 =item removal_architectures
 442
 443 For removal/archival purposes, these architectures are consulted if
 444 there is more than one architecture applicable. If the bug is in a
 445 package not in any of these architectures, the architecture actually
 446 checked is undefined.
 447
 448 Default: value of default_architectures
 449
 450 =cut
 451
 452 set_default(\%config,'removal_architectures',
 453             $config{default_architectures},
 454            );
 455
 456
 457 =item package_name_re
 458
 459 The regex which will match a package name
 460
 461 Default: '[a-z0-9][a-z0-9\.+-]+'
 462
 463 =cut
 464
 465 set_default(\%config,'package_name_re',
 466             '[a-z0-9][a-z0-9\.+-]+');
 467
 468 =item package_version_re
 469
 470 The regex which will match a package version
 471
 472 Default: '[A-Za-z0-9:+\.-]+'
 473
 474 =cut
 475
 476
 477 set_default(\%config,'package_version_re',
 478             '[A-Za-z0-9:+\.~-]+');
 479
 480
 481 =item default_package
 482
 483 This is the name of the default package. If set, bugs assigned to
 484 packages without a maintainer and bugs missing a Package: psuedoheader
 485 will be assigned to this package instead.
 486
 487 Defaults to unset, which is the traditional debbugs behavoir
 488
 489 =cut
 490
 491 set_default(\%config,'default_package',
 492             undef
 493            );
 494
 495
 496 =item control_internal_requester
 497
 498 This address is used by Debbugs::Control as the request address which
 499 sent a control request for faked log messages.
 500
 501 Default:"Debbugs Internal Request <$config{maintainer_email}>"
 502
 503 =cut
 504
 505 set_default(\%config,'control_internal_requester',
 506             "Debbugs Internal Request <$config{maintainer_email}>",
 507            );
 508
 509 =item control_internal_request_addr
 510
 511 This address is used by Debbugs::Control as the address to which a
 512 faked log message request was sent.
 513
 514 Default: "internal_control\@$config{email_domain}";
 515
 516 =cut
 517
 518 set_default(\%config,'control_internal_request_addr',
 519             'internal_control@'.$config{email_domain},
 520            );
 521
 522
 523 =item exclude_from_control
 524
 525 Addresses which are not allowed to send messages to control
 526
 527 =cut
 528
 529 set_default(\%config,'exclude_from_control',[]);
 530
 531
 532
 533
 534 set_default(\%config,'default_severity','normal');
 535 set_default(\%config,'show_severities','critical, grave, normal, minor, wishlist');
 536 set_default(\%config,'strong_severities',[qw(critical grave)]);
 537 set_default(\%config,'severity_list',[qw(critical grave normal wishlist)]);
 538 set_default(\%config,'severity_display',{critical => "Critical $config{bugs}",
 539                                          grave    => "Grave $config{bugs}",
 540                                          normal   => "Normal $config{bugs}",
 541                                          wishlist => "Wishlist $config{bugs}",
 542                                         });
 543
 544 set_default(\%config,'tags',[qw(patch wontfix moreinfo unreproducible fixed),
 545                              @{$config{distributions}}
 546                             ]);
 547
 548 set_default(\%config,'bounce_froms','^mailer|^da?emon|^post.*mast|^root|^wpuser|^mmdf|^smt.*|'.
 549             '^mrgate|^vmmail|^mail.*system|^uucp|-maiser-|^mal\@|'.
 550             '^mail.*agent|^tcpmail|^bitmail|^mailman');
 551
 552 set_default(\%config,'config_dir',dirname(exists $ENV{DEBBUGS_CONFIG_FILE}?$ENV{DEBBUGS_CONFIG_FILE}:'/etc/debbugs/config'));
 553 set_default(\%config,'spool_dir','/var/lib/debbugs/spool');
 554 set_default(\%config,'incoming_dir','incoming');
 555 set_default(\%config,'web_dir','/var/lib/debbugs/www');
 556 set_default(\%config,'doc_dir','/var/lib/debbugs/www/txt');
 557 set_default(\%config,'lib_path','/usr/lib/debbugs');
 558
 559
 560 =item template_dir
 561
 562 directory of templates; defaults to /usr/share/debbugs/templates.
 563
 564 =cut
 565
 566 set_default(\%config,'template_dir','/usr/share/debbugs/templates');
 567
 568
 569 set_default(\%config,'maintainer_file',$config{config_dir}.'/Maintainers');
 570 set_default(\%config,'maintainer_file_override',$config{config_dir}.'/Maintainers.override');
 571 set_default(\%config,'pseudo_maint_file',$config{config_dir}.'/pseudo-packages.maint');
 572 set_default(\%config,'pseudo_desc_file',$config{config_dir}.'/pseudo-packages.description');
 573 set_default(\%config,'package_source',$config{config_dir}.'/indices/sources');
 574
 575
 576 =item version_packages_dir
 577
 578 Location where the version package information is kept; defaults to
 579 spool_dir/../versions/pkg
 580
 581 =cut
 582
 583 set_default(\%config,'version_packages_dir',$config{spool_dir}.'/../versions/pkg');
 584
 585 =item version_time_index
 586
 587 Location of the version/time index file. Defaults to
 588 spool_dir/../versions/idx/versions_time.idx if spool_dir/../versions
 589 exists; otherwise defaults to undef.
 590
 591 =cut
 592
 593
 594 set_default(\%config,'version_time_index', -d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/versions_time.idx' : undef);
 595
 596 =item version_index
 597
 598 Location of the version index file. Defaults to
 599 spool_dir/../versions/indices/versions.idx if spool_dir/../versions
 600 exists; otherwise defaults to undef.
 601
 602 =cut
 603
 604 set_default(\%config,'version_index',-d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/versions.idx' : undef);
 605
 606 =item binary_source_map
 607
 608 Location of the binary -> source map. Defaults to
 609 spool_dir/../versions/indices/bin2src.idx if spool_dir/../versions
 610 exists; otherwise defaults to undef.
 611
 612 =cut
 613
 614 set_default(\%config,'binary_source_map',-d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/binsrc.idx' : undef);
 615
 616 =item source_binary_map
 617
 618 Location of the source -> binary map. Defaults to
 619 spool_dir/../versions/indices/src2bin.idx if spool_dir/../versions
 620 exists; otherwise defaults to undef.
 621
 622 =cut
 623
 624 set_default(\%config,'source_binary_map',-d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/srcbin.idx' : undef);
 625
 626
 627
 628 set_default(\%config,'post_processall',[]);
 629
 630 =item sendmail
 631
 632 Sets the sendmail binary to execute; defaults to /usr/lib/sendmail
 633
 634 =cut
 635
 636 set_default(\%config,'sendmail','/usr/lib/sendmail');
 637
 638 =item spam_scan
 639
 640 Whether or not spamscan is being used; defaults to 0 (not being used
 641
 642 =cut
 643
 644 set_default(\%config,'spam_scan',0);
 645
 646 =item spam_crossassassin_db
 647
 648 Location of the crosassassin database, defaults to
 649 spool_dir/../CrossAssassinDb
 650
 651 =cut
 652
 653 set_default(\%config,'spam_crossassassin_db',$config{spool_dir}.'/../CrossAssassinDb');
 654
 655 =item spam_max_cross
 656
 657 Maximum number of cross-posted messages
 658
 659 =cut
 660
 661 set_default(\%config,'spam_max_cross',6);
 662
 663
 664 =item spam_spams_per_thread
 665
 666 Number of spams for each thread (on average). Defaults to 200
 667
 668 =cut
 669
 670 set_default(\%config,'spam_spams_per_thread',200);
 671
 672 =item spam_max_threads
 673
 674 Maximum number of threads to start. Defaults to 20
 675
 676 =cut
 677
 678 set_default(\%config,'spam_max_threads',20);
 679
 680 =item spam_keep_running
 681
 682 Maximum number of seconds to run without restarting. Defaults to 3600.
 683
 684 =cut
 685
 686 set_default(\%config,'spam_keep_running',3600);
 687
 688 =item spam_mailbox
 689
 690 Location to store spam messages; is run through strftime to allow for
 691 %d,%m,%Y, et al. Defaults to 'spool_dir/../mail/spam/assassinated.%Y-%m-%d'
 692
 693 =cut
 694
 695 set_default(\%config,'spam_mailbox',$config{spool_dir}.'/../mail/spam/assassinated.%Y-%m-%d');
 696
 697 =item spam_crossassassin_mailbox
 698
 699 Location to store crossassassinated messages; is run through strftime
 700 to allow for %d,%m,%Y, et al. Defaults to
 701 'spool_dir/../mail/spam/crossassassinated.%Y-%m-%d'
 702
 703 =cut
 704
 705 set_default(\%config,'spam_crossassassin_mailbox',$config{spool_dir}.'/../mail/spam/crossassassinated.%Y-%m-%d');
 706
 707 =item spam_local_tests_only
 708
 709 Whether only local tests are run, defaults to 0
 710
 711 =cut
 712
 713 set_default(\%config,'spam_local_tests_only',0);
 714
 715 =item spam_user_prefs
 716
 717 User preferences for spamassassin, defaults to $ENV{HOME}/.spamassassin/user_prefs
 718
 719 =cut
 720
 721 set_default(\%config,'spam_user_prefs',"$ENV{HOME}/.spamassassin/user_prefs");
 722
 723 =item spam_rules_dir
 724
 725 Site rules directory for spamassassin, defaults to
 726 '/usr/share/spamassassin'
 727
 728 =cut
 729
 730 set_default(\%config,'spam_rules_dir','/usr/share/spamassassin');
 731
 732
 733 =back
 734
 735
 736 =head2 Text Fields
 737
 738 The following are the only text fields in general use in the scripts;
 739 a few additional text fields are defined in text.in, but are only used
 740 in db2html and a few other specialty scripts.
 741
 742 Earlier versions of debbugs defined these values in /etc/debbugs/text,
 743 but now they are required to be in the configuration file. [Eventually
 744 the longer ones will move out into a fully fledged template system.]
 745
 746 =cut
 747
 748 =over
 749
 750 =item bad_email_prefix
 751
 752 This prefixes the text of all lines in a bad e-mail message ack.
 753
 754 =cut
 755
 756 set_default(\%config,'bad_email_prefix','');
 757
 758
 759 =item text_instructions
 760
 761 This gives more information about bad e-mails to receive.in
 762
 763 =cut
 764
 765 set_default(\%config,'text_instructions',$config{bad_email_prefix});
 766
 767 =item html_tail
 768
 769 This shows up at the end of (most) html pages
 770
 771 In many pages this has been replaced by the html/tail template.
 772
 773 =cut
 774
 775 set_default(\%config,'html_tail',<<END);
 776  <ADDRESS>$config{maintainer} &lt;<A HREF=\"mailto:$config{maintainer_email}\">$config{maintainer_email}</A>&gt;.
 777  Last modified:
 778  <!--timestamp-->
 779  SUBSTITUTE_DTIME
 780  <!--timestamp-->
 781  <P>
 782  <A HREF=\"http://$config{web_domain}/\">Debian $config{bug} tracking system</A><BR>
 783  Copyright (C) 1999 Darren O. Benham,
 784  1997,2003 nCipher Corporation Ltd,
 785  1994-97 Ian Jackson.
 786  </ADDRESS>
 787 END
 788
 789
 790 =item html_expire_note
 791
 792 This message explains what happens to archive/remove-able bugs
 793
 794 =cut
 795
 796 set_default(\%config,'html_expire_note',
 797             "(Closed $config{bugs} are archived $config{remove_age} days after the last related message is received.)");
 798
 799 =back
 800
 801 =cut
 802
 803
 804 sub read_config{
 805      my ($conf_file) = @_;
 806      # first, figure out what type of file we're reading in.
 807      my $fh = new IO::File $conf_file,'r'
 808           or die "Unable to open configuration file $conf_file for reading: $!";
 809      # A new version configuration file must have a comment as its first line
 810      my $first_line = <$fh>;
 811      my ($version) = defined $first_line?$first_line =~ /VERSION:\s*(\d+)/i:undef;
 812      if (defined $version) {
 813           if ($version == 1) {
 814                # Do something here;
 815                die "Version 1 configuration files not implemented yet";
 816           }
 817           else {
 818                die "Version $version configuration files are not supported";
 819           }
 820      }
 821      else {
 822           # Ugh. Old configuration file
 823           # What we do here is we create a new Safe compartment
 824           # so fucked up crap in the config file doesn't sink us.
 825           my $cpt = new Safe or die "Unable to create safe compartment";
 826           # perldoc Opcode; for details
 827           $cpt->permit('require',':filesys_read','entereval','caller','pack','unpack','dofile');
 828           $cpt->reval(qq(require '$conf_file';));
 829           die "Error in configuration file: $@" if $@;
 830           # Now what we do is check out the contents of %EXPORT_TAGS to see exactly which variables
 831           # we want to glob in from the configuration file
 832           for my $variable (@{$EXPORT_TAGS{globals}}) {
 833                my ($hash_name,$glob_name,$glob_type) = __convert_name($variable);
 834                my $var_glob = $cpt->varglob($glob_name);
 835                my $value; #= $cpt->reval("return $variable");
 836                # print STDERR "$variable $value",qq(\n);
 837                if (defined $var_glob) {{
 838                     no strict 'refs';
 839                     if ($glob_type eq '%') {
 840                          $value = {%{*{$var_glob}}} if defined *{$var_glob}{HASH};
 841                     }
 842                     elsif ($glob_type eq '@') {
 843                          $value = [@{*{$var_glob}}] if defined *{$var_glob}{ARRAY};
 844                     }
 845                     else {
 846                          $value = ${*{$var_glob}};
 847                     }
 848                     # We punt here, because we can't tell if the value was
 849                     # defined intentionally, or if it was just left alone;
 850                     # this tries to set sane defaults.
 851                     set_default(\%config,$hash_name,$value) if defined $value;
 852                }}
 853           }
 854      }
 855 }
 856
 857 sub __convert_name{
 858      my ($variable) = @_;
 859      my $hash_name = $variable;
 860      $hash_name =~ s/^([\$\%\@])g//;
 861      my $glob_type = $1;
 862      my $glob_name = 'g'.$hash_name;
 863      $hash_name =~ s/(HTML|CGI)/ucfirst(lc($1))/ge;
 864      $hash_name =~ s/^([A-Z]+)/lc($1)/e;
 865      $hash_name =~ s/([A-Z]+)/'_'.lc($1)/ge;
 866      return $hash_name unless wantarray;
 867      return ($hash_name,$glob_name,$glob_type);
 868 }
 869
 870 # set_default
 871
 872 # sets the configuration hash to the default value if it's not set,
 873 # otherwise doesn't do anything
 874 # If $USING_GLOBALS, then sets an appropriate global.
 875
 876 sub set_default{
 877      my ($config,$option,$value) = @_;
 878      my $varname;
 879      if ($USING_GLOBALS) {
 880           # fix up the variable name
 881           $varname = 'g'.join('',map {ucfirst $_} split /_/, $option);
 882           # Fix stupid HTML names
 883           $varname =~ s/(Html|Cgi)/uc($1)/ge;
 884      }
 885      # update the configuration value
 886      if (not $USING_GLOBALS and not exists $config->{$option}) {
 887           $config->{$option} = $value;
 888      }
 889      elsif ($USING_GLOBALS) {{
 890           no strict 'refs';
 891           # Need to check if a value has already been set in a global
 892           if (defined *{"Debbugs::Config::${varname}"}) {
 893                $config->{$option} = *{"Debbugs::Config::${varname}"};
 894           }
 895           else {
 896                $config->{$option} = $value;
 897           }
 898      }}
 899      if ($USING_GLOBALS) {{
 900           no strict 'refs';
 901           *{"Debbugs::Config::${varname}"} = $config->{$option};
 902      }}
 903 }
 904
 905
 906 ### import magick
 907
 908 # All we care about here is whether we've been called with the globals or text option;
 909 # if so, then we need to export some symbols back up.
 910 # In any event, we call exporter.
 911
 912 sub import {
 913      if (grep /^:(?:text|globals)$/, @_) {
 914           $USING_GLOBALS=1;
 915           for my $variable (map {@$_} @EXPORT_TAGS{map{(/^:(text|globals)$/?($1):())} @_}) {
 916                my $tmp = $variable;
 917                no strict 'refs';
 918                # Yes, I don't care if these are only used once
 919                no warnings 'once';
 920                # No, it doesn't bother me that I'm assigning an undefined value to a typeglob
 921                no warnings 'misc';
 922                my ($hash_name,$glob_name,$glob_type) = __convert_name($variable);
 923                $tmp =~ s/^[\%\$\@]//;
 924                *{"Debbugs::Config::${tmp}"} = ref($config{$hash_name})?$config{$hash_name}:\$config{$hash_name};
 925           }
 926      }
 927      Debbugs::Config->export_to_level(1,@_);
 928 }
 929
 930
 931 1;