+
+DOCUMENTATION=yes
+AC_ARG_ENABLE(documentation,
+ [AS_HELP_STRING([--enable-documentation],
+ [build Documentation. Default: on])],
+ [DOCUMENTATION=$enableval])
+AC_SUBST(DOCUMENTATION)
+
+AC_ARG_WITH(ncsb-dir,
+ [AS_HELP_STRING([--with-ncsb-dir=DIR],
+ [location of Century Schoolbook fonts.])],
+ [NCSB_DIR=$withval],
+ [NCSB_DIR=""])
+
+reloc_b=no
+AC_ARG_ENABLE(relocation,
+ [AS_HELP_STRING([--enable-relocation],
+ [compile with dynamic relocation. Default: off])],
+ [reloc_b=$enableval])
+
+rpath_b=no
+AC_ARG_ENABLE(rpath,
+ [AS_HELP_STRING([--enable-rpath],
+ [hardcode runtime library path. Default: off])],
+ [rpath_b=$enableval])
+
+LINK_GXX_STATICALLY=no
+AC_ARG_ENABLE(static-gxx,
+ [AS_HELP_STRING([--enable-static-gxx],
+ [link libstdc++.a statically. Default: off])],
+ [LINK_GXX_STATICALLY=$enableval])
+AC_SUBST(LINK_GXX_STATICALLY)
+
+# must come before any header checks
+STEPMAKE_COMPILE
+
+AC_CHECK_PROG(FCLIST, fc-list, fc-list)
+AC_MSG_CHECKING([New Century Schoolbook PFB files])
+AC_SUBST(NCSB_SOURCE_FILES)
+if test "$NCSB_DIR" != "" ; then
+ NCSB_SOURCE_FILES=""
+ for f in c059013l c059016l c059033l c059036l; do
+ if test ! -f "$NCSB_DIR/$f.pfb"; then
+ STEPMAKE_WARN($NCSB_DIR does not contain $f.pfb.)
+ else
+ NCSB_SOURCE_FILES="$NCSB_DIR/$f.pfb $NCSB_SOURCE_FILES"
+ fi
+ done
+else
+ if test "$FCLIST" != ""; then
+ for style in Roman Italic "Bold Italic" Bold; do
+ NCSB_FILE=`$FCLIST "Century Schoolbook L:style=$style:foundry=urw:fontformat=Type 1" file \
+ | head -n 1`
+ NCSB_FILE=`echo $NCSB_FILE | sed 's/^\(.*\):$/\1/g'`
+ NCSB_FILE=`$PYTHON "$srcdir/scripts/auxiliar/readlink.py" $NCSB_FILE`
+ NCSB_SOURCE_FILES="$NCSB_FILE $NCSB_SOURCE_FILES"
+ done
+ else
+ AC_MSG_RESULT(not found)
+ echo "Can't find Century Schoolbook files. Install FontConfig's fc-list,"
+ echo "or use --with-ncsb-dir"
+ fi
+fi
+AC_MSG_RESULT($NCSB_SOURCE_FILES)
+
+AC_LANG([C++])
+
+STEPMAKE_PYTHON(REQUIRED, 2.4)
+STEPMAKE_GCC(REQUIRED, 3.4)
+
+STEPMAKE_CXX(REQUIRED)
+STEPMAKE_GXX(REQUIRED, 3.4)
+STEPMAKE_CXXTEMPLATE
+STEPMAKE_STL_DATA_METHOD
+STEPMAKE_LIB(REQUIRED)
+STEPMAKE_DLOPEN
+# Do not use bison 1.50 and 1.75.
+# 1.29 is required fr %locations, but I'm not sure it's enough --ns
+STEPMAKE_BISON(OPTIONAL, 1.29)
+STEPMAKE_FLEX(REQUIRED)
+STEPMAKE_FLEXLEXER(REQUIRED)
+STEPMAKE_FLEXLEXER_LOCATION
+STEPMAKE_LOCALE
+STEPMAKE_GETTEXT
+STEPMAKE_MSGFMT(REQUIRED)
+STEPMAKE_TEXMF(REQUIRED)
+STEPMAKE_TEXMF_DIRS
+STEPMAKE_GUILE_DEVEL(REQUIRED, 1.8.2)
+
+# check for 3 typedefs added in Guile 1.9
+save_CXXFLAGS="$CXXFLAGS"
+CXXFLAGS="$GUILE_CFLAGS $CXXFLAGS"
+AC_CHECK_TYPES([scm_t_hash_fold_fn, scm_t_hash_handle_fn],
+ [AC_DEFINE(HAVE_GUILE_HASH_FUNC)], [],
+ [#include <libguile.h>])
+AC_CHECK_TYPES([scm_t_subr],
+ [AC_DEFINE(HAVE_GUILE_SUBR_TYPE)], [],
+ [#include <libguile.h>])
+CXXFLAGS="$save_CXXFLAGS"
+
+## check rational bugfix.
+save_CPPFLAGS="$CPPFLAGS"
+CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
+AC_MSG_CHECKING(GUILE rational bugfix)
+AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <libguile.h>
+#ifdef SCM_FRACTION_REDUCED_BIT
+#error
+#endif
+]])],[AC_MSG_RESULT(ok)],[REQUIRED="$REQUIRED GUILE-with-rational-bugfix"
+AC_MSG_RESULT(Must have patched GUILE rational support. See INSTALL.txt)])
+CPPFLAGS="$save_CPPFLAGS"
+
+
+STEPMAKE_PYTHON_DEVEL(REQUIRED)
+
+STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.60)
+
+STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20100501)
+STEPMAKE_PATH_PROG(FONTFORGE, fontforge, OPTIONAL, 20110222)
+
+STEPMAKE_PATH_PROG(T1ASM, t1asm, REQUIRED)
+
+AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h fpu_control.h])
+AC_CHECK_HEADERS([sstream])