make_invoice

   1 #! /usr/bin/perl
   2 # make_invoice makes latex invoices, and is released
   3 # under the terms of the GPL version 2, or any later version, at your
   4 # option. See the file README and COPYING for more information.
   5 # Copyright 2008 by Don Armstrong <don@donarmstrong.com>.
   6 # $Id: perl_script 495 2006-08-10 08:02:01Z don $
   7
   8
   9 use warnings;
  10 use strict;
  11
  12 use Getopt::Long;
  13 use Pod::Usage;
  14
  15 =head1 NAME
  16
  17 make_invoice - makes invoices using latex
  18
  19 =head1 SYNOPSIS
  20
  21  make_invoice [options]
  22
  23  Options:
  24   --log,-l the log file to use to make the invoice
  25   --template,-t the template to use to make the invoice
  26   --min-time-interval, -m minimum time to bill, default 0
  27   --time-granularity, -g time granularity, default 0
  28   --hourly-fee, -f hourly fee, default 50.00
  29   --svn,-s whether to use subversion or not
  30   --debug, -d debugging level (Default 0)
  31   --help, -h display this help
  32   --man, -m display manual
  33
  34 =head1 OPTIONS
  35
  36 =over
  37
  38 =item B<--log, -l>
  39
  40 The log file to use to generate the invoice
  41
  42 =item B<--template, -t>
  43
  44 The tex template to use to generate the invoice
  45
  46 =item B<--svn, -s>
  47
  48 Whether to use subversion or not; defaults to yes if .svn exists in
  49 the current directory.
  50
  51 =item B<--invoice,-i>
  52
  53 Invoice directory to place invoice in (automatically calculated if not
  54 passed.)
  55
  56 =item B<--min-time-interval, -m>
  57
  58 Minimum time interval to bill, defaults to 0.
  59
  60 =item B<--time-granularity, -g>
  61
  62 Time granularity, defaults to 0.
  63
  64 =item B<--hourly-fee,-f>
  65
  66 Hourly fee, defaults to 50.00
  67
  68 =item B<--tex-only>
  69
  70 Only output the LaTeX file
  71
  72 =item B<--log-only>
  73
  74 Only output the log file
  75
  76 =item B<--debug, -d>
  77
  78 Debug verbosity. (Default 0)
  79
  80 =item B<--help, -h>
  81
  82 Display brief useage information.
  83
  84 =item B<--man, -m>
  85
  86 Display this manual.
  87
  88 =back
  89
  90 =head1 EXAMPLES
  91
  92
  93 =cut
  94
  95
  96 use vars qw($DEBUG);
  97
  98 use Date::Manip;
  99 use POSIX qw(ceil strftime);
 100 use Cwd qw(cwd);
 101 use Text::Template;
 102
 103 use Params::Validate qw(validate_with :types);
 104
 105 my %options = (log             => undef,
 106                template        => undef,
 107                svn             => undef,
 108                invoice         => undef,
 109                time_interval   => 0.00,
 110                time_granularity => 0.00,
 111                hourly_fee      => '50.00',
 112                debug           => 0,
 113                help            => 0,
 114                man             => 0,
 115                log_only        => 0,
 116                tex_only        => 0,
 117                );
 118
 119 GetOptions(\%options,
 120            'log|l=s','template|t=s','invoice|i=s','svn|s!',
 121            'time_granularity|time-granularity|g=s',
 122            'time_interval|min-time-interval|T=s',
 123            'hourly_fee|hourly-fee|f=s',
 124            'log_only|log-only',
 125            'tex_only|tex-only',
 126            'debug|d+','help|h|?','man|m');
 127
 128 pod2usage() if $options{help};
 129 pod2usage({verbose=>2}) if $options{man};
 130
 131 $DEBUG = $options{debug};
 132
 133 my @USAGE_ERRORS;
 134 if (not defined $options{log}) {
 135      push @USAGE_ERRORS,"You must pass a log file with --log";
 136 }
 137 if (not defined $options{template}) {
 138      push @USAGE_ERRORS,"You must pass a template file with --template";
 139 }
 140
 141 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
 142
 143 if (not defined $options{svn}) {
 144      $options{svn} = -e '.svn';
 145 }
 146
 147
 148 my $log_fh = IO::File->new($options{log},'r') or
 149      die "Unable to open $options{log} for reading: $!";
 150 my $template_fh = IO::File->new($options{template},'r') or
 151      die "Unable to open $options{template} for reading: $!";
 152
 153
 154 my $calc_log = '';
 155 my $tex_log = <<'EOF';
 156 \setlength\LTleft{0pt plus 1fill minus 1fill}%
 157 \let\LTright\LTleft
 158 \begin{longtable}{|p{9cm}|r|r|r|r|}%
 159 %  \caption*{}
 160 \hline
 161   \mbox{Description} & Item Cost & Quantity & Cost & Total \\
 162 \endhead
 163 EOF
 164 my $totaldelta = undef;
 165
 166 my $total = 0;
 167
 168 my $first_date = undef;
 169 my $last_date = undef;
 170 my $time = undef;
 171 my $date = undef;
 172 my $date2 = undef;
 173 my @events;
 174
 175 while (<$log_fh>) {
 176      chomp;
 177      next if /^Total: \d+\.\d{2}$/;
 178      if (/^\s*\* /) {
 179           if (defined $time) {
 180                $tex_log .= format_events(date => $date,
 181                                          date2 => $date2,
 182                                          time => $time,
 183                                          total => \$total,
 184                                          events => \@events);
 185                @events = ();
 186                $date = undef;
 187                $time = undef;
 188           }
 189           s/\s*\[[\.\d]+\]\s*\[[\.\d]+\]\s*$//;
 190           my $string = $_;
 191           my ($d1,$d2) = map {s/^\s*\*\s*//;
 192                              UnixDate(ParseDate($_),'%s')
 193                         } split /\s*-\s*/;
 194           if (not defined $first_date) {
 195                $first_date = $d1;
 196           }
 197           $last_date = $d2;
 198           my $delta = $d2-$d1;
 199           $date = $d1;
 200           $date2 = $d2;
 201           my $hours = $delta / (60*60);
 202           if ($hours < $options{time_interval}) {
 203                $hours = $options{time_interval}
 204           }
 205           if ($options{time_granularity} > 0) {
 206                $hours = ceil($hours / $options{time_granularity})*$options{time_granularity};
 207           }
 208           $time = $hours;
 209           $totaldelta += $delta;
 210           $calc_log .= qq($string [).sprintf('%.2f',$hours).qq(] [).sprintf('%.2f',$totaldelta/(60*60)).qq(]\n);
 211      }
 212      elsif (/^\s+-\s*(.+)/) {
 213           my $event = $1;
 214           chomp $event;
 215           push @events,$event;
 216           $calc_log .= $_.qq(\n);
 217      }
 218      else {
 219           $calc_log .= $_.qq(\n);
 220      }
 221 }
 222 $calc_log .= "\nTotal: ".sprintf('%.2f',$totaldelta/(60*60)).qq(\n);
 223 if (defined $time) {
 224     $tex_log .= format_events(date => $date,
 225                                date2 => $date2,
 226                               time => $time,
 227                               total => \$total,
 228                               events => \@events);
 229      @events = ();
 230      $date = undef;
 231      $date2 = undef;
 232      $time = undef;
 233 }
 234
 235 $tex_log .= <<'EOF';
 236 \hline\hline
 237 \multicolumn{4}{|r|}{\textbf{Total}} & \$%
 238 EOF
 239
 240 $tex_log .= sprintf('%.2f',$total)."%\n";
 241
 242 $tex_log .= <<'EOF';
 243 \\
 244 \hline
 245 \end{longtable}
 246 EOF
 247
 248 my $template;
 249 {
 250      local $/;
 251      $template = <$template_fh>;
 252 }
 253
 254 my $invoice_start = strftime('%c',localtime($first_date));
 255 my $invoice_stop = strftime('%c',localtime($last_date));
 256
 257 my $tt = Text::Template->new(TYPE=>'string',
 258                              SOURCE => $template,
 259                              DELIMITERS => ['{--','--}'],
 260                             );
 261 my $tex_invoice = $tt->fill_in(HASH=>{start => $invoice_start,
 262                                       stop  => $invoice_stop,
 263                                       log   => $tex_log,
 264                                       total => sprintf('%0.2f',$total),
 265                                      }
 266                               );
 267 if (not defined $tex_invoice) {
 268      die $Text::Template::ERROR;
 269 }
 270
 271 if ($options{log_only}) {
 272     print $calc_log;
 273     exit 0;
 274 }
 275
 276 if ($options{tex_only}) {
 277     print $tex_invoice;
 278     exit 0;
 279 }
 280
 281
 282 my $invoice_date = strftime('%Y_%m_%d',localtime($last_date));
 283 my $invoice_dir = "invoice_$invoice_date";
 284
 285 if (not -d $invoice_dir) {
 286      if ($options{svn}) {
 287           system('svn','mkdir',$invoice_dir) == 0 or
 288                die "Unable to create invoice directory $invoice_dir";
 289      }
 290      else {
 291           system('mkdir','-p',$invoice_dir) == 0 or
 292                die "Unable to create invoice directory $invoice_dir";
 293      }
 294 }
 295
 296 my $cwd = cwd;
 297 if (-e 'common_makefile' and not -e '$invoice_dir/Makefile') {
 298      chdir($invoice_dir);
 299      system('ln','-sf','../common_makefile','Makefile') == 0 or
 300           die "Unable to link common_makefile to Makefile";
 301      if ($options{svn}) {
 302           system('svn','add','Makefile') == 0 or
 303                die "Unable to add Makefile";
 304      }
 305      chdir($cwd);
 306 }
 307
 308 # now we write stuff out
 309 chdir($invoice_dir);
 310 my $calc_log_fh = IO::File->new("log_${invoice_date}",'w') or
 311      die "Unable to open log_${invoice_date} for writing: $!";
 312 print {$calc_log_fh} $calc_log;
 313 close($calc_log_fh);
 314
 315 my $tex_invoice_fh = IO::File->new("invoice_${invoice_date}.tex",'w') or
 316      die "Unable to open log_${invoice_date} for writing: $!";
 317 print {$tex_invoice_fh} $tex_invoice;
 318 close($tex_invoice_fh);
 319
 320 if ($options{svn}) {
 321      system('svn','add',
 322             "log_${invoice_date}",
 323             "invoice_${invoice_date}.tex",
 324            ) == 0 or die "Unable to add log and invoice to svn";
 325      system('svn','propset','svn:ignore',
 326             "*.aux\n*.log\n*.dvi\n*.ps\n*.pdf\nauto\n",
 327             '.'
 328            ) == 0 or die "Unable to set svn:ignore";
 329 }
 330
 331
 332 sub format_events{
 333      my %param = validate_with(params => \@_,
 334                                spec   => {time => {type => SCALAR,
 335                                                   },
 336                                           date => {type => SCALAR,
 337                                                   },
 338                                           date2 => {type => SCALAR,
 339                                                    },
 340                                           total => {type => SCALARREF,
 341                                                    },
 342                                           events => {type => ARRAYREF,
 343                                                     },
 344                                          },
 345                               );
 346      ${$param{total}} += $param{time} * $options{hourly_fee};
 347
 348 #     $param{date} =~ s/\s+\d+\:\d+\:\d+\s+[A-Z]{0,3}\s*//;
 349      my $output = '\hline'."\n".'        \mbox{'.strftime('%A, %B %e, %H:%M',localtime($param{date})).
 350           ' to '.strftime('%H:%M %Z',localtime($param{date2}))."}\n\n".
 351          '         \begin{itemize*}'."\n";
 352      $output .= join('',map { s/_/\\_/g; "           \\item $_\n";} @{$param{events}});
 353      $output .= '         \end{itemize*} & \$'.sprintf('%.2f',$options{hourly_fee}).' & '.sprintf('%.2f',$param{time}).
 354          ' & \$'.sprintf('%.2f',$param{time}*$options{hourly_fee}).' & \$'.
 355              sprintf('%.2f',${$param{total}}) .
 356                  " \\\\\n";
 357      return $output;
 358 }
 359
 360 ## sub format_events{
 361 ##      my ($date,$date2,$time,@events) = @_;
 362 ##      my $output = '        \Fee{'.strftime('%A, %B %e, %H:%M',localtime(UnixDate($date,'%s'))).
 363 ##        ' to '.strftime('%H:%M %Z',localtime(UnixDate($date2,'%s')))."\n".
 364 ##        '         \begin{itemize*}'."\n";
 365 ##      $output .= join('',map {"           \\item $_\n"} @events);
 366 ##      $output .= '         \end{itemize*}}{50.00}{'.$time.'}'."\n";
 367 ##      return $output;
 368 ## }
 369
 370
 371 __END__