stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p "$1" 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)dnl
  29     ##set -x
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33     ## FIXME: what systems still do not have $() in /bin/sh?
  34     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\.[0-9]' \
  35         | head -n 1 \
  36         | sed -e 's/.*[^-.0-9]\([0-9][0-9]*\.[0-9][.0-9]*\).*/\1/' \
  37             -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  38     if test -z "$_ver"; then
  39         ## If empty, try date [fontforge]
  40         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  41             | head -n 1 \
  42             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  43     fi
  44     echo "$_ver"
  45     ##set +x
  46     changequote([, ])dnl
  47 ])
  48
  49 # Calculate simplistic numeric version from version string ($1)
  50 # As yet, we have no need for something more elaborate.
  51 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  52     echo "$1" | awk -F. '
  53     {
  54       if ([$]3) {three = [$]3}
  55       else {three = 0}
  56     }
  57     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  58 ])
  59
  60
  61 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  62 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  63     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  64 ])
  65
  66 # Check if tested program ($2) was found ($1).
  67 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  68 # We could abort here if a 'REQUIRED' program is not found
  69 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  70     STEPMAKE_CHECK_SEARCH_RESULT($1)
  71     if test $? -ne 0; then
  72         STEPMAKE_ADD_ENTRY($3, $2)
  73         if test "$3" = "REQUIRED"; then
  74             command="echo ERROR: $2 not found"
  75             # abort configure process here?
  76         else
  77             command="- echo $2 not found"
  78         fi
  79         eval "$1"='$command'
  80         false
  81     else
  82         true
  83     fi
  84 ])
  85
  86
  87 # Return if tested proram ($1) was found (true) or not (false).
  88 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  89     r="`eval echo '$'"$1"`"
  90     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  91         true
  92     else
  93         ##STEPMAKE_WARN(cannot find $2. $3)
  94         false
  95     fi
  96 ])
  97
  98
  99 # Check version of program ($1)
 100 # If version ($4: optional argument, supply if version cannot be
 101 # parsed using --version or -V ) is smaller than requested ($3), add
 102 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 103 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 104     r="`eval echo '$'"$1"`"
 105     AC_MSG_CHECKING([$r version])
 106     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 107     if test -n "$4"; then
 108         ver="$4"
 109     else
 110         ver=`STEPMAKE_GET_VERSION($exe)`
 111     fi
 112     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 113     req=`STEPMAKE_NUMERIC_VERSION($3)`
 114     AC_MSG_RESULT([$ver])
 115     if test "$num" -lt "$req"; then
 116         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 117     fi
 118     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 119     eval `echo $vervar=$num`
 120 ##    AC_SUBST(`eval echo $vervar`)
 121 ])
 122
 123 # Check version of program ($1)
 124 # If version is greater than or equals unsupported ($3),
 125 # add entry to unsupported list ($2, 'UNSUPPORTED')
 126 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 127     r="`eval echo '$'"$1"`"
 128     AC_MSG_CHECKING([$r version])
 129     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 130     ver=`STEPMAKE_GET_VERSION($exe)`
 131     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 132     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 133     AC_MSG_RESULT([$ver])
 134     if test "$num" -ge "$sup"; then
 135         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 136     fi
 137 ])
 138
 139 ### Macros to build configure.in
 140
 141
 142 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 143     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 144     if test "$BIBTEX2HTML" = "bib2html"; then
 145         BIBTEX2HTML_FLAGS='$< $(@)'
 146     else
 147         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 148     fi
 149     AC_SUBST(BIBTEX2HTML)
 150     AC_SUBST(BIBTEX2HTML_FLAGS)
 151 ])
 152
 153
 154 AC_DEFUN(STEPMAKE_BISON, [
 155     # ugh, automake: we want (and check for) bison
 156     AC_PROG_YACC
 157
 158     STEPMAKE_PROGS(BISON, bison, $1)
 159
 160     # urg.  should test functionality rather than version.
 161     if test "$BISON" = "bison" -a -n "$2"; then
 162         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 163     fi
 164 ])
 165
 166
 167 AC_DEFUN(STEPMAKE_COMPILE, [
 168     # -O is necessary to get inlining
 169     CFLAGS=${CFLAGS-""}
 170     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 171     LDFLAGS=${LDFLAGS-""}
 172     optimise_b=yes
 173     profile_b=no
 174     debug_b=yes
 175     pipe_b=yes
 176
 177     AC_ARG_ENABLE(debugging,
 178     [  --enable-debugging      compile with debugging info.  Default: on],
 179     [debug_b=$enableval])
 180
 181     AC_ARG_ENABLE(optimising,
 182     [  --enable-optimising     compile with optimising.  Default: on],
 183     [optimise_b=$enableval])
 184
 185     AC_ARG_ENABLE(profiling,
 186     [  --enable-profiling      compile with gprof support.  Default: off],
 187     [profile_b=$enableval])
 188
 189     AC_ARG_ENABLE(pipe,
 190     [  --enable-pipe           compile with -pipe.  Default: on],
 191     [pipe_b=$enableval])
 192
 193     if test "$optimise_b" = yes; then
 194         AC_DEFINE(NDEBUG)
 195         DEFINES="$DEFINES -DNDEBUG"
 196         OPTIMIZE="-O2 -finline-functions"
 197     fi
 198
 199     if test $profile_b = yes; then
 200         EXTRA_LIBES="-pg"
 201         OPTIMIZE="$OPTIMIZE -pg"
 202     fi
 203
 204     if test $debug_b = yes; then
 205         OPTIMIZE="$OPTIMIZE -g"
 206     fi
 207
 208     AC_PROG_CC
 209     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 210     LD='$(CC)'
 211     AC_SUBST(LD)
 212
 213     # If -pipe requested, test if it works and add to CFLAGS.
 214     if test "$pipe_b" = yes; then
 215         save_cflags="$CFLAGS"
 216         CFLAGS="-pipe $CFLAGS";
 217         AC_CACHE_CHECK([whether compiler understands -pipe],
 218             [stepmake_cflags_pipe],
 219             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 220                 [stepmake_cflags_pipe=yes],
 221                 [stepmake_cflags_pipe=no]))
 222         CFLAGS=$save_cflags
 223         if test $stepmake_cflags_pipe = yes; then
 224             OPTIMIZE="$OPTIMIZE -pipe"
 225         fi
 226     fi
 227
 228     CFLAGS="$CFLAGS $OPTIMIZE"
 229     CPPFLAGS=${CPPFLAGS-""}
 230
 231     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 232     save_cflags="$CFLAGS"
 233     case "$host" in
 234         alpha*-*-*)
 235             dnl should do compile test?
 236             AC_MSG_RESULT(-mieee)
 237             CFLAGS="-mieee $CFLAGS"
 238             ;;
 239         *)
 240             AC_MSG_RESULT([none])
 241             ;;
 242     esac
 243
 244     AC_SUBST(cross_compiling)
 245     AC_SUBST(CFLAGS)
 246     AC_SUBST(CPPFLAGS)
 247     AC_SUBST(LDFLAGS)
 248     AC_SUBST(ICFLAGS)
 249     AC_SUBST(ILDFLAGS)
 250     AC_SUBST(DEFINES)
 251     AC_SUBST(EXTRA_LIBES)
 252 ])
 253
 254 AC_DEFUN(STEPMAKE_CXX, [
 255     AC_LANG([C++])
 256     AC_PROG_CXX
 257     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 258
 259     CPPFLAGS="$CPPFLAGS $DEFINES"
 260     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 261     LDFLAGS="$LDFLAGS $EXTRA_LIBES"
 262
 263     AC_SUBST(CXXFLAGS)
 264     AC_SUBST(CXX)
 265     LD='$(CXX)'
 266     AC_SUBST(LD)
 267 ])
 268
 269
 270 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 271     AC_CACHE_CHECK([whether explicit instantiation is needed],
 272         lily_cv_need_explicit_instantiation,
 273         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 274     template <class T> struct foo { static int baz; };
 275     template <class T> int foo<T>::baz = 1;
 276     ]], [[ return foo<int>::baz; ]])],[lily_cv_need_explicit_instantiation=no],[lily_cv_need_explicit_instantiation=yes]))
 277     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 278         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 279     fi
 280 ])
 281
 282
 283 AC_DEFUN(STEPMAKE_DATADIR, [
 284     if test "$datadir" = "\${prefix}/share"; then
 285             datadir='${prefix}/share'
 286     fi
 287     presome=${prefix}
 288     if test "$prefix" = "NONE"; then
 289         presome=${ac_default_prefix}
 290     fi
 291
 292     build_package_datadir=$ugh_ugh_autoconf250_builddir/share/$package
 293
 294     DATADIR=`echo ${datadir} | sed "s!\\\${prefix}!$presome!"`
 295     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 296
 297     AC_SUBST(datadir)
 298     AC_SUBST(build_package_datadir)
 299     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 300     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 301 ])
 302
 303 ## ugh: cut & paste programming from datadir.
 304 AC_DEFUN(STEPMAKE_LIBDIR, [
 305
 306     if test "$libdir" = "\${exec_prefix}/lib"; then
 307         libdir='${exec_prefix}/lib'
 308     fi
 309     presome=$exec_prefix
 310     build_package_libdir=$ugh_ugh_autoconf250_builddir/lib/$package
 311
 312     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 313     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 314
 315     AC_SUBST(libdir)
 316     AC_SUBST(build_package_libdir)
 317     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 318     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 319 ])
 320
 321
 322 AC_DEFUN(STEPMAKE_END, [
 323     AC_SUBST(OPTIONAL)
 324     AC_SUBST(REQUIRED)
 325
 326     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 327     AC_OUTPUT
 328
 329     if test -n "$OPTIONAL"; then
 330         echo
 331         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 332     fi
 333
 334     if test -n "$REQUIRED"; then
 335         echo
 336         echo "ERROR: Please install required programs: $REQUIRED"
 337     fi
 338
 339     if test -n "$UNSUPPORTED"; then
 340         echo
 341         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 342     fi
 343
 344     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 345         echo
 346         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 347         if test -f config.cache ; then
 348             echo "Remove config.cache before rerunning ./configure"
 349         fi
 350     fi
 351
 352     if test -n "$REQUIRED$UNSUPPORTED"; then
 353         rm -f $srcdir/GNUmakefile
 354         exit 1
 355     fi
 356
 357     # regular in-place build
 358     # test for srcdir_build = yes ?
 359     if test "$srcdir_build" = "yes"; then
 360         rm -f $srcdir/GNUmakefile
 361         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 362         chmod 444 $srcdir/GNUmakefile
 363     else # --srcdir build
 364         rm -f GNUmakefile
 365         cp $srcdir/make/srcdir.make.in GNUmakefile
 366         chmod 444 GNUmakefile
 367     fi
 368 ])
 369
 370
 371 AC_DEFUN(STEPMAKE_FLEX, [
 372     # ugh, automake: we want (and check for) flex
 373     # AC_PROG_LEX
 374     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 375
 376     # AC_PROG_LEX()
 377     # ugh, ugh
 378     ac_cv_prog_lex_root=lex.yy
 379     STEPMAKE_PROGS(FLEX, flex, $1)
 380 ])
 381
 382
 383 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 384     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 385     if test $? -ne 0; then
 386         warn='FlexLexer.h (flex package)'
 387         STEPMAKE_ADD_ENTRY($1, $warn)
 388     fi
 389     # check for yyFlexLexer.yy_current_buffer,
 390     # in 2.5.4 <= flex < 2.5.29
 391     AC_LANG_PUSH(C++)
 392     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 393         [stepmake_flexlexer_yy_current_buffer],
 394         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 395 using namespace std;
 396 #include <FlexLexer.h>
 397 class yy_flex_lexer: public yyFlexLexer
 398 {
 399   public:
 400     yy_flex_lexer ()
 401     {
 402       yy_current_buffer = 0;
 403     }
 404 };
 405 ]])],
 406             [stepmake_flexlexer_yy_current_buffer=yes],
 407             [stepmake_flexlexer_yy_current_buffer=no]))
 408     if test $stepmake_flexlexer_yy_current_buffer = yes; then
 409         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 410     fi
 411     AC_LANG_POP(C++)
 412 ])
 413
 414
 415 AC_DEFUN(STEPMAKE_GCC, [
 416     if test "$GCC" = "yes"; then
 417         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 418     else
 419         warn="$CC (Please install *GNU* cc)"
 420         STEPMAKE_ADD_ENTRY($1, $warn)
 421     fi
 422 ])
 423
 424 AC_DEFUN(STEPMAKE_GETTEXT, [
 425     presome=${prefix}
 426     if test "$prefix" = "NONE"; then
 427             presome=${ac_default_prefix}
 428     fi
 429     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 430
 431     AC_SUBST(localedir)
 432     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 433     # ouch.  autoconf <= 2.57's gettext check fails for
 434     # g++ >= 3.3 (with -std=gnu++98, the default).
 435     # While the check is OK for g++ -std=c++98,
 436     # LilyPond needs GNU g++, so who is to blame here?
 437     # Use a workaround until this is resolved:
 438     # for g++ >= 3.3, select C language.
 439     GCC_UNSUPPORTED=
 440     STEPMAKE_CHECK_VERSION_UNSUPPORTED(CXX, GCC_UNSUPPORTED, 3.3)
 441     if test -n "$GCC_UNSUPPORTED"; then
 442         AC_MSG_WARN([autoconf <= 2.59 with g++ >= 3.3 gettext test broken.])
 443         AC_MSG_WARN([Trying gcc, cross fingers.])
 444         AC_LANG_PUSH(C)
 445     fi
 446     AC_CHECK_LIB(intl, gettext)
 447     AC_CHECK_FUNCS(gettext)
 448     if test -n "$GCC_UNSUPPORTED"; then
 449         AC_LANG_POP(C)
 450     fi
 451 ])
 452
 453
 454 AC_DEFUN(STEPMAKE_GUILE, [
 455     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 456 ])
 457
 458
 459 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 460 #
 461 #   This macro runs the guile-config script, installed with Guile,
 462 #   to find out where Guile's header files and libraries are
 463 #   installed.  It sets two variables, marked for substitution, as
 464 #   by AC_SUBST.
 465 #
 466 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 467 #             code that uses Guile header files.  This is almost
 468 #             always just a -I flag.
 469 #
 470 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 471 #             program against Guile.  This includes -lguile for
 472 #             the Guile library itself, any libraries that Guile
 473 #             itself requires (like -lqthreads), and so on.  It may
 474 #             also include a -L flag to tell the compiler where to
 475 #             find the libraries.
 476
 477 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 478     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 479     if test -x $exe; then
 480         AC_MSG_CHECKING([guile compile flags])
 481         GUILE_CFLAGS="`$guile_config compile`"
 482         AC_MSG_RESULT($GUILE_CFLAGS)
 483         AC_MSG_CHECKING([guile link flags])
 484         GUILE_LDFLAGS="`$guile_config link`"
 485         AC_MSG_RESULT($GUILE_LDFLAGS)
 486     fi
 487     AC_SUBST(GUILE_CFLAGS)
 488     AC_SUBST(GUILE_LDFLAGS)
 489 ])
 490
 491
 492 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 493     ## First, let's just see if we can find Guile at all.
 494     AC_MSG_CHECKING([for guile-config])
 495     for guile_config in $GUILE_CONFIG guile-config $target-guile-config $build-guile-config; do
 496         AC_MSG_RESULT([$guile_config])
 497         if ! $guile_config --version > /dev/null 2>&1 ; then
 498             AC_MSG_WARN([cannot execute $guile_config])
 499             AC_MSG_CHECKING([if we are cross compiling])
 500             GUILE_CONFIG='echo no guile-config'
 501         else
 502             GUILE_CONFIG=$guile_config
 503             break
 504         fi
 505     done
 506     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 507     if test $? -ne 0; then
 508         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 509     fi
 510
 511     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 512     # urg.  should test functionality rather than version.
 513     if test $? -eq 0 -a -n "$2"; then
 514         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 515     fi
 516
 517     AC_SUBST(GUILE_CONFIG)
 518
 519     guile_version="$ver"
 520     changequote(<<, >>)dnl
 521     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 522     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 523     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 524     changequote([, ])dnl
 525     STEPMAKE_GUILE_FLAGS
 526     save_CPPFLAGS="$CPPFLAGS"
 527     save_LIBS="$LIBS"
 528     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 529     LIBS="$GUILE_LDFLAGS $LIBS"
 530     AC_CHECK_HEADERS([libguile.h])
 531     AC_CHECK_LIB(guile, scm_boot_guile)
 532     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 533     if test "$libguile_b" = "no"; then
 534             warn='libguile (libguile-dev, guile-devel or guile-dev
 535    package).'
 536             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 537     fi
 538     CPPFLAGS="$save_CPPFLAGS"
 539     LIBS="$save_LIBS"
 540     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 541     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 542     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 543 ])
 544
 545
 546 AC_DEFUN(STEPMAKE_GXX, [
 547     if test "$GXX" = "yes"; then
 548         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 549     else
 550         warn="$CXX (Please install *GNU* c++)"
 551         STEPMAKE_ADD_ENTRY($1, $warn)
 552     fi
 553 ])
 554
 555
 556 AC_DEFUN(STEPMAKE_INIT, [
 557
 558     AC_PREREQ(2.50)
 559     . $srcdir/VERSION
 560     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 561     if test x$MY_PATCH_LEVEL != x; then
 562         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 563     fi
 564
 565     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 566     changequote(<<, >>)dnl
 567     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 568     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 569     changequote([, ])dnl
 570
 571     # No versioning on directory names of sub-packages
 572     # urg, urg
 573     stepmake=${datadir}/stepmake
 574     presome=${prefix}
 575     if test "$prefix" = "NONE"; then
 576             presome=${ac_default_prefix}
 577     fi
 578     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 579
 580     # urg, how is this supposed to work?
 581     if test "$program_prefix" = "NONE"; then
 582           program_prefix=
 583     fi
 584     if test "$program_suffix" = "NONE"; then
 585           program_suffix=
 586     fi
 587
 588     AC_MSG_CHECKING(Package)
 589     if test "$PACKAGE" = "STEPMAKE"; then
 590         AC_MSG_RESULT(Stepmake package!)
 591
 592         AC_MSG_CHECKING(builddir)
 593
 594         ugh_ugh_autoconf250_builddir="`pwd`"
 595
 596         if test "$srcdir" = "."; then
 597             srcdir_build=yes
 598         else
 599             srcdir_build=no
 600             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 601             package_srcdir="`dirname  $srcdir`"
 602         fi
 603         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 604
 605         (cd stepmake 2>/dev/null || mkdir stepmake)
 606         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 607 # only possible with autoconf < 2.50 -- hardcoded in configure.in
 608 #       AC_CONFIG_AUX_DIR(bin)
 609         stepmake=stepmake
 610     else
 611         AC_MSG_RESULT($PACKAGE)
 612
 613         AC_MSG_CHECKING(builddir)
 614         ugh_ugh_autoconf250_builddir="`pwd`"
 615         if test "$srcdir" = "."; then
 616             srcdir_build=yes
 617         else
 618             srcdir_build=no
 619         fi
 620         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 621
 622         AC_MSG_CHECKING(for stepmake)
 623         # Check for installed stepmake
 624         if test -d $stepmake; then
 625             AC_MSG_RESULT($stepmake)
 626         else
 627             stepmake="`cd $srcdir/stepmake; pwd`"
 628             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 629         fi
 630
 631 # only possible with autoconf < 2.50 -- hardcoded in configure.in
 632 #       AC_CONFIG_AUX_DIR(\
 633 #         stepmake/bin\
 634 #         $srcdir/stepmake/bin\
 635 #       )
 636     fi
 637
 638     AC_SUBST(ugh_ugh_autoconf250_builddir)
 639     AC_SUBST(stepmake)
 640     AC_SUBST(package)
 641     AC_SUBST(PACKAGE)
 642     AC_SUBST(PACKAGE_NAME)
 643     # We don't need the upper case variant,
 644     # so stick to macros are uppercase convention.
 645     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 646     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 647     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 648     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 649     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 650
 651     if test -z "$package_depth"; then
 652         package_depth="."
 653     else
 654         package_depth="../$package_depth"
 655     fi
 656     export package_depth
 657     AC_SUBST(package_depth)
 658
 659     AUTOGENERATE="This file was automatically generated by configure"
 660     AC_SUBST(AUTOGENERATE)
 661
 662     CONFIGSUFFIX=
 663     AC_ARG_ENABLE(config,
 664     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 665                             do \`make conf=CONF' to get output in ./out-CONF],
 666     [CONFIGURATION=$enableval])
 667
 668     ##'
 669
 670     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 671     CONFIGFILE=config$CONFIGSUFFIX
 672     AC_SUBST(CONFIGSUFFIX)
 673
 674     AC_CANONICAL_HOST
 675     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 676     STEPMAKE_PROGS(FIND, find, REQUIRED)
 677
 678     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 679
 680     if test "$(echo 2)" != "2" ||
 681         test "x`uname`" = "xHP-UX"; then
 682         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 683         AC_PATH_PROG(BASH, bash, $KSH)
 684         STEPMAKE_WARN(avoiding buggy /bin/sh)
 685         AC_PATH_PROG(SHELL, bash, $KSH)
 686     else
 687         SHELL=/bin/sh
 688         AC_PATH_PROG(BASH, bash, $SHELL)
 689     fi
 690     AC_SUBST(SHELL)
 691
 692     STEPMAKE_PYTHON(REQUIRED, 1.5)
 693
 694     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 695         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 696         if test "$?" = 1; then
 697             warn='make (Please install *GNU* make)'
 698             # STEPMAKE_WARN($warn)
 699             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 700         fi
 701     fi
 702
 703     if test "$OSTYPE" = "cygwin" -o "$OSTYPE" = "cygwin32" -o "$OSTYPE" = "Windows_NT"; then
 704         LN=cp # hard link does not work under cygnus-nt
 705         LN_S='cp -r' # symbolic link does not work for native nt
 706         ZIP="zip -r -9" #
 707         program_suffix=.exe
 708         ROOTSEP=':'
 709         DIRSEP='/'
 710         PATHSEP=':'
 711         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
 712     else
 713         ROOTSEP=':'
 714         DIRSEP='/'
 715         PATHSEP=':'
 716         LN=ln
 717         LN_S='ln -s'
 718         ZIP="zip -r -9"
 719         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-sh -c"
 720     fi
 721     AC_SUBST(program_prefix)
 722     AC_SUBST(program_suffix)
 723     AC_SUBST(ZIP)
 724     AC_SUBST(LN)
 725     AC_SUBST(LN_S)
 726     AC_SUBST(INSTALL)
 727     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 728     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 729     AC_SUBST(DIRSEP)
 730     AC_SUBST(PATHSEP)
 731     AC_SUBST(ROOTSEP)
 732
 733     STEPMAKE_DATADIR
 734     STEPMAKE_LIBDIR
 735 ])
 736
 737
 738 AC_DEFUN(STEPMAKE_KPATHSEA, [
 739
 740     AC_ARG_WITH(kpathsea-include,
 741         [  --with-kpathsea-include=DIR
 742                           location of the kpathsea include dir],[
 743             if test "$withval" = "yes" -o "$withval" = "no"; then
 744                 AC_MSG_WARN(Usage: --with-kpathsea-include=includedir)
 745             else
 746                 CPPFLAGS="$CPPFLAGS -I${withval}"
 747             fi
 748             ])
 749
 750     AC_ARG_WITH(kpathsea-lib,
 751         [  --with-kpathsea-lib=DIR location of the kpathsea lib dir],[
 752             if test "$withval" = "yes" -o "$withval" = "no"; then
 753                 AC_MSG_WARN(Usage: --with-kpathsea-lib=libdir)
 754             else
 755                 LDFLAGS="$LDFLAGS -L${withval}"
 756             fi
 757             ])
 758
 759     kpathsea_b=yes
 760     #FIXME --with-xxx is meant for specifying a PATH too,
 761     # so this should read: --enable-kpathsea,
 762     # or --with-kpathsea-include=PATH --with-kpathsea-lib=PATH
 763     AC_ARG_WITH(kpathsea,
 764     [  --with-kpathsea         use kpathsea lib.  Default: on],
 765     [kpathsea_b=$with_kpathsea])
 766
 767     if test "$kpathsea_b" != "no"; then
 768         AC_CHECK_HEADERS([kpathsea/kpathsea.h],,kpathsea_b=no)
 769         AC_CHECK_LIB(kpathsea, kpse_find_file)
 770         AC_CHECK_FUNCS(kpse_find_file,,kpathsea_b=no)
 771         if test "$kpathsea_b" = "no"; then
 772             warn='kpathsea (libkpathsea-dev, kpathsea-devel or tetex-devel
 773    package).
 774    Else, please specify the directories where kpathsea/kpathsea.h and
 775    libkpathsea.a are installed using --with-kpathsea-include and
 776    --with-kpathsea-lib options.  You should install kpathsea; see
 777    INSTALL.txt.  Rerun ./configure --without-kpathsea only if kpathsea
 778    is not available for your platform.'
 779             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 780         fi
 781     fi
 782     AC_MSG_CHECKING(whether to use kpathsea)
 783     if test "$kpathsea_b" != no; then
 784         AC_MSG_RESULT(yes)
 785         KPATHSEA=1
 786     else
 787         AC_MSG_RESULT(no)
 788         KPATHSEA=0
 789     fi
 790
 791     AC_SUBST(KPATHSEA)
 792     AC_DEFINE_UNQUOTED(KPATHSEA, $KPATHSEA)
 793 ])
 794
 795
 796 AC_DEFUN(STEPMAKE_LIB, [
 797     STEPMAKE_PROGS(AR, ar, $1)
 798     AC_PROG_RANLIB
 799     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 800 ])
 801
 802
 803 AC_DEFUN(STEPMAKE_LIBTOOL, [
 804     # libtool.info ...
 805     # **Never** try to set library version numbers so that they correspond
 806     # to the release number of your package.  This is an abuse that only
 807     # fosters misunderstanding of the purpose of library versions.
 808
 809     REVISION=$PATCH_LEVEL
 810     # CURRENT=$MINOR_VERSION
 811     CURRENT=`expr $MINOR_VERSION + 1`
 812     # AGE=`expr $MAJOR_VERSION + 1`
 813     AGE=$MAJOR_VERSION
 814     AC_SUBST(CURRENT)
 815     AC_SUBST(REVISION)
 816     AC_SUBST(AGE)
 817 ])
 818
 819
 820 AC_DEFUN(STEPMAKE_LOCALE, [
 821     lang=English
 822     ALL_LINGUAS="en nl"
 823
 824     # with/enable ??
 825     AC_ARG_WITH(localedir,
 826     [  --with-localedir=LOCALE use LOCALE as locale dir.  Default:
 827                             PREFIX/share/locale ],
 828     localedir=$with_localedir,
 829     localedir='${prefix}/share/locale')
 830
 831     AC_ARG_WITH(lang,
 832     [  --with-lang=LANG        use LANG as language to emit messages],
 833     language=$with_lang,
 834     language=English)
 835
 836     AC_MSG_CHECKING(language)
 837     case "$language" in
 838       En* | en* | Am* | am* | US* | us*)
 839             lang=English;;
 840       NL | nl | Du* | du* | Ned* | ned*)
 841             lang=Dutch;;
 842       "")
 843             lang=English;;
 844       *)
 845             lang=unknown;;
 846     esac
 847     AC_MSG_RESULT($lang)
 848
 849     if test "$lang" = "unknown" ; then
 850         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 851     fi
 852
 853 ])
 854
 855
 856 AC_DEFUN(STEPMAKE_MAKEINFO, [
 857     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 858     if test "$MAKEINFO" = "makeinfo"; then
 859         AC_MSG_CHECKING(whether makeinfo can split html by @node)
 860         mkdir -p out
 861         makeinfo --html --output=out/split <<EOF
 862 \input texinfo
 863 \input texinfo @c -*-texinfo-*-
 864 @setfilename split.info
 865 @settitle split.info
 866 @bye
 867 EOF
 868         if test -d out/split; then
 869             SPLITTING_MAKEINFO=yes
 870             AC_MSG_RESULT(yes)
 871             rm -rf out/split
 872         else
 873             AC_MSG_RESULT(no)
 874             STEPMAKE_WARN(your html documentation will be one large file)
 875             rm -rf out/split
 876         fi
 877     fi
 878     AC_SUBST(SPLITTING_MAKEINFO)
 879 ])
 880
 881
 882
 883 AC_DEFUN(STEPMAKE_MAN, [
 884     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 885     AC_SUBST(GROFF)
 886     STEPMAKE_PROGS(TROFF, troff, $1)
 887     AC_SUBST(TROFF)
 888     STEPMAKE_PROGS(TBL, tbl, $1)
 889     AC_SUBST(TBL)
 890 ])
 891
 892
 893 AC_DEFUN(STEPMAKE_MSGFMT, [
 894     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 895 ])
 896
 897
 898 # Check for program ($2), set full path result to ($1).
 899 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 900 AC_DEFUN(STEPMAKE_PATH_PROG, [
 901     AC_CHECK_PROGS($1, $2, no)
 902     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 903     if test $? -eq 0; then
 904         AC_PATH_PROG($1, $2)
 905         if test -n "$4"; then
 906             STEPMAKE_CHECK_VERSION($1, $3, $4)
 907         fi
 908     fi
 909 ])
 910
 911
 912 # Check for program in set of names ($2), set result to ($1) .
 913 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 914 # If exists, and a minimal version ($4) is required
 915 AC_DEFUN(STEPMAKE_PROGS, [
 916     AC_CHECK_PROGS($1, $2, no)
 917     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 918     if test $? -eq 0 -a -n "$4"; then
 919         STEPMAKE_CHECK_VERSION($1, $3, $4)
 920     fi
 921 ])
 922
 923
 924 AC_DEFUN(STEPMAKE_PERL, [
 925     STEPMAKE_PATH_PROG(PERL, perl, $1)
 926 ])
 927
 928
 929 AC_DEFUN(STEPMAKE_PYTHON, [
 930     unset pv
 931     AC_MSG_CHECKING([for python])
 932     for python in $PYTHON python python2 python2.3 python2.2 python2.1 python2.0; do
 933         AC_MSG_RESULT([$python])
 934         if ! $python -V > /dev/null 2>&1 ; then
 935             #AC_MSG_WARN([cannot execute $python])
 936             PYTHON='echo no python'
 937         else
 938             unset pv
 939             STEPMAKE_CHECK_VERSION(python, pv, $2)
 940             if test -z "$pv"; then
 941                 PYTHON=$python
 942                 break
 943             fi
 944         fi
 945     done
 946     if test -n "$pv"; then
 947         STEPMAKE_ADD_ENTRY($1, $pv)
 948     fi
 949     AC_PATH_PROG(PYTHON, $PYTHON)
 950     AC_SUBST(PYTHON)
 951 ])
 952
 953 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 954     unset PYTHON_HEADER PYTHON_INCLUDE
 955     if test -n "$PYTHON"; then
 956         changequote(<<, >>)dnl
 957         # alternatively, for python >= 2.0
 958         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
 959         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
 960         changequote([, ])dnl
 961     fi
 962
 963     ##AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
 964     if test -z "$PYTHON_HEADER"; then
 965         #URG -- how to extend include path?
 966         ac_compile="$ac_compile -I$PYTHON_INCLUDE"
 967         ac_cpp="$ac_cpp -I$PYTHON_INCLUDE"
 968         CPPFLAGS="$CPPFLAGS -I$PYTHON_INCLUDE"
 969         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
 970     fi
 971
 972     if test -z "$PYTHON_HEADER"; then
 973         warn="$PYTHON_INCLUDE/Python.h (python-devel, python-dev or libpython-dev package)"
 974         STEPMAKE_ADD_ENTRY($1, $warn)
 975     fi
 976 ])
 977
 978
 979 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
 980     AC_ARG_ENABLE(tfm-path,
 981     [  --enable-tfm-path=PATH  set path of tex directories where tfm files live,
 982                             esp.: cmr10.tfm.  Default: use kpsewhich],
 983     [tfm_path=$enableval],
 984     [tfm_path=auto] )
 985
 986     # ugh
 987     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
 988     AC_MSG_CHECKING(for tfm path)
 989
 990     TFM_FONTS="cmr msam"
 991
 992     if test "x$tfm_path" = xauto ; then
 993         if test "x$KPSEWHICH" != "xno" ; then
 994             for i in $TFM_FONTS; do
 995                 dir=`$KPSEWHICH tfm ${i}10.tfm`
 996                 TFM_PATH="$TFM_PATH `dirname $dir`"
 997             done
 998         else
 999             STEPMAKE_WARN(Please specify where cmr10.tfm lives:
1000     ./configure --enable-tfm-path=/usr/local/TeX/lib/tex/fonts)
1001         fi
1002     else
1003          TFM_PATH=$tfm_path
1004     fi
1005
1006     TFM_PATH=`echo $TFM_PATH | tr ':' ' '`
1007     AC_MSG_RESULT($TFM_PATH)
1008     AC_SUBST(TFM_PATH)
1009 ])
1010
1011
1012 AC_DEFUN(STEPMAKE_TEXMF, [
1013     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1014     # STEPMAKE_PROGS(INIMETAFONT, inimf inimfont "$METAFONT -ini", $1)
1015
1016     AC_MSG_CHECKING(for working metafont mode)
1017     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1018     for MFMODE in $modelist; do
1019         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1020         if test -f mfput.tfm; then
1021             break;
1022         fi
1023     done
1024     AC_MSG_RESULT($MFMODE)
1025
1026     rm -f mfput.*
1027
1028     AC_SUBST(MFMODE)
1029 ])
1030
1031
1032 AC_DEFUN(STEPMAKE_WARN, [
1033     AC_MSG_WARN($1)
1034     warn_b=yes
1035 ])
1036
1037
1038 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1039 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1040 dnl also defines GSTUFF_PKG_ERRORS on error
1041 AC_DEFUN(PKG_CHECK_MODULES, [
1042   succeeded=no
1043
1044   if test -z "$PKG_CONFIG"; then
1045     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1046   fi
1047
1048   if test "$PKG_CONFIG" = "no" ; then
1049      echo "*** The pkg-config script could not be found. Make sure it is"
1050      echo "*** in your path, or set the PKG_CONFIG environment variable"
1051      echo "*** to the full path to pkg-config."
1052      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1053   else
1054      PKG_CONFIG_MIN_VERSION=0.9.0
1055      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1056         AC_MSG_CHECKING(for $2)
1057
1058         if $PKG_CONFIG --exists "$2" ; then
1059             AC_MSG_RESULT(yes)
1060             succeeded=yes
1061
1062             AC_MSG_CHECKING($1_CFLAGS)
1063             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1064             AC_MSG_RESULT($$1_CFLAGS)
1065
1066             AC_MSG_CHECKING($1_LIBS)
1067             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1068             AC_MSG_RESULT($$1_LIBS)
1069         else
1070             $1_CFLAGS=""
1071             $1_LIBS=""
1072             ## If we have a custom action on failure, don't print errors, but
1073             ## do set a variable so people can do so.
1074             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1075             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1076         fi
1077
1078         AC_SUBST($1_CFLAGS)
1079         AC_SUBST($1_LIBS)
1080      else
1081         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1082         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1083      fi
1084   fi
1085
1086   if test $succeeded = yes; then
1087      ifelse([$3], , :, [$3])
1088   else
1089      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1090   fi
1091 ])
1092
1093
1094 AC_DEFUN(STEPMAKE_FREETYPE2, [
1095     PKG_CHECK_MODULES(FREETYPE2, freetype2 >= 0, have_freetype2=true, true)
1096     if $have_freetype2 ; then
1097         AC_DEFINE(HAVE_FREETYPE2)
1098         AC_SUBST(FREETYPE2_CFLAGS)
1099         AC_SUBST(FREETYPE2_LIBS)
1100     fi
1101 ])
1102
1103 AC_DEFUN(STEPMAKE_GTK2, [
1104     PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.4.0, have_gtk2=true, true)
1105     if $have_gtk2 ; then
1106         AC_DEFINE(HAVE_GTK2)
1107         AC_SUBST(GTK2_CFLAGS)
1108         AC_SUBST(GTK2_LIBS)
1109     fi
1110 ])
1111
1112 AC_DEFUN(STEPMAKE_PANGO, [
1113     PKG_CHECK_MODULES(PANGO, pango >= 1.6.0, have_pango16=true, true)
1114     if $have_pango16 ; then
1115         AC_DEFINE(HAVE_PANGO16)
1116         PANGO_CFLAGS="$PANGO_CFLAGS $GTK2_CFLAGS"
1117         PANGO_LIBS="$PANGO_LIBS $GTK2_LIBS"
1118         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1119         LIBS="$PANGO_LIBS $LIBS"
1120         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1121         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1122         AC_SUBST(PANGO_CFLAGS)
1123         AC_SUBST(PANGO_LIBS)
1124 fi
1125 ])
1126
1127
1128 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1129     PKG_CHECK_MODULES(PANGO_FT2, pangoft2 >= 1.6.0, have_pangoft2=true, true)
1130     if $have_pangoft2 ; then
1131         AC_DEFINE(HAVE_PANGO_FT2)
1132         PANGO_FT2_CFLAGS="$PANGO_FT2_CFLAGS $GTK2_CFLAGS"
1133         PANGO_FT2_LIBS="$PANGO_FT2_LIBS $GTK2_LIBS"
1134         CPPFLAGS="$PANGO_FT2_CFLAGS $CPPFLAGS"
1135         LIBS="$PANGO_FT2_LIBS $LIBS"
1136         AC_CHECK_HEADERS([pango/pangoft2.h])
1137         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1138         AC_SUBST(PANGO_FT2_CFLAGS)
1139         AC_SUBST(PANGO_FT2_LIBS)
1140 fi
1141 ])