Debbugs/Config.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later
   3 # version at your option.
   4 # See the file README and COPYING for more information.
   5 #
   6 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
   7
   8 package Debbugs::Config;
   9
  10 =head1 NAME
  11
  12 Debbugs::Config -- Configuration information for debbugs
  13
  14 =head1 SYNOPSIS
  15
  16  use Debbugs::Config;
  17
  18 # to get the compatiblity interface
  19
  20  use Debbugs::Config qw(:globals);
  21
  22 =head1 DESCRIPTION
  23
  24 This module provides configuration variables for all of debbugs.
  25
  26 =head1 CONFIGURATION FILES
  27
  28 The default configuration file location is /etc/debbugs/config; this
  29 configuration file location can be set by modifying the
  30 DEBBUGS_CONFIG_FILE env variable to point at a different location.
  31
  32 =cut
  33
  34 use warnings;
  35 use strict;
  36 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT $USING_GLOBALS %config);
  37 use base qw(Exporter);
  38
  39 BEGIN {
  40      # set the version for version checking
  41      $VERSION     = 1.00;
  42      $DEBUG = 0 unless defined $DEBUG;
  43      $USING_GLOBALS = 0;
  44
  45      @EXPORT = ();
  46      %EXPORT_TAGS = (globals => [qw($gEmailDomain $gListDomain $gWebHost $gWebHostBugDir),
  47                                  qw($gWebDomain $gHTMLSuffix $gCGIDomain $gMirrors),
  48                                  qw($gPackagePages $gSubscriptionDomain $gProject $gProjectTitle),
  49                                  qw($gMaintainer $gMaintainerWebpage $gMaintainerEmail $gUnknownMaintainerEmail),
  50                                  qw($gSubmitList $gMaintList $gQuietList $gForwardList),
  51                                  qw($gDoneList $gRequestList $gSubmitterList $gControlList),
  52                                  qw($gStrongList),
  53                                  qw($gPackageVersionRe),
  54                                  qw($gSummaryList $gMirrorList $gMailer $gBug),
  55                                  qw($gBugs $gRemoveAge $gSaveOldBugs $gDefaultSeverity),
  56                                  qw($gShowSeverities $gBounceFroms $gConfigDir $gSpoolDir),
  57                                  qw($gIncomingDir $gWebDir $gDocDir $gMaintainerFile),
  58                                  qw($gMaintainerFileOverride $gPseudoMaintFile $gPseudoDescFile $gPackageSource),
  59                                  qw($gVersionPackagesDir $gVersionIndex $gBinarySourceMap $gSourceBinaryMap),
  60                                  qw($gVersionTimeIndex),
  61                                  qw($gSendmail $gLibPath $gSpamScan @gExcludeFromControl),
  62                                  qw(%gSeverityDisplay @gTags @gSeverityList @gStrongSeverities),
  63                                  qw(%gSearchEstraier),
  64                                  qw(%gDistributionAliases),
  65                                  qw(@gPostProcessall @gRemovalDefaultDistributionTags @gRemovalDistributionTags @gRemovalArchitectures),
  66                                  qw(@gRemovalStrongSeverityDefaultDistributionTags),
  67                                  qw(@gDefaultArchitectures),
  68                                  qw($gTemplateDir),
  69                                  qw($gDefaultPackage),
  70                                  qw($gSpamMaxThreads $gSpamSpamsPerThread $gSpamKeepRunning $gSpamScan $gSpamCrossassassinDb),
  71                                 ],
  72                      text     => [qw($gBadEmailPrefix $gHTMLTail $gHTMLExpireNote),
  73                                  ],
  74                      config   => [qw(%config)],
  75                     );
  76      @EXPORT_OK = ();
  77      Exporter::export_ok_tags(qw(globals text config));
  78      $EXPORT_TAGS{all} = [@EXPORT_OK];
  79      $ENV{HOME} = '' if not defined $ENV{HOME};
  80 }
  81
  82 use File::Basename qw(dirname);
  83 use IO::File;
  84 use Safe;
  85
  86 =head1 CONFIGURATION VARIABLES
  87
  88 =head2 General Configuration
  89
  90 =over
  91
  92 =cut
  93
  94 # read in the files;
  95 %config = ();
  96 # untaint $ENV{DEBBUGS_CONFIG_FILE} if it's owned by us
  97 # This enables us to test things that are -T.
  98 if (exists $ENV{DEBBUGS_CONFIG_FILE}) {
  99      if (${[stat($ENV{DEBBUGS_CONFIG_FILE})]}[4] = $<) {
 100           $ENV{DEBBUGS_CONFIG_FILE} =~ /(.+)/;
 101           $ENV{DEBBUGS_CONFIG_FILE} = $1;
 102      }
 103      else {
 104           die "Environmental variable DEBBUGS_CONFIG_FILE set, and $ENV{DEBBUGS_CONFIG_FILE} is not owned by the user running this script.";
 105      }
 106 }
 107 read_config(exists $ENV{DEBBUGS_CONFIG_FILE}?$ENV{DEBBUGS_CONFIG_FILE}:'/etc/debbugs/config');
 108
 109 =item email_domain $gEmailDomain
 110
 111 The email domain of the bts
 112
 113 =cut
 114
 115 set_default(\%config,'email_domain','bugs.something');
 116
 117 =item list_domain $gListDomain
 118
 119 The list domain of the bts, defaults to the email domain
 120
 121 =cut
 122
 123 set_default(\%config,'list_domain',$config{email_domain});
 124
 125 =item web_host $gWebHost
 126
 127 The web host of the bts; defaults to the email domain
 128
 129 =cut
 130
 131 set_default(\%config,'web_host',$config{email_domain});
 132
 133 =item web_host_bug_dir $gWebHostDir
 134
 135 The directory of the web host on which bugs are kept, defaults to C<''>
 136
 137 =cut
 138
 139 set_default(\%config,'web_host_bug_dir','');
 140
 141 =item web_domain $gWebDomain
 142
 143 Full path of the web domain where bugs are kept, defaults to the
 144 concatenation of L</web_host> and L</web_host_bug_dir>
 145
 146 =cut
 147
 148 set_default(\%config,'web_domain',$config{web_host}.($config{web_host}=~m{/$}?'':'/').$config{web_host_bug_dir});
 149
 150 =item html_suffix $gHTMLSuffix
 151
 152 Suffix of html pages, defaults to .html
 153
 154 =cut
 155
 156 set_default(\%config,'html_suffix','.html');
 157
 158 =item cgi_domain $gCGIDomain
 159
 160 Full path of the web domain where cgi scripts are kept. Defaults to
 161 the concatentation of L</web_host> and cgi.
 162
 163 =cut
 164
 165 set_default(\%config,'cgi_domain',$config{web_domain}.($config{web_domain}=~m{/$}?'':'/').'cgi');
 166
 167 =item mirrors @gMirrors
 168
 169 List of mirrors [What these mirrors are used for, no one knows.]
 170
 171 =cut
 172
 173
 174 set_default(\%config,'mirrors',[]);
 175
 176 =item package_pages  $gPackagePages
 177
 178 Domain where the package pages are kept; links should work in a
 179 package_pages/foopackage manner. Defaults to undef, which means that
 180 package links will not be made.
 181
 182 =cut
 183
 184
 185 set_default(\%config,'package_pages',undef);
 186
 187 =item package_pages  $gUsertagPackageDomain
 188
 189 Domain where where usertags of packages belong; defaults to $gPackagePages
 190
 191 =cut
 192
 193 set_default(\%config,'usertag_package_domain',$config{package_pages});
 194
 195
 196 =item subscription_domain $gSubscriptionDomain
 197
 198 Domain where subscriptions to package lists happen
 199
 200 =cut
 201
 202
 203 set_default(\%config,'subscription_domain',undef);
 204
 205 =back
 206
 207 =cut
 208
 209
 210 =head2 Project Identification
 211
 212 =over
 213
 214 =item project $gProject
 215
 216 Name of the project
 217
 218 Default: 'Something'
 219
 220 =cut
 221
 222 set_default(\%config,'project','Something');
 223
 224 =item project_title $gProjectTitle
 225
 226 Name of this install of Debbugs, defaults to "L</project> Debbugs Install"
 227
 228 Default: "$config{project} Debbugs Install"
 229
 230 =cut
 231
 232 set_default(\%config,'project_title',"$config{project} Debbugs Install");
 233
 234 =item maintainer $gMaintainer
 235
 236 Name of the maintainer of this debbugs install
 237
 238 Default: 'Local DebBugs Owner's
 239
 240 =cut
 241
 242 set_default(\%config,'maintainer','Local DebBugs Owner');
 243
 244 =item maintainer_webpage $gMaintainerWebpage
 245
 246 Webpage of the maintainer of this install of debbugs
 247
 248 Default: "$config{web_domain}/~owner"
 249
 250 =cut
 251
 252 set_default(\%config,'maintainer_webpage',"$config{web_domain}/~owner");
 253
 254 =item maintainer_email $gMaintainerEmail
 255
 256 Email address of the maintainer of this Debbugs install
 257
 258 Default: 'root@'.$config{email_domain}
 259
 260 =cut
 261
 262 set_default(\%config,'maintainer_email','root@'.$config{email_domain});
 263
 264 =item unknown_maintainer_email
 265
 266 Email address where packages with an unknown maintainer will be sent
 267
 268 Default: $config{maintainer_email}
 269
 270 =back
 271
 272 =cut
 273
 274 set_default(\%config,'unknown_maintainer_email',$config{maintainer_email});
 275
 276 =head2 BTS Mailing Lists
 277
 278
 279 =over
 280
 281 =item submit_list
 282
 283 =item maint_list
 284
 285 =item forward_list
 286
 287 =item done_list
 288
 289 =item request_list
 290
 291 =item submitter_list
 292
 293 =item control_list
 294
 295 =item summary_list
 296
 297 =item mirror_list
 298
 299 =back
 300
 301 =cut
 302
 303 set_default(\%config,   'submit_list',   'bug-submit-list');
 304 set_default(\%config,    'maint_list',    'bug-maint-list');
 305 set_default(\%config,    'quiet_list',    'bug-quiet-list');
 306 set_default(\%config,  'forward_list',  'bug-forward-list');
 307 set_default(\%config,     'done_list',     'bug-done-list');
 308 set_default(\%config,  'request_list',  'bug-request-list');
 309 set_default(\%config,'submitter_list','bug-submitter-list');
 310 set_default(\%config,  'control_list',  'bug-control-list');
 311 set_default(\%config,  'summary_list',  'bug-summary-list');
 312 set_default(\%config,   'mirror_list',   'bug-mirror-list');
 313 set_default(\%config,   'strong_list',   'bug-strong-list');
 314
 315 =head2 Misc Options
 316
 317 =over
 318
 319 =cut
 320
 321 set_default(\%config,'mailer','exim');
 322 set_default(\%config,'bug','bug');
 323 set_default(\%config,'bugs','bugs');
 324
 325 =item remove_age
 326
 327 Age at which bugs are archived/removed
 328
 329 Default: 28
 330
 331 =cut
 332
 333 set_default(\%config,'remove_age',28);
 334
 335 =item save_old_bugs
 336
 337 Whether old bugs are saved or deleted
 338
 339 Default: 1
 340
 341 =cut
 342
 343 set_default(\%config,'save_old_bugs',1);
 344
 345 =item distribution_aliases
 346
 347 Map of distribution aliases to the distribution name
 348
 349 Default:
 350          {experimental => 'experimental',
 351           unstable     => 'unstable',
 352           testing      => 'testing',
 353           stable       => 'stable',
 354           oldstable    => 'oldstable',
 355           sid          => 'unstable',
 356           lenny        => 'testing',
 357           etch         => 'stable',
 358           sarge        => 'oldstable',
 359          }
 360
 361 =cut
 362
 363 set_default(\%config,'distribution_aliases',
 364             {experimental => 'experimental',
 365              unstable     => 'unstable',
 366              testing      => 'testing',
 367              stable       => 'stable',
 368              oldstable    => 'oldstable',
 369              sid          => 'unstable',
 370              lenny        => 'testing',
 371              etch         => 'stable',
 372              sarge        => 'oldstable',
 373             },
 374            );
 375
 376
 377
 378 =item distributions
 379
 380 List of valid distributions
 381
 382 Default: The values of the distribution aliases map.
 383
 384 =cut
 385
 386 my %_distributions_default;
 387 @_distributions_default{values %{$config{distribution_aliases}}} = values %{$config{distribution_aliases}};
 388 set_default(\%config,'distributions',[keys %_distributions_default]);
 389
 390
 391 =item default_architectures
 392
 393 List of default architectures to use when architecture(s) are not
 394 specified
 395
 396 Default: i386 amd64 arm ppc sparc alpha
 397
 398 =cut
 399
 400 set_default(\%config,'default_architectures',
 401             [qw(i386 amd64 arm powerpc sparc alpha)]
 402            );
 403
 404 =item removal_unremovable_tags
 405
 406 Bugs which have these tags set cannot be archived
 407
 408 Default: []
 409
 410 =cut
 411
 412 set_default(\%config,'removal_unremovable_tags',
 413             [],
 414            );
 415
 416 =item removal_distribution_tags
 417
 418 Tags which specifiy distributions to check
 419
 420 Default: @{$config{distributions}}
 421
 422 =cut
 423
 424 set_default(\%config,'removal_distribution_tags',
 425             [@{$config{distributions}}]);
 426
 427 =item removal_default_distribution_tags
 428
 429 For removal/archival purposes, all bugs are assumed to have these tags
 430 set.
 431
 432 Default: qw(unstable testing);
 433
 434 =cut
 435
 436 set_default(\%config,'removal_default_distribution_tags',
 437             [qw(unstable testing)]
 438            );
 439
 440 =item removal_strong_severity_default_distribution_tags
 441
 442 For removal/archival purposes, all bugs with strong severity are
 443 assumed to have these tags set.
 444
 445 Default: qw(unstable testing stable);
 446
 447 =cut
 448
 449 set_default(\%config,'removal_strong_severity_default_distribution_tags',
 450             [qw(unstable testing stable)]
 451            );
 452
 453
 454 =item removal_architectures
 455
 456 For removal/archival purposes, these architectures are consulted if
 457 there is more than one architecture applicable. If the bug is in a
 458 package not in any of these architectures, the architecture actually
 459 checked is undefined.
 460
 461 Default: value of default_architectures
 462
 463 =cut
 464
 465 set_default(\%config,'removal_architectures',
 466             $config{default_architectures},
 467            );
 468
 469
 470 =item package_name_re
 471
 472 The regex which will match a package name
 473
 474 Default: '[a-z0-9][a-z0-9\.+-]+'
 475
 476 =cut
 477
 478 set_default(\%config,'package_name_re',
 479             '[a-z0-9][a-z0-9\.+-]+');
 480
 481 =item package_version_re
 482
 483 The regex which will match a package version
 484
 485 Default: '[A-Za-z0-9:+\.-]+'
 486
 487 =cut
 488
 489
 490 set_default(\%config,'package_version_re',
 491             '[A-Za-z0-9:+\.~-]+');
 492
 493
 494 =item default_package
 495
 496 This is the name of the default package. If set, bugs assigned to
 497 packages without a maintainer and bugs missing a Package: psuedoheader
 498 will be assigned to this package instead.
 499
 500 Defaults to unset, which is the traditional debbugs behavoir
 501
 502 =cut
 503
 504 set_default(\%config,'default_package',
 505             undef
 506            );
 507
 508
 509 =item control_internal_requester
 510
 511 This address is used by Debbugs::Control as the request address which
 512 sent a control request for faked log messages.
 513
 514 Default:"Debbugs Internal Request <$config{maintainer_email}>"
 515
 516 =cut
 517
 518 set_default(\%config,'control_internal_requester',
 519             "Debbugs Internal Request <$config{maintainer_email}>",
 520            );
 521
 522 =item control_internal_request_addr
 523
 524 This address is used by Debbugs::Control as the address to which a
 525 faked log message request was sent.
 526
 527 Default: "internal_control\@$config{email_domain}";
 528
 529 =cut
 530
 531 set_default(\%config,'control_internal_request_addr',
 532             'internal_control@'.$config{email_domain},
 533            );
 534
 535
 536 =item exclude_from_control
 537
 538 Addresses which are not allowed to send messages to control
 539
 540 =cut
 541
 542 set_default(\%config,'exclude_from_control',[]);
 543
 544
 545
 546 =item default_severity
 547
 548 The default severity of bugs which have no severity set
 549
 550 Default: normal
 551
 552 =cut
 553
 554 set_default(\%config,'default_severity','normal');
 555
 556 =item severity_display
 557
 558 A hashref of severities and the informative text which describes them.
 559
 560 Default:
 561
 562  {critical => "Critical $config{bugs}",
 563   grave    => "Grave $config{bugs}",
 564   normal   => "Normal $config{bugs}",
 565   wishlist => "Wishlist $config{bugs}",
 566  }
 567
 568 =cut
 569
 570 set_default(\%config,'severity_display',{critical => "Critical $config{bugs}",
 571                                          grave    => "Grave $config{bugs}",
 572                                          normal   => "Normal $config{bugs}",
 573                                          wishlist => "Wishlist $config{bugs}",
 574                                         });
 575
 576 =item show_severities
 577
 578 A scalar list of the severities to show
 579
 580 Defaults to the concatenation of the keys of the severity_display
 581 hashlist with ', ' above.
 582
 583 =cut
 584
 585 set_default(\%config,'show_severities',join(', ',keys %{$config{severity_display}}));
 586
 587 =item strong_severities
 588
 589 An arrayref of the serious severities which shoud be emphasized
 590
 591 Default: [qw(critical grave)]
 592
 593 =cut
 594
 595 set_default(\%config,'strong_severities',[qw(critical grave)]);
 596
 597 =item severity_list
 598
 599 An arrayref of a list of the severities
 600
 601 Defaults to the keys of the severity display hashref
 602
 603 =cut
 604
 605 set_default(\%config,'severity_list',[keys %{$config{severity_display}}]);
 606
 607 =item tags
 608
 609 An arrayref of the tags used
 610
 611 Default: [qw(patch wontfix moreinfo unreproducible fixed)] and also
 612 includes the distributions.
 613
 614 =cut
 615
 616 set_default(\%config,'tags',[qw(patch wontfix moreinfo unreproducible fixed),
 617                              @{$config{distributions}}
 618                             ]);
 619
 620 set_default(\%config,'bounce_froms','^mailer|^da?emon|^post.*mast|^root|^wpuser|^mmdf|^smt.*|'.
 621             '^mrgate|^vmmail|^mail.*system|^uucp|-maiser-|^mal\@|'.
 622             '^mail.*agent|^tcpmail|^bitmail|^mailman');
 623
 624 set_default(\%config,'config_dir',dirname(exists $ENV{DEBBUGS_CONFIG_FILE}?$ENV{DEBBUGS_CONFIG_FILE}:'/etc/debbugs/config'));
 625 set_default(\%config,'spool_dir','/var/lib/debbugs/spool');
 626
 627 =item usertag_dir
 628
 629 Directory which contains the usertags
 630
 631 Default: $config{spool_dir}/user
 632
 633 =cut
 634
 635 set_default(\%config,'usertag_dir',$config{spool_dir}.'/user');
 636 set_default(\%config,'incoming_dir','incoming');
 637 set_default(\%config,'web_dir','/var/lib/debbugs/www');
 638 set_default(\%config,'doc_dir','/var/lib/debbugs/www/txt');
 639 set_default(\%config,'lib_path','/usr/lib/debbugs');
 640
 641
 642 =item template_dir
 643
 644 directory of templates; defaults to /usr/share/debbugs/templates.
 645
 646 =cut
 647
 648 set_default(\%config,'template_dir','/usr/share/debbugs/templates');
 649
 650
 651 set_default(\%config,'maintainer_file',$config{config_dir}.'/Maintainers');
 652 set_default(\%config,'maintainer_file_override',$config{config_dir}.'/Maintainers.override');
 653 set_default(\%config,'pseudo_maint_file',$config{config_dir}.'/pseudo-packages.maint');
 654 set_default(\%config,'pseudo_desc_file',$config{config_dir}.'/pseudo-packages.description');
 655 set_default(\%config,'package_source',$config{config_dir}.'/indices/sources');
 656
 657
 658 =item version_packages_dir
 659
 660 Location where the version package information is kept; defaults to
 661 spool_dir/../versions/pkg
 662
 663 =cut
 664
 665 set_default(\%config,'version_packages_dir',$config{spool_dir}.'/../versions/pkg');
 666
 667 =item version_time_index
 668
 669 Location of the version/time index file. Defaults to
 670 spool_dir/../versions/idx/versions_time.idx if spool_dir/../versions
 671 exists; otherwise defaults to undef.
 672
 673 =cut
 674
 675
 676 set_default(\%config,'version_time_index', -d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/versions_time.idx' : undef);
 677
 678 =item version_index
 679
 680 Location of the version index file. Defaults to
 681 spool_dir/../versions/indices/versions.idx if spool_dir/../versions
 682 exists; otherwise defaults to undef.
 683
 684 =cut
 685
 686 set_default(\%config,'version_index',-d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/versions.idx' : undef);
 687
 688 =item binary_source_map
 689
 690 Location of the binary -> source map. Defaults to
 691 spool_dir/../versions/indices/bin2src.idx if spool_dir/../versions
 692 exists; otherwise defaults to undef.
 693
 694 =cut
 695
 696 set_default(\%config,'binary_source_map',-d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/binsrc.idx' : undef);
 697
 698 =item source_binary_map
 699
 700 Location of the source -> binary map. Defaults to
 701 spool_dir/../versions/indices/src2bin.idx if spool_dir/../versions
 702 exists; otherwise defaults to undef.
 703
 704 =cut
 705
 706 set_default(\%config,'source_binary_map',-d $config{spool_dir}.'/../versions' ? $config{spool_dir}.'/../versions/indices/srcbin.idx' : undef);
 707
 708
 709
 710 set_default(\%config,'post_processall',[]);
 711
 712 =item sendmail
 713
 714 Sets the sendmail binary to execute; defaults to /usr/lib/sendmail
 715
 716 =cut
 717
 718 set_default(\%config,'sendmail','/usr/lib/sendmail');
 719
 720 =item spam_scan
 721
 722 Whether or not spamscan is being used; defaults to 0 (not being used
 723
 724 =cut
 725
 726 set_default(\%config,'spam_scan',0);
 727
 728 =item spam_crossassassin_db
 729
 730 Location of the crosassassin database, defaults to
 731 spool_dir/../CrossAssassinDb
 732
 733 =cut
 734
 735 set_default(\%config,'spam_crossassassin_db',$config{spool_dir}.'/../CrossAssassinDb');
 736
 737 =item spam_max_cross
 738
 739 Maximum number of cross-posted messages
 740
 741 =cut
 742
 743 set_default(\%config,'spam_max_cross',6);
 744
 745
 746 =item spam_spams_per_thread
 747
 748 Number of spams for each thread (on average). Defaults to 200
 749
 750 =cut
 751
 752 set_default(\%config,'spam_spams_per_thread',200);
 753
 754 =item spam_max_threads
 755
 756 Maximum number of threads to start. Defaults to 20
 757
 758 =cut
 759
 760 set_default(\%config,'spam_max_threads',20);
 761
 762 =item spam_keep_running
 763
 764 Maximum number of seconds to run without restarting. Defaults to 3600.
 765
 766 =cut
 767
 768 set_default(\%config,'spam_keep_running',3600);
 769
 770 =item spam_mailbox
 771
 772 Location to store spam messages; is run through strftime to allow for
 773 %d,%m,%Y, et al. Defaults to 'spool_dir/../mail/spam/assassinated.%Y-%m-%d'
 774
 775 =cut
 776
 777 set_default(\%config,'spam_mailbox',$config{spool_dir}.'/../mail/spam/assassinated.%Y-%m-%d');
 778
 779 =item spam_crossassassin_mailbox
 780
 781 Location to store crossassassinated messages; is run through strftime
 782 to allow for %d,%m,%Y, et al. Defaults to
 783 'spool_dir/../mail/spam/crossassassinated.%Y-%m-%d'
 784
 785 =cut
 786
 787 set_default(\%config,'spam_crossassassin_mailbox',$config{spool_dir}.'/../mail/spam/crossassassinated.%Y-%m-%d');
 788
 789 =item spam_local_tests_only
 790
 791 Whether only local tests are run, defaults to 0
 792
 793 =cut
 794
 795 set_default(\%config,'spam_local_tests_only',0);
 796
 797 =item spam_user_prefs
 798
 799 User preferences for spamassassin, defaults to $ENV{HOME}/.spamassassin/user_prefs
 800
 801 =cut
 802
 803 set_default(\%config,'spam_user_prefs',"$ENV{HOME}/.spamassassin/user_prefs");
 804
 805 =item spam_rules_dir
 806
 807 Site rules directory for spamassassin, defaults to
 808 '/usr/share/spamassassin'
 809
 810 =cut
 811
 812 set_default(\%config,'spam_rules_dir','/usr/share/spamassassin');
 813
 814 =back
 815
 816
 817 =head2 Text Fields
 818
 819 The following are the only text fields in general use in the scripts;
 820 a few additional text fields are defined in text.in, but are only used
 821 in db2html and a few other specialty scripts.
 822
 823 Earlier versions of debbugs defined these values in /etc/debbugs/text,
 824 but now they are required to be in the configuration file. [Eventually
 825 the longer ones will move out into a fully fledged template system.]
 826
 827 =cut
 828
 829 =over
 830
 831 =item bad_email_prefix
 832
 833 This prefixes the text of all lines in a bad e-mail message ack.
 834
 835 =cut
 836
 837 set_default(\%config,'bad_email_prefix','');
 838
 839
 840 =item text_instructions
 841
 842 This gives more information about bad e-mails to receive.in
 843
 844 =cut
 845
 846 set_default(\%config,'text_instructions',$config{bad_email_prefix});
 847
 848 =item html_tail
 849
 850 This shows up at the end of (most) html pages
 851
 852 In many pages this has been replaced by the html/tail template.
 853
 854 =cut
 855
 856 set_default(\%config,'html_tail',<<END);
 857  <ADDRESS>$config{maintainer} &lt;<A HREF=\"mailto:$config{maintainer_email}\">$config{maintainer_email}</A>&gt;.
 858  Last modified:
 859  <!--timestamp-->
 860  SUBSTITUTE_DTIME
 861  <!--timestamp-->
 862  <P>
 863  <A HREF=\"http://$config{web_domain}/\">Debian $config{bug} tracking system</A><BR>
 864  Copyright (C) 1999 Darren O. Benham,
 865  1997,2003 nCipher Corporation Ltd,
 866  1994-97 Ian Jackson.
 867  </ADDRESS>
 868 END
 869
 870
 871 =item html_expire_note
 872
 873 This message explains what happens to archive/remove-able bugs
 874
 875 =cut
 876
 877 set_default(\%config,'html_expire_note',
 878             "(Closed $config{bugs} are archived $config{remove_age} days after the last related message is received.)");
 879
 880 =back
 881
 882 =cut
 883
 884
 885 sub read_config{
 886      my ($conf_file) = @_;
 887      # first, figure out what type of file we're reading in.
 888      my $fh = new IO::File $conf_file,'r'
 889           or die "Unable to open configuration file $conf_file for reading: $!";
 890      # A new version configuration file must have a comment as its first line
 891      my $first_line = <$fh>;
 892      my ($version) = defined $first_line?$first_line =~ /VERSION:\s*(\d+)/i:undef;
 893      if (defined $version) {
 894           if ($version == 1) {
 895                # Do something here;
 896                die "Version 1 configuration files not implemented yet";
 897           }
 898           else {
 899                die "Version $version configuration files are not supported";
 900           }
 901      }
 902      else {
 903           # Ugh. Old configuration file
 904           # What we do here is we create a new Safe compartment
 905           # so fucked up crap in the config file doesn't sink us.
 906           my $cpt = new Safe or die "Unable to create safe compartment";
 907           # perldoc Opcode; for details
 908           $cpt->permit('require',':filesys_read','entereval','caller','pack','unpack','dofile');
 909           $cpt->reval(qq(require '$conf_file';));
 910           die "Error in configuration file: $@" if $@;
 911           # Now what we do is check out the contents of %EXPORT_TAGS to see exactly which variables
 912           # we want to glob in from the configuration file
 913           for my $variable (@{$EXPORT_TAGS{globals}}) {
 914                my ($hash_name,$glob_name,$glob_type) = __convert_name($variable);
 915                my $var_glob = $cpt->varglob($glob_name);
 916                my $value; #= $cpt->reval("return $variable");
 917                # print STDERR "$variable $value",qq(\n);
 918                if (defined $var_glob) {{
 919                     no strict 'refs';
 920                     if ($glob_type eq '%') {
 921                          $value = {%{*{$var_glob}}} if defined *{$var_glob}{HASH};
 922                     }
 923                     elsif ($glob_type eq '@') {
 924                          $value = [@{*{$var_glob}}] if defined *{$var_glob}{ARRAY};
 925                     }
 926                     else {
 927                          $value = ${*{$var_glob}};
 928                     }
 929                     # We punt here, because we can't tell if the value was
 930                     # defined intentionally, or if it was just left alone;
 931                     # this tries to set sane defaults.
 932                     set_default(\%config,$hash_name,$value) if defined $value;
 933                }}
 934           }
 935      }
 936 }
 937
 938 sub __convert_name{
 939      my ($variable) = @_;
 940      my $hash_name = $variable;
 941      $hash_name =~ s/^([\$\%\@])g//;
 942      my $glob_type = $1;
 943      my $glob_name = 'g'.$hash_name;
 944      $hash_name =~ s/(HTML|CGI)/ucfirst(lc($1))/ge;
 945      $hash_name =~ s/^([A-Z]+)/lc($1)/e;
 946      $hash_name =~ s/([A-Z]+)/'_'.lc($1)/ge;
 947      return $hash_name unless wantarray;
 948      return ($hash_name,$glob_name,$glob_type);
 949 }
 950
 951 # set_default
 952
 953 # sets the configuration hash to the default value if it's not set,
 954 # otherwise doesn't do anything
 955 # If $USING_GLOBALS, then sets an appropriate global.
 956
 957 sub set_default{
 958      my ($config,$option,$value) = @_;
 959      my $varname;
 960      if ($USING_GLOBALS) {
 961           # fix up the variable name
 962           $varname = 'g'.join('',map {ucfirst $_} split /_/, $option);
 963           # Fix stupid HTML names
 964           $varname =~ s/(Html|Cgi)/uc($1)/ge;
 965      }
 966      # update the configuration value
 967      if (not $USING_GLOBALS and not exists $config->{$option}) {
 968           $config->{$option} = $value;
 969      }
 970      elsif ($USING_GLOBALS) {{
 971           no strict 'refs';
 972           # Need to check if a value has already been set in a global
 973           if (defined *{"Debbugs::Config::${varname}"}) {
 974                $config->{$option} = *{"Debbugs::Config::${varname}"};
 975           }
 976           else {
 977                $config->{$option} = $value;
 978           }
 979      }}
 980      if ($USING_GLOBALS) {{
 981           no strict 'refs';
 982           *{"Debbugs::Config::${varname}"} = $config->{$option};
 983      }}
 984 }
 985
 986
 987 ### import magick
 988
 989 # All we care about here is whether we've been called with the globals or text option;
 990 # if so, then we need to export some symbols back up.
 991 # In any event, we call exporter.
 992
 993 sub import {
 994      if (grep /^:(?:text|globals)$/, @_) {
 995           $USING_GLOBALS=1;
 996           for my $variable (map {@$_} @EXPORT_TAGS{map{(/^:(text|globals)$/?($1):())} @_}) {
 997                my $tmp = $variable;
 998                no strict 'refs';
 999                # Yes, I don't care if these are only used once
1000                no warnings 'once';
1001                # No, it doesn't bother me that I'm assigning an undefined value to a typeglob
1002                no warnings 'misc';
1003                my ($hash_name,$glob_name,$glob_type) = __convert_name($variable);
1004                $tmp =~ s/^[\%\$\@]//;
1005                *{"Debbugs::Config::${tmp}"} = ref($config{$hash_name})?$config{$hash_name}:\$config{$hash_name};
1006           }
1007      }
1008      Debbugs::Config->export_to_level(1,@_);
1009 }
1010
1011
1012 1;