stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 |
  36                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  37                 head -n 1 |
  38                 tr ' ' '\n' |
  39                 sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' |
  40                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  41                 head -n 1\`\"
  42
  43     if test -z "$_ver"; then
  44         ## If empty, try date [fontforge]
  45         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  46             | head -n 1 \
  47             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  48     fi
  49     echo "$_ver"
  50     changequote([, ])#dnl
  51 ])
  52
  53 # Calculate simplistic numeric version from version string ($1)
  54 # As yet, we have no need for something more elaborate.
  55 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  56     echo "$1" | awk -F. '
  57     {
  58       if ([$]3) {three = [$]3}
  59       else {three = 0}
  60     }
  61     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  62 ])
  63
  64
  65 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  66 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  67     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  68 ])
  69
  70 # Check if tested program ($2) was found ($1).
  71 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  72 # We could abort here if a 'REQUIRED' program is not found
  73 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  74     STEPMAKE_CHECK_SEARCH_RESULT($1)
  75     if test $? -ne 0; then
  76         STEPMAKE_ADD_ENTRY($3, $2)
  77         if test "$3" = "REQUIRED"; then
  78             command="echo ERROR: $2 not found"
  79             # abort configure process here?
  80         else
  81             command="- echo $2 not found"
  82         fi
  83         eval "$1"='$command'
  84         false
  85     else
  86         true
  87     fi
  88 ])
  89
  90
  91 # Return if tested proram ($1) was found (true) or not (false).
  92 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  93     r="`eval echo '$'"$1"`"
  94     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  95         true
  96     else
  97         ##STEPMAKE_WARN(cannot find $2. $3)
  98         false
  99     fi
 100 ])
 101
 102
 103 # Check version of program ($1)
 104 # If version ($4: optional argument, supply if version cannot be
 105 # parsed using --version or -V ) is smaller than requested ($3), add
 106 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 107 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 108     r="`eval echo '$'"$1"`"
 109     AC_MSG_CHECKING([$r version])
 110     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 111     if test -n "$4"; then
 112         ver="$4"
 113     else
 114         ver=`STEPMAKE_GET_VERSION($exe)`
 115     fi
 116     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 117     req=`STEPMAKE_NUMERIC_VERSION($3)`
 118     AC_MSG_RESULT([$ver])
 119     if test "$num" -lt "$req"; then
 120         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 121     fi
 122     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 123     eval `echo $vervar=$num`
 124 ##    AC_SUBST(`eval echo $vervar`)
 125 ])
 126
 127 # Check version of program ($1)
 128 # If version is greater than or equals unsupported ($3),
 129 # add entry to unsupported list ($2, 'UNSUPPORTED')
 130 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 131     r="`eval echo '$'"$1"`"
 132     AC_MSG_CHECKING([$r version])
 133     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 134     ver=`STEPMAKE_GET_VERSION($exe)`
 135     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 136     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 137     AC_MSG_RESULT([$ver])
 138     if test "$num" -ge "$sup"; then
 139         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 140     fi
 141 ])
 142
 143 ### Macros to build configure.in
 144
 145
 146 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 147     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 148     if test "$BIBTEX2HTML" = "bib2html"; then
 149         BIBTEX2HTML_FLAGS='$< $(@)'
 150     else
 151         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 152     fi
 153     AC_SUBST(BIBTEX2HTML)
 154     AC_SUBST(BIBTEX2HTML_FLAGS)
 155 ])
 156
 157
 158 AC_DEFUN(STEPMAKE_BISON, [
 159     # ugh, automake: we want (and check for) bison
 160     AC_PROG_YACC
 161
 162     STEPMAKE_PROGS(BISON, bison, $1)
 163
 164     # urg.  should test functionality rather than version.
 165     if test "$BISON" = "bison" -a -n "$2"; then
 166         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 167     fi
 168 ])
 169
 170 AC_DEFUN(STEPMAKE_COMPILE_BEFORE, [
 171     # -O is necessary to get inlining
 172     CFLAGS=${CFLAGS-""}
 173     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 174     LDFLAGS=${LDFLAGS-""}
 175     optimise_b=yes
 176     profile_b=no
 177     debug_b=yes
 178     pipe_b=yes
 179
 180     AC_ARG_ENABLE(debugging,
 181     [AS_HELP_STRING([--enable-debugging],
 182                     [compile with debugging info.  Default: on])],
 183     [debug_b=$enableval])
 184
 185     AC_ARG_ENABLE(optimising,
 186     [AS_HELP_STRING([--enable-optimising],
 187                     [compile with optimising.  Default: on])],
 188     [optimise_b=$enableval])
 189
 190     AC_ARG_ENABLE(profiling,
 191     [AS_HELP_STRING([--enable-profiling],
 192                     [compile with gprof support.  Default: off])],
 193     [profile_b=$enableval])
 194
 195     AC_ARG_ENABLE(pipe,
 196     [AS_HELP_STRING([--enable-pipe],
 197                     [compile with -pipe.  Default: on])],
 198     [pipe_b=$enableval])
 199
 200     if test "$optimise_b" = yes; then
 201         AC_DEFINE(NDEBUG)
 202         DEFINES="$DEFINES -DNDEBUG"
 203         OPTIMIZE=" -O2 -finline-functions"
 204     fi
 205
 206     if test $profile_b = yes; then
 207         EXTRA_LIBS="-pg"
 208         OPTIMIZE="$OPTIMIZE -pg"
 209     fi
 210
 211     if test $debug_b = yes; then
 212         OPTIMIZE="$OPTIMIZE -g"
 213     fi
 214 ])
 215
 216 AC_DEFUN(STEPMAKE_COMPILE, [
 217
 218     AC_REQUIRE([STEPMAKE_COMPILE_BEFORE])
 219     AC_REQUIRE([AC_PROG_CC])
 220
 221     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 222     LD='$(CC)'
 223     AC_SUBST(LD)
 224
 225     # If -pipe requested, test if it works and add to CFLAGS.
 226     if test "$pipe_b" = yes; then
 227         save_cflags="$CFLAGS"
 228         CFLAGS=" -pipe $CFLAGS";
 229         AC_CACHE_CHECK([whether compiler understands -pipe],
 230             [stepmake_cv_cflags_pipe],
 231             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 232                 [stepmake_cv_cflags_pipe=yes],
 233                 [stepmake_cv_cflags_pipe=no]))
 234         CFLAGS=$save_cflags
 235         if test $stepmake_cv_cflags_pipe = yes; then
 236             OPTIMIZE="$OPTIMIZE -pipe"
 237         fi
 238     fi
 239
 240     CFLAGS="$CFLAGS $OPTIMIZE"
 241     CPPFLAGS=${CPPFLAGS-""}
 242
 243     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 244     save_cflags="$CFLAGS"
 245     case "$host" in
 246         alpha*-*-*)
 247             dnl should do compile test?
 248             AC_MSG_RESULT(-mieee)
 249             CFLAGS=" -mieee $CFLAGS"
 250             ;;
 251         *)
 252             AC_MSG_RESULT([none])
 253             ;;
 254     esac
 255
 256     AC_SUBST(cross_compiling)
 257     AC_SUBST(CFLAGS)
 258     AC_SUBST(CPPFLAGS)
 259     AC_SUBST(LDFLAGS)
 260     AC_SUBST(DEFINES)
 261     AC_SUBST(EXTRA_LIBS)
 262 ])
 263
 264 AC_DEFUN(STEPMAKE_CXX, [
 265     AC_PROG_CXX
 266     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 267
 268     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 269     LD='$(CXX)'
 270
 271     AC_SUBST(CXX)
 272     AC_SUBST(CXXFLAGS)
 273     AC_SUBST(LD)
 274 ])
 275
 276
 277 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 278     AC_CACHE_CHECK([whether explicit instantiation is needed],
 279         stepmake_cv_need_explicit_instantiation,
 280         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 281     template <class T> struct foo { static int baz; };
 282     template <class T> int foo<T>::baz = 1;
 283     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 284     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 285         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 286     fi
 287 ])
 288
 289 AC_DEFUN(STEPMAKE_GXXCODEGENBUG, [
 290     AC_MSG_CHECKING([options for known g++ tail call bug])
 291     case "$GXX:$CXX_VERSION" in
 292         yes:400600?)
 293             AC_MSG_RESULT([-fno-optimize-sibling-calls])
 294             CXXFLAGS="$CXXFLAGS -fno-optimize-sibling-calls"
 295             ;;
 296         *) AC_MSG_RESULT([none])
 297     esac
 298     AC_SUBST(CXXFLAGS)
 299 ])
 300
 301
 302 AC_DEFUN(STEPMAKE_DATADIR, [
 303     if test "$datadir" = "\${prefix}/share"; then
 304             datadir='${prefix}/share'
 305     fi
 306     presome=${prefix}
 307     if test "$prefix" = "NONE"; then
 308         presome=${ac_default_prefix}
 309     fi
 310
 311     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 312
 313     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 314     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 315     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 316
 317     AC_SUBST(datadir)
 318     AC_SUBST(datarootdir)
 319     AC_SUBST(build_package_datadir)
 320     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 321     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 322 ])
 323
 324 ## ugh: cut & paste programming from datadir.
 325 AC_DEFUN(STEPMAKE_LIBDIR, [
 326
 327     if test "$libdir" = "\${exec_prefix}/lib"; then
 328         libdir='${exec_prefix}/lib'
 329     fi
 330     presome=$exec_prefix
 331     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 332
 333     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 334     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 335
 336     AC_SUBST(libdir)
 337     AC_SUBST(build_package_libdir)
 338     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 339     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 340 ])
 341
 342
 343 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 344     # undo expanding of explicit --infodir=/usr/share
 345     # to ease install-time override with prefix=...
 346     strip=`echo $includedir | eval sed s@^$prefix@@`
 347     if test "$includedir" = "`eval echo $prefix$strip`"; then
 348             includedir='${prefix}'$strip''
 349     fi
 350     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 351     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 352             libdir='${exec_prefix}'$strip''
 353     fi
 354     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 355     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 356             infodir='${datarootdir}'$strip''
 357     fi
 358     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 359     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 360             mandir='${datarootdir}'$strip''
 361     fi
 362 ])
 363
 364
 365 AC_DEFUN(STEPMAKE_END, [
 366     STEPMAKE_PREFIX_EXPAND_FIXUP
 367
 368     AC_SUBST(OPTIONAL)
 369     AC_SUBST(REQUIRED)
 370
 371     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 372     AC_OUTPUT
 373
 374     if test -n "$OPTIONAL"; then
 375         echo
 376         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 377     fi
 378
 379     if test -n "$REQUIRED"; then
 380         echo
 381         echo "ERROR: Please install required programs: $REQUIRED"
 382     fi
 383
 384     if test -n "$UNSUPPORTED"; then
 385         echo
 386         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 387     fi
 388
 389     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 390         echo
 391         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 392         if test -f config.cache ; then
 393             echo "Remove config.cache before rerunning ./configure"
 394         fi
 395     fi
 396
 397     if test -n "$REQUIRED$UNSUPPORTED"; then
 398         rm -f $srcdir/GNUmakefile
 399         exit 1
 400     fi
 401
 402     # regular in-place build
 403     # test for srcdir_build = yes ?
 404     if test "$srcdir_build" = "yes"; then
 405         rm -f $srcdir/GNUmakefile
 406         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 407         chmod 444 $srcdir/GNUmakefile
 408     else
 409         if test -f $srcdir/GNUmakefile; then
 410             cat <<EOF
 411 Source directory already configured.  Please clean the source directory
 412
 413      make -C $srcdir distclean
 414
 415 and rerun configure.
 416 EOF
 417             exit 2
 418         fi
 419
 420         for d in 2 3 4 ; do
 421             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name GNUmakefile`; do
 422                 mkdir -p $(dirname $mf)
 423                 cat <<EOF | $PYTHON -  > $mf
 424 print 'depth=' + ('../' * ( $d-1 ) )
 425 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 426 print 'include \$(configure-srcdir)/$mf'
 427 print 'MODULE_INCLUDES += \$(src-dir)/\$(outbase)'
 428 EOF
 429             done
 430             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 431                 mkdir -p $(dirname $mf)
 432                 cat <<EOF | $PYTHON -  > $mf
 433 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 434 print 'include \$(configure-srcdir)/$mf'
 435 EOF
 436             done
 437         done
 438
 439
 440         cat <<EOF > GNUmakefile
 441 depth = .
 442 include config\$(if \$(conf),-\$(conf),).make
 443 include \$(configure-srcdir)/GNUmakefile.in
 444 EOF
 445         AC_SUBST(VPATH)
 446     fi
 447 ])
 448
 449
 450 AC_DEFUN(STEPMAKE_FLEX, [
 451     # ugh, automake: we want (and check for) flex
 452     # AC_PROG_LEX
 453     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 454
 455     # AC_PROG_LEX()
 456     # ugh, ugh
 457     ac_cv_prog_lex_root=lex.yy
 458     STEPMAKE_PROGS(FLEX, flex, $1)
 459 ])
 460
 461
 462 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 463     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 464     if test $? -ne 0; then
 465         warn='FlexLexer.h (flex package)'
 466         STEPMAKE_ADD_ENTRY($1, $warn)
 467     fi
 468     # check for yyFlexLexer.yy_current_buffer,
 469     # in 2.5.4 <= flex < 2.5.29
 470     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 471         [stepmake_cv_flexlexer_yy_current_buffer],
 472         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 473 using namespace std;
 474 #include <FlexLexer.h>
 475 class yy_flex_lexer: public yyFlexLexer
 476 {
 477   public:
 478     yy_flex_lexer ()
 479     {
 480       yy_current_buffer = 0;
 481     }
 482 };
 483 ]])],
 484             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 485             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 486     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 487         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 488     fi
 489 ])
 490
 491
 492
 493 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 494         AC_MSG_CHECKING([FlexLexer.h location])
 495
 496         # ugh.
 497         cat <<EOF > conftest.cc
 498 using namespace std;
 499 #include <FlexLexer.h>
 500 EOF
 501         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 502           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 503           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 504         rm conftest.cc
 505         AC_SUBST(FLEXLEXER_FILE)
 506         AC_MSG_RESULT($FLEXLEXER_FILE)
 507 ])
 508
 509 AC_DEFUN(STEPMAKE_GCC_OR_CLANG, [
 510     STEPMAKE_HAS_CLANG()
 511     if test "$HAS_CLANG" = "no"; then
 512         if test "$GCC" = "yes"; then
 513             STEPMAKE_CHECK_VERSION(CC, $1, $2)
 514         else
 515             warn="$CC (Please install *GNU* cc)"
 516             STEPMAKE_ADD_ENTRY($1, $warn)
 517         fi
 518     fi
 519     # no else, we're fine with any clang
 520 ])
 521
 522 AC_DEFUN(STEPMAKE_GETTEXT, [
 523     presome=${prefix}
 524     if test "$prefix" = "NONE"; then
 525             presome=${ac_default_prefix}
 526     fi
 527     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 528
 529     AC_SUBST(localedir)
 530     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 531     AC_CHECK_LIB(intl, gettext)
 532     AC_CHECK_FUNCS(gettext)
 533 ])
 534
 535
 536 AC_DEFUN(STEPMAKE_GUILE, [
 537     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 538 ])
 539
 540
 541 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 542 #
 543 #   This macro runs the guile-config script, installed with Guile,
 544 #   to find out where Guile's header files and libraries are
 545 #   installed.  It sets two variables, marked for substitution, as
 546 #   by AC_SUBST.
 547 #
 548 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 549 #             code that uses Guile header files.  This is almost
 550 #             always just a -I flag.
 551 #
 552 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 553 #             program against Guile.  This includes -lguile for
 554 #             the Guile library itself, any libraries that Guile
 555 #             itself requires (like -lqthreads), and so on.  It may
 556 #             also include a -L flag to tell the compiler where to
 557 #             find the libraries.
 558
 559 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 560     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 561     if test -x $exe; then
 562         AC_MSG_CHECKING([guile compile flags])
 563         GUILE_CFLAGS="`$guile_config compile`"
 564         AC_MSG_RESULT($GUILE_CFLAGS)
 565         AC_MSG_CHECKING([guile link flags])
 566         GUILE_LDFLAGS="`$guile_config link`"
 567         AC_MSG_RESULT($GUILE_LDFLAGS)
 568     fi
 569     AC_SUBST(GUILE_CFLAGS)
 570     AC_SUBST(GUILE_LDFLAGS)
 571 ])
 572
 573
 574 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 575     ## First, let's just see if we can find Guile at all.
 576     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 577     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 578     AC_MSG_CHECKING([for guile-config])
 579     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config; do
 580         AC_MSG_RESULT([$guile_config])
 581         if ! $guile_config --version > /dev/null 2>&1 ; then
 582             AC_MSG_WARN([cannot execute $guile_config])
 583             AC_MSG_CHECKING([if we are cross compiling])
 584             GUILE_CONFIG='echo no guile-config'
 585         else
 586             GUILE_CONFIG=$guile_config
 587             break
 588         fi
 589     done
 590     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 591     if test $? -ne 0; then
 592         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 593     fi
 594
 595     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 596     # urg.  should test functionality rather than version.
 597     if test $? -eq 0 -a -n "$2"; then
 598         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 599     fi
 600
 601     AC_SUBST(GUILE_CONFIG)
 602
 603     guile_version="$ver"
 604     changequote(<<, >>)#dnl
 605     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 606     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 607     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 608     changequote([, ])#dnl
 609     STEPMAKE_GUILE_FLAGS
 610     save_CPPFLAGS="$CPPFLAGS"
 611     save_LIBS="$LIBS"
 612     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 613     LIBS="$GUILE_LDFLAGS $LIBS"
 614     AC_CHECK_HEADERS([libguile.h])
 615     AC_CHECK_LIB(guile, scm_boot_guile)
 616     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 617     if test "$libguile_b" = "no"; then
 618             warn='libguile (libguile-dev, guile-devel or guile-dev
 619    package).'
 620             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 621     fi
 622     CPPFLAGS="$save_CPPFLAGS"
 623     LIBS="$save_LIBS"
 624     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 625     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 626     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 627 ])
 628
 629
 630 AC_DEFUN(STEPMAKE_DLOPEN, [
 631     AC_CHECK_LIB(dl, dlopen)
 632     AC_CHECK_FUNCS(dlopen)
 633 ])
 634
 635 AC_DEFUN(STEPMAKE_HAS_CLANG, [
 636     AC_EGREP_CPP(yes,
 637       [#ifdef __clang__
 638        yes
 639        #endif
 640       ], HAS_CLANG=yes, HAS_CLANG=no)
 641 ])
 642
 643 AC_DEFUN(STEPMAKE_GXX_OR_CLANG, [
 644     STEPMAKE_HAS_CLANG()
 645     if test "$HAS_CLANG" = "no"; then
 646         if test "$GXX" = "yes"; then
 647             STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 648         else
 649             warn="$CXX (Please install *GNU* c++)"
 650             STEPMAKE_ADD_ENTRY($1, $warn)
 651         fi
 652     fi
 653     # no else, we're fine with any clang
 654 ])
 655
 656
 657 AC_DEFUN(STEPMAKE_INIT, [
 658
 659     . $srcdir/VERSION
 660     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 661     MICRO_VERSION=$PATCH_LEVEL
 662     TOPLEVEL_VERSION=$FULL_VERSION
 663     if test x$MY_PATCH_LEVEL != x; then
 664         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 665     fi
 666     VERSION=$FULL_VERSION
 667     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 668     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 669     changequote(<<, >>)#dnl
 670     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 671     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 672     changequote([, ])#dnl
 673
 674     # No versioning on directory names of sub-packages
 675     # urg, urg
 676     stepmake=${datadir}/stepmake
 677     presome=${prefix}
 678     if test "$prefix" = "NONE"; then
 679             presome=${ac_default_prefix}
 680     fi
 681     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 682
 683     # urg, how is this supposed to work?
 684     if test "$program_prefix" = "NONE"; then
 685           program_prefix=
 686     fi
 687     if test "$program_suffix" = "NONE"; then
 688           program_suffix=
 689     fi
 690
 691     AC_MSG_CHECKING(Package)
 692     if test "$PACKAGE" = "STEPMAKE"; then
 693         AC_MSG_RESULT(Stepmake package!)
 694
 695         AC_MSG_CHECKING(builddir)
 696
 697         ugh_ugh_autoconf250_builddir="`pwd`"
 698
 699         if test "$srcdir" = "."; then
 700             srcdir_build=yes
 701         else
 702             srcdir_build=no
 703             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 704             package_srcdir="`dirname  $srcdir`"
 705         fi
 706         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 707
 708         (cd stepmake 2>/dev/null || mkdir stepmake)
 709         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 710         stepmake=stepmake
 711     else
 712         AC_MSG_RESULT($PACKAGE)
 713
 714         AC_MSG_CHECKING(builddir)
 715         ugh_ugh_autoconf250_builddir="`pwd`"
 716
 717         here_dir=$(cd . && pwd)
 718         full_src_dir=$(cd $srcdir && pwd)
 719
 720         if test "$full_src_dir" = "$here_dir"; then
 721             srcdir_build=yes
 722         else
 723             srcdir_build=no
 724         fi
 725         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 726
 727         AC_MSG_CHECKING(for stepmake)
 728         # Check for installed stepmake
 729         if test -d $stepmake; then
 730             AC_MSG_RESULT($stepmake)
 731         else
 732             stepmake="`cd $srcdir/stepmake; pwd`"
 733             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 734         fi
 735     fi
 736
 737     AC_SUBST(ugh_ugh_autoconf250_builddir)
 738
 739     # Use absolute directory for non-srcdir builds, so that build
 740     # dir can be moved.
 741     if test "$srcdir_build" = "no" ;  then
 742         srcdir="`cd $srcdir; pwd`"
 743     fi
 744
 745     AC_SUBST(srcdir)
 746     AC_SUBST(stepmake)
 747     AC_SUBST(package)
 748     AC_SUBST(PACKAGE)
 749     AC_SUBST(PACKAGE_NAME)
 750     AC_SUBST(VERSION)
 751     AC_SUBST(MAJOR_VERSION)
 752     AC_SUBST(MINOR_VERSION)
 753     AC_SUBST(MICRO_VERSION)
 754
 755     # stepmake nonstandard names
 756     AC_SUBST(PATCH_LEVEL)
 757     AC_SUBST(TOPLEVEL_VERSION)
 758
 759     # We don't need the upper case variant,
 760     # so stick to macros are uppercase convention.
 761     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 762     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 763     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 764     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 765     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 766
 767     if test -z "$package_depth"; then
 768         package_depth="."
 769     else
 770         package_depth="../$package_depth"
 771     fi
 772     export package_depth
 773     AC_SUBST(package_depth)
 774
 775     AUTOGENERATE="This file was automatically generated by configure"
 776     AC_SUBST(AUTOGENERATE)
 777
 778     CONFIGSUFFIX=
 779     AC_ARG_ENABLE(config,
 780     [AS_HELP_STRING([--enable-config=CONF],
 781                     [put settings in config-CONF.make and config-CONF.h;
 782                     do `make conf=CONF' to get output in ./out-CONF])],
 783     [CONFIGURATION=$enableval])
 784
 785     ##'`#
 786
 787     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 788     CONFIGFILE=config$CONFIGSUFFIX
 789     AC_SUBST(CONFIGSUFFIX)
 790
 791     AC_CANONICAL_HOST
 792     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 793     STEPMAKE_PROGS(FIND, find, REQUIRED)
 794
 795     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 796
 797     if test "$(echo 2)" != "2" ||
 798         test "x`uname`" = "xHP-UX"; then
 799         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 800         AC_PATH_PROG(BASH, bash, $KSH)
 801         STEPMAKE_WARN(avoiding buggy /bin/sh)
 802         AC_PATH_PROG(SHELL, bash, $KSH)
 803     else
 804         SHELL=/bin/sh
 805         AC_PATH_PROG(BASH, bash, $SHELL)
 806     fi
 807     AC_SUBST(SHELL)
 808
 809     STEPMAKE_PYTHON(REQUIRED, 1.5)
 810
 811     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 812         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 813         if test "$?" = 1; then
 814             warn='make (Please install *GNU* make)'
 815             # STEPMAKE_WARN($warn)
 816             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 817         fi
 818     fi
 819
 820     ROOTSEP=':'
 821     DIRSEP='/'
 822     PATHSEP=':'
 823     LN=ln
 824     LN_S='ln -s'
 825     ZIP="zip -r -9"
 826
 827     AC_SUBST(program_prefix)
 828     AC_SUBST(program_suffix)
 829     AC_SUBST(ZIP)
 830     AC_SUBST(LN)
 831     AC_SUBST(LN_S)
 832     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 833     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 834     AC_SUBST(DIRSEP)
 835     AC_SUBST(PATHSEP)
 836     AC_SUBST(ROOTSEP)
 837
 838     STEPMAKE_DATADIR
 839     STEPMAKE_LIBDIR
 840 ])
 841
 842
 843 AC_DEFUN(STEPMAKE_LIB, [
 844     STEPMAKE_PROGS(AR, ar, $1)
 845     AC_PROG_RANLIB
 846     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 847 ])
 848
 849
 850 AC_DEFUN(STEPMAKE_LIBTOOL, [
 851     # libtool.info ...
 852     # **Never** try to set library version numbers so that they correspond
 853     # to the release number of your package.  This is an abuse that only
 854     # fosters misunderstanding of the purpose of library versions.
 855
 856     REVISION=$PATCH_LEVEL
 857     # CURRENT=$MINOR_VERSION
 858     CURRENT=`expr $MINOR_VERSION + 1`
 859     # AGE=`expr $MAJOR_VERSION + 1`
 860     AGE=$MAJOR_VERSION
 861     AC_SUBST(CURRENT)
 862     AC_SUBST(REVISION)
 863     AC_SUBST(AGE)
 864 ])
 865
 866
 867 AC_DEFUN(STEPMAKE_LOCALE, [
 868     lang=English
 869     ALL_LINGUAS="en nl"
 870
 871     # with/enable ??
 872     AC_ARG_WITH(localedir,
 873     [AS_HELP_STRING([--with-localedir=DIR],
 874                     [location of locales.  Default: PREFIX/share/locale])],
 875     localedir=$with_localedir,
 876     localedir='${prefix}/share/locale')
 877
 878     AC_ARG_WITH(lang,
 879     [AS_HELP_STRING([--with-lang=LANG],
 880                     [use LANG as language to emit messages])],
 881     language=$with_lang,
 882     language=English)
 883
 884     AC_MSG_CHECKING(language)
 885     case "$language" in
 886       En* | en* | Am* | am* | US* | us*)
 887             lang=English;;
 888       NL | nl | Du* | du* | Ned* | ned*)
 889             lang=Dutch;;
 890       "")
 891             lang=English;;
 892       *)
 893             lang=unknown;;
 894     esac
 895     AC_MSG_RESULT($lang)
 896
 897     if test "$lang" = "unknown" ; then
 898         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 899     fi
 900
 901 ])
 902
 903
 904 AC_DEFUN(STEPMAKE_MAKEINFO, [
 905     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 906 ])
 907
 908
 909 AC_DEFUN(STEPMAKE_MAN, [
 910     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 911     AC_SUBST(GROFF)
 912     STEPMAKE_PROGS(TROFF, troff, $1)
 913     AC_SUBST(TROFF)
 914     STEPMAKE_PROGS(TBL, tbl, $1)
 915     AC_SUBST(TBL)
 916 ])
 917
 918
 919 AC_DEFUN(STEPMAKE_MSGFMT, [
 920     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 921 ])
 922
 923
 924 # Check for program ($2), set full path result to ($1).
 925 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 926 AC_DEFUN(STEPMAKE_PATH_PROG, [
 927     AC_CHECK_PROGS($1, $2, no)
 928     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 929     if test $? -eq 0; then
 930         AC_PATH_PROG($1, $2)
 931         if test -n "$4"; then
 932             STEPMAKE_CHECK_VERSION($1, $3, $4)
 933         fi
 934     fi
 935 ])
 936
 937
 938 # Check for program in set of names ($2), set result to ($1) .
 939 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 940 # If exists, and a minimal version ($4) is required
 941 AC_DEFUN(STEPMAKE_PROGS, [
 942     AC_CHECK_PROGS($1, $2, no)
 943     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 944     if test $? -eq 0 -a -n "$4"; then
 945         STEPMAKE_CHECK_VERSION($1, $3, $4)
 946     fi
 947 ])
 948
 949
 950 AC_DEFUN(STEPMAKE_PERL, [
 951     STEPMAKE_PATH_PROG(PERL, perl, $1)
 952 ])
 953
 954
 955 AC_DEFUN(STEPMAKE_PYTHON, [
 956     unset pv
 957     AC_MSG_CHECKING([for python])
 958     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 959         AC_MSG_RESULT([$python])
 960         if ! $python -V > /dev/null 2>&1 ; then
 961             #AC_MSG_WARN([cannot execute $python])
 962             PYTHON='echo no python'
 963         else
 964             unset pv
 965             STEPMAKE_CHECK_VERSION(python, pv, $2)
 966             if test -z "$pv"; then
 967                 PYTHON=$python
 968                 break
 969             fi
 970         fi
 971     done
 972     if test -n "$pv"; then
 973         STEPMAKE_ADD_ENTRY($1, $pv)
 974     fi
 975     # clear cached value since arg 2 might point us to a new binary
 976     unset ac_cv_path_PYTHON
 977
 978     AC_PATH_PROG(PYTHON, $PYTHON)
 979     AC_SUBST(PYTHON)
 980 ])
 981
 982 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 983     AC_ARG_WITH(python-include,
 984         [AS_HELP_STRING([--with-python-include=DIR],
 985                         [location of the python include dir])],[
 986         if test "$withval" = "yes" -o "$withval" = "no"; then
 987             AC_MSG_WARN(Usage: --with-python-include=includedir)
 988         else
 989             PYTHON_CFLAGS="-I${withval}"
 990         fi
 991     ])
 992
 993     AC_ARG_WITH(python-lib,
 994         [AS_HELP_STRING([--with-python-lib=NAME],
 995                         [name of the python lib])],[
 996         if test "$withval" = "yes" -o "$withval" = "no"; then
 997             AC_MSG_WARN(Usage: --with-python-lib=name)
 998         else
 999             LDFLAGS="$LDFLAGS -l${withval}"
1000         fi
1001     ])
1002
1003     AC_CHECK_PROGS(PYTHON_CONFIG, python-config, no)
1004
1005     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
1006         # Clean out junk: http://bugs.python.org/issue3290
1007         # Python headers may need some -f* flags, leave them in.
1008         # We want the sed commands to look like 's/-[WDOm][[:alnum:][:punct:]][[:alnum:][:punct:]]*//g' and 's/-arch [^[:space:]]*//g', but automake eats brackets.
1009         PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
1010         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
1011     fi
1012
1013     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
1014         changequote(<<, >>)#dnl
1015         # alternatively, for python >= 2.0
1016         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
1017         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
1018         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
1019         changequote([, ])#dnl
1020     fi
1021
1022     if test -z "$PYTHON_HEADER"; then
1023         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
1024         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
1025     fi
1026
1027     if test -z "$PYTHON_HEADER"; then
1028         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1029         STEPMAKE_ADD_ENTRY($1, $warn)
1030     fi
1031 ])
1032
1033
1034
1035 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1036     AC_CACHE_CHECK([for stl.data () method],
1037         [stepmake_cv_stl_data_method],
1038         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1039 #include <vector>
1040 using namespace std;
1041 vector <int> v;
1042 void *p = v.data ();
1043 ]])],
1044             [stepmake_cv_stl_data_method=yes],
1045             [stepmake_cv_stl_data_method=no]))
1046     if test $stepmake_cv_stl_data_method = yes; then
1047         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1048     fi
1049 ])
1050
1051
1052 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1053     # ugh
1054     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1055 ])
1056
1057 AC_DEFUN(STEPMAKE_TEXMF, [
1058     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1059     STEPMAKE_PROGS(METAPOST, mpost, $1)
1060
1061     AC_MSG_CHECKING(for working metafont mode)
1062     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1063     for MFMODE in $modelist; do
1064         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1065         if test -f mfput.tfm; then
1066             break;
1067         fi
1068     done
1069     AC_MSG_RESULT($MFMODE)
1070
1071     rm -f mfput.*
1072
1073     AC_SUBST(MFMODE)
1074 ])
1075
1076
1077 AC_DEFUN(STEPMAKE_WARN, [
1078     AC_MSG_WARN($1)
1079     warn_b=yes
1080 ])
1081
1082
1083 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1084 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1085 dnl also defines GSTUFF_PKG_ERRORS on error
1086 AC_DEFUN(PKG_CHECK_MODULES, [
1087   succeeded=no
1088
1089   if test -z "$PKG_CONFIG"; then
1090     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1091   fi
1092
1093   if test "$PKG_CONFIG" = "no" ; then
1094      echo "*** The pkg-config script could not be found. Make sure it is"
1095      echo "*** in your path, or set the PKG_CONFIG environment variable"
1096      echo "*** to the full path to pkg-config."
1097      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1098   else
1099      PKG_CONFIG_MIN_VERSION=0.9.0
1100      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1101         AC_MSG_CHECKING(for $2)
1102
1103         if $PKG_CONFIG --exists "$2" ; then
1104             AC_MSG_RESULT(yes)
1105             succeeded=yes
1106
1107             AC_MSG_CHECKING($1_CFLAGS)
1108             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1109             AC_MSG_RESULT($$1_CFLAGS)
1110
1111             AC_MSG_CHECKING($1_LIBS)
1112             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1113             AC_MSG_RESULT($$1_LIBS)
1114         else
1115             $1_CFLAGS=""
1116             $1_LIBS=""
1117             ## If we have a custom action on failure, don't print errors, but
1118             ## do set a variable so people can do so.
1119             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1120             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1121         fi
1122
1123         AC_SUBST($1_CFLAGS)
1124         AC_SUBST($1_LIBS)
1125      fi
1126   fi
1127
1128   if test $succeeded = yes; then
1129      ifelse([$3], , :, [$3])
1130   else
1131      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1132   fi
1133 ])
1134
1135 AC_DEFUN(STEPMAKE_FREETYPE2, [
1136     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1137     if test "$have_freetype2" = yes; then
1138         AC_DEFINE(HAVE_FREETYPE2)
1139         save_CPPFLAGS="$CPPFLAGS"
1140         save_LIBS="$LIBS"
1141         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1142         LIBS="$FREETYPE2_LIBS $LIBS"
1143         AC_SUBST(FREETYPE2_CFLAGS)
1144         AC_SUBST(FREETYPE2_LIBS)
1145         CPPFLAGS="$save_CPPFLAGS"
1146         LIBS="$save_LIBS"
1147     else
1148         # UGR
1149         #r="lib$1-dev or $1-devel"
1150         r="libfreetype6-dev or freetype?-devel"
1151         ver="`pkg-config --modversion $1`"
1152         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1153     fi
1154 ])
1155
1156 AC_DEFUN(STEPMAKE_PANGO, [
1157     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1158     if test "$have_pango16" = yes ; then
1159         AC_DEFINE(HAVE_PANGO16)
1160         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1161         save_CPPFLAGS="$CPPFLAGS"
1162         save_LIBS="$LIBS"
1163         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1164         LIBS="$PANGO_LIBS $LIBS"
1165         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1166         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1167         AC_SUBST(PANGO_CFLAGS)
1168         AC_SUBST(PANGO_LIBS)
1169         CPPFLAGS="$save_CPPFLAGS"
1170         LIBS="$save_LIBS"
1171     else
1172         # UGR
1173         #r="lib$1-dev or $1-devel"
1174         r="libpango1.0-dev or pango1.0-devel"
1175         ver="`pkg-config --modversion $1`"
1176         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1177     fi
1178 ])
1179
1180 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1181     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1182     if test "$have_pangoft2" = yes ; then
1183         AC_DEFINE(HAVE_PANGO16)
1184         AC_DEFINE(HAVE_PANGO_FT2)
1185         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1186         save_CPPFLAGS="$CPPFLAGS"
1187         save_LIBS="$LIBS"
1188         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1189         LIBS="$PANGO_FT2_LIBS $LIBS"
1190         AC_CHECK_HEADERS([pango/pangoft2.h])
1191         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1192         AC_SUBST(PANGO_FT2_CFLAGS)
1193         AC_SUBST(PANGO_FT2_LIBS)
1194         CPPFLAGS="$save_CPPFLAGS"
1195         LIBS="$save_LIBS"
1196     else
1197         # UGR
1198         #r="lib$1-dev or $1-devel"e
1199         r="libpango1.0-dev or pango?-devel"
1200         ver="`pkg-config --modversion $1`"
1201         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1202     fi
1203 ])
1204
1205 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1206     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1207     if test "$have_fontconfig" = yes ; then
1208         AC_DEFINE(HAVE_FONTCONFIG)
1209         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1210         save_CPPFLAGS="$CPPFLAGS"
1211         save_LIBS="$LIBS"
1212         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1213         LIBS="$FONTCONFIG_LIBS $LIBS"
1214         AC_SUBST(FONTCONFIG_CFLAGS)
1215         AC_SUBST(FONTCONFIG_LIBS)
1216         CPPFLAGS="$save_CPPFLAGS"
1217         LIBS="$save_LIBS"
1218     else
1219         r="lib$1-dev or $1-devel"
1220         ver="`pkg-config --modversion $1`"
1221         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1222     fi
1223 ])
1224
1225 AC_DEFUN(STEPMAKE_WINDOWS, [
1226     AC_CYGWIN
1227     AC_MINGW32
1228
1229     if test "$CYGWIN" = "yes"; then
1230         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1231         program_suffix=.exe
1232         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1233     elif test "$MINGW32" = "yes"; then
1234         LN='cp -r'
1235         LN_S='cp -r'
1236         program_suffix=.exe
1237         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1238         PATHSEP=';'
1239     fi
1240
1241     AC_SUBST(LN)
1242     AC_SUBST(LN_S)
1243     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1244     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1245     AC_SUBST(DIRSEP)
1246     AC_SUBST(PATHSEP)
1247     AC_SUBST(program_suffix)
1248
1249     AC_MSG_CHECKING([for some flavor of Windows])
1250     if test "$CYGWIN$MINGW32" = "nono"; then
1251         PLATFORM_WINDOWS=no
1252     else
1253         PLATFORM_WINDOWS=yes
1254     fi
1255     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1256     AC_SUBST(PLATFORM_WINDOWS)
1257     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1258     AC_SUBST(WINDRES)
1259 ])