+fet_beginchar("Right Comma","rcomma","rcomma");
+ draw_comma;
+fet_endchar;
+
+fet_beginchar("Left Comma","lcomma","lcomma");
+ draw_comma;
+ xy_mirror_char;
+fet_endchar;
+
+def draw_varcomma =
+ save thick, thin, ht, wd, alpha;
+ alpha:=35;
+ thin# = 1.2 stafflinethickness#;
+ thick# = 3 stafflinethickness#;
+ ht# = .6 staff_space#;
+ wd# = .25 staff_space#;
+ define_pixels(thin, thick, ht, alpha);
+ set_char_box(wd#, wd#, ht#, ht#);
+ z1 = (-b, -d);
+ z2 = (w, h);
+ draw_brush(z1, thin, z2, thick);
+enddef;
+
+fet_beginchar("Right Varied Comma","rvarcomma","rvarcomma");
+ draw_varcomma;
+fet_endchar;
+
+fet_beginchar("Left Varied Comma","lvarcomma","lvarcomma");
+ draw_varcomma;
+ xy_mirror_char;
+fet_endchar;
+
+thick#:=1/24designsize;
+define_blacker_pixels(thick);
+
+rthin:=1/8*staff_space;
+rthick:=2thick+rthin;
+
+def draw_arpeggio =
+ save alpha;
+ alpha:=-40;
+ save ne,nw,se,sw; pair ne,nw,se,sw;
+ save x,y;
+
+ se=dir alpha; nw=dir (alpha+180);
+ ne=dir (alpha+90); sw=dir (alpha-90);
+ penpos1(rthin,alpha+90);
+ penpos2(5/4rthick,alpha);
+ penpos4(5/4rthick,alpha);
+ penpos5(rthin,alpha+90);
+ penpos3(3/4rthick,alpha);
+
+ z1=(width/2, height) - overshoot*se;
+ z2=2[z4,(width/2,height/2)];
+ z3=1/2[z2,z4];
+ x4=2/8staff_space;
+ y4=rthin;
+
+ z5=2[z1,(width/2,height/2)];
+ z6=z2l+1/2rthin*sw;
+ z7=z4l+1/2rthin*sw+1/2rthin*se;
+ z8=2[z6,(width/2,height/2)];
+ z9=2[z7,(width/2,height/2)];
+
+ fill z1l{se}..{se}z6..z3l..z7{se}..{se}z5l..z5r{nw}..{nw}z8..z3r..z9{nw}..{nw}z1r.. cycle;
+ penlabels(1,2,3,4,5,6,7,8,9);
+ enddef;
+
+fet_beginchar("Arpeggio","arpeggio","arpeggio");
+ %draw_staff (-2, 2, 0.0);
+ save height, overshoot, width;
+ height# = staff_space#;
+ width# = 0.8height#;
+ overshoot# = 0.25 staff_space#;
+ define_pixels (height,overshoot,width);
+ set_char_box(0, width#, 0, height#);
+ draw_arpeggio;
+ fet_endchar;
+
+% Extendable Trill symbol.
+% Not yet used
+% Rename me to Trill, rename Trill to Tr?
+fet_beginchar("Trill-element","trill-element","trillelement");
+ save height, overshoot;
+ height# = staff_space#;
+ width# = 0.8height#;
+ overshoot# = 0.25 staff_space#;
+ define_pixels (height,overshoot,width);
+ set_char_box(0, height#, 0, width#);
+ draw_arpeggio;
+ currentpicture := currentpicture shifted -(width/2, height/2);
+ currentpicture := currentpicture rotated 90;
+ currentpicture := currentpicture shifted (height/2, width/2);
+ fet_endchar;
+
+
+
+%
+% Arpeggio arrow by Chris Jackson <chris@fluffhouse.org.uk>
+%
+
+def draw_arpeggio_arrow =
+ save thinness, height, width, overshoot, se, sw, ne, nw, alpha;
+ pair ne, nw, se, sw;
+ height# = staff_space#;
+ width# = 0.8height#;
+ overshoot# = 0.25 staff_space#;
+ define_pixels (height,overshoot,width);
+ set_char_box(0, width#, 0, height#);
+ alpha := -40;
+ nw = dir (alpha+180);
+ sw = dir (alpha-90); se = dir alpha;
+
+ penpos1(rthin, alpha+90);
+ penpos2(5/4 rthick, alpha);
+ penpos3(5/4 rthick, 0);
+
+ z1 = (width/2, height) - overshoot*se; % numbering is consistent with the arpeggio symbol
+ z2 = 2[z4,(width/2,height/2)];
+ z3 = (0.5 width, 0.5 height);
+ z4 = (0.25 staff_space, rthin);
+ z6 = z2l + 1/2rthin*sw;
+ z9 = (width/2, height) + overshoot*se;
+ fill z1l {se}..{se} z6 .. z3l .. z3r.. z9{nw} ..{nw} z1r.. cycle;
+
+ bot z10 = ( 0.5w, 0 );
+ lft z11 = (-0.3w, 0.8h);
+ rt z12 = ( 1.3w, 0.8h);
+ pickup pencircle scaled 0.5 rthin;
+ filldraw z3 -- z12 {dir -130} .. {dir -110} z10 {dir 110} .. {dir 130} z11 -- cycle;
+enddef;
+
+fet_beginchar("Arpeggio arrow down", "arpeggio-arrow--1", "arpeggioarrowdown");
+ draw_arpeggio_arrow;
+fet_endchar;
+
+
+fet_beginchar("Arpeggio arrow up", "arpeggio-arrow-1", "arpeggioarrowup");
+ draw_arpeggio_arrow;
+ currentpicture := currentpicture scaled -1 shifted (0.8staff_space, staff_space);
+fet_endchar;
+
+
+
+
+% Hmm
+input feta-slag;
+
+% railroad tracks.
+%
+% I actually have no clue how they should look, so we use a slightly curvy
+% and tapered shape.
+%
+fet_beginchar("Caesura", "caesura", "caesura");
+ save slant, space_between, clearance;
+ save alpha, p;
+ save botthick, topthick;
+ save krom ;
+
+ path p;
+
+ botthick = 1.5 stafflinethickness;
+ topthick = 2.5 stafflinethickness;
+ pickup pencircle scaled botthick;
+
+
+ slant = 3.5 ;
+ space_between# = 0.6 staff_space#;
+ clearance# = 0.2 staff_space#;
+ height# = 1.2 staff_space#;
+
+ set_char_box(0, 2.0 staff_space#, staff_space# - clearance#, height#);
+ define_pixels (space_between, clearance, height);
+
+ bot y1 = -d;
+ top y2 = h;
+
+ lft x1 = 0;
+ x2 = (y2 - y1) / slant;
+
+ krom = 10;
+
+ alpha = angle (z2 - z1);
+ penpos1 (botthick, alpha - krom);
+ penpos3 (botthick, alpha - krom + 90);
+
+ penpos2 (topthick, alpha + krom );
+ penpos4 (topthick, alpha + krom + 90);
+ z3 = z1; z4 = z2;
+ penlabels (1,2,3,4);
+
+ p := z3r{(z1r - z1l)} .. z4r{z2r-z2l} .. z2r{z4l-z4r} .. z4l{z2l-z2r} .. z3l{z1l-z1r} .. z1l{z3r-z3l} .. cycle;
+ fill p;
+ fill p shifted (space_between , 0);
+
+fet_endchar;