+fet_beginchar ("accordion push", "push");
+ save width, height;
+
+ height# := 2.0 staff_space# + 3.0 stafflinethickness#;
+ width# := 0.4 height#;
+
+ define_pixels(height, width);
+
+ save linewidth;
+
+ linewidth# := stafflinethickness# + .05 staff_space#;
+ define_whole_blacker_pixels (linewidth);
+
+ set_char_box (width#, 0,
+ 0, height#);
+
+ pickup pencircle scaled linewidth;
+
+ lft x1 = -width;
+ top y1 = height;
+
+ rt x2 = 0;
+ y2 = 0.5 * (y1 + y3);
+
+ x3 = x1;
+ bot y3 = 0;
+
+ save nw_offset, ne_offset;
+ pair nw_offset, ne_offset;
+ save sw_offset, se_offset, line_radius;
+ pair sw_offset, se_offset;
+
+ line_radius := linewidth / 2;
+ nw_offset := line_radius * unitvector (z1 - z2);
+ ne_offset := nw_offset rotated -90;
+ sw_offset := line_radius * unitvector (z3 - z2);
+ se_offset := sw_offset rotated 90;
+
+ z4 = ((z1 - ne_offset)
+ -- (z2 - ne_offset))
+ intersectionpoint
+ ((z2 - se_offset)
+ -- (z3 - se_offset));
+
+ fill z1 + ne_offset
+ -- z2 + ne_offset
+ .. rt z2 {down}
+ .. z2 + se_offset
+ -- z3 + se_offset
+ .. z3 + sw_offset {- se_offset}
+ .. z3 - se_offset
+ -- z4
+ -- z1 - ne_offset
+ .. z1 + nw_offset {ne_offset}
+ .. cycle;
+fet_endchar;
+
+
+fet_beginchar ("accordion pull", "pull");
+ save width, height;
+
+ height# := 2.0 staff_space# + 3.0 stafflinethickness#;
+ width# := 0.4 height#;
+
+ define_pixels(height, width);
+
+ save linewidth;
+
+ linewidth# := stafflinethickness# + .05 staff_space#;
+ define_whole_blacker_pixels (linewidth);
+
+ set_char_box (width# - linewidth#, linewidth#,
+ 0, height#);
+
+ pickup pencircle scaled linewidth;
+
+ save penradius;
+ penradius := linewidth / 2;
+
+ rt x1 = linewidth;
+ bot y1 = 0;
+
+ x2 = x1;
+ top y2 = height;
+
+ lft x3= -width + linewidth;
+ y3 = y2;
+
+ x4 = x3;
+ y4 = y2 - linewidth;
+
+ x5 = x1;
+ y5 = y4;
+
+ fill z1 + penradius * right {up}
+ -- z2 + penradius * right {up}
+ .. z2 + penradius * up {left}
+ -- z3 + penradius * up {left}
+ .. z3 + penradius * left {down}
+ -- z4 + penradius * left {down}
+ .. z4 + penradius * down {right}
+ -- z5 + penradius * (down + left)
+ -- z1 + penradius * left {down}
+ .. z1 + penradius * down {right}
+ .. cycle;
+fet_endchar;
+