+% from an email to Rune Zedeler:
+%
+%
+% For example, the 8th rest was vaguely based on a book with trumpet
+% studies by Duhem, and by Baerenreiters cello suites. I included my
+% findings in a comment in the mf file. One of the things that I tried
+% to do was make the rest a little lighter and narrower than the black
+% note head. I think this looks better in polyphonic music, when the
+% rest is below a head from a different voice.
+%
+%
+
+save bulb_diam, thin, thick;
+
+bulb_diam# := 0.64 staff_space#;
+thin# := 1.4 linethickness# - 0.02 staff_space#;
+thick# := 2.2 linethickness#;
+crook_thin := 0.5 linethickness + 0.08 staff_space;
+
+lower_brush := 1.5 linethickness;
+
+define_pixels ( bulb_diam, thin, thick);
+
+%
+% PAT is a compact way to pass the brush shape to the routine.
+%
+
+def draw_rest_bulb(expr ycenter, ycut, pat, stretch) =
+begingroup;
+ save x,y,pt;
+ z1l = point 0 of pat;
+ z2l = point 1 of pat;
+ z2r = point 3 of pat;
+ z1r = point 4 of pat;
+ z1 = 0.5[z1l,z1r];
+ z2 = 0.5[z2l,z2r];
+ y10 = ycenter;
+ z10 = whatever[z2, z1] + left*bulb_diam*stretch;
+
+
+ z3 = z10+bulb_diam/2.15*dir(-72) ;
+ z5 = z10 + up*bulb_diam/2 + right*linethickness/3;
+
+ z7 = 0.5 [z4, z5] + crook_thin * (0.45 ,0.4 ) / 1.3;
+ x8 = x10-0.4bulb_diam;
+ y8 = y10 + 0.25 linethickness;
+
+ z6 = whatever [z1l, z2l];
+ z6 = z3 + whatever * dir(12);
+
+ z4 = z3 + whatever * (z6-z3)
+ + 1.1 crook_thin *(unitvector (z6 -z3) rotated 90);
+ x4 = x10+bulb_diam*.62 ;
+ y4 := ceiling (y4);
+
+ (pt,whatever) = pat intersectiontimes ((0,ycut)--(w,ycut));
+
+ fill point pt of pat {-direction pt of pat} .. tension 2
+ .. z4{left} .. tension 0.9 .. z7
+ .. z5{left} .. z8 .. z3{right}
+ .. {curl 0.2} z6 {right} .. tension 10 .. {left} point pt of pat -- cycle;
+
+ labels(3, 4, 5, 6, 7, 8, 9, 10, 11);
+
+endgroup;
+enddef;