Debbugs/CGI/Pkgreport.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 #
   5 # [Other people have contributed to this file; their copyrights should
   6 # be listed here too.]
   7 # Copyright 2008 by Don Armstrong <don@donarmstrong.com>.
   8
   9
  10 package Debbugs::CGI::Pkgreport;
  11
  12 =head1 NAME
  13
  14 Debbugs::CGI::Pkgreport -- specific routines for the pkgreport cgi script
  15
  16 =head1 SYNOPSIS
  17
  18
  19 =head1 DESCRIPTION
  20
  21
  22 =head1 BUGS
  23
  24 None known.
  25
  26 =cut
  27
  28 use warnings;
  29 use strict;
  30 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  31 use Exporter qw(import);
  32
  33 use IO::Scalar;
  34 use Params::Validate qw(validate_with :types);
  35
  36 use Debbugs::Config qw(:config :globals);
  37 use Debbugs::CGI qw(:url :html :util);
  38 use Debbugs::Common qw(:misc :util :date);
  39 use Debbugs::Status qw(:status);
  40 use Debbugs::Bugs qw(bug_filter);
  41 use Debbugs::Packages qw(:mapping);
  42
  43 use Debbugs::Text qw(:templates);
  44 use Encode qw(decode_utf8);
  45
  46 use POSIX qw(strftime);
  47
  48
  49 BEGIN{
  50      ($VERSION) = q$Revision: 494 $ =~ /^Revision:\s+([^\s+])/;
  51      $DEBUG = 0 unless defined $DEBUG;
  52
  53      @EXPORT = ();
  54      %EXPORT_TAGS = (html => [qw(short_bug_status_html pkg_htmlizebugs),
  55                              ],
  56                      misc => [qw(generate_package_info),
  57                               qw(determine_ordering),
  58                              ],
  59                     );
  60      @EXPORT_OK = (qw());
  61      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  62      $EXPORT_TAGS{all} = [@EXPORT_OK];
  63 }
  64
  65 =head2 generate_package_info
  66
  67      generate_package_info($srcorbin,$package)
  68
  69 Generates the informational bits for a package and returns it
  70
  71 =cut
  72
  73 sub generate_package_info{
  74      my %param = validate_with(params => \@_,
  75                                spec  => {binary => {type => BOOLEAN,
  76                                                     default => 1,
  77                                                    },
  78                                          package => {type => SCALAR,#|ARRAYREF,
  79                                                     },
  80                                          options => {type => HASHREF,
  81                                                     },
  82                                          bugs    => {type => ARRAYREF,
  83                                                     },
  84                                         },
  85                               );
  86
  87      my $output_scalar = '';
  88      my $output = globify_scalar(\$output_scalar);
  89
  90      my $package = $param{package};
  91
  92      my %pkgsrc = %{getpkgsrc()};
  93      my $srcforpkg = $package;
  94      if ($param{binary} and exists $pkgsrc{$package}
  95          and defined $pkgsrc{$package}) {
  96           $srcforpkg = $pkgsrc{$package};
  97      }
  98
  99      my $showpkg = html_escape($package);
 100      my $maintainers = getmaintainers();
 101      my $maint = $maintainers->{$srcforpkg};
 102      if (defined $maint) {
 103           print {$output} '<p>';
 104           print {$output} (($maint =~ /,/)? "Maintainer for $showpkg is "
 105                            : "Maintainers for $showpkg are ") .
 106                                 package_links(maint => $maint);
 107           print {$output} ".</p>\n";
 108      }
 109      else {
 110           print {$output} "<p>There is no maintainer for $showpkg. ".
 111                "This means that this package no longer exists (or never existed). ".
 112                    "Please do not report new bugs against this package. </p>\n";
 113      }
 114      my @pkgs = getsrcpkgs($srcforpkg);
 115      @pkgs = grep( !/^\Q$package\E$/, @pkgs );
 116      if ( @pkgs ) {
 117           @pkgs = sort @pkgs;
 118           if ($param{binary}) {
 119                print {$output} "<p>You may want to refer to the following packages that are part of the same source:\n";
 120           }
 121           else {
 122                print {$output} "<p>You may want to refer to the following individual bug pages:\n";
 123           }
 124           #push @pkgs, $src if ( $src && !grep(/^\Q$src\E$/, @pkgs) );
 125           print {$output} scalar package_links(package=>[@pkgs]);
 126           print {$output} ".\n";
 127      }
 128      my @references;
 129      my $pseudodesc = getpseudodesc();
 130      if ($package and defined($pseudodesc) and exists($pseudodesc->{$package})) {
 131           push @references, "to the <a href=\"$config{web_domain}/pseudo-packages$config{html_suffix}\">".
 132                "list of other pseudo-packages</a>";
 133      }
 134      elsif (not defined $maint and not @{$param{bugs}}) {
 135         # don't bother printing out this information, because it's
 136         # already present above.
 137         #  print {$output} "<p>There is no record of the " . html_escape($package) .
 138         #       ($param{binary} ? " package" : " source package") .
 139         #           ", and no bugs have been filed against it.</p>";
 140      }
 141      else {
 142           if ($package and defined $config{package_pages} and length $config{package_pages}) {
 143                push @references, sprintf "to the <a href=\"%s\">%s package page</a>",
 144                     html_escape("$config{package_pages}/$package"), html_escape("$package");
 145           }
 146           if (defined $config{package_tracking_domain} and
 147               length $config{package_tracking_domain}) {
 148                my $ptslink = $param{binary} ? $srcforpkg : $package;
 149                # the pts only wants the source, and doesn't care about src: (#566089)
 150                $ptslink =~ s/^src://;
 151                push @references, q(to the <a href=").html_escape("$config{package_tracking_domain}/$ptslink").q(">Package Tracking System</a>);
 152           }
 153           # Only output this if the source listing is non-trivial.
 154           if ($param{binary} and $srcforpkg) {
 155                push @references,
 156                     "to the source package ".
 157                          package_links(src=>$srcforpkg,
 158                                        options => $param{options}) .
 159                               "'s bug page";
 160           }
 161      }
 162      if (@references) {
 163           $references[$#references] = "or $references[$#references]" if @references > 1;
 164           print {$output} "<p>You might like to refer ", join(", ", @references), ".</p>\n";
 165      }
 166      if (defined $maint) {
 167           print {$output} "<p>If you find a bug not listed here, please\n";
 168           printf {$output} "<a href=\"%s\">report it</a>.</p>\n",
 169                html_escape("$config{web_domain}/Reporting$config{html_suffix}");
 170      }
 171      return decode_utf8($output_scalar);
 172 }
 173
 174
 175 =head2 short_bug_status_html
 176
 177      print short_bug_status_html(status => read_bug(bug => 5),
 178                                  options => \%param,
 179                                 );
 180
 181 =over
 182
 183 =item status -- status hashref as returned by read_bug
 184
 185 =item options -- hashref of options to pass to package_links (defaults
 186 to an empty hashref)
 187
 188 =item bug_options -- hashref of options to pass to bug_links (default
 189 to an empty hashref)
 190
 191 =item snippet -- optional snippet of information about the bug to
 192 display below
 193
 194
 195 =back
 196
 197
 198
 199 =cut
 200
 201 sub short_bug_status_html {
 202      my %param = validate_with(params => \@_,
 203                                spec   => {status => {type => HASHREF,
 204                                                     },
 205                                           options => {type => HASHREF,
 206                                                       default => {},
 207                                                      },
 208                                           bug_options => {type => HASHREF,
 209                                                           default => {},
 210                                                          },
 211                                           snippet => {type => SCALAR,
 212                                                       default => '',
 213                                                      },
 214                                          },
 215                               );
 216
 217      my %status = %{$param{status}};
 218
 219      $status{tags_array} = [sort(split(/\s+/, $status{tags}))];
 220      $status{date_text} = strftime('%a, %e %b %Y %T UTC', gmtime($status{date}));
 221      $status{mergedwith_array} = [split(/ /,$status{mergedwith})];
 222
 223      my @blockedby= split(/ /, $status{blockedby});
 224      $status{blockedby_array} = [];
 225      if (@blockedby && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 226           for my $b (@blockedby) {
 227                my %s = %{get_bug_status($b)};
 228                next if (defined $s{pending} and $s{pending} eq 'fixed') or (defined $s{done} and length $s{done});
 229                push @{$status{blockedby_array}},{bug_num => $b, subject => $s{subject}, status => \%s};
 230           }
 231      }
 232
 233      my @blocks= split(/ /, $status{blocks});
 234      $status{blocks_array} = [];
 235      if (@blocks && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 236           for my $b (@blocks) {
 237                my %s = %{get_bug_status($b)};
 238                next if (defined $s{pending} and $s{pending} eq 'fixed') or (defined $s{done} and length $s{done});
 239                push @{$status{blocks_array}}, {bug_num => $b, subject => $s{subject}, status => \%s};
 240           }
 241      }
 242      my $days = bug_archiveable(bug => $status{id},
 243                                 status => \%status,
 244                                 days_until => 1,
 245                                );
 246      $status{archive_days} = $days;
 247      return fill_in_template(template => 'cgi/short_bug_status',
 248                              variables => {status => \%status,
 249                                            isstrongseverity => \&Debbugs::Status::isstrongseverity,
 250                                            html_escape   => \&Debbugs::CGI::html_escape,
 251                                            looks_like_number => \&Scalar::Util::looks_like_number,
 252                                           },
 253                              hole_var  => {'&package_links' => \&Debbugs::CGI::package_links,
 254                                            '&bug_links'     => \&Debbugs::CGI::bug_links,
 255                                            '&version_url'   => \&Debbugs::CGI::version_url,
 256                                            '&secs_to_english' => \&Debbugs::Common::secs_to_english,
 257                                            '&strftime'      => \&POSIX::strftime,
 258                                            '&maybelink'     => \&Debbugs::CGI::maybelink,
 259                                           },
 260                             );
 261 }
 262
 263
 264 sub pkg_htmlizebugs {
 265      my %param = validate_with(params => \@_,
 266                                spec   => {bugs => {type => ARRAYREF,
 267                                                   },
 268                                           names => {type => ARRAYREF,
 269                                                    },
 270                                           title => {type => ARRAYREF,
 271                                                    },
 272                                           prior => {type => ARRAYREF,
 273                                                    },
 274                                           order => {type => ARRAYREF,
 275                                                    },
 276                                           ordering => {type => SCALAR,
 277                                                       },
 278                                           bugusertags => {type => HASHREF,
 279                                                           default => {},
 280                                                          },
 281                                           bug_rev => {type => BOOLEAN,
 282                                                       default => 0,
 283                                                      },
 284                                           bug_order => {type => SCALAR,
 285                                                        },
 286                                           repeatmerged => {type => BOOLEAN,
 287                                                            default => 1,
 288                                                           },
 289                                           include => {type => ARRAYREF,
 290                                                       default => [],
 291                                                      },
 292                                           exclude => {type => ARRAYREF,
 293                                                       default => [],
 294                                                      },
 295                                           this     => {type => SCALAR,
 296                                                        default => '',
 297                                                       },
 298                                           options  => {type => HASHREF,
 299                                                        default => {},
 300                                                       },
 301                                           dist     => {type => SCALAR,
 302                                                        optional => 1,
 303                                                       },
 304                                           schema   => {type => OBJECT,
 305                                                        optional => 1,
 306                                                       },
 307                                          }
 308                               );
 309      my @bugs = @{$param{bugs}};
 310
 311      my @status = ();
 312      my %count;
 313      my $header = '';
 314      my $footer = "<h2 class=\"outstanding\">Summary</h2>\n";
 315
 316      if (@bugs == 0) {
 317           return "<HR><H2>No reports found!</H2></HR>\n";
 318      }
 319
 320      if ( $param{bug_rev} ) {
 321           @bugs = sort {$b<=>$a} @bugs;
 322      }
 323      else {
 324           @bugs = sort {$a<=>$b} @bugs;
 325      }
 326      my %seenmerged;
 327
 328      my %common = (
 329                    'show_list_header' => 1,
 330                    'show_list_footer' => 1,
 331                   );
 332
 333      my %section = ();
 334      # Make the include/exclude map
 335      my %include;
 336      my %exclude;
 337      for my $include (make_list($param{include})) {
 338           next unless defined $include;
 339           my ($key,$value) = split /\s*:\s*/,$include,2;
 340           unless (defined $value) {
 341                $key = 'tags';
 342                $value = $include;
 343           }
 344           push @{$include{$key}}, split /\s*,\s*/, $value;
 345      }
 346      for my $exclude (make_list($param{exclude})) {
 347           next unless defined $exclude;
 348           my ($key,$value) = split /\s*:\s*/,$exclude,2;
 349           unless (defined $value) {
 350                $key = 'tags';
 351                $value = $exclude;
 352           }
 353           push @{$exclude{$key}}, split /\s*,\s*/, $value;
 354      }
 355
 356      foreach my $bug (@bugs) {
 357          my %status = %{get_bug_status(bug=>$bug,
 358                                        (map {exists $param{$_}?($_,$param{$_}):()}
 359                                         qw(dist version schema bugusertags)
 360                                        ),
 361                                         (exists $param{arch}?(arch => $param{arch}):(arch => $config{default_architectures})),
 362                                        )};
 363           next unless %status;
 364           next if bug_filter(bug => $bug,
 365                              status => \%status,
 366                              repeat_merged => $param{repeatmerged},
 367                              seen_merged => \%seenmerged,
 368                              (keys %include ? (include => \%include):()),
 369                              (keys %exclude ? (exclude => \%exclude):()),
 370                             );
 371
 372           my $html = "<li>"; #<a href=\"%s\">#%d: %s</a>\n<br>",
 373           $html .= short_bug_status_html(status  => \%status,
 374                                          options => $param{options},
 375                                         ) . "\n";
 376           push @status, [ $bug, \%status, $html ];
 377      }
 378      if ($param{bug_order} eq 'age') {
 379           # MWHAHAHAHA
 380           @status = sort {$a->[1]{log_modified} <=> $b->[1]{log_modified}} @status;
 381      }
 382      elsif ($param{bug_order} eq 'agerev') {
 383           @status = sort {$b->[1]{log_modified} <=> $a->[1]{log_modified}} @status;
 384      }
 385      for my $entry (@status) {
 386           my $key = "";
 387           for my $i (0..$#{$param{prior}}) {
 388                my $v = get_bug_order_index($param{prior}[$i], $entry->[1]);
 389                $count{"g_${i}_${v}"}++;
 390                $key .= "_$v";
 391           }
 392           $section{$key} .= $entry->[2];
 393           $count{"_$key"}++;
 394      }
 395
 396      my $result = "";
 397      if ($param{ordering} eq "raw") {
 398           $result .= "<UL class=\"bugs\">\n" . join("", map( { $_->[ 2 ] } @status ) ) . "</UL>\n";
 399      }
 400      else {
 401           $header .= "<div class=\"msgreceived\">\n<ul>\n";
 402           my @keys_in_order = ("");
 403           for my $o (@{$param{order}}) {
 404                push @keys_in_order, "X";
 405                while ((my $k = shift @keys_in_order) ne "X") {
 406                     for my $k2 (@{$o}) {
 407                          $k2+=0;
 408                          push @keys_in_order, "${k}_${k2}";
 409                     }
 410                }
 411           }
 412           for my $order (@keys_in_order) {
 413                next unless defined $section{$order};
 414                my @ttl = split /_/, $order;
 415                shift @ttl;
 416                my $title = $param{title}[0]->[$ttl[0]] . " bugs";
 417                if ($#ttl > 0) {
 418                     $title .= " -- ";
 419                     $title .= join("; ", grep {($_ || "") ne ""}
 420                                    map { $param{title}[$_]->[$ttl[$_]] } 1..$#ttl);
 421                }
 422                $title = html_escape($title);
 423
 424                my $count = $count{"_$order"};
 425                my $bugs = $count == 1 ? "bug" : "bugs";
 426
 427                $header .= "<li><a href=\"#$order\">$title</a> ($count $bugs)</li>\n";
 428                if ($common{show_list_header}) {
 429                     my $count = $count{"_$order"};
 430                     my $bugs = $count == 1 ? "bug" : "bugs";
 431                     $result .= "<H2 CLASS=\"outstanding\"><a name=\"$order\"></a>$title ($count $bugs)</H2>\n";
 432                }
 433                else {
 434                     $result .= "<H2 CLASS=\"outstanding\">$title</H2>\n";
 435                }
 436                $result .= "<div class=\"msgreceived\">\n<UL class=\"bugs\">\n";
 437                $result .= "\n\n\n\n";
 438                $result .= $section{$order};
 439                $result .= "\n\n\n\n";
 440                $result .= "</UL>\n</div>\n";
 441           }
 442           $header .= "</ul></div>\n";
 443
 444           $footer .= "<div class=\"msgreceived\">\n<ul>\n";
 445           for my $i (0..$#{$param{prior}}) {
 446                my $local_result = '';
 447                foreach my $key ( @{$param{order}[$i]} ) {
 448                     my $count = $count{"g_${i}_$key"};
 449                     next if !$count or !$param{title}[$i]->[$key];
 450                     $local_result .= "<li>$count $param{title}[$i]->[$key]</li>\n";
 451                }
 452                if ( $local_result ) {
 453                     $footer .= "<li>$param{names}[$i]<ul>\n$local_result</ul></li>\n";
 454                }
 455           }
 456           $footer .= "</ul>\n</div>\n";
 457      }
 458
 459      $result = $header . $result if ( $common{show_list_header} );
 460      $result .= $footer if ( $common{show_list_footer} );
 461      return $result;
 462 }
 463
 464 sub parse_order_statement_into_boolean {
 465     my ($statement,$status,$tags) = @_;
 466
 467     if (not defined $tags) {
 468         $tags = {map { $_, 1 } split / /, $status->{"tags"}
 469                 }
 470             if defined $status->{"tags"};
 471
 472     }
 473     # replace all + with &&
 474     $statement =~ s/\+/&&/g;
 475     # replace all , with ||
 476     $statement =~ s/,/||/g;
 477     $statement =~ s{([^\&\|\=]+) # field
 478                     =
 479                     ([^\&\|\=]+) # value
 480               }{
 481                   my $ok = 0;
 482                   if ($1 eq 'tag') {
 483                       $ok = 1 if defined $tags->{$2};
 484                   } else {
 485                       $ok = 1 if defined $status->{$1} and
 486                           $status->{$1} eq $2;
 487                   }
 488                   $ok;
 489               }exg;
 490     # check that the parsed statement is just valid boolean statements
 491     if ($statement =~ /^([01\(\)\&\|]+)$/) {
 492         return eval "$1";
 493     } else {
 494         # this is an invalid boolean statement
 495         return 0;
 496     }
 497 }
 498
 499 sub get_bug_order_index {
 500      my $order = shift;
 501      my $status = shift;
 502      my $pos = 0;
 503      my $tags = {map { $_, 1 } split / /, $status->{"tags"}
 504                 }
 505          if defined $status->{"tags"};
 506      for my $el (@${order}) {
 507          if (not length $el or
 508              parse_order_statement_into_boolean($el,$status,$tags)
 509             ) {
 510              return $pos;
 511          }
 512          $pos++;
 513      }
 514      return $pos;
 515 }
 516
 517 # sets: my @names; my @prior; my @title; my @order;
 518
 519 sub determine_ordering {
 520      my %param = validate_with(params => \@_,
 521                               spec => {cats => {type => HASHREF,
 522                                                },
 523                                        param => {type => HASHREF,
 524                                                 },
 525                                        ordering => {type => SCALARREF,
 526                                                    },
 527                                        names    => {type => ARRAYREF,
 528                                                    },
 529                                        pend_rev => {type => BOOLEAN,
 530                                                     default => 0,
 531                                                    },
 532                                        sev_rev  => {type => BOOLEAN,
 533                                                     default => 0,
 534                                                    },
 535                                        prior    => {type => ARRAYREF,
 536                                                    },
 537                                        title    => {type => ARRAYREF,
 538                                                    },
 539                                        order    => {type => ARRAYREF,
 540                                                    },
 541                                       },
 542                              );
 543      $param{cats}{status}[0]{ord} = [ reverse @{$param{cats}{status}[0]{ord}} ]
 544           if ($param{pend_rev});
 545      $param{cats}{severity}[0]{ord} = [ reverse @{$param{cats}{severity}[0]{ord}} ]
 546           if ($param{sev_rev});
 547
 548      my $i;
 549      if (defined $param{param}{"pri0"}) {
 550           my @c = ();
 551           $i = 0;
 552           while (defined $param{param}{"pri$i"}) {
 553                my $h = {};
 554
 555                my ($pri) = make_list($param{param}{"pri$i"});
 556                if ($pri =~ m/^([^:]*):(.*)$/) {
 557                     $h->{"nam"} = $1; # overridden later if necesary
 558                     $h->{"pri"} = [ map { "$1=$_" } (split /,/, $2) ];
 559                }
 560                else {
 561                     $h->{"pri"} = [ split /,/, $pri ];
 562                }
 563
 564                ($h->{"nam"}) = make_list($param{param}{"nam$i"})
 565                     if (defined $param{param}{"nam$i"});
 566                $h->{"ord"} = [ map {split /\s*,\s*/} make_list($param{param}{"ord$i"}) ]
 567                     if (defined $param{param}{"ord$i"});
 568                $h->{"ttl"} = [ map {split /\s*,\s*/} make_list($param{param}{"ttl$i"}) ]
 569                     if (defined $param{param}{"ttl$i"});
 570
 571                push @c, $h;
 572                $i++;
 573           }
 574           $param{cats}{"_"} = [@c];
 575           ${$param{ordering}} = "_";
 576      }
 577
 578      ${$param{ordering}} = "normal" unless defined $param{cats}{${$param{ordering}}};
 579
 580      sub get_ordering {
 581           my @res;
 582           my $cats = shift;
 583           my $o = shift;
 584           for my $c (@{$cats->{$o}}) {
 585                if (ref($c) eq "HASH") {
 586                     push @res, $c;
 587                }
 588                else {
 589                     push @res, get_ordering($cats, $c);
 590                }
 591           }
 592           return @res;
 593      }
 594      my @cats = get_ordering($param{cats}, ${$param{ordering}});
 595
 596      sub toenglish {
 597           my $expr = shift;
 598           $expr =~ s/[+]/ and /g;
 599           $expr =~ s/[a-z]+=//g;
 600           return $expr;
 601      }
 602
 603      $i = 0;
 604      for my $c (@cats) {
 605           $i++;
 606           push @{$param{prior}}, $c->{"pri"};
 607           push @{$param{names}}, ($c->{"nam"} || "Bug attribute #" . $i);
 608           if (defined $c->{"ord"}) {
 609                push @{$param{order}}, $c->{"ord"};
 610           }
 611           else {
 612                push @{$param{order}}, [ 0..$#{$param{prior}[-1]} ];
 613           }
 614           my @t = @{ $c->{"ttl"} } if defined $c->{ttl};
 615           if (@t < $#{$param{prior}[-1]}) {
 616                push @t, map { toenglish($param{prior}[-1][$_]) } @t..($#{$param{prior}[-1]});
 617           }
 618           push @t, $c->{"def"} || "";
 619           push @{$param{title}}, [@t];
 620      }
 621 }
 622
 623
 624
 625
 626 1;
 627
 628
 629 __END__
 630
 631
 632
 633
 634
 635