bibtex_to_paper

   1 #!/usr/bin/perl
   2 # bibtex_to_paper opens the paper corresponding to a bibtex key
   3 # and is released under the terms of the GNU GPL version 3, or any
   4 # later version, at your option. See the file README and COPYING for
   5 # more information.
   6 # Copyright 2014 by Don Armstrong <don@donarmstrong.com>.
   7
   8
   9 use warnings;
  10 use strict;
  11
  12 use Getopt::Long;
  13 use Pod::Usage;
  14
  15 use File::Find;
  16 use File::Basename qw(basename);
  17 use File::Spec qw(rel2abs);
  18 use Text::BibTeX;
  19 use User;
  20 use Data::Printer;
  21 use POSIX;
  22
  23 use DBI;
  24
  25 =head1 NAME
  26
  27 bibtex_to_paper - opens the paper corresponding to a bibtex key
  28
  29 =head1 SYNOPSIS
  30
  31 bibtex_to_paper [options] bibtexkey
  32
  33  Options:
  34   --bibtex, -b bibtex file to look up key in
  35   --bibtex-cache, -c bibtex cache file
  36   --build-cache, -B build cache using bibtex files
  37   --search-by-pmid Search term is a pmid instead of a bibtex key
  38   --pdf-dir pdf directory
  39   --pdfviewer, -p pdf viewer to use
  40   --only-print Only print PDF file name
  41   --debug, -d debugging level (Default 0)
  42   --help, -h display this help
  43   --man, -m display manual
  44
  45 =head1 OPTIONS
  46
  47 =over
  48
  49 =item B<--bibtex, -b>
  50
  51 Bibtex file to look key up in
  52
  53 =item B<--bibtex-cache, -c>
  54
  55 Bibtex cache file; rebuilt if bibtex file changes
  56
  57 =item B<--pdfviewer, -p>
  58
  59 PDF viewer to use; defaults to evince unless a .xoj exists, in which
  60 case xournal is used.
  61
  62 =item B<--only-print>
  63
  64 Only print the PDF file name, don't open it.
  65
  66 =item B<--debug, -d>
  67
  68 Debug verbosity. (Default 0)
  69
  70 =item B<--help, -h>
  71
  72 Display brief usage information.
  73
  74 =item B<--man, -m>
  75
  76 Display this manual.
  77
  78 =back
  79
  80 =head1 EXAMPLES
  81
  82 bibtex_to_paper
  83
  84 =cut
  85
  86
  87 use vars qw($DEBUG);
  88
  89 my %options = (debug           => 0,
  90                help            => 0,
  91                man             => 0,
  92                only_print      => 0,
  93                search_by_pmid  => 0,
  94                'bibtex_cache'  => File::Spec->catfile(User->Home,'.bibtex_to_paper_cache'),
  95               );
  96
  97 GetOptions(\%options,
  98            'build_cache|build-cache!',
  99            'bibtex|b=s@',
 100            'bibtex_cache|bibtex-cache|c=s',
 101            'pdfviewer|p=s',
 102            'only_print|only-print!',
 103            'search_by_pmid|search-by-pmid!',
 104            'clear_cache|clear-cache!',
 105            'papers_directory|papers-directory=s@',
 106            'debug|d+','help|h|?','man|m');
 107
 108 pod2usage() if $options{help};
 109 pod2usage({verbose=>2}) if $options{man};
 110
 111 $DEBUG = $options{debug};
 112
 113 my @USAGE_ERRORS;
 114 if (not exists $options{bibtex} and
 115     not exists $options{bibtex_cache}) {
 116     push @USAGE_ERRORS,
 117         "You must give at least one of --bibtex".
 118         "or --bibtex-cache";
 119 }
 120
 121 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
 122
 123 main();
 124
 125 sub main{
 126
 127     my $dbh;
 128     my $sth;
 129     if (exists $options{bibtex_cache}) {
 130         my $initialize = 0;
 131         if (-e $options{bibtex_cache}) {
 132             ($dbh,$sth) = open_cache($options{bibtex_cache});
 133         } else {
 134             ($dbh,$sth) = initialize_database($options{bibtex_cache});
 135         }
 136     }
 137
 138     if (exists $options{clear_cache}) {
 139         clear_cache($dbh,$sth);
 140     }
 141     my %entries;
 142     if (exists $options{build_cache}) {
 143         $options{bibtex} //= [];
 144         $options{bibtex} =
 145             [@ARGV,
 146              @{ref $options{bibtex}?$options{bibtex}:[$options{bibtex}]},
 147             ];
 148         @ARGV = ();
 149     }
 150     if (exists $options{bibtex}) {
 151         for my $bibtex_file (@{ref $options{bibtex}?$options{bibtex}:[$options{bibtex}]}) {
 152             parse_bibtex_file($bibtex_file,\%entries);
 153         }
 154     }
 155
 156     if (exists $options{papers_directory} and
 157         defined $dbh
 158        ) {
 159         load_papers_into_database($dbh,$sth,$options{papers_directory});
 160     }
 161
 162     p %entries if $DEBUG;
 163     if (keys %entries and
 164         defined $dbh) {
 165         load_bibtex_entries_into_database($dbh,$sth,\%entries);
 166     }
 167
 168     p @ARGV if $DEBUG;
 169     for my $bibtex_key (@ARGV) {
 170         open_bibtex_key(\%options,$dbh,$sth,\%entries,$bibtex_key);
 171     }
 172
 173 }
 174
 175 sub clear_cache {
 176     my ($dbh,$sth) = @_;
 177     $sth->{clear_papers_cache}->execute();
 178     $sth->{clear_bibtex_cache}->execute();
 179 }
 180
 181 sub load_papers_into_database {
 182     my ($dbh,$sth,$dir) = @_;
 183
 184     my @dirs = ref($dir)?@{$dir}:$dir;
 185
 186     my $actually_load_it = sub {
 187         if (/\.git/) {
 188             $File::Find::prune = 1;
 189             return;
 190         }
 191         return unless /\.pdf$/;
 192         my $xoj = 0;
 193         if (-e "${_}.xoj") {
 194             $xoj = 1;
 195         }
 196         insert_or_replace_papers($dbh,$sth,basename($File::Find::name),File::Spec->rel2abs($_),$xoj);
 197     };
 198
 199     my @pdfs;
 200     find($actually_load_it,@dirs);
 201 }
 202
 203 sub insert_or_replace_papers {
 204     my ($dbh,$sth,$file_name,$file_loc,$has_xoj) = @_;
 205     $sth->{insert_papers}->execute($file_name,$file_loc,$has_xoj);
 206     $sth->{insert_papers}->finish();
 207 }
 208
 209 sub load_bibtex_entries_into_database {
 210     my ($dbh,$sth,$entries) = @_;
 211     for my $entry (keys %{$entries}) {
 212         next unless defined $entries->{$entry};
 213         $sth->{insert_bibtex}->execute($entry,@{$entries->{$entry}}{qw(file_name pmid doi html)});
 214         $sth->{insert_bibtex}->finish();
 215         print STDERR "inserted $entry {".join(',',map {defined $_?"'$_'":"'undef'"} %{$entries->{$entry}})."}\n" if $DEBUG;
 216     }
 217 }
 218
 219 sub open_bibtex_key {
 220     my ($options,$dbh,$sth,$entries,$bibtex_key) = @_;
 221     if (not defined $dbh) {
 222         open_entry($dbh,$sth,$entries->{$bibtex_key},$options);
 223     } else {
 224         my $entry;
 225         if ($options->{search_by_pmid}) {
 226             $entry = select_entry_from_pmid($dbh,$sth,$bibtex_key);
 227         } else {
 228             $entry = select_entry_from_bibtex_key($dbh,$sth,$bibtex_key);
 229         }
 230         p $entry if $DEBUG;
 231         open_entry($dbh,$sth,$entry,$options);
 232     }
 233 }
 234
 235 sub fork_exec {
 236     my (@cmd) = @_;
 237     my $child = fork();
 238     if (not defined $child) {
 239         die "Unable to fork for some reason: $!";
 240     }
 241     if ($child == 0) {
 242         foreach (0 .. (POSIX::sysconf (&POSIX::_SC_OPEN_MAX) || 1024))
 243            { POSIX::close $_ }
 244         open (STDIN, "</dev/null");
 245         open (STDOUT, ">/dev/null");
 246         open (STDERR, ">&STDOUT");
 247         exec(@cmd);
 248     } else {
 249         return $child;
 250     }
 251
 252 }
 253
 254 sub open_pdf {
 255     my ($file_name,$options,$has_xoj) = @_;
 256     print STDERR "opening $file_name\n" if $DEBUG;
 257     if ($has_xoj) {
 258         fork_exec('xournal',$file_name);
 259     } else {
 260         fork_exec('xournal',$file_name)
 261     }
 262 }
 263
 264 sub open_browser{
 265     my ($file) = @_;
 266     fork_exec('sensible-browser',$file);
 267 }
 268
 269 sub open_entry{
 270     my ($dbh,$sth,$entry,$options) = @_;
 271
 272     return unless defined $entry and ref $entry and keys %{$entry};
 273     if ($DEBUG) {
 274         print STDERR "Entry: \n";
 275         p $entry;
 276     }
 277     if (defined $entry->{file_name} and length $entry->{file_name}) {
 278         my $paper = select_one($dbh,$sth->{select_papers_by_name},$entry->{file_name});
 279         if (not defined $paper) {
 280             my ($pmid) = $entry->{file_name} =~ /pmid_(\d+)/;
 281             if (defined $pmid and length $pmid) {
 282                 $paper = select_one($dbh,$sth->{select_papers_by_pmid},'%pmid_'.$pmid.'.%');
 283             }
 284         }
 285         p $paper if $DEBUG;
 286         print STDERR $entry->{file_name} if $DEBUG;
 287         if (defined $paper) {
 288             if ($options->{only_print}) {
 289                 print $paper->{path};
 290                 return;
 291             }
 292             open_pdf($paper->{path},$options,$paper->{has_xoj});
 293             return;
 294         } else {
 295             print STDERR "Unable to find paper\n" if $DEBUG;
 296         }
 297     }
 298     if (defined $entry->{doi}) {
 299         if ($options->{only_print}) {
 300             print $entry->{doi};
 301             return;
 302         }
 303         my $url = $entry->{doi};
 304         $url =~ s{^doi://}{http://dx.doi.org/};
 305         open_browser($url,$options);
 306         return;
 307     }
 308     if (defined $entry->{html}) {
 309         if ($options->{only_print}) {
 310             print $entry->{html};
 311             return;
 312         }
 313         open_browser($entry->{html},$options);
 314         return;
 315     }
 316 }
 317
 318 sub select_entry_from_pmid{
 319     my ($dbh,$sth,$pmid) = @_;
 320
 321     return select_one($dbh,$sth->{select_bibtex_by_pmid},$pmid);
 322 }
 323
 324
 325 sub select_entry_from_bibtex_key{
 326     my ($dbh,$sth,$bibtex_key) = @_;
 327
 328     my $entry = select_one($dbh,$sth->{select_bibtex_by_key},$bibtex_key);
 329     if (not defined $entry) {
 330         print STDERR "Unable to find entry by exact search\n" if $DEBUG;
 331         $bibtex_key =~ s/:.*$//;
 332         $entry = select_one($dbh,$sth->{select_bibtex_by_approximate_key},$bibtex_key.'%');
 333     }
 334     print STDERR "Found entry\n" if $DEBUG and defined $entry;
 335     return $entry;
 336 }
 337
 338 sub select_one{
 339     my ($dbh,$sth,@bind_vals) = @_;
 340     $sth->execute(@bind_vals) or
 341         die "Unable to select one: ".$dbh->errstr();
 342     my $results = $sth->fetchall_arrayref({});
 343     $sth->finish();
 344     return ref($results)?$results->[0]:undef;
 345 }
 346
 347 sub parse_bibtex_file {
 348     my ($file,$entries) = @_;
 349
 350     my $bibfile = Text::BibTeX::File->new($file)
 351         or die "Unable to open $file for reading: $!";
 352     my @entry_comments;
 353     my $entry;
 354     while ($entry = Text::BibTeX::Entry->new($bibfile)) {
 355         print STDERR "In Entry ".$entry->metatype() if $DEBUG;
 356         if ($entry->metatype() == BTE_COMMENT) {
 357             push @entry_comments,$entry->value();
 358         } elsif ($entry->metatype() == BTE_REGULAR) {
 359             my $entry_key = $entry->key();
 360             if (not defined $entry_key) {
 361                 @entry_comments = ();
 362                 next;
 363             }
 364             my %entry_data;
 365             # if there is a file comment, use it as the file name
 366             for my $comment (@entry_comments) {
 367                 next unless $comment =~ /^\s*file(?:name)?:?\s*(.+?)\s*$/i;
 368                 next unless length $1;
 369                 $entry_data{file_name} = $1.'.pdf';
 370                 last;
 371             }
 372             my %field_prefix = (doi => 'doi://',
 373                                 html => 'http://',
 374                                 file => '',
 375                                 pmid => '',
 376                                );
 377             my %field_name = (doi => 'doi',
 378                               html => 'html',
 379                               pmid => 'pmid',
 380                               file => 'file_name',);
 381             for my $field (qw(file doi html pmid)) {
 382                 my $field_value = $entry->get($field);
 383                 if (defined $field_value and $field_value =~ /\S+/) {
 384                     $entry_data{$field_name{$field}} =
 385                         $field_prefix{$field}.$field_value if
 386                         not defined $entry_data{$field_name{$field}};
 387                 }
 388             }
 389             $entries->{$entry_key} = {} if not defined $entries->{$entry_key};
 390             for my $field (keys %entry_data) {
 391                 $entries->{$entry_key}{$field} = $entry_data{$field} if
 392                     defined $entry_data{$field};
 393             }
 394             # reset the entry comments
 395             @entry_comments = ();
 396         } else {
 397             # do nothing
 398         }
 399         print STDERR "\n" if $DEBUG;
 400     }
 401     return $entries;
 402 }
 403
 404
 405 sub initialize_database {
 406     my ($cache) = @_;
 407     return open_cache($cache,1);
 408 }
 409
 410 sub open_cache {
 411     my ($cache,$initialize) = @_;
 412     my $dbh = DBI->connect("dbi:SQLite:dbname=$cache","","") or
 413         die "Unable to open/create database $cache";
 414     if ($initialize) {
 415         $dbh->do("DROP TABLE IF EXISTS bibtex;");
 416         $dbh->do("DROP TABLE IF EXISTS papers;");
 417         $dbh->do(<<EOF);
 418 CREATE TABLE bibtex (
 419 bibtex_key TEXT PRIMARY KEY,
 420 file_name TEXT,
 421 pmid TEXT,
 422 doi TEXT,
 423 html TEXT
 424 );
 425 EOF
 426         $dbh->do(<<EOF);
 427 CREATE UNIQUE INDEX bibtex_file_name ON bibtex(file_name);
 428 EOF
 429         $dbh->do(<<EOF);
 430 CREATE UNIQUE INDEX bibtex_bibtex_key ON bibtex(bibtex_key);
 431 EOF
 432         $dbh->do(<<EOF);
 433 CREATE INDEX bibtex_pmid ON bibtex(pmid);
 434 EOF
 435         $dbh->do(<<EOF);
 436 CREATE TABLE papers (
 437 file_name TEXT PRIMARY KEY,
 438 path TEXT,
 439 has_xoj BOOLEAN
 440 );
 441 EOF
 442         $dbh->do(<<EOF);
 443 CREATE UNIQUE INDEX papers_path ON papers(path);
 444 EOF
 445         $dbh->do(<<EOF);
 446 CREATE UNIQUE INDEX papers_file_name ON papers(file_name);
 447 EOF
 448     }
 449     my %s =
 450         (insert_papers => <<'EOF',
 451 INSERT OR REPLACE INTO papers(file_name,path,has_xoj) VALUES (?,?,?);
 452 EOF
 453          insert_bibtex => <<'EOF',
 454 INSERT OR REPLACE INTO bibtex (bibtex_key,file_name,pmid,doi,html) VALUES (?,?,?,?,?);
 455 EOF
 456          select_papers_by_name => <<'EOF',
 457 SELECT * FROM papers WHERE file_name = ?;
 458 EOF
 459          select_papers_by_pmid => <<'EOF',
 460 SELECT * FROM papers WHERE file_name LIKE ?;
 461 EOF
 462          select_papers_by_path => <<'EOF',
 463 SELECT * FROM papers WHERE path = ?;
 464 EOF
 465          select_bibtex_by_key => <<'EOF',
 466 SELECT * FROM bibtex WHERE bibtex_key = ?;
 467 EOF
 468          select_bibtex_by_approximate_key => <<'EOF',
 469 SELECT * FROM bibtex WHERE bibtex_key LIKE ?;
 470 EOF
 471          select_bibtex_by_file_name => <<'EOF',
 472 SELECT * FROM bibtex WHERE file_name = ?;
 473 EOF
 474          select_bibtex_by_pmid => <<'EOF',
 475 SELECT * FROM bibtex WHERE pmid = ?;
 476 EOF
 477          clear_papers_cache => <<'EOF',
 478 DELETE FROM papers;
 479 EOF
 480          clear_bibtex_cache => <<'EOF',
 481 DELETE FROM bibtex;
 482 EOF
 483         );
 484     my $st;
 485     for my $key (keys %s) {
 486         $st->{$key}=$dbh->prepare($s{$key}) //
 487             die "Unable to prepare sql statement: ".$dbh->errstr;
 488     }
 489     return ($dbh,$st);
 490 }
 491
 492
 493 __END__