rip_movie

   1 #! /usr/bin/perl
   2 # rip_movie uses HandBrakeCLI to rip movies, and is released
   3 # under the terms of the GPL version 2, or any later version, at your
   4 # option. See the file README and COPYING for more information.
   5 # Copyright 2011 by Don Armstrong <don@donarmstrong.com>.
   6 # $Id: perl_script 1432 2009-04-21 02:42:41Z don $
   7
   8
   9 use warnings;
  10 use strict;
  11
  12 use Getopt::Long;
  13 use Pod::Usage;
  14
  15 =head1 NAME
  16
  17 rip_movie - Rips Movies using HandBrakeCLI
  18
  19 =head1 SYNOPSIS
  20
  21  rip_movie
  22
  23  Options:
  24   --debug, -d debugging level (Default 0)
  25   --help, -h display this help
  26   --man, -m display manual
  27
  28 =head1 OPTIONS
  29
  30 =over
  31
  32 =item B<--output>
  33
  34 Override the output filename
  35
  36 =item B<--min-duration>
  37
  38 Minimum duration in minutes for a track to be considered an episode
  39 (Default 25 minutes)
  40
  41 =item B<--titles>
  42
  43 Optional titles to rip; overrides title autodetection
  44
  45 =item B<--debug, -d>
  46
  47 Debug verbosity. (Default 0)
  48
  49 =item B<--help, -h>
  50
  51 Display brief usage information.
  52
  53 =item B<--man, -m>
  54
  55 Display this manual.
  56
  57 =back
  58
  59 =head1 EXAMPLES
  60
  61 rip_movie
  62
  63 =cut
  64
  65 use List::Util qw(reduce);
  66
  67 use vars qw($DEBUG);
  68
  69 my %options = (debug           => 0,
  70                help            => 0,
  71                man             => 0,
  72                min_duration    => 25,
  73                );
  74
  75 GetOptions(\%options,
  76            'titles|title|t=i@',
  77            'min_duration|min-duration=i',
  78            'debug|d+','help|h|?','man|m');
  79
  80 pod2usage() if $options{help};
  81 pod2usage({verbose=>2}) if $options{man};
  82
  83 $DEBUG = $options{debug};
  84
  85 my @titles_to_rip;
  86
  87 my @USAGE_ERRORS;
  88 if (exists $options{min_duration}) {
  89     $options{min_duration}*=60;
  90 }
  91 if (exists $options{titles}) {
  92     for my $title (@{$options{titles}}) {
  93         if ($title < 1) {
  94             push @USAGE_ERRORS,"Title '$title' is not a valid title; must be greater than zero.";
  95         }
  96         push @titles_to_rip,$title;
  97     }
  98 }
  99
 100 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
 101
 102
 103 my $result = qx(HandBrakeCLI -i /dev/dvd -t 0 -o /dev/null 2>&1);
 104
 105 #print STDERR $result;
 106 my ($title) = $result =~ /^libdvdnav:\s+DVD\s+Title:\s+(.+)/im;
 107 die "no title" if not defined $title;
 108 my $filename = lc($title);
 109 $filename =~ s/[\s_-]+/_/;
 110
 111 use Data::Dumper;
 112
 113 my @titles;
 114 for my $title_bit ($result =~ /\n(\+ title \d+:.+?)(?=\n\+ title\s+|$)/gs) {
 115     my %title;
 116     # title number
 117     $title_bit =~ /^\+ title (\d+):/;
 118     $title{num} = $1;
 119     my ($duration) = $title_bit =~ /^\s+\+\s+duration:\s+([\d:]+)$/m;
 120     # HH:MM:SS, so (HH*60 + MM) * 60 + SS
 121     $duration = reduce {$a * 60 + $b } split /:/, $duration;
 122     $title{duration} = $duration;
 123     # figure out audio tracks
 124     $title_bit =~ /(?<leadspace>\s+)\+\s+audio\s+tracks:\n # audio track header
 125                    (?<audiotracks>(?:\g{leadspace}\s+\+\s+\d+\,.+\n){1,}) # audio track information
 126                   /x;
 127     my $at_info = $+{audiotracks};
 128     my @at_nums = $at_info =~ /^\s+\+\s+(\d+)\,/mg;
 129     $title{audio_tracks} = [@at_nums];
 130     # figure out subtitle tracks
 131     $title_bit =~ /(?<leadspace>\s+)\+\s+subtitle\s+tracks:\n # subtitle track header
 132                    (?<subtittracks>(?:\g{leadspace}\s+\+\s+\d+\,.+(?:\n|$)){1,}) # subtitle track information
 133                   /x;
 134     my $st_info = $+{subtittracks};
 135     my @st_nums = $st_info =~ /^\s+\+\s+(\d+)\,/mg;
 136     $title{subtitle_tracks} = [@st_nums];
 137     push @titles,\%title;
 138 }
 139
 140 if (not @titles_to_rip) {
 141     my $longest_title;
 142     for my $i (0..$#titles) {
 143         my $title = $titles[$i];
 144         if (not defined $longest_title or
 145             $title->{duration} > $titles[$longest_title]{duration}) {
 146             $longest_title = $i;
 147         }
 148         if ($title->{duration} >= $options{min_duration}) {
 149             push @titles_to_rip,$i+1;
 150         }
 151     }
 152     if (not @titles_to_rip) {
 153         push @titles_to_rip,$longest_title+1;
 154     }
 155 }
 156 my $invalid_titles = 0;
 157 for my $i (@titles_to_rip) {
 158     if ($i > @titles or $i < 1) {
 159         print STDERR "Invalid title $i\n";
 160         $invalid_titles = 1;
 161     }
 162 }
 163 exit 1 if $invalid_titles;
 164
 165 my $multiple_titles = @titles_to_rip > 1;
 166
 167 for my $i (@titles_to_rip) {
 168     system('HandBrakeCLI','-i','/dev/dvd','-t',$i,
 169            '-o',$filename.($multiple_titles ? '_'.$i : '').".mkv",
 170            '-e','x264','-2','-q','21',
 171            '-a',join(',',@{$titles[$i-1]{audio_tracks}}),
 172            '-s',join(',',@{$titles[$i-1]{subtitle_tracks}}),
 173           );
 174 }
 175
 176
 177
 178
 179
 180 __END__