Debbugs/Config.pm

   1
   2 package Debbugs::Config;
   3
   4 =head1 NAME
   5
   6 Debbugs::Config -- Configuration information for debbugs
   7
   8 =head1 SYNOPSIS
   9
  10  use Debbugs::Config;
  11
  12 # to get the compatiblity interface
  13
  14  use Debbugs::Config qw(:globals);
  15
  16 =head1 DESCRIPTION
  17
  18 This module provides configuration variables for all of debbugs.
  19
  20 =head1 CONFIGURATION FILES
  21
  22 The default configuration file location is /etc/debbugs/config; this
  23 configuration file location can be set by modifying the
  24 DEBBUGS_CONFIG_FILE env variable to point at a different location.
  25
  26 =cut
  27
  28 use warnings;
  29 use strict;
  30 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT $USING_GLOBALS %config);
  31 use base qw(Exporter);
  32
  33 BEGIN {
  34      # set the version for version checking
  35      $VERSION     = 1.00;
  36      $DEBUG = 0 unless defined $DEBUG;
  37      $USING_GLOBALS = 0;
  38
  39      @EXPORT = ();
  40      %EXPORT_TAGS = (globals => [qw($gEmailDomain $gListDomain $gWebHost $gWebHostBugDir),
  41                                  qw($gWebDomain $gHTMLSuffix $gCGIDomain $gMirrors),
  42                                  qw($gPackagePages $gSubscriptionDomain $gProject $gProjectTitle),
  43                                  qw($gMaintainer $gMaintainerWebpage $gMaintainerEmail $gUnknownMaintainerEmail),
  44                                  qw($gSubmitList $gMaintList $gQuietList $gForwardList),
  45                                  qw($gDoneList $gRequestList $gSubmitterList $gControlList),
  46                                  qw($gStrongList),
  47                                  qw($gSummaryList $gMirrorList $gMailer $gBug),
  48                                  qw($gBugs $gRemoveAge $gSaveOldBugs $gDefaultSeverity),
  49                                  qw($gShowSeverities $gBounceFroms $gConfigDir $gSpoolDir),
  50                                  qw($gIncomingDir $gWebDir $gDocDir $gMaintainerFile),
  51                                  qw($gMaintainerFileOverride $gPseudoDescFile $gPackageSource),
  52                                  qw($gVersionPackagesDir $gVersionIndex $gBinarySourceMap $gSourceBinaryMap),
  53                                  qw($gSendmail $gLibPath $gSpamScan),
  54                                  qw(%gSeverityDisplay @gTags @gSeverityList @gStrongSeverities),
  55                                  qw(%gSearchEstraier),
  56                                  qw(@gPostProcessall),
  57                                 ],
  58                      text     => [qw($gBadEmailPrefix $gHTMLTail $gHTMLExpireNote),
  59                                  ],
  60                      config   => [qw(%config)],
  61                     );
  62      @EXPORT_OK = ();
  63      Exporter::export_ok_tags(qw(globals text config));
  64      $EXPORT_TAGS{all} = [@EXPORT_OK];
  65 }
  66
  67 use File::Basename qw(dirname);
  68 use IO::File;
  69 use Safe;
  70
  71 =head1 CONFIGURATION VARIABLES
  72
  73 =head2 General Configuration
  74
  75 =over
  76
  77 =cut
  78
  79 # read in the files;
  80 %config = ();
  81 # untaint $ENV{DEBBUGS_CONFIG_FILE} if it's owned by us
  82 # This enables us to test things that are -T.
  83 if (exists $ENV{DEBBUGS_CONFIG_FILE} and
  84     ${[stat($ENV{DEBBUGS_CONFIG_FILE})]}[4] = $<) {
  85      $ENV{DEBBUGS_CONFIG_FILE} =~ /(.+)/;
  86      $ENV{DEBBUGS_CONFIG_FILE} = $1;
  87 }
  88 read_config(exists $ENV{DEBBUGS_CONFIG_FILE}?$ENV{DEBBUGS_CONFIG_FILE}:'/etc/debbugs/config');
  89
  90 =item email_domain $gEmailDomain
  91
  92 The email domain of the bts
  93
  94 =cut
  95
  96 set_default(\%config,'email_domain','bugs.something');
  97
  98 =item list_domain $gListDomain
  99
 100 The list domain of the bts, defaults to the email domain
 101
 102 =cut
 103
 104 set_default(\%config,'list_domain',$config{email_domain});
 105
 106 =item web_host $gWebHost
 107
 108 The web host of the bts; defaults to the email domain
 109
 110 =cut
 111
 112 set_default(\%config,'web_host',$config{email_domain});
 113
 114 =item web_host_bug_dir $gWebHostDir
 115
 116 The directory of the web host on which bugs are kept, defaults to C<''>
 117
 118 =cut
 119
 120 set_default(\%config,'web_host_bug_dir','');
 121
 122 =item web_domain $gWebDomain
 123
 124 Full path of the web domain where bugs are kept, defaults to the
 125 concatenation of L</web_host> and L</web_host_bug_dir>
 126
 127 =cut
 128
 129 set_default(\%config,'web_domain',$config{web_host}.'/'.$config{web_host_bug_dir});
 130
 131 =item html_suffix $gHTMLSuffix
 132
 133 Suffix of html pages, defaults to .html
 134
 135 =cut
 136
 137 set_default(\%config,'html_suffix','.html');
 138
 139 =item cgi_domain $gCGIDomain
 140
 141 Full path of the web domain where cgi scripts are kept. Defaults to
 142 the concatentation of L</web_host> and cgi.
 143
 144 =cut
 145
 146 set_default(\%config,'cgi_domain',$config{web_domain}.($config{web_domain}=~m{/$}?'':'/').'cgi');
 147
 148 =item mirrors @gMirrors
 149
 150 List of mirrors [What these mirrors are used for, no one knows.]
 151
 152 =cut
 153
 154
 155 set_default(\%config,'mirrors',[]);
 156
 157 =item package_pages  $gPackagePages
 158
 159 Domain where the package pages are kept; links should work in a
 160 package_pages/foopackage manner. Defaults to undef, which means that
 161 package links will not be made.
 162
 163 =cut
 164
 165
 166 set_default(\%config,'package_pages',undef);
 167
 168 =item subscription_domain $gSubscriptionDomain
 169
 170 Domain where subscriptions to package lists happen
 171
 172 =cut
 173
 174
 175 set_default(\%config,'subscription_domain',undef);
 176
 177 =back
 178
 179 =cut
 180
 181
 182 =head2 Project Identification
 183
 184 =over
 185
 186 =item project $gProject
 187
 188 Name of the project
 189
 190 Default: 'Something'
 191
 192 =cut
 193
 194 set_default(\%config,'project','Something');
 195
 196 =item project_title $gProjectTitle
 197
 198 Name of this install of Debbugs, defaults to "L</project> Debbugs Install"
 199
 200 Default: "$config{project} Debbugs Install"
 201
 202 =cut
 203
 204 set_default(\%config,'project_title',"$config{project} Debbugs Install");
 205
 206 =item maintainer $gMaintainer
 207
 208 Name of the maintainer of this debbugs install
 209
 210 Default: 'Local DebBugs Owner's
 211
 212 =cut
 213
 214 set_default(\%config,'maintainer','Local DebBugs Owner');
 215
 216 =item maintainer_webpage $gMaintainerWebpage
 217
 218 Webpage of the maintainer of this install of debbugs
 219
 220 Default: "$config{web_domain}/~owner"
 221
 222 =cut
 223
 224 set_default(\%config,'maintainer_webpage',"$config{web_domain}/~owner");
 225
 226 =item maintainer_email
 227
 228 Email address of the maintainer of this Debbugs install
 229
 230 Default: 'root@'.$config{email_domain}
 231
 232 =cut
 233
 234 set_default(\%config,'maintainer_email','root@'.$config{email_domain});
 235
 236 =item unknown_maintainer_email
 237
 238 Email address where packages with an unknown maintainer will be sent
 239
 240 Default: $config{maintainer_email}
 241
 242 =back
 243
 244 =cut
 245
 246 set_default(\%config,'unknown_maintainer_email',$config{maintainer_email});
 247
 248 =head2 BTS Mailing Lists
 249
 250
 251 =over
 252
 253 =item submit_list
 254
 255 =item maint_list
 256
 257 =item forward_list
 258
 259 =item done_list
 260
 261 =item request_list
 262
 263 =item submitter_list
 264
 265 =item control_list
 266
 267 =item summary_list
 268
 269 =item mirror_list
 270
 271 =back
 272
 273 =cut
 274
 275 set_default(\%config,   'submit_list',   'bug-submit-list');
 276 set_default(\%config,    'maint_list',    'bug-maint-list');
 277 set_default(\%config,    'quiet_list',    'bug-quiet-list');
 278 set_default(\%config,  'forward_list',  'bug-forward-list');
 279 set_default(\%config,     'done_list',     'bug-done-list');
 280 set_default(\%config,  'request_list',  'bug-request-list');
 281 set_default(\%config,'submitter_list','bug-submitter-list');
 282 set_default(\%config,  'control_list',  'bug-control-list');
 283 set_default(\%config,  'summary_list',  'bug-summary-list');
 284 set_default(\%config,   'mirror_list',   'bug-mirror-list');
 285 set_default(\%config,   'strong_list',   'bug-strong-list');
 286
 287 =head2 Misc Options
 288
 289 =over
 290
 291 =cut
 292
 293 set_default(\%config,'mailer','exim');
 294 set_default(\%config,'bug','bug');
 295 set_default(\%config,'bugs','bugs');
 296
 297 =item remove_age
 298
 299 Age at which bugs are archived/removed
 300
 301 Default: 28
 302
 303 =cut
 304
 305 set_default(\%config,'remove_age',28);
 306
 307 =item save_old_bugs
 308
 309 Whether old bugs are saved or deleted
 310
 311 Default: 1
 312
 313 =cut
 314
 315 set_default(\%config,'save_old_bugs',1);
 316
 317 =item distributions
 318
 319 List of valid distributions
 320
 321 Default: qw(experimental unstable testing stable oldstable);
 322
 323 =cut
 324
 325 set_default(\%config,'distributions',[qw(experimental unstable testing stable oldstable)]);
 326
 327 =item removal_distribution_tags
 328
 329 Tags which specifiy distributions to check
 330
 331 Default: @{$config{distributions}}
 332
 333 =cut
 334
 335 set_default(\%config,'removal_distribution_tags',
 336             [@{$config{distributions}}]);
 337
 338 =item removal_default_distribution_tags
 339
 340 For removal/archival purposes, all bugs are assumed to have these tags
 341 set.
 342
 343 Default: qw(unstable testing);
 344
 345 =cut
 346
 347 set_default(\%config,'removal_default_distribution_tags',
 348             [qw(unstable testing)]
 349            );
 350
 351 =item package_name_re
 352
 353 The regex which will match a package name
 354
 355 Default: '[a-z0-9][a-z0-9\.+-]+'
 356
 357 =cut
 358
 359 set_default(\%config,'package_name_re',
 360             '[a-z0-9][a-z0-9\.+-]+');
 361
 362 =item package_version_re
 363
 364 The regex which will match a package version
 365
 366 Default: '[A-Za-z0-9:+\.-]+'
 367
 368 =cut
 369
 370 set_default(\%config,'package_version_re',
 371             '[A-Za-z0-9:+\.-]+');
 372
 373
 374
 375
 376
 377
 378
 379 set_default(\%config,'default_severity','normal');
 380 set_default(\%config,'show_severities','critical, grave, normal, minor, wishlist');
 381 set_default(\%config,'strong_severities',[qw(critical grave)]);
 382 set_default(\%config,'severity_list',[qw(critical grave normal wishlist)]);
 383 set_default(\%config,'severity_display',{critical => "Critical $config{bugs}",
 384                                          grave    => "Grave $config{bugs}",
 385                                          normal   => "Normal $config{bugs}",
 386                                          wishlist => "Wishlist $config{bugs}",
 387                                         });
 388
 389 set_default(\%config,'tags',[qw(patch wontfix moreinfo unreproducible fixed),
 390                              @{$config{distributions}}
 391                             ]);
 392
 393 set_default(\%config,'bounce_froms','^mailer|^da?emon|^post.*mast|^root|^wpuser|^mmdf|^smt.*|'.
 394             '^mrgate|^vmmail|^mail.*system|^uucp|-maiser-|^mal\@|'.
 395             '^mail.*agent|^tcpmail|^bitmail|^mailman');
 396
 397 set_default(\%config,'config_dir',dirname(exists $ENV{DEBBUGS_CONFIG_FILE}?$ENV{DEBBUGS_CONFIG_FILE}:'/etc/debbugs/config'));
 398 set_default(\%config,'spool_dir','/var/lib/debbugs/spool');
 399 set_default(\%config,'incoming_dir','incoming');
 400 set_default(\%config,'web_dir','/var/lib/debbugs/www');
 401 set_default(\%config,'doc_dir','/var/lib/debbugs/www/txt');
 402 set_default(\%config,'lib_path','/usr/lib/debbugs');
 403
 404 set_default(\%config,'maintainer_file',$config{config_dir}.'/Maintainers');
 405 set_default(\%config,'maintainer_file_override',$config{config_dir}.'/Maintainers.override');
 406 set_default(\%config,'pseudo_desc_file',$config{config_dir}.'/pseudo-packages.description');
 407 set_default(\%config,'package_source',$config{config_dir}.'/indices/sources');
 408
 409 set_default(\%config,'version_packages_dir',$config{spool_dir}.'/../versions/pkg');
 410
 411 set_default(\%config,'post_processall',[]);
 412
 413 =item sendmail
 414
 415 Sets the sendmail binary to execute; defaults to /usr/lib/sendmail
 416
 417 =cut
 418
 419 set_default(\%config,'sendmail','/usr/lib/sendmail');
 420
 421 =item spam_scan
 422
 423 Whether or not spamscan is being used; defaults to 0 (not being used
 424
 425 =cut
 426
 427 set_default(\%config,'spam_scan',0);
 428
 429
 430 =back
 431
 432
 433 =head2 Text Fields
 434
 435 The following are the only text fields in general use in the scripts;
 436 a few additional text fields are defined in text.in, but are only used
 437 in db2html and a few other specialty scripts.
 438
 439 Earlier versions of debbugs defined these values in /etc/debbugs/text,
 440 but now they are required to be in the configuration file. [Eventually
 441 the longer ones will move out into a fully fledged template system.]
 442
 443 =cut
 444
 445 =over
 446
 447 =item bad_email_prefix
 448
 449 This prefixes the text of all lines in a bad e-mail message ack.
 450
 451 =cut
 452
 453 set_default(\%config,'bad_email_prefix','');
 454
 455
 456 =item text_instructions
 457
 458 This gives more information about bad e-mails to receive.in
 459
 460 =cut
 461
 462 set_default(\%config,'text_instructions',$config{bad_email_prefix});
 463
 464 =item html_tail
 465
 466 This shows up at the end of (most) html pages
 467
 468 =cut
 469
 470 set_default(\%config,'html_tail',<<END);
 471  <ADDRESS>$config{maintainer} &lt;<A HREF=\"mailto:$config{maintainer_email}\">$config{maintainer_email}</A>&gt;.
 472  Last modified:
 473  <!--timestamp-->
 474  SUBSTITUTE_DTIME
 475  <!--timestamp-->
 476  <P>
 477  <A HREF=\"http://$config{web_domain}/\">Debian $config{bug} tracking system</A><BR>
 478  Copyright (C) 1999 Darren O. Benham,
 479  1997,2003 nCipher Corporation Ltd,
 480  1994-97 Ian Jackson.
 481  </ADDRESS>
 482 END
 483
 484
 485 =item html_expire_note
 486
 487 This message explains what happens to archive/remove-able bugs
 488
 489 =cut
 490
 491 set_default(\%config,'html_expire_note',
 492             "(Closed $config{bugs} are archived $config{remove_age} days after the last related message is received.)");
 493
 494 =back
 495
 496 =cut
 497
 498
 499 sub read_config{
 500      my ($conf_file) = @_;
 501      # first, figure out what type of file we're reading in.
 502      my $fh = new IO::File $conf_file,'r'
 503           or die "Unable to open configuration file $conf_file for reading: $!";
 504      # A new version configuration file must have a comment as its first line
 505      my $first_line = <$fh>;
 506      my ($version) = defined $first_line?$first_line =~ /VERSION:\s*(\d+)/i:undef;
 507      if (defined $version) {
 508           if ($version == 1) {
 509                # Do something here;
 510                die "Version 1 configuration files not implemented yet";
 511           }
 512           else {
 513                die "Version $version configuration files are not supported";
 514           }
 515      }
 516      else {
 517           # Ugh. Old configuration file
 518           # What we do here is we create a new Safe compartment
 519           # so fucked up crap in the config file doesn't sink us.
 520           my $cpt = new Safe or die "Unable to create safe compartment";
 521           # perldoc Opcode; for details
 522           $cpt->permit('require',':filesys_read','entereval','caller','pack','unpack','dofile');
 523           $cpt->reval(qq(require '$conf_file';));
 524           die "Error in configuration file: $@" if $@;
 525           # Now what we do is check out the contents of %EXPORT_TAGS to see exactly which variables
 526           # we want to glob in from the configuration file
 527           for my $variable (@{$EXPORT_TAGS{globals}}) {
 528                my ($hash_name,$glob_name,$glob_type) = __convert_name($variable);
 529                my $var_glob = $cpt->varglob($glob_name);
 530                my $value; #= $cpt->reval("return $variable");
 531                # print STDERR "$variable $value",qq(\n);
 532                if (defined $var_glob) {{
 533                     no strict 'refs';
 534                     if ($glob_type eq '%') {
 535                          $value = {%{*{$var_glob}}} if defined *{$var_glob}{HASH};
 536                     }
 537                     elsif ($glob_type eq '@') {
 538                          $value = [@{*{$var_glob}}] if defined *{$var_glob}{ARRAY};
 539                     }
 540                     else {
 541                          $value = ${*{$var_glob}};
 542                     }
 543                     # We punt here, because we can't tell if the value was
 544                     # defined intentionally, or if it was just left alone;
 545                     # this tries to set sane defaults.
 546                     set_default(\%config,$hash_name,$value) if defined $value;
 547                }}
 548           }
 549      }
 550 }
 551
 552 sub __convert_name{
 553      my ($variable) = @_;
 554      my $hash_name = $variable;
 555      $hash_name =~ s/^([\$\%\@])g//;
 556      my $glob_type = $1;
 557      my $glob_name = 'g'.$hash_name;
 558      $hash_name =~ s/(HTML|CGI)/ucfirst(lc($1))/ge;
 559      $hash_name =~ s/^([A-Z]+)/lc($1)/e;
 560      $hash_name =~ s/([A-Z]+)/'_'.lc($1)/ge;
 561      return $hash_name unless wantarray;
 562      return ($hash_name,$glob_name,$glob_type);
 563 }
 564
 565 # set_default
 566
 567 # sets the configuration hash to the default value if it's not set,
 568 # otherwise doesn't do anything
 569 # If $USING_GLOBALS, then sets an appropriate global.
 570
 571 sub set_default{
 572      my ($config,$option,$value) = @_;
 573      my $varname;
 574      if ($USING_GLOBALS) {
 575           # fix up the variable name
 576           $varname = 'g'.join('',map {ucfirst $_} split /_/, $option);
 577           # Fix stupid HTML names
 578           $varname =~ s/(Html|Cgi)/uc($1)/ge;
 579      }
 580      # update the configuration value
 581      if (not $USING_GLOBALS and not exists $config->{$option}) {
 582           $config->{$option} = $value;
 583      }
 584      elsif ($USING_GLOBALS) {{
 585           no strict 'refs';
 586           # Need to check if a value has already been set in a global
 587           if (defined *{"Debbugs::Config::${varname}"}) {
 588                $config->{$option} = *{"Debbugs::Config::${varname}"};
 589           }
 590           else {
 591                $config->{$option} = $value;
 592           }
 593      }}
 594      if ($USING_GLOBALS) {{
 595           no strict 'refs';
 596           *{"Debbugs::Config::${varname}"} = $config->{$option};
 597      }}
 598 }
 599
 600
 601 ### import magick
 602
 603 # All we care about here is whether we've been called with the globals or text option;
 604 # if so, then we need to export some symbols back up.
 605 # In any event, we call exporter.
 606
 607 sub import {
 608      if (grep /^:(?:text|globals)$/, @_) {
 609           $USING_GLOBALS=1;
 610           for my $variable (map {@$_} @EXPORT_TAGS{map{(/^:(text|globals)$/?($1):())} @_}) {
 611                my $tmp = $variable;
 612                no strict 'refs';
 613                # Yes, I don't care if these are only used once
 614                no warnings 'once';
 615                # No, it doesn't bother me that I'm assigning an undefined value to a typeglob
 616                no warnings 'misc';
 617                my ($hash_name,$glob_name,$glob_type) = __convert_name($variable);
 618                $tmp =~ s/^[\%\$\@]//;
 619                *{"Debbugs::Config::${tmp}"} = ref($config{$hash_name})?$config{$hash_name}:\$config{$hash_name};
 620           }
 621      }
 622      Debbugs::Config->export_to_level(1,@_);
 623 }
 624
 625
 626 1;