stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 |
  36                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  37                 head -n 1 |
  38                 tr ' ' '\n' |
  39                 sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' |
  40                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  41                 head -n 1\`\"
  42
  43     if test -z "$_ver"; then
  44         ## If empty, try date [fontforge]
  45         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  46             | head -n 1 \
  47             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  48     fi
  49     echo "$_ver"
  50     changequote([, ])#dnl
  51 ])
  52
  53 # Calculate simplistic numeric version from version string ($1)
  54 # As yet, we have no need for something more elaborate.
  55 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  56     echo "$1" | awk -F. '
  57     {
  58       if ([$]3) {three = [$]3}
  59       else {three = 0}
  60     }
  61     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  62 ])
  63
  64
  65 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  66 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  67     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  68 ])
  69
  70 # Check if tested program ($2) was found ($1).
  71 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  72 # We could abort here if a 'REQUIRED' program is not found
  73 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  74     STEPMAKE_CHECK_SEARCH_RESULT($1)
  75     if test $? -ne 0; then
  76         STEPMAKE_ADD_ENTRY($3, $2)
  77         if test "$3" = "REQUIRED"; then
  78             command="echo ERROR: $2 not found"
  79             # abort configure process here?
  80         else
  81             command="- echo $2 not found"
  82         fi
  83         eval "$1"='$command'
  84         false
  85     else
  86         true
  87     fi
  88 ])
  89
  90
  91 # Return if tested proram ($1) was found (true) or not (false).
  92 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  93     r="`eval echo '$'"$1"`"
  94     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  95         true
  96     else
  97         ##STEPMAKE_WARN(cannot find $2. $3)
  98         false
  99     fi
 100 ])
 101
 102
 103 # Check version of program ($1)
 104 # If version ($4: optional argument, supply if version cannot be
 105 # parsed using --version or -V ) is smaller than requested ($3), add
 106 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 107 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 108     r="`eval echo '$'"$1"`"
 109     AC_MSG_CHECKING([$r version])
 110     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 111     if test -n "$4"; then
 112         ver="$4"
 113     else
 114         ver=`STEPMAKE_GET_VERSION($exe)`
 115     fi
 116     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 117     req=`STEPMAKE_NUMERIC_VERSION($3)`
 118     AC_MSG_RESULT([$ver])
 119     if test "$num" -lt "$req"; then
 120         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 121     fi
 122     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 123     eval `echo $vervar=$num`
 124 ##    AC_SUBST(`eval echo $vervar`)
 125 ])
 126
 127 # Check version of program ($1)
 128 # If version is greater than or equals unsupported ($3),
 129 # add entry to unsupported list ($2, 'UNSUPPORTED')
 130 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 131     r="`eval echo '$'"$1"`"
 132     AC_MSG_CHECKING([$r version])
 133     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 134     ver=`STEPMAKE_GET_VERSION($exe)`
 135     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 136     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 137     AC_MSG_RESULT([$ver])
 138     if test "$num" -ge "$sup"; then
 139         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 140     fi
 141 ])
 142
 143 ### Macros to build configure.in
 144
 145
 146 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 147     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 148     if test "$BIBTEX2HTML" = "bib2html"; then
 149         BIBTEX2HTML_FLAGS='$< $(@)'
 150     else
 151         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 152     fi
 153     AC_SUBST(BIBTEX2HTML)
 154     AC_SUBST(BIBTEX2HTML_FLAGS)
 155 ])
 156
 157
 158 AC_DEFUN(STEPMAKE_BISON, [
 159     # ugh, automake: we want (and check for) bison
 160     AC_PROG_YACC
 161
 162     STEPMAKE_PROGS(BISON, bison, $1)
 163
 164     # urg.  should test functionality rather than version.
 165     if test "$BISON" = "bison" -a -n "$2"; then
 166         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 167     fi
 168 ])
 169
 170 AC_DEFUN(STEPMAKE_COMPILE_BEFORE, [
 171     # -O is necessary to get inlining
 172     CFLAGS=${CFLAGS-""}
 173     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 174     LDFLAGS=${LDFLAGS-""}
 175     optimise_b=yes
 176     profile_b=no
 177     debug_b=yes
 178     pipe_b=yes
 179
 180     AC_ARG_ENABLE(debugging,
 181     [  --enable-debugging      compile with debugging info.  Default: on],
 182     [debug_b=$enableval])
 183
 184     AC_ARG_ENABLE(optimising,
 185     [  --enable-optimising     compile with optimising.  Default: on],
 186     [optimise_b=$enableval])
 187
 188     AC_ARG_ENABLE(profiling,
 189     [  --enable-profiling      compile with gprof support.  Default: off],
 190     [profile_b=$enableval])
 191
 192     AC_ARG_ENABLE(pipe,
 193     [  --enable-pipe           compile with -pipe.  Default: on],
 194     [pipe_b=$enableval])
 195
 196     if test "$optimise_b" = yes; then
 197         AC_DEFINE(NDEBUG)
 198         DEFINES="$DEFINES -DNDEBUG"
 199         OPTIMIZE=" -O2 -finline-functions"
 200     fi
 201
 202     if test $profile_b = yes; then
 203         EXTRA_LIBS="-pg"
 204         OPTIMIZE="$OPTIMIZE -pg"
 205     fi
 206
 207     if test $debug_b = yes; then
 208         OPTIMIZE="$OPTIMIZE -g"
 209     fi
 210 ])
 211
 212 AC_DEFUN(STEPMAKE_COMPILE, [
 213
 214     AC_REQUIRE([STEPMAKE_COMPILE_BEFORE])
 215     AC_REQUIRE([AC_PROG_CC])
 216
 217     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 218     LD='$(CC)'
 219     AC_SUBST(LD)
 220
 221     # If -pipe requested, test if it works and add to CFLAGS.
 222     if test "$pipe_b" = yes; then
 223         save_cflags="$CFLAGS"
 224         CFLAGS=" -pipe $CFLAGS";
 225         AC_CACHE_CHECK([whether compiler understands -pipe],
 226             [stepmake_cv_cflags_pipe],
 227             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 228                 [stepmake_cv_cflags_pipe=yes],
 229                 [stepmake_cv_cflags_pipe=no]))
 230         CFLAGS=$save_cflags
 231         if test $stepmake_cv_cflags_pipe = yes; then
 232             OPTIMIZE="$OPTIMIZE -pipe"
 233         fi
 234     fi
 235
 236     CFLAGS="$CFLAGS $OPTIMIZE"
 237     CPPFLAGS=${CPPFLAGS-""}
 238
 239     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 240     save_cflags="$CFLAGS"
 241     case "$host" in
 242         alpha*-*-*)
 243             dnl should do compile test?
 244             AC_MSG_RESULT(-mieee)
 245             CFLAGS=" -mieee $CFLAGS"
 246             ;;
 247         *)
 248             AC_MSG_RESULT([none])
 249             ;;
 250     esac
 251
 252     AC_SUBST(cross_compiling)
 253     AC_SUBST(CFLAGS)
 254     AC_SUBST(CPPFLAGS)
 255     AC_SUBST(LDFLAGS)
 256     AC_SUBST(DEFINES)
 257     AC_SUBST(EXTRA_LIBS)
 258 ])
 259
 260 AC_DEFUN(STEPMAKE_CXX, [
 261     AC_PROG_CXX
 262     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 263
 264     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 265     LD='$(CXX)'
 266
 267     AC_SUBST(CXX)
 268     AC_SUBST(CXXFLAGS)
 269     AC_SUBST(LD)
 270 ])
 271
 272
 273 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 274     AC_CACHE_CHECK([whether explicit instantiation is needed],
 275         stepmake_cv_need_explicit_instantiation,
 276         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 277     template <class T> struct foo { static int baz; };
 278     template <class T> int foo<T>::baz = 1;
 279     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 280     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 281         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 282     fi
 283 ])
 284
 285
 286 AC_DEFUN(STEPMAKE_DATADIR, [
 287     if test "$datadir" = "\${prefix}/share"; then
 288             datadir='${prefix}/share'
 289     fi
 290     presome=${prefix}
 291     if test "$prefix" = "NONE"; then
 292         presome=${ac_default_prefix}
 293     fi
 294
 295     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 296
 297     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 298     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 299     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 300
 301     AC_SUBST(datadir)
 302     AC_SUBST(datarootdir)
 303     AC_SUBST(build_package_datadir)
 304     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 305     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 306 ])
 307
 308 ## ugh: cut & paste programming from datadir.
 309 AC_DEFUN(STEPMAKE_LIBDIR, [
 310
 311     if test "$libdir" = "\${exec_prefix}/lib"; then
 312         libdir='${exec_prefix}/lib'
 313     fi
 314     presome=$exec_prefix
 315     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 316
 317     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 318     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 319
 320     AC_SUBST(libdir)
 321     AC_SUBST(build_package_libdir)
 322     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 323     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 324 ])
 325
 326
 327 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 328     # undo expanding of explicit --infodir=/usr/share
 329     # to ease install-time override with prefix=...
 330     strip=`echo $includedir | eval sed s@^$prefix@@`
 331     if test "$includedir" = "`eval echo $prefix$strip`"; then
 332             includedir='${prefix}'$strip''
 333     fi
 334     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 335     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 336             libdir='${exec_prefix}'$strip''
 337     fi
 338     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 339     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 340             infodir='${datarootdir}'$strip''
 341     fi
 342     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 343     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 344             mandir='${datarootdir}'$strip''
 345     fi
 346 ])
 347
 348
 349 AC_DEFUN(STEPMAKE_END, [
 350     STEPMAKE_PREFIX_EXPAND_FIXUP
 351
 352     AC_SUBST(OPTIONAL)
 353     AC_SUBST(REQUIRED)
 354
 355     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 356     AC_OUTPUT
 357
 358     if test -n "$OPTIONAL"; then
 359         echo
 360         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 361     fi
 362
 363     if test -n "$REQUIRED"; then
 364         echo
 365         echo "ERROR: Please install required programs: $REQUIRED"
 366     fi
 367
 368     if test -n "$UNSUPPORTED"; then
 369         echo
 370         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 371     fi
 372
 373     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 374         echo
 375         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 376         if test -f config.cache ; then
 377             echo "Remove config.cache before rerunning ./configure"
 378         fi
 379     fi
 380
 381     if test -n "$REQUIRED$UNSUPPORTED"; then
 382         rm -f $srcdir/GNUmakefile
 383         exit 1
 384     fi
 385
 386     # regular in-place build
 387     # test for srcdir_build = yes ?
 388     if test "$srcdir_build" = "yes"; then
 389         rm -f $srcdir/GNUmakefile
 390         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 391         chmod 444 $srcdir/GNUmakefile
 392     else
 393         if test -f $srcdir/GNUmakefile; then
 394             cat <<EOF
 395 Source directory already configured.  Please clean the source directory
 396
 397      make -C $srcdir distclean
 398
 399 and rerun configure.
 400 EOF
 401             exit 2
 402         fi
 403
 404         for d in 2 3 4 ; do
 405             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name GNUmakefile`; do
 406                 mkdir -p $(dirname $mf)
 407                 cat <<EOF | $PYTHON -  > $mf
 408 print 'depth=' + ('../' * ( $d-1 ) )
 409 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 410 print 'include \$(configure-srcdir)/$mf'
 411 print 'MODULE_INCLUDES += \$(src-dir)/\$(outbase)'
 412 EOF
 413             done
 414             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 415                 mkdir -p $(dirname $mf)
 416                 cat <<EOF | $PYTHON -  > $mf
 417 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 418 print 'include \$(configure-srcdir)/$mf'
 419 EOF
 420             done
 421         done
 422
 423
 424         cat <<EOF > GNUmakefile
 425 depth = ./
 426 include config\$(if \$(conf),-\$(conf),).make
 427 include \$(configure-srcdir)/GNUmakefile.in
 428 EOF
 429         AC_SUBST(VPATH)
 430     fi
 431 ])
 432
 433
 434 AC_DEFUN(STEPMAKE_FLEX, [
 435     # ugh, automake: we want (and check for) flex
 436     # AC_PROG_LEX
 437     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 438
 439     # AC_PROG_LEX()
 440     # ugh, ugh
 441     ac_cv_prog_lex_root=lex.yy
 442     STEPMAKE_PROGS(FLEX, flex, $1)
 443 ])
 444
 445
 446 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 447     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 448     if test $? -ne 0; then
 449         warn='FlexLexer.h (flex package)'
 450         STEPMAKE_ADD_ENTRY($1, $warn)
 451     fi
 452     # check for yyFlexLexer.yy_current_buffer,
 453     # in 2.5.4 <= flex < 2.5.29
 454     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 455         [stepmake_cv_flexlexer_yy_current_buffer],
 456         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 457 using namespace std;
 458 #include <FlexLexer.h>
 459 class yy_flex_lexer: public yyFlexLexer
 460 {
 461   public:
 462     yy_flex_lexer ()
 463     {
 464       yy_current_buffer = 0;
 465     }
 466 };
 467 ]])],
 468             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 469             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 470     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 471         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 472     fi
 473 ])
 474
 475
 476
 477 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 478         AC_MSG_CHECKING([FlexLexer.h location])
 479
 480         # ugh.
 481         cat <<EOF > conftest.cc
 482 using namespace std;
 483 #include <FlexLexer.h>
 484 EOF
 485         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 486           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 487           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 488         rm conftest.cc
 489         AC_SUBST(FLEXLEXER_FILE)
 490         AC_MSG_RESULT($FLEXLEXER_FILE)
 491 ])
 492
 493 AC_DEFUN(STEPMAKE_GCC, [
 494     if test "$GCC" = "yes"; then
 495         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 496     else
 497         warn="$CC (Please install *GNU* cc)"
 498         STEPMAKE_ADD_ENTRY($1, $warn)
 499     fi
 500 ])
 501
 502 AC_DEFUN(STEPMAKE_GETTEXT, [
 503     presome=${prefix}
 504     if test "$prefix" = "NONE"; then
 505             presome=${ac_default_prefix}
 506     fi
 507     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 508
 509     AC_SUBST(localedir)
 510     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 511     # ouch.  autoconf <= 2.57's gettext check fails for
 512     # g++ >= 3.3 (with -std=gnu++98, the default).
 513     # While the check is OK for g++ -std=c++98,
 514     # LilyPond needs GNU g++, so who is to blame here?
 515     # Use a workaround until this is resolved:
 516     # for g++ >= 3.3, select C language.
 517     GCC_UNSUPPORTED=
 518     STEPMAKE_CHECK_VERSION_UNSUPPORTED(CXX, GCC_UNSUPPORTED, 3.3)
 519     if test -n "$GCC_UNSUPPORTED"; then
 520         AC_MSG_WARN([autoconf <= 2.59 with g++ >= 3.3 gettext test broken.])
 521         AC_MSG_WARN([Trying gcc, cross fingers.])
 522         AC_LANG_PUSH(C)
 523     fi
 524     AC_CHECK_LIB(intl, gettext)
 525     AC_CHECK_FUNCS(gettext)
 526     if test -n "$GCC_UNSUPPORTED"; then
 527         AC_LANG_POP(C)
 528     fi
 529 ])
 530
 531
 532 AC_DEFUN(STEPMAKE_GUILE, [
 533     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 534 ])
 535
 536
 537 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 538 #
 539 #   This macro runs the guile-config script, installed with Guile,
 540 #   to find out where Guile's header files and libraries are
 541 #   installed.  It sets two variables, marked for substitution, as
 542 #   by AC_SUBST.
 543 #
 544 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 545 #             code that uses Guile header files.  This is almost
 546 #             always just a -I flag.
 547 #
 548 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 549 #             program against Guile.  This includes -lguile for
 550 #             the Guile library itself, any libraries that Guile
 551 #             itself requires (like -lqthreads), and so on.  It may
 552 #             also include a -L flag to tell the compiler where to
 553 #             find the libraries.
 554
 555 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 556     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 557     if test -x $exe; then
 558         AC_MSG_CHECKING([guile compile flags])
 559         GUILE_CFLAGS="`$guile_config compile`"
 560         AC_MSG_RESULT($GUILE_CFLAGS)
 561         AC_MSG_CHECKING([guile link flags])
 562         GUILE_LDFLAGS="`$guile_config link`"
 563         AC_MSG_RESULT($GUILE_LDFLAGS)
 564     fi
 565     AC_SUBST(GUILE_CFLAGS)
 566     AC_SUBST(GUILE_LDFLAGS)
 567 ])
 568
 569
 570 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 571     ## First, let's just see if we can find Guile at all.
 572     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 573     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 574     AC_MSG_CHECKING([for guile-config])
 575     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config; do
 576         AC_MSG_RESULT([$guile_config])
 577         if ! $guile_config --version > /dev/null 2>&1 ; then
 578             AC_MSG_WARN([cannot execute $guile_config])
 579             AC_MSG_CHECKING([if we are cross compiling])
 580             GUILE_CONFIG='echo no guile-config'
 581         else
 582             GUILE_CONFIG=$guile_config
 583             break
 584         fi
 585     done
 586     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 587     if test $? -ne 0; then
 588         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 589     fi
 590
 591     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 592     # urg.  should test functionality rather than version.
 593     if test $? -eq 0 -a -n "$2"; then
 594         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 595     fi
 596
 597     AC_SUBST(GUILE_CONFIG)
 598
 599     guile_version="$ver"
 600     changequote(<<, >>)#dnl
 601     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 602     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 603     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 604     changequote([, ])#dnl
 605     STEPMAKE_GUILE_FLAGS
 606     save_CPPFLAGS="$CPPFLAGS"
 607     save_LIBS="$LIBS"
 608     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 609     LIBS="$GUILE_LDFLAGS $LIBS"
 610     AC_CHECK_HEADERS([libguile.h])
 611     AC_CHECK_LIB(guile, scm_boot_guile)
 612     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 613     if test "$libguile_b" = "no"; then
 614             warn='libguile (libguile-dev, guile-devel or guile-dev
 615    package).'
 616             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 617     fi
 618     CPPFLAGS="$save_CPPFLAGS"
 619     LIBS="$save_LIBS"
 620     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 621     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 622     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 623 ])
 624
 625
 626 AC_DEFUN(STEPMAKE_DLOPEN, [
 627     AC_CHECK_LIB(dl, dlopen)
 628     AC_CHECK_FUNCS(dlopen)
 629 ])
 630
 631 AC_DEFUN(STEPMAKE_GXX, [
 632     if test "$GXX" = "yes"; then
 633         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 634     else
 635         warn="$CXX (Please install *GNU* c++)"
 636         STEPMAKE_ADD_ENTRY($1, $warn)
 637     fi
 638 ])
 639
 640
 641 AC_DEFUN(STEPMAKE_INIT, [
 642
 643     . $srcdir/VERSION
 644     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 645     MICRO_VERSION=$PATCH_LEVEL
 646     TOPLEVEL_VERSION=$FULL_VERSION
 647     if test x$MY_PATCH_LEVEL != x; then
 648         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 649     fi
 650     VERSION=$FULL_VERSION
 651     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 652     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 653     changequote(<<, >>)#dnl
 654     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 655     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 656     changequote([, ])#dnl
 657
 658     # No versioning on directory names of sub-packages
 659     # urg, urg
 660     stepmake=${datadir}/stepmake
 661     presome=${prefix}
 662     if test "$prefix" = "NONE"; then
 663             presome=${ac_default_prefix}
 664     fi
 665     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 666
 667     # urg, how is this supposed to work?
 668     if test "$program_prefix" = "NONE"; then
 669           program_prefix=
 670     fi
 671     if test "$program_suffix" = "NONE"; then
 672           program_suffix=
 673     fi
 674
 675     AC_MSG_CHECKING(Package)
 676     if test "$PACKAGE" = "STEPMAKE"; then
 677         AC_MSG_RESULT(Stepmake package!)
 678
 679         AC_MSG_CHECKING(builddir)
 680
 681         ugh_ugh_autoconf250_builddir="`pwd`"
 682
 683         if test "$srcdir" = "."; then
 684             srcdir_build=yes
 685         else
 686             srcdir_build=no
 687             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 688             package_srcdir="`dirname  $srcdir`"
 689         fi
 690         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 691
 692         (cd stepmake 2>/dev/null || mkdir stepmake)
 693         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 694         stepmake=stepmake
 695     else
 696         AC_MSG_RESULT($PACKAGE)
 697
 698         AC_MSG_CHECKING(builddir)
 699         ugh_ugh_autoconf250_builddir="`pwd`"
 700
 701         here_dir=$(cd . && pwd)
 702         full_src_dir=$(cd $srcdir && pwd)
 703
 704         if test "$full_src_dir" = "$here_dir"; then
 705             srcdir_build=yes
 706         else
 707             srcdir_build=no
 708         fi
 709         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 710
 711         AC_MSG_CHECKING(for stepmake)
 712         # Check for installed stepmake
 713         if test -d $stepmake; then
 714             AC_MSG_RESULT($stepmake)
 715         else
 716             stepmake="`cd $srcdir/stepmake; pwd`"
 717             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 718         fi
 719     fi
 720
 721     AC_SUBST(ugh_ugh_autoconf250_builddir)
 722
 723     # Use absolute directory for non-srcdir builds, so that build
 724     # dir can be moved.
 725     if test "$srcdir_build" = "no" ;  then
 726         srcdir="`cd $srcdir; pwd`"
 727     fi
 728
 729     AC_SUBST(srcdir)
 730     AC_SUBST(stepmake)
 731     AC_SUBST(package)
 732     AC_SUBST(PACKAGE)
 733     AC_SUBST(PACKAGE_NAME)
 734     AC_SUBST(VERSION)
 735     AC_SUBST(MAJOR_VERSION)
 736     AC_SUBST(MINOR_VERSION)
 737     AC_SUBST(MICRO_VERSION)
 738
 739     # stepmake nonstandard names
 740     AC_SUBST(PATCH_LEVEL)
 741     AC_SUBST(TOPLEVEL_VERSION)
 742
 743     # We don't need the upper case variant,
 744     # so stick to macros are uppercase convention.
 745     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 746     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 747     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 748     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 749     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 750
 751     if test -z "$package_depth"; then
 752         package_depth="."
 753     else
 754         package_depth="../$package_depth"
 755     fi
 756     export package_depth
 757     AC_SUBST(package_depth)
 758
 759     AUTOGENERATE="This file was automatically generated by configure"
 760     AC_SUBST(AUTOGENERATE)
 761
 762     CONFIGSUFFIX=
 763     AC_ARG_ENABLE(config,
 764     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 765                             do `make conf=CONF' to get output in ./out-CONF],
 766     [CONFIGURATION=$enableval])
 767
 768     ##'`#
 769
 770     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 771     CONFIGFILE=config$CONFIGSUFFIX
 772     AC_SUBST(CONFIGSUFFIX)
 773
 774     AC_CANONICAL_HOST
 775     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 776     STEPMAKE_PROGS(FIND, find, REQUIRED)
 777
 778     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 779
 780     if test "$(echo 2)" != "2" ||
 781         test "x`uname`" = "xHP-UX"; then
 782         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 783         AC_PATH_PROG(BASH, bash, $KSH)
 784         STEPMAKE_WARN(avoiding buggy /bin/sh)
 785         AC_PATH_PROG(SHELL, bash, $KSH)
 786     else
 787         SHELL=/bin/sh
 788         AC_PATH_PROG(BASH, bash, $SHELL)
 789     fi
 790     AC_SUBST(SHELL)
 791
 792     STEPMAKE_PYTHON(REQUIRED, 1.5)
 793
 794     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 795         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 796         if test "$?" = 1; then
 797             warn='make (Please install *GNU* make)'
 798             # STEPMAKE_WARN($warn)
 799             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 800         fi
 801     fi
 802
 803     ROOTSEP=':'
 804     DIRSEP='/'
 805     PATHSEP=':'
 806     LN=ln
 807     LN_S='ln -s'
 808     ZIP="zip -r -9"
 809
 810     AC_SUBST(program_prefix)
 811     AC_SUBST(program_suffix)
 812     AC_SUBST(ZIP)
 813     AC_SUBST(LN)
 814     AC_SUBST(LN_S)
 815     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 816     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 817     AC_SUBST(DIRSEP)
 818     AC_SUBST(PATHSEP)
 819     AC_SUBST(ROOTSEP)
 820
 821     STEPMAKE_DATADIR
 822     STEPMAKE_LIBDIR
 823 ])
 824
 825
 826 AC_DEFUN(STEPMAKE_LIB, [
 827     STEPMAKE_PROGS(AR, ar, $1)
 828     AC_PROG_RANLIB
 829     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 830 ])
 831
 832
 833 AC_DEFUN(STEPMAKE_LIBTOOL, [
 834     # libtool.info ...
 835     # **Never** try to set library version numbers so that they correspond
 836     # to the release number of your package.  This is an abuse that only
 837     # fosters misunderstanding of the purpose of library versions.
 838
 839     REVISION=$PATCH_LEVEL
 840     # CURRENT=$MINOR_VERSION
 841     CURRENT=`expr $MINOR_VERSION + 1`
 842     # AGE=`expr $MAJOR_VERSION + 1`
 843     AGE=$MAJOR_VERSION
 844     AC_SUBST(CURRENT)
 845     AC_SUBST(REVISION)
 846     AC_SUBST(AGE)
 847 ])
 848
 849
 850 AC_DEFUN(STEPMAKE_LOCALE, [
 851     lang=English
 852     ALL_LINGUAS="en nl"
 853
 854     # with/enable ??
 855     AC_ARG_WITH(localedir,
 856     [  --with-localedir=DIR    location of locales.  Default: PREFIX/share/locale ],
 857     localedir=$with_localedir,
 858     localedir='${prefix}/share/locale')
 859
 860     AC_ARG_WITH(lang,
 861     [  --with-lang=LANG        use LANG as language to emit messages],
 862     language=$with_lang,
 863     language=English)
 864
 865     AC_MSG_CHECKING(language)
 866     case "$language" in
 867       En* | en* | Am* | am* | US* | us*)
 868             lang=English;;
 869       NL | nl | Du* | du* | Ned* | ned*)
 870             lang=Dutch;;
 871       "")
 872             lang=English;;
 873       *)
 874             lang=unknown;;
 875     esac
 876     AC_MSG_RESULT($lang)
 877
 878     if test "$lang" = "unknown" ; then
 879         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 880     fi
 881
 882 ])
 883
 884
 885 AC_DEFUN(STEPMAKE_MAKEINFO, [
 886     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 887 ])
 888
 889
 890 AC_DEFUN(STEPMAKE_MAN, [
 891     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 892     AC_SUBST(GROFF)
 893     STEPMAKE_PROGS(TROFF, troff, $1)
 894     AC_SUBST(TROFF)
 895     STEPMAKE_PROGS(TBL, tbl, $1)
 896     AC_SUBST(TBL)
 897 ])
 898
 899
 900 AC_DEFUN(STEPMAKE_MSGFMT, [
 901     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 902 ])
 903
 904
 905 # Check for program ($2), set full path result to ($1).
 906 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 907 AC_DEFUN(STEPMAKE_PATH_PROG, [
 908     AC_CHECK_PROGS($1, $2, no)
 909     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 910     if test $? -eq 0; then
 911         AC_PATH_PROG($1, $2)
 912         if test -n "$4"; then
 913             STEPMAKE_CHECK_VERSION($1, $3, $4)
 914         fi
 915     fi
 916 ])
 917
 918
 919 # Check for program in set of names ($2), set result to ($1) .
 920 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 921 # If exists, and a minimal version ($4) is required
 922 AC_DEFUN(STEPMAKE_PROGS, [
 923     AC_CHECK_PROGS($1, $2, no)
 924     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 925     if test $? -eq 0 -a -n "$4"; then
 926         STEPMAKE_CHECK_VERSION($1, $3, $4)
 927     fi
 928 ])
 929
 930
 931 AC_DEFUN(STEPMAKE_PERL, [
 932     STEPMAKE_PATH_PROG(PERL, perl, $1)
 933 ])
 934
 935
 936 AC_DEFUN(STEPMAKE_PYTHON, [
 937     unset pv
 938     AC_MSG_CHECKING([for python])
 939     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 940         AC_MSG_RESULT([$python])
 941         if ! $python -V > /dev/null 2>&1 ; then
 942             #AC_MSG_WARN([cannot execute $python])
 943             PYTHON='echo no python'
 944         else
 945             unset pv
 946             STEPMAKE_CHECK_VERSION(python, pv, $2)
 947             if test -z "$pv"; then
 948                 PYTHON=$python
 949                 break
 950             fi
 951         fi
 952     done
 953     if test -n "$pv"; then
 954         STEPMAKE_ADD_ENTRY($1, $pv)
 955     fi
 956     # clear cached value since arg 2 might point us to a new binary
 957     unset ac_cv_path_PYTHON
 958
 959     AC_PATH_PROG(PYTHON, $PYTHON)
 960     AC_SUBST(PYTHON)
 961 ])
 962
 963 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 964     AC_ARG_WITH(python-include,
 965         [  --with-python-include=DIR
 966                           location of the python include dir],[
 967             if test "$withval" = "yes" -o "$withval" = "no"; then
 968                 AC_MSG_WARN(Usage: --with-python-include=includedir)
 969             else
 970                 PYTHON_CFLAGS="-I${withval}"
 971             fi
 972             ])
 973
 974     AC_ARG_WITH(python-lib,
 975         [  --with-python-lib=NAME  name of the python lib],[
 976             if test "$withval" = "yes" -o "$withval" = "no"; then
 977                 AC_MSG_WARN(Usage: --with-python-lib=name)
 978             else
 979                 LDFLAGS="$LDFLAGS -l${withval}"
 980             fi
 981             ])
 982
 983     AC_CHECK_PROGS(PYTHON_CONFIG, python-config, no)
 984
 985     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
 986         # Clean out junk: http://bugs.python.org/issue3290
 987         # Python headers may need some -f* flags, leave them in.
 988         # We want the sed commands to look like 's/-[WDOm][[:alnum:][:punct:]][[:alnum:][:punct:]]*//g' and 's/-arch [^[:space:]]*//g', but automake eats brackets.
 989         PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
 990         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 991     fi
 992
 993     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
 994         changequote(<<, >>)#dnl
 995         # alternatively, for python >= 2.0
 996         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
 997         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
 998         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
 999         changequote([, ])#dnl
