jobs_to_org

   1 #!/usr/bin/perl
   2 # jobs_to_org finds jobs in different job sites and turns them into org things
   3 # and is released under the terms of the GNU GPL version 3, or any
   4 # later version, at your option. See the file README and COPYING for
   5 # more information.
   6 # Copyright 2016 by Don Armstrong <don@donarmstrong.com>.
   7
   8
   9 use warnings;
  10 use strict;
  11
  12 use Getopt::Long;
  13 use Pod::Usage;
  14
  15 =head1 NAME
  16
  17 jobs_to_org - finds jobs in different job sites and turns them into org things
  18
  19 =head1 SYNOPSIS
  20
  21 jobs_to_org [options]
  22
  23  Options:
  24    --debug, -d debugging level (Default 0)
  25    --help, -h display this help
  26    --man, -m display manual
  27
  28 =head1 OPTIONS
  29
  30 =over
  31
  32 =item B<--debug, -d>
  33
  34 Debug verbosity. (Default 0)
  35
  36 =item B<--help, -h>
  37
  38 Display brief usage information.
  39
  40 =item B<--man, -m>
  41
  42 Display this manual.
  43
  44 =back
  45
  46 =head1 EXAMPLES
  47
  48 jobs_to_org
  49
  50 =cut
  51
  52 use OSSP::uuid;
  53 use WWW::Mechanize;
  54 use WWW::Mechanize::TreeBuilder;
  55 use vars qw($DEBUG);
  56 use Data::Printer;
  57 use Text::Wrap;
  58 use POSIX qw(strftime);
  59
  60 tie my $uuid, 'OSSP::uuid::tie';
  61 $uuid= ["v1"];
  62
  63 my %options = (debug           => 0,
  64                help            => 0,
  65                man             => 0,
  66                pages           => 1,
  67                site            => 'herc',
  68               );
  69
  70 GetOptions(\%options,
  71            'site|s=s',
  72            'pages|p=i',
  73            'debug|d+','help|h|?','man|m');
  74
  75 pod2usage() if $options{help};
  76 pod2usage({verbose=>2}) if $options{man};
  77
  78 $DEBUG = $options{debug};
  79
  80 my @USAGE_ERRORS;
  81 # if (1) {
  82 #     push @USAGE_ERRORS,"You must pass something";
  83 # }
  84
  85 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
  86
  87 my %sites =
  88     (herc => {url => 'http://main.hercjobs.org/jobs/search?keywords=professor+AND+%28genomics+OR+bioinformatics+OR+biology+OR+informatics%29&discipline=academic-faculty&category=academic-faculty&category=allied-health&category=biological-biomedical-sciences&category=computer-information-sciences&category=education&category=interdisciplinary&category=mathematics-statistics&category=medical-research&category=physical-sciences&sort=DATE_POSTED+DESC',
  89               next_selector => [class => "bti-pagination-previous-link bti-pagination-prev-next",text => '>'],
  90               job_selector => [url_regex => qr{^\/jobs\/\d+/.+}],
  91               university => [itemprop=>"hiringOrganization",itemtype=>"http://schema.org/Organization"],
  92               description => [class=>"bti-jd-description",itemprop=>"description"],
  93               date => [class=>"bti-jd-detail-text",
  94                        sub {scalar $_[0]->parent()->attr('class') eq 'bti-jd-details-action'}],
  95               position => [class=>"bti-jd-title",itemprop=>"title"],
  96              },
  97      nature => {url => 'http://www.nature.com/naturejobs/science/jobs?utf8=%E2%9C%93&q%5B%5D=professor&job_type%5B%5D=Assistant+Professor&job_type%5B%5D=Professor&order_by=created_on',
  98                 next_selector => [class=>"next_page",url_regex=>qr{^/naturejobs/science/jobs},],
  99                 job_selector => [url_regex => qr{^/naturejobs/science/jobs/\d+-.+}],
 100                 university => [href => qr{^/naturejobs/science/employer-directory/\d+$}],
 101                 description => [class=>"job-description"],
 102                 date => [],
 103                 position => [class=>'job-title heading'],
 104                },
 105      vitae => {url => 'https://chroniclevitae.com/job_search?job_search%5Bdistance_from_zip%5D=10&job_search%5Bemployment_type%5D=Full-time&job_search%5Bposition_type%5D=63',
 106                next_selector => [text_regex => qr{Next}, url_regex=>qr{^/job_search}],
 107                job_selector => [url_regex => qr{/jobs/\d+-\d+$}],
 108                university => [href => qr{/institutions/\d+$}],
 109                description => [class => 'job-listing__content__description'],
 110                date => [_tag => 'td', content => qr/\,\s+20\d{2}$/],
 111                position => [_tag => 'h1',
 112                             sub {scalar $_[0]->parent()->attr('class') eq 'page-title page-title--two-col'},
 113                            ],
 114               },
 115     );
 116
 117 binmode STDOUT,":utf8";
 118 get_jobs($options{site},$options{pages});
 119
 120 sub get_jobs {
 121     my ($site,$pages) = @_;
 122
 123     my $todays_date = strftime('%Y-%m-%d %H:%M:%S',localtime());
 124
 125     my $m = WWW::Mechanize->new();
 126     WWW::Mechanize::TreeBuilder->meta->apply($m);
 127     if (not defined $sites{$site}) {
 128         die "Unknown site $site";
 129     }
 130     my $s = $sites{$site};
 131     $m->get($s->{url});
 132     for (1..$pages) {
 133         my %seen;
 134         my @job_urls = grep { ! $seen{ $_->URI()->abs() }++ }
 135             $m->find_all_links(@{$s->{job_selector}});
 136         for my $j_u (@job_urls) {
 137             $m->get($j_u);
 138             my $university = 'No university';
 139             eval {
 140                 $university = $m->tree->look_down(@{$s->{university}})->as_text();
 141             };
 142             my $date = $todays_date;
 143             eval {
 144                 $date = $m->tree->look_down(@{$s->{date}})->as_text() // $todays_date if
 145                     @{$s->{date}};
 146             };
 147             my $description = 'unknown';
 148             eval {
 149                 $description = $m->tree->look_down(@{$s->{description}})->as_text();
 150             };
 151             my $position = 'Unknown';
 152             eval {
 153                 $position = $m->tree->look_down(@{$s->{position}})->as_text();
 154             };
 155             print format_job($university,$position,$j_u->URI->abs(),$description,$date);
 156             $m->back();
 157         }
 158         $m->follow_link(@{$s->{next_selector}}) or die "Unable to find next link";
 159     }
 160 }
 161
 162 sub format_job {
 163     my ($university,$position,$url,$text,$date) = @_;
 164     $text = wrap('   ','   ',$text);
 165     my $ret = <<"EOF";
 166 ** TODO $university -- $position
 167    :PROPERTIES:
 168    :ID:       $uuid
 169    :END:
 170 [[$url]]
 171 [$date]
 172
 173 $text
 174
 175 EOF
 176     return $ret;
 177 }
 178
 179
 180
 181 __END__