stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4 AC_DEFUN(AC_STEPMAKE_COMPILE, [
   5     # -O is necessary to get inlining
   6     OPTIMIZE=""
   7     CXXFLAGS=${CXXFLAGS:-""}
   8     CFLAGS=${CFLAGS:-""}
   9     checking_b=yes
  10     optimise_b=no
  11     profile_b=no
  12     debug_b=yes
  13
  14     AC_ARG_ENABLE(checking,
  15     [  enable-checking         set runtime checks (assert calls). Default: on],
  16     [checking_b=$enableval] )
  17
  18     # actually, the default is: tja='-O' to get inlining...
  19     # off=''  --jcn
  20
  21     #actually, that sucks.
  22     #  tja looks like a typo.  Default is optimisation off. --hwn
  23
  24     AC_ARG_ENABLE(optimise,
  25     [  enable-optimise         use maximal speed optimisations. Default: off],
  26     [optimise_b=$enableval])
  27
  28     AC_ARG_ENABLE(profiling,
  29     [  enable-profiling        compile with gprof support. Default: off],
  30     [profile_b=$enableval])
  31
  32     AC_ARG_ENABLE(debugging,
  33     [  enable-debugging        set debug info. Default: on],
  34     [debug_b=$enableval])
  35
  36     AC_ARG_ENABLE(mingw-prefix,
  37     [  enable-mingw-prefix=DIR set the mingw32 directory (standalone windows32 exes)],
  38     [MINGWPREFIX=$enableval],
  39     [MINGWPREFIX=no])
  40
  41     if test "$printing_b" = no; then
  42         # ugh
  43         AC_DEFINE(NPRINT)
  44         DEFINES="$DEFINES -DNPRINT"
  45     fi
  46
  47     if test "$checking_b" = no; then
  48         # ugh
  49         AC_DEFINE(NDEBUG)
  50         DEFINES="$DEFINES -DNDEBUG"
  51     fi
  52
  53     if test "$optimise_b" = yes; then
  54         OPTIMIZE="-O2 -finline-functions"
  55     fi
  56
  57     if test "$optimise_b" = no; then
  58         OPTIMIZE=""
  59     fi
  60
  61     if test $profile_b = yes; then
  62         EXTRA_LIBES="-pg"
  63         OPTIMIZE="$OPTIMIZE -pg"
  64     fi
  65
  66     if test $debug_b = yes; then
  67         OPTIMIZE="$OPTIMIZE -g"
  68     fi
  69
  70     # however, C++ support in mingw32 v 0.1.4 is still flaky
  71     if test x$MINGWPREFIX != xno; then
  72         ICFLAGS="-I$MINGWPREFIX/include"
  73         ILDFLAGS="-$MINGWPREFIX/lib"
  74     fi
  75
  76     AC_PROG_CC
  77     LD='$(CC)'
  78     AC_SUBST(LD)
  79
  80     CPPFLAGS=${CPPFLAGS:-""}
  81     AC_SUBST(CPPFLAGS)
  82     AC_SUBST(LDFLAGS)
  83     AC_SUBST(ICFLAGS)
  84     AC_SUBST(ILDFLAGS)
  85     AC_SUBST(DEFINES)
  86     AC_SUBST(EXTRA_LIBES)
  87 ])
  88
  89 AC_DEFUN(AC_STEPMAKE_CXX, [
  90     AC_LANG_CPLUSPLUS
  91     AC_PROG_CXX
  92
  93     AC_CHECK_HEADER(FlexLexer.h, true,
  94         AC_STEPMAKE_WARN(can"\'"t find flex header. Please install Flex headers correctly))
  95
  96     CPPFLAGS="$CPPFLAGS $DEFINES"
  97     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
  98     LDFLAGS=$EXTRA_LIBES
  99
 100     AC_SUBST(CXXFLAGS)
 101     AC_SUBST(CXX)
 102     LD='$(CXX)'
 103     AC_SUBST(LD)
 104 ])
 105
 106 AC_DEFUN(AC_STEPMAKE_CXXTEMPLATE, [
 107     AC_CACHE_CHECK([whether explicit instantiation is needed],
 108         lily_cv_need_explicit_instantiation,
 109         AC_TRY_LINK([
 110     template <class T> struct foo { static int baz; };
 111     template <class T> int foo<T>::baz = 1;
 112     ], [ return foo<int>::baz; ],
 113             lily_cv_need_explicit_instantiation=no,
 114             lily_cv_need_explicit_instantiation=yes))
 115     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 116         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 117     fi
 118 ])
 119
 120 AC_DEFUN(AC_STEPMAKE_DATADIR, [
 121     if test "$datadir" = "\${prefix}/share"; then
 122             datadir='${prefix}/share/'$package
 123     fi
 124     DIR_DATADIR=${datadir}
 125     presome=${prefix}
 126     if test "$prefix" = "NONE"; then
 127             presome=${ac_default_prefix}
 128     fi
 129     DIR_DATADIR=`echo ${DIR_DATADIR} | sed "s!\\\${prefix}!$presome!"`
 130     AC_SUBST(datadir)
 131     AC_SUBST(DIR_DATADIR)
 132     AC_DEFINE_UNQUOTED(DIR_DATADIR, "${DIR_DATADIR}")
 133 ])
 134
 135 AC_DEFUN(AC_STEPMAKE_END, [
 136     AC_OUTPUT($CONFIGFILE.make:config.make.in)
 137
 138     rm -f GNUmakefile
 139     cp make/toplevel.make.in ./GNUmakefile
 140     chmod 444 GNUmakefile
 141 ])
 142
 143 AC_DEFUN(AC_STEPMAKE_GXX, [
 144     # ugh autoconf
 145     changequote(<<, >>)dnl
 146     if $CXX --version | grep '2\.[78]' > /dev/null ||
 147         $CXX --version | grep 'egcs' > /dev/null
 148     changequote([, ])dnl
 149     then
 150             true
 151     else
 152             AC_STEPMAKE_WARN(can\'t find g++ 2.7, 2.8 or egcs)
 153     fi
 154 ])
 155
 156 AC_DEFUN(AC_STEPMAKE_GUILE, [
 157     # urg, must check for different functions in libguile
 158     # to force new check iso reading from cache
 159     AC_CHECK_LIB(guile, scm_shell, \
 160       LIBS="-lguile $LIBS" AC_DEFINE(HAVE_LIBGUILE), \
 161       AC_CHECK_LIB(readline, readline) \
 162       AC_CHECK_LIB(dl, dlopen) \
 163       AC_CHECK_LIB(socket, socket)\
 164       AC_CHECK_LIB(termcap,tgetent)\
 165       AC_CHECK_LIB(m, fabs)\
 166       AC_CHECK_LIB(guile, scm_boot_guile)\
 167     )
 168 ])
 169
 170 AC_DEFUN(AC_STEPMAKE_INIT, [
 171
 172     . $srcdir/VERSION
 173     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 174     if test x$MY_PATCH_LEVEL != x; then
 175         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 176     fi
 177
 178     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 179     changequote(<<, >>)dnl
 180     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 181     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 182     changequote([, ])dnl
 183
 184     # No versioning on directory names of sub-packages
 185     # urg, urg
 186     stepmake=${datadir}/stepmake
 187     presome=${prefix}
 188     if test "$prefix" = "NONE"; then
 189             presome=${ac_default_prefix}
 190     fi
 191     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 192
 193     if test "x$PACKAGE" = "xSTEPMAKE"; then
 194         echo Stepmake package!
 195         (cd stepmake; rm -f stepmake; ln -s ../stepmake .)
 196         (cd stepmake; rm -f bin; ln -s ../bin .)
 197         AC_CONFIG_AUX_DIR(bin)
 198         stepmake=stepmake
 199     else
 200         echo Package: $PACKAGE
 201         # Check for installed stepmake
 202         if test -d $stepmake; then
 203             echo Using installed stepmake: $stepmake
 204         else
 205             stepmake='$(depth)'/stepmake
 206             echo Using local stepmake: $datadir/stepmake not found
 207         fi
 208         AC_CONFIG_AUX_DIR(\
 209           $HOME/usr/local/share/stepmake/bin\
 210           $HOME/usr/local/lib/stepmake/bin\
 211           $HOME/usr/share/stepmake/bin\
 212           $HOME/usr/lib/stepmake/bin\
 213           /usr/local/share/stepmake/bin\
 214           /usr/local/lib/stepmake/bin\
 215           /usr/share/stepmake/bin\
 216           /usr/lib/stepmake/bin\
 217           stepmake/bin\
 218         )
 219     fi
 220
 221     AC_SUBST(stepmake)
 222     AC_SUBST(package)
 223     AC_SUBST(PACKAGE)
 224     AC_SUBST(PACKAGE_NAME)
 225     AC_DEFINE_UNQUOTED(PACKAGE, "${PACKAGE_NAME}")
 226     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 227
 228     package_depth=`dirname $cache_file`
 229     AC_SUBST(package_depth)
 230
 231     AUTOGENERATE="This file was automatically generated by configure"
 232     AC_SUBST(AUTOGENERATE)
 233     absolute_builddir="`pwd`"
 234     AC_SUBST(absolute_builddir)
 235
 236     STATE_VECTOR=`ls make/STATE-VECTOR 2>/dev/null`
 237     if test "x$STATE_VECTOR" != "x"; then
 238         STATE_VECTOR="\$(depth)/$STATE_VECTOR"
 239     fi
 240     AC_SUBST(STATE_VECTOR)
 241
 242     CONFIGSUFFIX=
 243     AC_ARG_ENABLE(config,
 244     [  enable-config=FILE      put configure settings in config-FILE.make],
 245     [CONFIGSUFFIX=$enableval])
 246
 247     if test "$CONFIGSUFFIX" != "" ; then
 248         CONFIGFILE=config-$CONFIGSUFFIX
 249     else
 250         CONFIGFILE=config
 251     fi
 252     AC_SUBST(CONFIGSUFFIX)
 253
 254     AC_CANONICAL_HOST
 255     AC_CHECK_PROGS(MAKE, make, error)
 256     AC_CHECK_PROGS(FIND, find, error)
 257
 258
 259 dnl system supplied INSTALL is unsafe; use our own install.
 260 dnl    AC_PROG_INSTALL
 261 dnl    if test "$INSTALL" = "bin/install-sh"; then
 262 dnl     export INSTALL="\$\(depth\)/bin/install-sh"
 263 dnl    fi
 264
 265     AC_CHECK_PROGS(TAR, tar, error)
 266     AC_CHECK_PROGS(BASH, bash, /bin/sh)
 267
 268     AC_PATH_PROG(PYTHON, ${PYTHON:-python}, -echo no python)
 269     AC_SUBST(PYTHON)
 270
 271
 272     AC_CHECK_SEARCH_RESULT($MAKE, GNU make,  You should install GNU make)
 273     if test $MAKE != "error" ; then
 274         $MAKE -v| grep GNU > /dev/null
 275         if test "$?" = 1
 276         then
 277                 AC_STEPMAKE_WARN(Please install *GNU* make)
 278         fi
 279     fi
 280
 281     AC_CHECK_SEARCH_RESULT($PYTHON, python, You should install Python)
 282
 283     if test "x$OSTYPE" = "xcygwin32" || test "x$OSTYPE" = "xWindows_NT"; then
 284         LN=cp # hard link does not work under cygnus-nt
 285         LN_S=cp # symbolic link does not work for native nt
 286         ZIP="zip -r -9" #
 287         DOTEXE=.exe
 288        DIRSEP='\\'
 289         PATHSEP=';'
 290        INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
 291     else
 292         DIRSEP='/'
 293         PATHSEP=':'
 294         LN=ln
 295         LN_S='ln -s'
 296         ZIP="zip -r -9"
 297         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-sh -c"
 298     fi
 299     AC_SUBST(DOTEXE)
 300     AC_SUBST(ZIP)
 301     AC_SUBST(LN)
 302     AC_SUBST(LN_S)
 303     AC_SUBST(INSTALL)
 304     AC_DEFINE_UNQUOTED(DIRSEP, '${DIRSEP}')
 305     AC_DEFINE_UNQUOTED(PATHSEP, '${PATHSEP}')
 306     AC_SUBST(PATHSEP)
 307     AC_SUBST(DIRSEP)
 308
 309
 310     AC_STEPMAKE_DATADIR
 311 ])
 312
 313 AC_DEFUN(AC_STEPMAKE_LEXYACC, [
 314     # ugh, automake: we want (and check for) bison
 315     AC_PROG_YACC
 316     # ugh, automake: we want (and check for) flex
 317     # AC_PROG_LEX
 318     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 319
 320     # AC_DECL_YYTEXT
 321     # ugh, ugh
 322     ac_cv_prog_lex_root=lex.yy
 323
 324     AC_CHECK_PROGS(BISON, bison, error)
 325     AC_CHECK_PROGS(FLEX, flex, error)
 326     AC_CHECK_SEARCH_RESULT($BISON, bison,  Please install Bison, 1.25 or better)
 327     AC_CHECK_SEARCH_RESULT($FLEX,  flex, Please install Flex, 2.5 or better)
 328
 329     if test $BISON != "error"; then
 330         bison_version=`$BISON --version| sed 's/^.*version 1.//g' `
 331         if test $bison_version -lt 25; then
 332             AC_STEPMAKE_WARN(Your bison is a bit old (1.$bison_version). You might have to install 1.25)
 333         fi
 334     fi
 335
 336     AC_SUBST(BISON)
 337     AC_SUBST(FLEX)
 338 ])
 339
 340 AC_DEFUN(AC_STEPMAKE_LIB, [
 341     AC_CHECK_PROGS(AR, ar, error)
 342     AC_PROG_RANLIB
 343
 344     AC_SUBST(AR)
 345     AC_SUBST(RANLIB)
 346 ])
 347
 348 AC_DEFUN(AC_STEPMAKE_LIBTOOL, [
 349     # libtool.info ...
 350     # **Never** try to set library version numbers so that they correspond
 351     # to the release number of your package.  This is an abuse that only
 352     # fosters misunderstanding of the purpose of library versions.
 353
 354     REVISION=$PATCH_LEVEL
 355     # CURRENT=$MINOR_VERSION
 356     CURRENT=`expr $MINOR_VERSION + 1`
 357     # AGE=$(expr $MAJOR_VERSION + 1)
 358     AGE=$MAJOR_VERSION
 359     AC_SUBST(CURRENT)
 360     AC_SUBST(REVISION)
 361     AC_SUBST(AGE)
 362 ])
 363
 364 AC_DEFUN(AC_STEPMAKE_LOCALE, [
 365     lang=English
 366     ALL_LINGUAS="en nl"
 367
 368     # with/enable ??
 369     AC_ARG_WITH(localedir,
 370     [  with-localedir=LOCALE   use LOCALE as locale dir. Default: PREFIX/share/locale ],
 371     localedir=$with_localedir,
 372     localedir='${prefix}/share/locale')
 373
 374     AC_ARG_WITH(lang,
 375     [  with-lang=LANG          use LANG as language to emit messages],
 376     language=$with_lang,
 377     language=English)
 378
 379     AC_MSG_CHECKING(language)
 380     case "$language" in
 381       En* | en* | Am* | am* | US* | us*)
 382             lang=English;;
 383       NL | nl | Du* | du* | Ned* | ned*)
 384             lang=Dutch;;
 385       "")
 386             lang=English;;
 387       *)
 388             lang=unknown;;
 389     esac
 390     AC_MSG_RESULT($lang)
 391
 392     if test "$lang" = "unknown" ; then
 393         AC_STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 394     fi
 395
 396 ])
 397
 398 AC_DEFUN(AC_STEPMAKE_GETTEXT, [
 399     DIR_LOCALEDIR=${localedir}
 400     presome=${prefix}
 401     if test "$prefix" = "NONE"; then
 402             presome=${ac_default_prefix}
 403     fi
 404     DIR_LOCALEDIR=`echo ${DIR_LOCALEDIR} | sed "s!\\\${prefix}!$presome!"`
 405     AC_SUBST(localedir)
 406     AC_SUBST(DIR_LOCALEDIR)
 407     AC_DEFINE_UNQUOTED(DIR_LOCALEDIR, "${DIR_LOCALEDIR}")
 408
 409     AC_CHECK_LIB(intl, gettext)
 410     AC_CHECK_FUNCS(gettext)
 411 ])
 412
 413 AC_DEFUN(AC_STEPMAKE_MAN, [
 414     AC_CHECK_PROGS(TROFF, troff, -echo no troff)
 415 ])
 416
 417 AC_DEFUN(AC_STEPMAKE_MSGFMT, [
 418     # AC_CHECK_PROGS(MSGFMT, msgfmt, -echo no msgfmt)
 419     AC_CHECK_PROGS(MSGFMT, msgfmt, \$(SHELL) \$(step-bindir)/fake-msgfmt.sh )
 420     AC_MSG_CHECKING(whether msgfmt accepts -o)
 421     msgfmt_output="`msgfmt -o bla 2>&1 | grep usage`"
 422     if test "$msgfmt_output" = ""; then
 423         AC_MSG_RESULT(yes)
 424     else
 425         # urg
 426         MSGFMT="\$(SHELL) \$(step-bindir)/fake-msgfmt.sh"
 427         AC_MSG_RESULT(no)
 428         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 429     fi
 430     if test ! -n "$MSGFMT"; then
 431         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 432     fi
 433 ])
 434
 435 AC_DEFUN(AC_STEPMAKE_TEXMF_DIRS, [
 436     AC_ARG_ENABLE(tex-prefix,
 437     [  enable-tex-prefix=DIR   set the tex-directory to find TeX subdirectories. (default: PREFIX)],
 438     [TEXPREFIX=$enableval],
 439     [TEXPREFIX=auto] )
 440
 441     AC_ARG_ENABLE(tex-dir,
 442     [  enable-tex-dir=DIR      set the directory to put $PACKAGE_NAME TeX files in. ],
 443     [TEXDIR=$enableval],
 444     [TEXDIR=auto] )
 445
 446     AC_ARG_ENABLE(mf-dir,
 447     [  enable-mf-dir=DIR       set the directory to put $PACKAGE_NAME MetaFont files in. ],
 448     [MFDIR=$enableval],
 449     [MFDIR=auto])
 450
 451     if test "x$TEXPREFIX" = xauto ; then
 452         AC_TEX_PREFIX(TEXPREFIX)
 453     else
 454      find_texprefix=$TEXPREFIX
 455     fi
 456
 457     if test "x$MFDIR" = xauto; then
 458         AC_MF_SUBDIR(MFDIR)
 459     fi
 460
 461     if test "x$TEXDIR" = xauto ; then
 462         AC_TEX_SUBDIR(TEXDIR)
 463     fi
 464     AC_SUBST(TEXPREFIX)
 465     AC_SUBST(TEXDIR)
 466     AC_SUBST(MFDIR)
 467 ])
 468
 469 AC_DEFUN(AC_STEPMAKE_TEXMF, [
 470     # urg, never know what names these teTeX guys will think up
 471     AC_CHECK_PROGS(METAFONT, mf, no)
 472     if test "x$METAFONT" = "xno"; then
 473         AC_CHECK_PROGS(MFONT, mfont, -echo no mf or mfont)
 474         METAFONT=$MFONT
 475     fi
 476
 477     AC_CHECK_PROGS(METAPOST, mp, no)
 478     if test "x$METAPOST" = "xno"; then
 479         AC_CHECK_PROGS(MPOST, mpost, -echo no mp or mpost)
 480         METAPOST=$MPOST
 481     fi
 482
 483     AC_SUBST(METAFONT)
 484     AC_SUBST(METAPOST)
 485 ])
 486
 487 AC_DEFUN(AC_STEPMAKE_WARN, [
 488     AC_MSG_WARN($1)
 489     warn_b=yes
 490 ])
 491
 492 AC_DEFUN(AC_STEPMAKE_YODL, [
 493     if test "x$YODL" = "x"; then
 494         AC_CHECK_PROGS(STRIPROFF, striproff, -echo no striproff)
 495         AC_CHECK_PROGS(YODL, yodl, -echo no yodl)
 496         AC_CHECK_PROGS(YODL2HTML, yodl2html, -echo no yodl)
 497         AC_CHECK_PROGS(YODL2LATEX, yodl2latex, )
 498         AC_CHECK_PROGS(YODL2MAN, yodl2man, -echo no yodl)
 499         AC_CHECK_PROGS(YODL2MSLESS, yodl2msless, -echo no yodl)
 500         AC_CHECK_PROGS(YODL2TEXINFO, yodl2texinfo, -echo no yodl)
 501         AC_CHECK_PROGS(YODL2TXT, yodl2txt, -echo no yodl)
 502         YODL2LESS_DIR='$(bindir)/'
 503     else
 504         AC_SUBST(STRIPROFF)
 505         AC_SUBST(YODL)
 506         AC_SUBST(YODL2HTML)
 507         AC_SUBST(YODL2LATEX)
 508         AC_SUBST(YODL2LESS_DIR)
 509         AC_SUBST(YODL2MAN)
 510         AC_SUBST(YODL2MSLESS)
 511         AC_SUBST(YODL2TEXINFO)
 512         AC_SUBST(YODL2TXT)
 513         export STRIPROFF YODL YODL2HTML YODL2LATEX YODL2MAN YODL2MSLESS YODL2TEXINFO YODL2TXT
 514     fi
 515     if test "x$YODL" = "-echo no yodl"; then
 516         AC_STEPMAKE_WARN(Did not find YODL (Yodl is Yet Oneother Document Language, see http://www.cs.uu.nl/~hanwen/yodl))
 517     fi
 518 ])
 519
 520 dnl should cache result.
 521 dnl should  look in $prefix first.
 522 dnl should probably assume TDS
 523
 524 AC_DEFUN(AC_TEX_PREFIX, [
 525
 526
 527     AC_MSG_CHECKING(TeX/MF root dir directory)
 528
 529     find_root_prefix="$prefix"
 530
 531
 532     test "x$find_root_prefix" = xNONE && find_root_prefix="$ac_default_prefix"
 533     find_texpostfix="";
 534     for postfix in "/lib/tex/" "/lib/texmf" "/lib" "/tex" "/texmf"; do
 535         find_texprefix="$find_root_prefix$postfix"
 536         if test -d $find_texprefix; then
 537             find_texpostfix=$postfix
 538             break;
 539         fi
 540     done
 541
 542     if test "x$find_texpostfix" = x; then
 543         find_texpostfix='/lib/texmf/tex'
 544         AC_STEPMAKE_WARN(Cannot determine the TeX-directory. Please use --enable-tex-prefix)
 545     fi
 546
 547     find_texprefix="$find_root_prefix/$find_texpostfix"
 548
 549     # only assign if variablename not empty
 550     if test x != "x[$]$1"; then
 551         $1='${prefix}'/"$find_texpostfix"
 552     fi
 553     AC_MSG_RESULT($find_texprefix)
 554
 555 ])
 556
 557
 558 # find a directory inside a prefix,
 559 # $1 the prefix (expanded version)
 560 # $2 variable to assign
 561 # $3 the directory name
 562 # $4 description
 563 AC_DEFUN(AC_FIND_DIR_IN_PREFIX, [
 564
 565     AC_MSG_CHECKING($4 directory)
 566     find_dirdir=`(cd $1;
 567       $FIND ./ -type d -a -name $3 -print |sort|head -1|sed 's#^\./##')`
 568
 569
 570     if test "x$find_dirdir" = x; then
 571        find_dirdir="/$3";
 572        AC_STEPMAKE_WARN(Cannot determine $4 subdirectory. Please set from command-line)
 573         true
 574     fi
 575     $2=$find_dirdir
 576     AC_MSG_RESULT($1/$find_dirdir)
 577 ])
 578
 579 # ugh.  this is hopeless
 580 AC_DEFUN(AC_KPSE_TEX_DIR, [
 581         kpse_paths=`(kpsepath -n latex tex; kpsepath -n tex tex) | sed 's/:/ /g' | tr ' ' '\012' |sort | uniq -d`
 582         kpse_syspaths=`echo $kpse_paths | grep '!'| sed 's/!//g'`
 583         echo $kpse_paths
 584         if test -w "$kpse_syspaths";
 585         then
 586                 dir=`echo $kpse_syspaths | head -1`
 587         else
 588                 dir=`echo $kpse_paths | grep -v '!'| head -1`
 589         fi
 590         if test "$prefix" = "NONE"; then
 591                 local_prefix=$ac_default_prefix
 592                 local_prefix_quote='${prefix}'
 593
 594         else
 595                 local_prefix=$prefix
 596                 local_prefix_quote=$prefix
 597         fi
 598         echo $local_prefix_quote = $local_prefix
 599         echo $dir
 600         echo $dir  | sed 's!'$local_prefix'!\$local_prefix_quote!g'
 601 ])
 602
 603 AC_DEFUN(AC_TEX_SUBDIR, [
 604 dnl    AC_REQUIRE([AC_TEX_PREFIX])
 605     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, tex,TeX input)
 606     $1="$TEXPREFIX/$$1"
 607 ])
 608
 609 AC_DEFUN(AC_MF_SUBDIR, [
 610 dnl     AC_REQUIRE([AC_TEX_PREFIX])
 611     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, source, MF input)
 612     $1="$TEXPREFIX/$$1"
 613 ])
 614
 615 AC_DEFUN(AC_CHECK_SEARCH_RESULT, [
 616         result="`echo \"$1\" | grep echo`"
 617         if test "x$1" = "xerror" -o "x$result" != "x"; then
 618                 AC_STEPMAKE_WARN(can\'t find $2. $3)
 619         fi
 620 ])
 621
 622
 623 # Configure paths for GTK+
 624 # Owen Taylor     97-11-3
 625
 626 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 627 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
 628 dnl
 629 AC_DEFUN(AM_PATH_GTK,
 630 [dnl
 631 dnl Get the cflags and libraries from the gtk-config script
 632 dnl
 633   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
 634   min_gtk_version=ifelse([$1], ,1.1.1,$1)
 635   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
 636   no_gtk=""
 637   if test "$GTK_CONFIG" != "no" ; then
 638     GTK_CFLAGS=`$GTK_CONFIG --cflags`
 639     GTK_LIBS=`$GTK_CONFIG --libs`
 640     ac_save_CFLAGS="$CFLAGS"
 641     ac_save_LIBS="$LIBS"
 642     ac_save_CXXFLAGS="$CXXFLAGS"
 643     CFLAGS="$CFLAGS $GTK_CFLAGS"
 644     CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 645     LIBS="$LIBS $GTK_LIBS"
 646 dnl
 647 dnl Now check if the installed GTK is sufficiently new. (Also sanity
 648 dnl checks the results of gtk-config to some extent
 649 dnl
 650     AC_TRY_RUN([
 651 #include <gtk/gtk.h>
 652 #include <stdio.h>
 653
 654 int
 655 main ()
 656 {
 657   int major, minor, micro;
 658
 659   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
 660      printf("%s, bad version string\n", "$min_gtk_version");
 661      exit(1);
 662    }
 663
 664    return !((gtk_major_version > major) ||
 665             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
 666             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
 667 }
 668 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 669      CFLAGS="$ac_save_CFLAGS"
 670      CXXFLAGS="$ac_save_CXXFLAGS"
 671      LIBS="$ac_save_LIBS"
 672   else
 673      no_gtk=yes
 674   fi
 675   if test "x$no_gtk" = x ; then
 676      AC_MSG_RESULT(yes)
 677      ifelse([$2], , :, [$2])
 678   else
 679      AC_MSG_RESULT(no)
 680      GTK_CFLAGS=""
 681      GTK_LIBS=""
 682      ifelse([$3], , :, [$3])
 683   fi
 684   CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 685   AC_SUBST(CXXFLAGS)
 686   AC_SUBST(GTK_CFLAGS)
 687   AC_SUBST(GTK_LIBS)
 688 ])
 689
 690
 691 # Configure paths for GTK--
 692 # Erik Andersen 30 May 1998
 693 # Modified by Tero Pulkkinen (added the compiler checks... I hope they work..)
 694
 695 dnl Test for GTK__, and define GTK___CFLAGS and GTK___LIBS
 696 dnl   to be used as follows:
 697 dnl AM_PATH_GTKMM([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 698 dnl
 699
 700 dnl Get the cflags and libraries from the gtkmm-config script
 701 dnl
 702 AC_ARG_WITH(gtkmm-prefix,[  --with-gtkmm-prefix=PREFIX
 703                           Prefix where GTK-- is installed (optional)],
 704             gtkmm_config_prefix="$withval", gtkmm_config_prefix="")
 705 AC_ARG_WITH(gtkmm-exec-prefix,[  --with-gtkmm-exec-prefix=PREFIX
 706                           Exec prefix where GTK-- is installed (optional)],
 707             gtkmm_config_exec_prefix="$withval", gtkmm_config_exec_prefix="")
 708 AC_ARG_ENABLE(gtkmmtest, [  --disable-gtkmmtest     Do not try to compile and run a test GTK-- program],
 709                     , enable_gtkmmtest=yes)
 710
 711   if test x$gtkmm_config_exec_prefix != x ; then
 712      gtkmm_config_args="$gtkmm_config_args --exec-prefix=$gtkmm_config_exec_prefix"
 713      if test x${GTKMM_CONFIG+set} != xset ; then
 714         GTKMM_CONFIG=$gtkmm_config_exec_prefix/bin/gtkmm-config
 715      fi
 716   fi
 717   if test x$gtkmm_config_prefix != x ; then
 718      gtkmm_config_args="$gtkmm_config_args --prefix=$gtkmm_config_prefix"
 719      if test x${GTKMM_CONFIG+set} != xset ; then
 720         GTKMM_CONFIG=$gtkmm_config_prefix/bin/gtkmm-config
 721      fi
 722   fi
 723
 724
 725 AC_DEFUN(AM_PATH_GTKMM,
 726 [dnl
 727
 728 dnl
 729 dnl Check check if the installed GTK-- is sufficiently new.
 730 dnl
 731   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 732   min_gtkmm_version=ifelse([$1], ,0.9.14,$1)
 733
 734   AC_MSG_CHECKING(for GTK-- - version >= $min_gtkmm_version)
 735   no_gtkmm=""
 736   if test "$GTKMM_CONFIG" = "no" ; then
 737     no_gtkmm=yes
 738   else
 739     AC_LANG_SAVE
 740     AC_LANG_CPLUSPLUS
 741
 742     GTK___CFLAGS=`$GTKMM_CONFIG $gtkmm_config_args --cflags`
 743     GTK___LIBS=`$GTKMM_CONFIG $gtkmm_config_args --libs`
 744     gtkmm_config_major_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 745            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 746     gtkmm_config_minor_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 747            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 748     gtkmm_config_micro_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 749            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
 750     if test "x$enable_gtkmmtest" = "xyes" ; then
 751       ac_save_CXXFLAGS="$CXXFLAGS"
 752       ac_save_LIBS="$LIBS"
 753       CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 754       LIBS="$LIBS $GTK___LIBS"
 755 dnl
 756 dnl Now check if the installed GTK-- is sufficiently new. (Also sanity
 757 dnl checks the results of gtkmm-config to some extent
 758 dnl
 759       rm -f conf.gtkmmtest
 760       AC_TRY_RUN([
 761 #include <gtk--.h>
 762 #include <stdio.h>
 763 #include <stdlib.h>
 764
 765 int
 766 main ()
 767 {
 768   int major, minor, micro;
 769   char *tmp_version;
 770
 771   system ("touch conf.gtkmmtest");
 772
 773   /* HP/UX 0 (%@#!) writes to sscanf strings */
 774   tmp_version = g_strdup("$min_gtkmm_version");
 775   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
 776      printf("%s, bad version string\n", "$min_gtkmm_version");
 777      exit(1);
 778    }
 779
 780   if ((gtkmm_major_version != $gtkmm_config_major_version) ||
 781       (gtkmm_minor_version != $gtkmm_config_minor_version) ||
 782       (gtkmm_micro_version != $gtkmm_config_micro_version))
 783     {
 784       printf("\n*** 'gtkmm-config --version' returned %d.%d.%d, but GTK-- (%d.%d.%d)\n",
 785              $gtkmm_config_major_version, $gtkmm_config_minor_version, $gtkmm_config_micro_version,
 786              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 787       printf ("*** was found! If gtkmm-config was correct, then it is best\n");
 788       printf ("*** to remove the old version of GTK--. You may also be able to fix the error\n");
 789       printf("*** by modifying your LD_LIBRARY_PATH enviroment variable, or by editing\n");
 790       printf("*** /etc/ld.so.conf. Make sure you have run ldconfig if that is\n");
 791       printf("*** required on your system.\n");
 792       printf("*** If gtkmm-config was wrong, set the environment variable GTKMM_CONFIG\n");
 793       printf("*** to point to the correct copy of gtkmm-config, and remove the file config.cache\n");
 794       printf("*** before re-running configure\n");
 795     }
 796 /* GTK-- does not have the GTKMM_*_VERSION constants */
 797 /*
 798   else if ((gtkmm_major_version != GTKMM_MAJOR_VERSION) ||
 799            (gtkmm_minor_version != GTKMM_MINOR_VERSION) ||
 800            (gtkmm_micro_version != GTKMM_MICRO_VERSION))
 801     {
 802       printf("*** GTK-- header files (version %d.%d.%d) do not match\n",
 803              GTKMM_MAJOR_VERSION, GTKMM_MINOR_VERSION, GTKMM_MICRO_VERSION);
 804       printf("*** library (version %d.%d.%d)\n",
 805              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 806     }
 807 */
 808   else
 809     {
 810       if ((gtkmm_major_version > major) ||
 811         ((gtkmm_major_version == major) && (gtkmm_minor_version > minor)) ||
 812         ((gtkmm_major_version == major) && (gtkmm_minor_version == minor) && (gtkmm_micro_version >= micro)))
 813       {
 814         return 0;
 815        }
 816      else
 817       {
 818         printf("\n*** An old version of GTK-- (%d.%d.%d) was found.\n",
 819                gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 820         printf("*** You need a version of GTK-- newer than %d.%d.%d. The latest version of\n",
 821                major, minor, micro);
 822         printf("*** GTK-- is always available from ftp://ftp.gtk.org.\n");
 823         printf("***\n");
 824         printf("*** If you have already installed a sufficiently new version, this error\n");
 825         printf("*** probably means that the wrong copy of the gtkmm-config shell script is\n");
 826         printf("*** being found. The easiest way to fix this is to remove the old version\n");
 827         printf("*** of GTK--, but you can also set the GTKMM_CONFIG environment to point to the\n");
 828         printf("*** correct copy of gtkmm-config. (In this case, you will have to\n");
 829         printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
 830         printf("*** so that the correct libraries are found at run-time))\n");
 831       }
 832     }
 833   return 1;
 834 }
 835 ],, no_gtkmm=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 836        CXXFLAGS="$ac_save_CXXFLAGS"
 837        LIBS="$ac_save_LIBS"
 838      fi
 839   fi
 840   if test "x$no_gtkmm" = x ; then
 841      AC_MSG_RESULT(yes)
 842      ifelse([$2], , :, [$2])
 843   else
 844      AC_MSG_RESULT(no)
 845      if test "$GTKMM_CONFIG" = "no" ; then
 846        echo "*** The gtkmm-config script installed by GTK-- could not be found"
 847        echo "*** If GTK-- was installed in PREFIX, make sure PREFIX/bin is in"
 848        echo "*** your path, or set the GTK_CONFIG environment variable to the"
 849        echo "*** full path to gtk-config."
 850        echo "*** The gtkmm-config script was not available in GTK-- versions"
 851        echo "*** prior to 0.9.12. Perhaps you need to update your installed"
 852        echo "*** version to 0.9.12 or later"
 853      else
 854        if test -f conf.gtkmmtest ; then
 855         :
 856        else
 857           echo "*** Could not run GTK-- test program, checking why..."
 858           CXXFLAGS="$CFLAGS $GTKMM_CXXFLAGS"
 859           LIBS="$LIBS $GTK___LIBS"
 860           AC_TRY_LINK([
 861 #include <gtk--.h>
 862 #include <stdio.h>
 863 ],      [ return ((gtkmm_major_version) || (gtkmm_minor_version) || (gtkmm_micro_version)); ],
 864         [ echo "*** The test program compiled, but did not run. This usually means"
 865           echo "*** that the run-time linker is not finding GTK-- or finding the wrong"
 866           echo "*** version of GTK--. If it is not finding GTK--, you'll need to set your"
 867           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 868           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 869           echo "*** is required on your system"
 870           echo "***"
 871           echo "*** If you have an old version installed, it is best to remove it, although"
 872           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH" ],
 873         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 874           echo "*** exact error that occured. This usually means GTK-- was incorrectly installed"
 875           echo "*** or that you have moved GTK-- since it was installed. In the latter case, you"
 876           echo "*** may want to edit the gtkmm-config script: $GTKMM_CONFIG" ])
 877           CXXFLAGS="$ac_save_CXXFLAGS"
 878           LIBS="$ac_save_LIBS"
 879        fi
 880      fi
 881      GTK___CFLAGS=""
 882      GTK__LIBS=""
 883      ifelse([$3], , :, [$3])
 884      AC_LANG_RESTORE
 885   fi
 886   AC_SUBST(GTK___CFLAGS)
 887   AC_SUBST(GTK___LIBS)
 888   rm -f conf.gtkmmtest
 889 ])
 890
 891 # Configure paths for GTK--DRAW
 892 # Derek Quinn Wyatt   98-08-21  (adapted from Jan Nieuwenhuizen's code)
 893
 894 dnl AM_PATH_GTK__DRAW([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 895 dnl Test for GTK--DRAW, and define GTK___CFLAGS and GTK___LIBS
 896 dnl
 897 AC_DEFUN(AM_PATH_GTK__DRAW,
 898 [dnl
 899 dnl Get the cflags and libraries from the gtk__-config script
 900 dnl
 901   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 902   min_gtk___version=ifelse([$1], ,0.0.5,$1)
 903   AC_MSG_CHECKING(for GTK--DRAW - version >= $min_gtk___version)
 904   no_gtk__=""
 905   if test "$GTKMM_CONFIG" != "no" ; then
 906     GTK___CFLAGS=`$GTKMM_CONFIG --cflags`
 907     GTK___LIBS=`$GTKMM_CONFIG --libs`
 908     GTK___DLIBS="$GTK___LIBS -lgtkmmdraw"
 909     GTK___LIBS="$GTK___DLIBS"
 910     ac_save_CFLAGS="$CFLAGS"
 911     ac_save_LIBS="$LIBS"
 912     ac_save_CXXFLAGS="$CXXFLAGS"
 913     CFLAGS="$CFLAGS $GTK___CFLAGS"
 914     CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 915     LIBS="$LIBS $GTK___LIBS"
 916 dnl
 917 dnl Now check if the installed GTK__ is sufficiently new. (Also sanity
 918 dnl checks the results of gtk__-config to some extent
 919 dnl
 920     AC_TRY_RUN([
 921 #include <gtk--.h>
 922 #include <stdio.h>
 923
 924 int
 925 main ()
 926 {
 927   // urg
 928   return 0;
 929 }
 930 ],, no_gtk__=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 931      CFLAGS="$ac_save_CFLAGS"
 932      CXXFLAGS="$ac_save_CXXFLAGS"
 933      LIBS="$ac_save_LIBS"
 934   else
 935      no_gtk__=yes
 936   fi
 937   if test "x$no_gtk__" = x ; then
 938      AC_MSG_RESULT(yes)
 939      ifelse([$2], , :, [$2])
 940   else
 941      AC_MSG_RESULT(no)
 942      GTK___CFLAGS=""
 943      GTK___LIBS=""
 944      ifelse([$3], , :, [$3])
 945   fi
 946   CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 947   AC_SUBST(CXXFLAGS)
 948   AC_SUBST(GTK___CFLAGS)
 949   AC_SUBST(GTK___LIBS)
 950 ])
 951