1000     fi
1001
1002     if test -z "$PYTHON_HEADER"; then
1003         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
1004         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
1005     fi
1006
1007     if test -z "$PYTHON_HEADER"; then
1008         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1009         STEPMAKE_ADD_ENTRY($1, $warn)
1010     fi
1011 ])
1012
1013
1014
1015 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1016     AC_CACHE_CHECK([for stl.data () method],
1017         [stepmake_cv_stl_data_method],
1018         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1019 #include <vector>
1020 using namespace std;
1021 vector <int> v;
1022 void *p = v.data ();
1023 ]])],
1024             [stepmake_cv_stl_data_method=yes],
1025             [stepmake_cv_stl_data_method=no]))
1026     if test $stepmake_cv_stl_data_method = yes; then
1027         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1028     fi
1029 ])
1030
1031
1032 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1033     # ugh
1034     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1035 ])
1036
1037 AC_DEFUN(STEPMAKE_TEXMF, [
1038     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1039     STEPMAKE_PROGS(METAPOST, mpost, $1)
1040
1041     AC_MSG_CHECKING(for working metafont mode)
1042     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1043     for MFMODE in $modelist; do
1044         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1045         if test -f mfput.tfm; then
1046             break;
1047         fi
1048     done
1049     AC_MSG_RESULT($MFMODE)
1050
1051     rm -f mfput.*
1052
1053     AC_SUBST(MFMODE)
1054 ])
1055
1056
1057 AC_DEFUN(STEPMAKE_WARN, [
1058     AC_MSG_WARN($1)
1059     warn_b=yes
1060 ])
1061
1062
1063 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1064 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1065 dnl also defines GSTUFF_PKG_ERRORS on error
1066 AC_DEFUN(PKG_CHECK_MODULES, [
1067   succeeded=no
1068
1069   if test -z "$PKG_CONFIG"; then
1070     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1071   fi
1072
1073   if test "$PKG_CONFIG" = "no" ; then
1074      echo "*** The pkg-config script could not be found. Make sure it is"
1075      echo "*** in your path, or set the PKG_CONFIG environment variable"
1076      echo "*** to the full path to pkg-config."
1077      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1078   else
1079      PKG_CONFIG_MIN_VERSION=0.9.0
1080      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1081         AC_MSG_CHECKING(for $2)
1082
1083         if $PKG_CONFIG --exists "$2" ; then
1084             AC_MSG_RESULT(yes)
1085             succeeded=yes
1086
1087             AC_MSG_CHECKING($1_CFLAGS)
1088             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1089             AC_MSG_RESULT($$1_CFLAGS)
1090
1091             AC_MSG_CHECKING($1_LIBS)
1092             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1093             AC_MSG_RESULT($$1_LIBS)
1094         else
1095             $1_CFLAGS=""
1096             $1_LIBS=""
1097             ## If we have a custom action on failure, don't print errors, but
1098             ## do set a variable so people can do so.
1099             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1100             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1101         fi
1102
1103         AC_SUBST($1_CFLAGS)
1104         AC_SUBST($1_LIBS)
1105      fi
1106   fi
1107
1108   if test $succeeded = yes; then
1109      ifelse([$3], , :, [$3])
1110   else
1111      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1112   fi
1113 ])
1114
1115 AC_DEFUN(STEPMAKE_FREETYPE2, [
1116     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1117     if test "$have_freetype2" = yes; then
1118         AC_DEFINE(HAVE_FREETYPE2)
1119         save_CPPFLAGS="$CPPFLAGS"
1120         save_LIBS="$LIBS"
1121         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1122         LIBS="$FREETYPE2_LIBS $LIBS"
1123         AC_SUBST(FREETYPE2_CFLAGS)
1124         AC_SUBST(FREETYPE2_LIBS)
1125         CPPFLAGS="$save_CPPFLAGS"
1126         LIBS="$save_LIBS"
1127     else
1128         # UGR
1129         #r="lib$1-dev or $1-devel"
1130         r="libfreetype6-dev or freetype?-devel"
1131         ver="`pkg-config --modversion $1`"
1132         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1133     fi
1134 ])
1135
1136 AC_DEFUN(STEPMAKE_PANGO, [
1137     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1138     if test "$have_pango16" = yes ; then
1139         AC_DEFINE(HAVE_PANGO16)
1140         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1141         save_CPPFLAGS="$CPPFLAGS"
1142         save_LIBS="$LIBS"
1143         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1144         LIBS="$PANGO_LIBS $LIBS"
1145         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1146         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1147         AC_SUBST(PANGO_CFLAGS)
1148         AC_SUBST(PANGO_LIBS)
1149         CPPFLAGS="$save_CPPFLAGS"
1150         LIBS="$save_LIBS"
1151     else
1152         # UGR
1153         #r="lib$1-dev or $1-devel"
1154         r="libpango1.0-dev or pango1.0-devel"
1155         ver="`pkg-config --modversion $1`"
1156         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1157     fi
1158 ])
1159
1160 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1161     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1162     if test "$have_pangoft2" = yes ; then
1163         AC_DEFINE(HAVE_PANGO16)
1164         AC_DEFINE(HAVE_PANGO_FT2)
1165         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1166         save_CPPFLAGS="$CPPFLAGS"
1167         save_LIBS="$LIBS"
1168         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1169         LIBS="$PANGO_FT2_LIBS $LIBS"
1170         AC_CHECK_HEADERS([pango/pangoft2.h])
1171         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1172         AC_SUBST(PANGO_FT2_CFLAGS)
1173         AC_SUBST(PANGO_FT2_LIBS)
1174         CPPFLAGS="$save_CPPFLAGS"
1175         LIBS="$save_LIBS"
1176     else
1177         # UGR
1178         #r="lib$1-dev or $1-devel"e
1179         r="libpango1.0-dev or pango?-devel"
1180         ver="`pkg-config --modversion $1`"
1181         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1182     fi
1183 ])
1184
1185 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1186     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1187     if test "$have_fontconfig" = yes ; then
1188         AC_DEFINE(HAVE_FONTCONFIG)
1189         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1190         save_CPPFLAGS="$CPPFLAGS"
1191         save_LIBS="$LIBS"
1192         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1193         LIBS="$FONTCONFIG_LIBS $LIBS"
1194         AC_SUBST(FONTCONFIG_CFLAGS)
1195         AC_SUBST(FONTCONFIG_LIBS)
1196         CPPFLAGS="$save_CPPFLAGS"
1197         LIBS="$save_LIBS"
1198     else
1199         r="lib$1-dev or $1-devel"
1200         ver="`pkg-config --modversion $1`"
1201         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1202     fi
1203 ])
1204
1205 AC_DEFUN(STEPMAKE_WINDOWS, [
1206     AC_CYGWIN
1207     AC_MINGW32
1208
1209     if test "$CYGWIN" = "yes"; then
1210         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1211         program_suffix=.exe
1212         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1213     elif test "$MINGW32" = "yes"; then
1214         LN='cp -r'
1215         LN_S='cp -r'
1216         program_suffix=.exe
1217         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1218         PATHSEP=';'
1219     fi
1220
1221     AC_SUBST(LN)
1222     AC_SUBST(LN_S)
1223     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1224     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1225     AC_SUBST(DIRSEP)
1226     AC_SUBST(PATHSEP)
1227     AC_SUBST(program_suffix)
1228
1229     AC_MSG_CHECKING([for some flavor of Windows])
1230     if test "$CYGWIN$MINGW32" = "nono"; then
1231         PLATFORM_WINDOWS=no
1232     else
1233         PLATFORM_WINDOWS=yes
1234     fi
1235     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1236     AC_SUBST(PLATFORM_WINDOWS)
1237     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1238     AC_SUBST(WINDRES)
1239 ])