acro_gene

   1 #!/usr/bin/perl
   2 # acro_gene outputs gene acronym definitions for use with acro
   3 # and is released under the terms of the GNU GPL version 3, or any
   4 # later version, at your option. See the file README and COPYING for
   5 # more information.
   6 # Copyright 2016 by Don Armstrong <don@donarmstrong.com>.
   7
   8
   9 use warnings;
  10 use strict;
  11
  12 use Getopt::Long;
  13 use Pod::Usage;
  14
  15 =head1 NAME
  16
  17 acro_gene - outputs gene acronym definitions for use with acro
  18
  19 =head1 SYNOPSIS
  20
  21 acro_gene [options] [gene1] [[gene2]...]
  22
  23  Options:
  24    --debug, -d debugging level (Default 0)
  25    --help, -h display this help
  26    --man, -m display manual
  27
  28 =head1 OPTIONS
  29
  30 =over
  31
  32 =item B<--debug, -d>
  33
  34 Debug verbosity. (Default 0)
  35
  36 =item B<--help, -h>
  37
  38 Display brief usage information.
  39
  40 =item B<--man, -m>
  41
  42 Display this manual.
  43
  44 =back
  45
  46 =head1 EXAMPLES
  47
  48 acro_gene
  49
  50 =cut
  51
  52
  53 use vars qw($DEBUG);
  54
  55 my %options = (debug           => 0,
  56                help            => 0,
  57                man             => 0,
  58                hgnc_db         => 'ftp://ftp.ebi.ac.uk/pub/databases/genenames/new/tsv/non_alt_loci_set.txt',
  59                gene_db         => [glob("~/.acro_gene_db")]->[0],
  60               );
  61
  62 GetOptions(\%options,
  63            'gene_db|gene-db=s',
  64            'hgnc_db|hgnc-db=s',
  65            'debug|d+','help|h|?','man|m');
  66
  67 pod2usage() if $options{help};
  68 pod2usage({verbose=>2}) if $options{man};
  69
  70 $DEBUG = $options{debug};
  71
  72 my @USAGE_ERRORS;
  73 if (not @ARGV) {
  74     push @USAGE_ERRORS,"You must provide a gene name";
  75 }
  76
  77 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
  78
  79
  80 if (! -e $options{gene_db}) {
  81     system('wget','-O',$options{gene_db},$options{hgnc_db});
  82 }
  83
  84 my $fh;
  85 open($fh,'<',$options{gene_db}) or
  86     die "Unable to open $options{gene_db} for reading: $!";
  87
  88 my @header;
  89 my %genes;
  90 while (<$fh>) {
  91     chomp;
  92     my @r = split /\t/;
  93     if (not @header) {
  94         @header = @r;
  95         next;
  96     }
  97     my %r;
  98     @r{@header} = @r;
  99     $genes{$r{symbol}} = $r{name};
 100 }
 101
 102 for (@ARGV) {
 103     my $gene = $_;
 104     my $name = $genes{$gene};
 105     print '\DeclareAcronym{'.
 106         $gene.'}{short=\href{http://www.genenames.org/cgi-bin/gene_symbol_report?match='.
 107         $gene.'}{'.$gene.'},long={'.$name.
 108         '},first-style=reversed}'."\n";
 109 }
 110
 111
 112 __END__