+% quarter note
+% Wanske p.38
+fet_beginchar("Quart diamondhead", "2diamond", "diamondhead")
+ set_char_box(0, black_notehead_width#, noteheight#/2, noteheight#/2);
+ save a_b,err_y_a,tilt,superness;
+ save b_h,a_w;
+ save a,beta,ai,bi, ht, wd;
+
+ a_b:= 1.8;
+ err_y_a:=-0.044;
+ b_h:=0.90;
+ a_w:=1.1;
+ tilt:=35;
+ superness:=0.495;
+
+ ht# =noteheight#;
+ 2beta#=ht#*b_h;
+ a# = beta#*a_b;
+
+ define_pixels(a,beta);
+
+ black := distorted_ellipse(.72 noteheight, .45 noteheight, -.2 noteheight , 0, superness)
+
+% beta,a*err_y_a,0,superness);
+
+ black:=black rotated tilt;
+ black:=black shifted (w/2,0);
+ fill black;
+fet_endchar;
+
+
+save pent;
+pen_thick# = 2stafflinethickness#;
+define_pixels(pen_thick);
+
+
+begingroup;
+
+
+def def_triangle_old =
+ save triangle,kern; path triangle;
+ kern = 1/3(x2-x1);
+ z2 = z1 rotated 120;
+ z3 = z1 rotated 240;
+ z12 = caveness[.5[z1,z2],z3];
+ z23 = z12 rotated 120;
+ z31 = z12 rotated 240;
+ triangle = z1 .. z12 .. z2 ..
+ z2 .. z23 .. z3 ..
+ z3 .. z31 .. z1 ..
+ cycle;
+ triangle := triangle shifted (-x1+pent/2-kern,0) xscaled xs;
+ pickup pencircle scaled pent xscaled xs;
+ hei = max(y1,-y2)+pent/2;
+ %set_char_box(-kern*xs*fac, ((x3-x1)*fac+pent#)*xs,hei*fac,hei*fac);
+ set_char_box(0, ((x3-x1-kern)*fac+pent#)*xs,hei*fac,hei*fac);
+enddef;
+
+
+def def_triangle =
+ save triangle,kern; path triangle;
+ save left_point, height, width;
+ pair exact_left_point;
+
+ exact_left_point := llap# * dir (90 + tilt);
+ height# = max (ypart exact_left_point,
+ -ypart (exact_left_point rotated 120)) + pen_thick#/2;
+
+ kern# = 1/3 xpart (exact_left_point - (exact_left_point rotated 120));
+ width# = xpart (-exact_left_point + (exact_left_point rotated 240));
+ define_pixels (kern);
+ z1 = (hround_pixels (xpart exact_left_point), vround_pixels (ypart exact_left_point));
+ z2 = z1 rotated 120;
+ z3 = z1 rotated 240;
+
+ z12 = caveness[.5[z1,z2],z3];
+ z23 = z12 rotated 120;
+ z31 = z12 rotated 240;
+ triangle = z1 .. z12 .. z2 ..
+ z2 .. z23 .. z3 ..
+ z3 .. z31 .. z1 ..
+ cycle;
+ triangle := triangle shifted (-x1+pen_thick/2-kern,0) xscaled xs;
+ pickup pencircle scaled pen_thick xscaled xs;
+% labels(1,2,12,23,31,3);
+ set_char_box(0, width# - kern#+ pen_thick#, height#, height#);
+enddef;
+
+fet_beginchar("Whole trianglehead", "0triangle", "wholetrianglehead")
+ save hei,xs;
+ save llap;
+ save tilt;
+
+ tilt = 40;
+ llap# = 3/4noteheight#;
+
+ xs = 1.5;
+ caveness:=0.1;
+ def_triangle;
+ draw triangle;
+fet_endchar;
+
+fet_beginchar("Half trianglehead", "1triangle", "halftrianglehead")
+ save hei,xs;
+ save llap;
+ save tilt;
+
+ tilt = 40;
+ llap# = 2/3noteheight#;
+ xs = 1.2;
+ caveness:=0.1;
+ def_triangle;
+ draw triangle;
+fet_endchar;
+
+fet_beginchar("Quart trianglehead", "2triangle", "trianglehead")
+ save hei,xs;
+ save llap;
+ save tilt;
+ tilt = 40;
+ llap# = 2/3noteheight#;
+ xs = 1.0;
+ caveness:=0.1;
+ def_triangle;
+ filldraw triangle;
+fet_endchar;
+
+endgroup;
+
+%%% Editable values:
+
+slash_slope := 1.7; % slope of slash. From scm/grob-description.scm. How to auto-copy?
+slt# := 2/3*0.48staff_space#; % thickness of lines. quarter notes get 1.5slt width.
+slh# := 2staff_space#; % height of char.
+
+%%% Calculated values:
+sxa# := 0; % how much the char exceeds the boundingbox horizontally:
+
+ % Width of hor. pen - with thanks to Pythagoras
+slxt# := sqrt(slt#*slt#+(slt#/slash_slope)*(slt#/slash_slope));
+slw# := slh#/slash_slope; % width of sloping part of slash:
+
+define_pixels(slt,slh,sxa,slxt,slw);
+
+
+%
+%
+% UUGGGH! FIXME -- get rid of those sharp corners.
+%
+%
+%
+
+
+def draw_slash(expr hwid_hash) =
+ wid# := slw#+2slxt#+hwid_hash;
+ set_char_box(0,wid#-2sxa#,slh#/2,slh#/2);
+ define_pixels (wid#);
+ pickup penrazor scaled slxt;
+ draw (-b+slxt/2-sxa,-d) -- (-b+slxt/2+slw-sxa,h);
+ draw (w-slxt/2-slw+sxa,-d) -- (w-slxt/2+sxa,h);
+ pickup penrazor scaled slt rotated 90;
+ draw (-b+slxt-sxa,-d+slt/2) -- (w-slw+sxa,-d+slt/2);
+ draw (-b+slw-sxa,h-slt/2) -- (w-slxt+sxa,h-slt/2);
+enddef;
+
+fet_beginchar("Whole slashhead","0slash","wholeslashhead")
+ draw_slash(staff_space#);
+fet_endchar;
+
+fet_beginchar("Half slashhead","1slash","halfslashhead")
+ draw_slash(0.6staff_space#);
+fet_endchar;
+
+fet_beginchar("Quart slashhead","2slash","quartslashhead")
+ draw_slash(-slxt#/2);
+fet_endchar;
+
+% thick is the distance between the two parallel lines in the cross (distance between centres of lines)
+def draw_cross(expr thick) =
+ pent := 1.2stafflinethickness;
+ pickup pencircle scaled pent;
+ % alfa is the slant of the lines (i.e. 1 means 45 degrees)
+ alfa := (2h-pent)/(w-pent);
+ % llen is the length of the little outer lines
+ % llen = thick / sin(2atan(alfa))
+ llen := thick/(ypart(dir(2angle(1,alfa))));
+ xa := llen/sqrt(1+alfa**2);
+ ya := xa*alfa;
+ xl := w/2-xa-pent/2;
+ yl := h-ya-pent/2;
+ save crz; path crz;
+ crz = (xa,0) -- (xa+xl,yl) -- (xl,yl+ya) -- (0,ya);
+ draw crz shifted(w/2,0);
+ draw crz xscaled -1 shifted(w/2,0);
+ draw crz yscaled -1 shifted(w/2,0);
+ draw crz scaled -1 shifted(w/2,0);
+enddef;
+
+fet_beginchar("Whole Crossed notehead", "0cross", "wholecrossedhead")
+ wid# := black_notehead_width#+4stafflinethickness#;
+ hei# := noteheight#+stafflinethickness#;
+ set_char_box(0, wid#,hei#/2,hei#/2);
+ draw_cross(3.75stafflinethickness);
+fet_endchar;
+
+fet_beginchar("Half Crossed notehead", "1cross", "halfcrossedhead")
+ wid# := black_notehead_width#+2stafflinethickness#;
+ hei# := noteheight#+stafflinethickness#/2;
+ set_char_box(0, wid#,hei#/2,hei#/2);
+ draw_cross(3stafflinethickness);
+fet_endchar;
+
+fet_beginchar("Crossed notehead", "2cross", "crossedhead")
+ wid# := black_notehead_width#;
+ hei# := noteheight#;
+ set_char_box(0, wid#,hei#/2,hei#/2);
+ draw_cross(stafflinethickness/4);
+fet_endchar;
+
+fet_beginchar("X-Circled notehead", "2xcircle", "xcircledhead")
+ wid# := black_notehead_width#*sqrt(sqrt2);
+ hei# := noteheight#*sqrt(sqrt2);
+ set_char_box(0, wid#,hei#/2,hei#/2);
+ cthick := (1.2+1/4)*stafflinethickness;
+ cxr := w/2-cthick/2;
+ cyr := h-cthick/2;
+ pickup pencircle scaled cthick;
+ draw fullcircle xscaled 2cxr yscaled 2cyr shifted (w/2,0);
+ xpos := cxr/sqrt2;
+ ypos := cyr/sqrt2;
+ draw (-xpos+w/2,-ypos) -- (xpos+w/2,ypos);
+ draw (-xpos+w/2,ypos) -- (xpos+w/2,-ypos);
+fet_endchar;
+
+
+%%%%%%%%%%%%
+%
+%
+% ledger (leger) lines
+%
+fet_beginchar("Ledger ending", "ledgerending", "ledgerending")
+set_char_box (5/2 ledgerlinethickness#, 5/2 ledgerlinethickness#,
+ ledgerlinethickness#/2,ledgerlinethickness#/2);
+
+
+ draw_rounded_block((-b,-d),(w,h), 0.8 ledgerlinethickness);
+fet_endchar;
+