Debbugs/CGI/Bugreport.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 #
   5 # [Other people have contributed to this file; their copyrights should
   6 # be listed here too.]
   7 # Copyright 2008 by Don Armstrong <don@donarmstrong.com>.
   8
   9
  10 package Debbugs::CGI::Bugreport;
  11
  12 =head1 NAME
  13
  14 Debbugs::CGI::Bugreport -- specific routines for the bugreport cgi script
  15
  16 =head1 SYNOPSIS
  17
  18
  19 =head1 DESCRIPTION
  20
  21
  22 =head1 BUGS
  23
  24 None known.
  25
  26 =cut
  27
  28 use warnings;
  29 use strict;
  30 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  31 use base qw(Exporter);
  32
  33 use IO::Scalar;
  34 use Params::Validate qw(validate_with :types);
  35 use Digest::MD5 qw(md5_hex);
  36 use Debbugs::Mail qw(get_addresses);
  37 use Debbugs::MIME qw(decode_rfc1522 create_mime_message);
  38 use Debbugs::CGI qw(:url :html :util);
  39 use Debbugs::Common qw(globify_scalar english_join);
  40 use Debbugs::UTF8;
  41 use Debbugs::Config qw(:config);
  42 use POSIX qw(strftime);
  43 use Encode qw(decode_utf8 encode_utf8);
  44
  45 BEGIN{
  46      ($VERSION) = q$Revision: 494 $ =~ /^Revision:\s+([^\s+])/;
  47      $DEBUG = 0 unless defined $DEBUG;
  48
  49      @EXPORT = ();
  50      %EXPORT_TAGS = ();
  51      @EXPORT_OK = (qw(display_entity handle_record handle_email_message));
  52      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  53      $EXPORT_TAGS{all} = [@EXPORT_OK];
  54 }
  55
  56
  57
  58 =head2 display_entity
  59
  60      display_entity(entity      => $entity,
  61                     bug_num     => $ref,
  62                     outer       => 1,
  63                     msg_num     => $msg_num,
  64                     attachments => \@attachments,
  65                     output      => \$output);
  66
  67
  68 =over
  69
  70 =item entity -- MIME::Parser entity
  71
  72 =item bug_num -- Bug number
  73
  74 =item outer -- Whether this is the outer entity; defaults to 1
  75
  76 =item msg_num -- message number in the log
  77
  78 =item attachments -- arrayref of attachments
  79
  80 =item output -- scalar reference for output
  81
  82 =back
  83
  84 =cut
  85
  86 sub display_entity {
  87     my %param = validate_with(params => \@_,
  88                               spec   => {entity      => {type => OBJECT,
  89                                                         },
  90                                          bug_num     => {type => SCALAR,
  91                                                          regex => qr/^\d+$/,
  92                                                         },
  93                                          outer       => {type => BOOLEAN,
  94                                                          default => 1,
  95                                                         },
  96                                          msg_num     => {type => SCALAR,
  97                                                         },
  98                                          attachments => {type => ARRAYREF,
  99                                                          default => [],
 100                                                         },
 101                                          output      => {type => SCALARREF|HANDLE,
 102                                                          default => \*STDOUT,
 103                                                         },
 104                                          terse       => {type => BOOLEAN,
 105                                                          default => 0,
 106                                                         },
 107                                          msg         => {type => SCALAR,
 108                                                          optional => 1,
 109                                                         },
 110                                          att         => {type => SCALAR,
 111                                                          optional => 1,
 112                                                         },
 113                                          trim_headers => {type => BOOLEAN,
 114                                                           default => 1,
 115                                                          },
 116                                         }
 117                              );
 118
 119     my $output = globify_scalar($param{output});
 120     my $entity = $param{entity};
 121     my $ref = $param{bug_num};
 122     my $top = $param{outer};
 123     my $xmessage = $param{msg_num};
 124     my $attachments = $param{attachments};
 125
 126     my $head = $entity->head;
 127     my $disposition = $head->mime_attr('content-disposition');
 128     $disposition = 'inline' if not defined $disposition or $disposition eq '';
 129     my $type = $entity->effective_type;
 130     my $filename = $entity->head->recommended_filename;
 131     $filename = '' unless defined $filename;
 132     $filename = decode_rfc1522($filename);
 133
 134     if ($param{outer} and
 135         not $param{terse} and
 136         not exists $param{att}) {
 137          my $header = $entity->head;
 138          print {$output} "<div class=\"headers\">\n";
 139          if ($param{trim_headers}) {
 140               my @headers;
 141               foreach (qw(From To Cc Subject Date)) {
 142                    my $head_field = $head->get($_);
 143                    next unless defined $head_field and $head_field ne '';
 144                    chomp $head_field;
 145                    if ($_ eq 'From') {
 146                        my $libravatar_url = __libravatar_url(decode_rfc1522($head_field));
 147                        if (defined $libravatar_url and length $libravatar_url) {
 148                            push @headers,q(<img src=").$libravatar_url.qq(">\n);
 149                        }
 150                    }
 151                    push @headers, qq(<p><span class="header">$_:</span> ) . html_escape(decode_rfc1522($head_field))."</p>\n";
 152               }
 153               print {$output} join(qq(), @headers);
 154          } else {
 155               print {$output} "<pre>".html_escape(decode_rfc1522($entity->head->stringify))."</pre>\n";
 156          }
 157          print {$output} "</div>\n";
 158     }
 159
 160     if (not (($param{outer} and $type =~ m{^text(?:/plain)?(?:;|$)})
 161              or $type =~ m{^multipart/}
 162             )) {
 163         push @$attachments, $param{entity};
 164         # output this attachment
 165         if (exists $param{att} and
 166             $param{att} == $#$attachments) {
 167             my $head = $entity->head;
 168             chomp(my $type = $entity->effective_type);
 169             my $body = $entity->stringify_body;
 170             # this attachment has its own content type, so we must not
 171             # try to convert it to UTF-8 or do anything funky.
 172             my @layers = PerlIO::get_layers($output);
 173             binmode($output,':raw');
 174             print {$output} "Content-Type: $type";
 175             my ($charset) = $head->get('Content-Type:') =~ m/charset\s*=\s*\"?([\w-]+)\"?/i;
 176             print {$output} qq(; charset="$charset") if defined $charset;
 177             print {$output} "\n";
 178             if ($filename ne '') {
 179                 my $qf = $filename;
 180                 $qf =~ s/"/\\"/g;
 181                 $qf =~ s[.*/][];
 182                 print {$output} qq{Content-Disposition: inline; filename="$qf"\n};
 183             }
 184             print {$output} "\n";
 185             my $decoder = MIME::Decoder->new($head->mime_encoding);
 186             $decoder->decode(IO::Scalar->new(\$body), $output);
 187             if (grep {/utf8/} @layers) {
 188                 binmode($output,':utf8');
 189             }
 190             return;
 191         }
 192         elsif (not exists $param{att}) {
 193              my @dlargs = (msg=>$xmessage, att=>$#$attachments);
 194              push @dlargs, (filename=>$filename) if $filename ne '';
 195              my $printname = $filename;
 196              $printname = 'Message part ' . ($#$attachments + 1) if $filename eq '';
 197              print {$output} '<pre class="mime">[<a href="' .
 198                   html_escape(bug_links(bug => $ref,
 199                                         links_only => 1,
 200                                         options => {@dlargs})
 201                              ) . qq{">$printname</a> } .
 202                                   "($type, $disposition)]</pre>\n";
 203         }
 204     }
 205
 206     return if not $param{outer} and $disposition eq 'attachment' and not exists $param{att};
 207     return unless ($type =~ m[^text/?] and
 208                    $type !~ m[^text/(?:html|enriched)(?:;|$)]) or
 209                   $type =~ m[^application/pgp(?:;|$)] or
 210                   $entity->parts;
 211
 212     if ($entity->is_multipart) {
 213         my @parts = $entity->parts;
 214         foreach my $part (@parts) {
 215             display_entity(entity => $part,
 216                            bug_num => $ref,
 217                            outer => 0,
 218                            msg_num => $xmessage,
 219                            output => $output,
 220                            attachments => $attachments,
 221                            terse => $param{terse},
 222                            exists $param{msg}?(msg=>$param{msg}):(),
 223                            exists $param{att}?(att=>$param{att}):(),
 224                           );
 225             # print {$output} "\n";
 226         }
 227     } elsif ($entity->parts) {
 228         # We must be dealing with a nested message.
 229          if (not exists $param{att}) {
 230               print {$output} "<blockquote>\n";
 231          }
 232         my @parts = $entity->parts;
 233         foreach my $part (@parts) {
 234             display_entity(entity => $part,
 235                            bug_num => $ref,
 236                            outer => 1,
 237                            msg_num => $xmessage,
 238                            output => $output,
 239                            attachments => $attachments,
 240                            terse => $param{terse},
 241                            exists $param{msg}?(msg=>$param{msg}):(),
 242                            exists $param{att}?(att=>$param{att}):(),
 243                           );
 244             # print {$output} "\n";
 245         }
 246          if (not exists $param{att}) {
 247               print {$output} "</blockquote>\n";
 248          }
 249     } elsif (not $param{terse}) {
 250          my $content_type = $entity->head->get('Content-Type:') || "text/html";
 251          my ($charset) = $content_type =~ m/charset\s*=\s*\"?([\w-]+)\"?/i;
 252          my $body = $entity->bodyhandle->as_string;
 253          $body = convert_to_utf8($body,$charset//'utf8');
 254          $body = html_escape($body);
 255          # Attempt to deal with format=flowed
 256          if ($content_type =~ m/format\s*=\s*\"?flowed\"?/i) {
 257               $body =~ s{^\ }{}mgo;
 258               # we ignore the other things that you can do with
 259               # flowed e-mails cause they don't really matter.
 260          }
 261          # Add links to URLs
 262          # We don't html escape here because we escape above;
 263          # wierd terminators are because of that
 264          $body =~ s{((?:ftp|http|https|svn|ftps|rsync)://[\S~-]+?/?) # Url
 265                     ((?:\&gt\;)?[)]?(?:'|\&\#39\;)?[:.\,]?(?:\s|$)) # terminators
 266               }{<a href=\"$1\">$1</a>$2}gox;
 267          # Add links to bug closures
 268          $body =~ s[(closes:\s*(?:bug)?\#?\s?\d+(?:,?\s*(?:bug)?\#?\s?\d+)*)]
 269                    [my $temp = $1;
 270                     $temp =~ s{(\d+)}
 271                               {bug_links(bug=>$1)}ge;
 272                     $temp;]gxie;
 273          if (defined $config{cve_tracker} and
 274              length $config{cve_tracker}
 275             ) {
 276              # Add links to CVE vulnerabilities (closes #568464)
 277              $body =~ s{(^|\s)(CVE-\d{4}-\d{4,})(\s|[,.-\[\]]|$)}
 278                        {$1<a href="http://$config{cve_tracker}$2">$2</a>$3}gxm;
 279          }
 280          if (not exists $param{att}) {
 281               print {$output} qq(<pre class="message">$body</pre>\n);
 282          }
 283     }
 284 }
 285
 286
 287 =head2 handle_email_message
 288
 289      handle_email_message($record->{text},
 290                           ref        => $bug_number,
 291                           msg_num => $msg_number,
 292                          );
 293
 294 Returns a decoded e-mail message and displays entities/attachments as
 295 appropriate.
 296
 297
 298 =cut
 299
 300 sub handle_email_message{
 301      my ($email,%param) = @_;
 302
 303      my $output;
 304      my $output_fh = globify_scalar(\$output);
 305      my $parser = MIME::Parser->new();
 306      # Because we are using memory, not tempfiles, there's no need to
 307      # clean up here like in Debbugs::MIME
 308      $parser->tmp_to_core(1);
 309      $parser->output_to_core(1);
 310      my $entity = $parser->parse_data( $email);
 311      my @attachments = ();
 312      display_entity(entity  => $entity,
 313                     bug_num => $param{ref},
 314                     outer   => 1,
 315                     msg_num => $param{msg_num},
 316                     output => $output_fh,
 317                     attachments => \@attachments,
 318                     terse       => $param{terse},
 319                     exists $param{msg}?(msg=>$param{msg}):(),
 320                     exists $param{att}?(att=>$param{att}):(),
 321                     exists $param{trim_headers}?(trim_headers=>$param{trim_headers}):(),
 322                    );
 323      return decode_utf8($output);
 324 }
 325
 326 =head2 handle_record
 327
 328      push @log, handle_record($record,$ref,$msg_num);
 329
 330 Deals with a record in a bug log as returned by
 331 L<Debbugs::Log::read_log_records>; returns the log information that
 332 should be output to the browser.
 333
 334 =cut
 335
 336 sub handle_record{
 337      my ($record,$bug_number,$msg_number,$seen_msg_ids) = @_;
 338
 339      # output needs to have the is_utf8 flag on to avoid double
 340      # encoding
 341      my $output = decode_utf8('');
 342      local $_ = $record->{type};
 343      if (/html/) {
 344          # $record->{text} is not in perl's internal encoding; convert it
 345          my $text = decode_rfc1522(decode_utf8($record->{text}));
 346           my ($time) = $text =~ /<!--\s+time:(\d+)\s+-->/;
 347           my $class = $text =~ /^<strong>(?:Acknowledgement|Reply|Information|Report|Notification)/m ? 'infmessage':'msgreceived';
 348           $output .= $text;
 349           # Link to forwarded http:// urls in the midst of the report
 350           # (even though these links already exist at the top)
 351           $output =~ s,((?:ftp|http|https)://[\S~-]+?/?)((?:[\)\'\:\.\,]|\&\#39;)?(?:\s|\.<|$)),<a href=\"$1\">$1</a>$2,go;
 352           # Add links to the cloned bugs
 353           $output =~ s{(Bug )(\d+)( cloned as bugs? )(\d+)(?:\-(\d+)|)}{$1.bug_links(bug=>$2).$3.bug_links(bug=>(defined $5)?[$4..$5]:$4)}eo;
 354           # Add links to merged bugs
 355           $output =~ s{(?<=Merged )([\d\s]+)(?=\.)}{join(' ',map {bug_links(bug=>$_)} (split /\s+/, $1))}eo;
 356           # Add links to blocked bugs
 357           $output =~ s{(?<=Blocking bugs)(?:( of )(\d+))?( (?:added|set to|removed):\s+)([\d\s\,]+)}
 358                       {(defined $2?$1.bug_links(bug=>$2):'').$3.
 359                            english_join([map {bug_links(bug=>$_)} (split /\,?\s+/, $4)])}eo;
 360           $output =~ s{((?:[Aa]dded|[Rr]emoved)\ blocking\ bug(?:\(s\))?)(?:(\ of\ )(\d+))?(:?\s+)
 361                        (\d+(?:,\s+\d+)*(?:\,?\s+and\s+\d+)?)}
 362                       {$1.(defined $3?$2.bug_links(bug=>$3):'').$4.
 363                            english_join([map {bug_links(bug=>$_)} (split /\,?\s+(?:and\s+)?/, $5)])}xeo;
 364           $output =~ s{([Aa]dded|[Rr]emoved)( indication that bug )(\d+)( blocks )([\d\s\,]+)}
 365                       {$1.$2.(bug_links(bug=>$3)).$4.
 366                            english_join([map {bug_links(bug=>$_)} (split /\,?\s+(?:and\s+)?/, $5)])}eo;
 367           # Add links to reassigned packages
 368           $output =~ s{(Bug reassigned from package \`)([^']+?)((?:'|\&\#39;) to \`)([^']+?)((?:'|\&\#39;))}
 369           {$1.q(<a href=").html_escape(package_links(package=>$2)).qq(">$2</a>).$3.q(<a href=").html_escape(package_links(package=>$4)).qq(">$4</a>).$5}eo;
 370           if (defined $time) {
 371                $output .= ' ('.strftime('%a, %d %b %Y %T GMT',gmtime($time)).') ';
 372           }
 373           $output .= '<a href="' .
 374                html_escape(bug_links(bug => $bug_number,
 375                                      options => {msg => ($msg_number+1)},
 376                                      links_only => 1,
 377                                     )
 378                           ) . '">Full text</a> and <a href="' .
 379                                html_escape(bug_links(bug => $bug_number,
 380                                                      options => {msg => ($msg_number+1),
 381                                                                  mbox => 'yes'},
 382                                                      links_only => 1)
 383                                           ) . '">rfc822 format</a> available.';
 384
 385           $output = qq(<div class="$class"><hr>\n<a name="$msg_number"></a>\n) . $output . "</div>\n";
 386      }
 387      elsif (/recips/) {
 388           my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 389           if (defined $msg_id and exists $$seen_msg_ids{$msg_id}) {
 390                return ();
 391           }
 392           elsif (defined $msg_id) {
 393                $$seen_msg_ids{$msg_id} = 1;
 394           }
 395           $output .= qq(<hr><p class="msgreceived"><a name="$msg_number"></a>\n);
 396           $output .= 'View this message in <a href="' . html_escape(bug_links(bug=>$bug_number, links_only => 1, options=>{msg=>$msg_number, mbox=>'yes'})) . '">rfc822 format</a></p>';
 397           $output .= handle_email_message($record->{text},
 398                                           ref     => $bug_number,
 399                                           msg_num => $msg_number,
 400                                          );
 401      }
 402      elsif (/autocheck/) {
 403           # Do nothing
 404      }
 405      elsif (/incoming-recv/) {
 406           my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 407           if (defined $msg_id and exists $$seen_msg_ids{$msg_id}) {
 408                return ();
 409           }
 410           elsif (defined $msg_id) {
 411                $$seen_msg_ids{$msg_id} = 1;
 412           }
 413           # Incomming Mail Message
 414           my ($received,$hostname) = $record->{text} =~ m/Received: \(at (\S+)\) by (\S+)\;/;
 415           $output .= qq|<hr><p class="msgreceived"><a name="$msg_number"></a><a name="msg$msg_number"></a><a href="#$msg_number">Message #$msg_number</a> received at |.
 416                html_escape("$received\@$hostname") .
 417                     q| (<a href="| . html_escape(bug_links(bug => $bug_number, links_only => 1, options => {msg=>$msg_number})) . '">full text</a>'.
 418                          q|, <a href="| . html_escape(bug_links(bug => $bug_number,
 419                                                                 links_only => 1,
 420                                                                 options => {msg=>$msg_number,
 421                                                                             mbox=>'yes'}
 422                                                                )
 423                                                      ) .'">mbox</a>)'.":</p>\n";
 424           $output .= handle_email_message($record->{text},
 425                                           ref     => $bug_number,
 426                                           msg_num => $msg_number,
 427                                          );
 428      }
 429      else {
 430           die "Unknown record type $_";
 431      }
 432      return $output;
 433 }
 434
 435
 436 sub __libravatar_url {
 437     my ($email) = @_;
 438     if (not defined $config{libravatar_uri} or not length $config{libravatar_uri}) {
 439         return undef;
 440     }
 441     ($email) = get_addresses($email);
 442     return $config{libravatar_uri}.md5_hex(lc($email)).($config{libravatar_uri_options}//'');
 443 }
 444
 445
 446 1;
 447
 448
 449 __END__
 450
 451
 452
 453
 454
 455