stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4 AC_DEFUN(AC_STEPMAKE_COMPILE, [
   5     # -O is necessary to get inlining
   6     OPTIMIZE=""
   7     CXXFLAGS=${CXXFLAGS:-""}
   8     CFLAGS=${CFLAGS:-""}
   9     checking_b=yes
  10     optimise_b=no
  11     profile_b=no
  12     debug_b=yes
  13
  14     AC_ARG_ENABLE(checking,
  15     [  enable-checking         set runtime checks (assert calls). Default: on],
  16     [checking_b=$enableval] )
  17
  18     # actually, the default is: tja='-O' to get inlining...
  19     # off=''  --jcn
  20
  21     #actually, that sucks.
  22     #  tja looks like a typo.  Default is optimisation off. --hwn
  23
  24     AC_ARG_ENABLE(optimise,
  25     [  enable-optimise         use maximal speed optimisations. Default: off],
  26     [optimise_b=$enableval])
  27
  28     AC_ARG_ENABLE(profiling,
  29     [  enable-profiling        compile with gprof support. Default: off],
  30     [profile_b=$enableval])
  31
  32     AC_ARG_ENABLE(debugging,
  33     [  enable-debugging        set debug info. Default: on],
  34     [debug_b=$enableval])
  35
  36     AC_ARG_ENABLE(mingw-prefix,
  37     [  enable-mingw-prefix=DIR set the mingw32 directory (standalone windows32 exes)],
  38     [MINGWPREFIX=$enableval],
  39     [MINGWPREFIX=no])
  40
  41     if test "$printing_b" = no; then
  42         # ugh
  43         AC_DEFINE(NPRINT)
  44         DEFINES="$DEFINES -DNPRINT"
  45     fi
  46
  47     if test "$checking_b" = no; then
  48         # ugh
  49         AC_DEFINE(NDEBUG)
  50         DEFINES="$DEFINES -DNDEBUG"
  51     fi
  52
  53     if test "$optimise_b" = yes; then
  54         OPTIMIZE="-O2 -finline-functions"
  55     fi
  56
  57     if test "$optimise_b" = no; then
  58         OPTIMIZE=""
  59     fi
  60
  61     if test $profile_b = yes; then
  62         EXTRA_LIBES="-pg"
  63         OPTIMIZE="$OPTIMIZE -pg"
  64     fi
  65
  66     if test $debug_b = yes; then
  67         OPTIMIZE="$OPTIMIZE -g"
  68     fi
  69
  70     # however, C++ support in mingw32 v 0.1.4 is still flaky
  71     if test x$MINGWPREFIX != xno; then
  72         ICFLAGS="-I$MINGWPREFIX/include"
  73         ILDFLAGS="-$MINGWPREFIX/lib"
  74     fi
  75
  76     AC_PROG_CC
  77     LD='$(CC)'
  78     AC_SUBST(LD)
  79
  80     CPPFLAGS=${CPPFLAGS:-""}
  81     AC_SUBST(CPPFLAGS)
  82     AC_SUBST(LDFLAGS)
  83     AC_SUBST(ICFLAGS)
  84     AC_SUBST(ILDFLAGS)
  85     AC_SUBST(DEFINES)
  86     AC_SUBST(EXTRA_LIBES)
  87 ])
  88
  89 AC_DEFUN(AC_STEPMAKE_CXX, [
  90     AC_LANG_CPLUSPLUS
  91     AC_PROG_CXX
  92
  93     AC_CHECK_HEADER(FlexLexer.h, true,
  94         AC_STEPMAKE_WARN(can"\'"t find flex header. Please install Flex headers correctly))
  95
  96     CPPFLAGS="$CPPFLAGS $DEFINES"
  97     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
  98     LDFLAGS=$EXTRA_LIBES
  99
 100     AC_SUBST(CXXFLAGS)
 101     AC_SUBST(CXX)
 102     LD='$(CXX)'
 103     AC_SUBST(LD)
 104 ])
 105
 106 AC_DEFUN(AC_STEPMAKE_CXXTEMPLATE, [
 107     AC_CACHE_CHECK([whether explicit instantiation is needed],
 108         lily_cv_need_explicit_instantiation,
 109         AC_TRY_LINK([
 110     template <class T> struct foo { static int baz; };
 111     template <class T> int foo<T>::baz = 1;
 112     ], [ return foo<int>::baz; ],
 113             lily_cv_need_explicit_instantiation=no,
 114             lily_cv_need_explicit_instantiation=yes))
 115     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 116         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 117     fi
 118 ])
 119
 120 AC_DEFUN(AC_STEPMAKE_DATADIR, [
 121     if test "$datadir" = "\${prefix}/share"; then
 122             datadir='${prefix}/share/'$package
 123     fi
 124     DIR_DATADIR=${datadir}
 125     presome=${prefix}
 126     if test "$prefix" = "NONE"; then
 127             presome=${ac_default_prefix}
 128     fi
 129     DIR_DATADIR=`echo ${DIR_DATADIR} | sed "s!\\\${prefix}!$presome!"`
 130     AC_SUBST(datadir)
 131     AC_SUBST(DIR_DATADIR)
 132     AC_DEFINE_UNQUOTED(DIR_DATADIR, "${DIR_DATADIR}")
 133 ])
 134
 135 AC_DEFUN(AC_STEPMAKE_END, [
 136     AC_OUTPUT($CONFIGFILE.make:config.make.in)
 137
 138     rm -f GNUmakefile
 139     cp make/toplevel.make.in ./GNUmakefile
 140     chmod 444 GNUmakefile
 141 ])
 142
 143 AC_DEFUN(AC_STEPMAKE_GXX, [
 144     # ugh autoconf
 145     changequote(<<, >>)dnl
 146     if $CXX --version | grep '2\.[78]' > /dev/null ||
 147         $CXX --version | grep 'egcs' > /dev/null
 148     changequote([, ])dnl
 149     then
 150             true
 151     else
 152             AC_STEPMAKE_WARN(can\'t find g++ 2.7, 2.8 or egcs)
 153     fi
 154 ])
 155
 156 AC_DEFUN(AC_STEPMAKE_INIT, [
 157
 158     . $srcdir/VERSION
 159     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 160     if test x$MY_PATCH_LEVEL != x; then
 161         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 162     fi
 163
 164     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 165     changequote(<<, >>)dnl
 166     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 167     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 168     changequote([, ])dnl
 169
 170     if test "x$PACKAGE" = "xSTEPMAKE"; then
 171         echo Stepmake package!
 172         (cd stepmake; rm -f stepmake; ln -s ../stepmake .)
 173         (cd stepmake; rm -f bin; ln -s ../bin .)
 174         AC_CONFIG_AUX_DIR(bin)
 175     else
 176         echo Package: $PACKAGE
 177         AC_CONFIG_AUX_DIR(stepmake/bin)
 178     fi
 179
 180     AC_SUBST(package)
 181     AC_SUBST(PACKAGE)
 182     AC_SUBST(PACKAGE_NAME)
 183     AC_DEFINE_UNQUOTED(PACKAGE, "${PACKAGE_NAME}")
 184     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 185
 186     package_depth=`dirname $cache_file`
 187     AC_SUBST(package_depth)
 188
 189     AUTOGENERATE="This file was automatically generated by configure"
 190     AC_SUBST(AUTOGENERATE)
 191     absolute_builddir="`pwd`"
 192     AC_SUBST(absolute_builddir)
 193
 194     # No versioning on directory names of sub-packages
 195     stepmake=stepmake
 196     AC_SUBST(stepmake)
 197
 198     STATE_VECTOR=`ls make/STATE-VECTOR 2>/dev/null`
 199     if test "x$STATE_VECTOR" != "x"; then
 200         STATE_VECTOR="\$(depth)/$STATE_VECTOR"
 201     fi
 202     AC_SUBST(STATE_VECTOR)
 203
 204     CONFIGSUFFIX=
 205     AC_ARG_ENABLE(config,
 206     [  enable-config=FILE      put configure settings in config-FILE.make],
 207     [CONFIGSUFFIX=$enableval])
 208
 209     if test "$CONFIGSUFFIX" != "" ; then
 210         CONFIGFILE=config-$CONFIGSUFFIX
 211     else
 212         CONFIGFILE=config
 213     fi
 214     AC_SUBST(CONFIGSUFFIX)
 215
 216     AC_CANONICAL_HOST
 217     AC_CHECK_PROGS(MAKE, make, error)
 218     AC_CHECK_PROGS(FIND, find, error)
 219
 220
 221 dnl system supplied INSTALL is unsafe; use our own install.
 222 dnl    AC_PROG_INSTALL
 223 dnl    if test "$INSTALL" = "bin/install-sh"; then
 224 dnl     export INSTALL="\$\(depth\)/bin/install-sh"
 225 dnl    fi
 226
 227     AC_CHECK_PROGS(TAR, tar, error)
 228     AC_CHECK_PROGS(BASH, bash, /bin/sh)
 229
 230     AC_PATH_PROG(PYTHON, ${PYTHON:-python}, -echo no python)
 231     AC_SUBST(PYTHON)
 232
 233
 234     AC_CHECK_SEARCH_RESULT($MAKE, GNU make,  You should install GNU make)
 235     if test $MAKE != "error" ; then
 236         $MAKE -v| grep GNU > /dev/null
 237         if test "$?" = 1
 238         then
 239                 AC_STEPMAKE_WARN(Please install *GNU* make)
 240         fi
 241     fi
 242
 243     AC_CHECK_SEARCH_RESULT($PYTHON, python, You should install Python)
 244
 245     if test "x$OSTYPE" = "xcygwin32" || test "x$OSTYPE" = "xWindows_NT"; then
 246         LN=cp # hard link does not work under cygnus-nt
 247         LN_S=cp # symbolic link does not work for native nt
 248         ZIP="zip -r -9" #
 249         DOTEXE=.exe
 250        DIRSEP='\\'
 251         PATHSEP=';'
 252        INSTALL="\$(stepdir)/../bin/install-dot-exe.sh -c"
 253     else
 254         DIRSEP='/'
 255         PATHSEP=':'
 256         LN=ln
 257         LN_S='ln -s'
 258         ZIP="zip -r -9"
 259         INSTALL="\$(stepdir)/../bin/install-sh -c"
 260     fi
 261     AC_SUBST(DOTEXE)
 262     AC_SUBST(ZIP)
 263     AC_SUBST(LN)
 264     AC_SUBST(LN_S)
 265     AC_SUBST(INSTALL)
 266     AC_DEFINE_UNQUOTED(DIRSEP, '${DIRSEP}')
 267     AC_DEFINE_UNQUOTED(PATHSEP, '${PATHSEP}')
 268     AC_SUBST(PATHSEP)
 269     AC_SUBST(DIRSEP)
 270
 271
 272     AC_STEPMAKE_DATADIR
 273 ])
 274
 275 AC_DEFUN(AC_STEPMAKE_LEXYACC, [
 276     # ugh, automake: we want (and check for) bison
 277     AC_PROG_YACC
 278     # ugh, automake: we want (and check for) flex
 279     # AC_PROG_LEX
 280     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 281
 282     # AC_DECL_YYTEXT
 283     # ugh, ugh
 284     ac_cv_prog_lex_root=lex.yy
 285
 286     AC_CHECK_PROGS(BISON, bison, error)
 287     AC_CHECK_PROGS(FLEX, flex, error)
 288     AC_CHECK_SEARCH_RESULT($BISON, bison,  Please install Bison, 1.25 or better)
 289     AC_CHECK_SEARCH_RESULT($FLEX,  flex, Please install Flex, 2.5 or better)
 290
 291     if test $BISON != "error"; then
 292         bison_version=`$BISON --version| sed 's/^.*version 1.//g' `
 293         if test $bison_version -lt 25; then
 294             AC_STEPMAKE_WARN(Your bison is a bit old (1.$bison_version). You might have to install 1.25)
 295         fi
 296     fi
 297
 298     AC_SUBST(BISON)
 299     AC_SUBST(FLEX)
 300 ])
 301
 302 AC_DEFUN(AC_STEPMAKE_LIB, [
 303     AC_CHECK_PROGS(AR, ar, error)
 304     AC_PROG_RANLIB
 305
 306     AC_SUBST(AR)
 307     AC_SUBST(RANLIB)
 308 ])
 309
 310 AC_DEFUN(AC_STEPMAKE_LIBTOOL, [
 311     # libtool.info ...
 312     # **Never** try to set library version numbers so that they correspond
 313     # to the release number of your package.  This is an abuse that only
 314     # fosters misunderstanding of the purpose of library versions.
 315
 316     REVISION=$PATCH_LEVEL
 317     # CURRENT=$MINOR_VERSION
 318     CURRENT=`expr $MINOR_VERSION + 1`
 319     # AGE=$(expr $MAJOR_VERSION + 1)
 320     AGE=$MAJOR_VERSION
 321     AC_SUBST(CURRENT)
 322     AC_SUBST(REVISION)
 323     AC_SUBST(AGE)
 324 ])
 325
 326 AC_DEFUN(AC_STEPMAKE_LOCALE, [
 327     lang=English
 328     ALL_LINGUAS="en nl"
 329
 330     # with/enable ??
 331     AC_ARG_WITH(localedir,
 332     [  with-localedir=LOCALE   use LOCALE as locale dir. Default: PREFIX/share/locale ],
 333     localedir=$with_localedir,
 334     localedir='${prefix}/share/locale')
 335
 336     AC_ARG_WITH(lang,
 337     [  with-lang=LANG          use LANG as language to emit messages],
 338     language=$with_lang,
 339     language=English)
 340
 341     AC_MSG_CHECKING(language)
 342     case "$language" in
 343       En* | en* | Am* | am* | US* | us*)
 344             lang=English;;
 345       NL | nl | Du* | du* | Ned* | ned*)
 346             lang=Dutch;;
 347       "")
 348             lang=English;;
 349       *)
 350             lang=unknown;;
 351     esac
 352     AC_MSG_RESULT($lang)
 353
 354     if test "$lang" = "unknown" ; then
 355         AC_STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 356     fi
 357
 358 ])
 359
 360 AC_DEFUN(AC_STEPMAKE_GETTEXT, [
 361     DIR_LOCALEDIR=${localedir}
 362     presome=${prefix}
 363     if test "$prefix" = "NONE"; then
 364             presome=${ac_default_prefix}
 365     fi
 366     DIR_LOCALEDIR=`echo ${DIR_LOCALEDIR} | sed "s!\\\${prefix}!$presome!"`
 367     AC_SUBST(localedir)
 368     AC_SUBST(DIR_LOCALEDIR)
 369     AC_DEFINE_UNQUOTED(DIR_LOCALEDIR, "${DIR_LOCALEDIR}")
 370
 371     AC_CHECK_LIB(intl, gettext)
 372     AC_CHECK_FUNCS(gettext)
 373 ])
 374
 375 AC_DEFUN(AC_STEPMAKE_MAN, [
 376     AC_CHECK_PROGS(TROFF, troff, -echo no troff)
 377 ])
 378
 379 AC_DEFUN(AC_STEPMAKE_MSGFMT, [
 380     # AC_CHECK_PROGS(MSGFMT, msgfmt, -echo no msgfmt)
 381     AC_CHECK_PROGS(MSGFMT, msgfmt, \$(SHELL) \$(step-bindir)/fake-msgfmt.sh )
 382     AC_MSG_CHECKING(whether msgfmt accepts -o)
 383     msgfmt_output="`msgfmt -o bla 2>&1 | grep usage`"
 384     if test "$msgfmt_output" = ""; then
 385         AC_MSG_RESULT(yes)
 386     else
 387         # urg
 388         MSGFMT="\$(SHELL) \$(step-bindir)/fake-msgfmt.sh"
 389         AC_MSG_RESULT(no)
 390         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 391     fi
 392     if test ! -n "$MSGFMT"; then
 393         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 394     fi
 395 ])
 396
 397 AC_DEFUN(AC_STEPMAKE_TEXMF, [
 398     AC_ARG_ENABLE(tex-prefix,
 399     [  enable-tex-prefix=DIR   set the tex-directory to find TeX subdirectories. (default: PREFIX)],
 400     [TEXPREFIX=$enableval],
 401     [TEXPREFIX=auto] )
 402
 403     AC_ARG_ENABLE(tex-dir,
 404     [  enable-tex-dir=DIR      set the directory to put $PACKAGE_NAME TeX files in. ],
 405     [TEXDIR=$enableval],
 406     [TEXDIR=auto] )
 407
 408     AC_ARG_ENABLE(mf-dir,
 409     [  enable-mf-dir=DIR       set the directory to put $PACKAGE_NAME MetaFont files in. ],
 410     [MFDIR=$enableval],
 411     [MFDIR=auto])
 412
 413     if test "x$TEXPREFIX" = xauto ; then
 414         AC_TEX_PREFIX(TEXPREFIX)
 415     else
 416      find_texprefix=$TEXPREFIX
 417     fi
 418
 419     if test "x$MFDIR" = xauto; then
 420         AC_MF_SUBDIR(MFDIR)
 421     fi
 422
 423     if test "x$TEXDIR" = xauto ; then
 424         AC_TEX_SUBDIR(TEXDIR)
 425     fi
 426
 427     AC_SUBST(TEXPREFIX)
 428     AC_SUBST(TEXDIR)
 429     AC_SUBST(MFDIR)
 430 ])
 431
 432 AC_DEFUN(AC_STEPMAKE_WARN, [
 433     AC_MSG_WARN($1)
 434     warn_b=yes
 435 ])
 436
 437 AC_DEFUN(AC_STEPMAKE_YODL, [
 438     if test "x$YODL" = "x"; then
 439         AC_CHECK_PROGS(STRIPROFF, striproff, -echo no striproff)
 440         AC_CHECK_PROGS(YODL, yodl, -echo no yodl)
 441         AC_CHECK_PROGS(YODL2HTML, yodl2html, -echo no yodl)
 442         AC_CHECK_PROGS(YODL2LATEX, yodl2latex, )
 443         AC_CHECK_PROGS(YODL2MAN, yodl2man, -echo no yodl)
 444         AC_CHECK_PROGS(YODL2MSLESS, yodl2msless, -echo no yodl)
 445         AC_CHECK_PROGS(YODL2TEXINFO, yodl2texinfo, -echo no yodl)
 446         AC_CHECK_PROGS(YODL2TXT, yodl2txt, -echo no yodl)
 447     else
 448         AC_SUBST(STRIPROFF)
 449         AC_SUBST(YODL)
 450         AC_SUBST(YODL2HTML)
 451         AC_SUBST(YODL2LATEX)
 452         AC_SUBST(YODL2MAN)
 453         AC_SUBST(YODL2MSLESS)
 454         AC_SUBST(YODL2TEXINFO)
 455         AC_SUBST(YODL2TXT)
 456         export STRIPROFF YODL YODL2HTML YODL2LATEX YODL2MAN YODL2MSLESS YODL2TEXINFO YODL2TXT
 457     fi
 458     if test "x$YODL" = "-echo no yodl"; then
 459         AC_STEPMAKE_WARN(Did not find YODL (Yodl is Yet Oneother Document Language, see http://www.cs.uu.nl/~hanwen/yodl))
 460     fi
 461 ])
 462
 463 dnl should cache result.
 464 dnl should  look in $prefix first.
 465 dnl should probably assume TDS
 466
 467 AC_DEFUN(AC_TEX_PREFIX, [
 468
 469
 470     AC_MSG_CHECKING(TeX/MF root dir directory)
 471
 472     find_root_prefix="$prefix"
 473
 474
 475     test "x$find_root_prefix" = xNONE && find_root_prefix="$ac_default_prefix"
 476     find_texpostfix="";
 477     for postfix in "/lib/tex/" "/lib/texmf" "/lib" "/tex" "/texmf"; do
 478         find_texprefix="$find_root_prefix$postfix"
 479         if test -d $find_texprefix; then
 480             find_texpostfix=$postfix
 481             break;
 482         fi
 483     done
 484
 485     if test "x$find_texpostfix" = x; then
 486         find_texpostfix='/lib/texmf/tex'
 487         AC_STEPMAKE_WARN(Cannot determine the TeX-directory. Please use --enable-tex-prefix)
 488     fi
 489
 490     find_texprefix="$find_root_prefix/$find_texpostfix"
 491
 492     # only assign if variablename not empty
 493     if test x != "x[$]$1"; then
 494         $1='${prefix}'/"$find_texpostfix"
 495     fi
 496     AC_MSG_RESULT($find_texprefix)
 497
 498 ])
 499
 500
 501 # find a directory inside a prefix,
 502 # $1 the prefix (expanded version)
 503 # $2 variable to assign
 504 # $3 the directory name
 505 # $4 description
 506 AC_DEFUN(AC_FIND_DIR_IN_PREFIX, [
 507
 508     AC_MSG_CHECKING($4 directory)
 509     find_dirdir=`(cd $1;
 510       $FIND ./ -type d -a -name $3 -print |sort|head -1|sed 's#^\./##')`
 511
 512
 513     if test "x$find_dirdir" = x; then
 514        find_dirdir="/$3";
 515        AC_STEPMAKE_WARN(Cannot determine $4 subdirectory. Please set from command-line)
 516         true
 517     fi
 518     $2=$find_dirdir
 519     AC_MSG_RESULT($1/$find_dirdir)
 520 ])
 521
 522 # ugh.  this is hopeless
 523 AC_DEFUN(AC_KPSE_TEX_DIR, [
 524         kpse_paths=`(kpsepath -n latex tex; kpsepath -n tex tex) | sed 's/:/ /g' | tr ' ' '\012' |sort | uniq -d`
 525         kpse_syspaths=`echo $kpse_paths | grep '!'| sed 's/!//g'`
 526         echo $kpse_paths
 527         if test -w "$kpse_syspaths";
 528         then
 529                 dir=`echo $kpse_syspaths | head -1`
 530         else
 531                 dir=`echo $kpse_paths | grep -v '!'| head -1`
 532         fi
 533         if test "$prefix" = "NONE"; then
 534                 local_prefix=$ac_default_prefix
 535                 local_prefix_quote='${prefix}'
 536
 537         else
 538                 local_prefix=$prefix
 539                 local_prefix_quote=$prefix
 540         fi
 541         echo $local_prefix_quote = $local_prefix
 542         echo $dir
 543         echo $dir  | sed 's!'$local_prefix'!\$local_prefix_quote!g'
 544 ])
 545
 546 AC_DEFUN(AC_TEX_SUBDIR, [
 547 dnl    AC_REQUIRE([AC_TEX_PREFIX])
 548     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, tex,TeX input)
 549     $1="$TEXPREFIX/$$1"
 550 ])
 551
 552 AC_DEFUN(AC_MF_SUBDIR, [
 553 dnl     AC_REQUIRE([AC_TEX_PREFIX])
 554     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, source, MF input)
 555     $1="$TEXPREFIX/$$1"
 556 ])
 557
 558 AC_DEFUN(AC_CHECK_SEARCH_RESULT, [
 559         result="`echo \"$1\" | grep echo`"
 560         if test "x$1" = "xerror" -o "x$result" != "x"; then
 561                 AC_STEPMAKE_WARN(can\'t find $2. $3)
 562         fi
 563 ])
 564
 565
 566 # Configure paths for GTK+
 567 # Owen Taylor     97-11-3
 568
 569 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 570 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
 571 dnl
 572 AC_DEFUN(AM_PATH_GTK,
 573 [dnl
 574 dnl Get the cflags and libraries from the gtk-config script
 575 dnl
 576   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
 577   min_gtk_version=ifelse([$1], ,1.1.1,$1)
 578   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
 579   no_gtk=""
 580   if test "$GTK_CONFIG" != "no" ; then
 581     GTK_CFLAGS=`$GTK_CONFIG --cflags`
 582     GTK_LIBS=`$GTK_CONFIG --libs`
 583     ac_save_CFLAGS="$CFLAGS"
 584     ac_save_LIBS="$LIBS"
 585     ac_save_CXXFLAGS="$CXXFLAGS"
 586     CFLAGS="$CFLAGS $GTK_CFLAGS"
 587     CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 588     LIBS="$LIBS $GTK_LIBS"
 589 dnl
 590 dnl Now check if the installed GTK is sufficiently new. (Also sanity
 591 dnl checks the results of gtk-config to some extent
 592 dnl
 593     AC_TRY_RUN([
 594 #include <gtk/gtk.h>
 595 #include <stdio.h>
 596
 597 int
 598 main ()
 599 {
 600   int major, minor, micro;
 601
 602   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
 603      printf("%s, bad version string\n", "$min_gtk_version");
 604      exit(1);
 605    }
 606
 607    return !((gtk_major_version > major) ||
 608             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
 609             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
 610 }
 611 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 612      CFLAGS="$ac_save_CFLAGS"
 613      CXXFLAGS="$ac_save_CXXFLAGS"
 614      LIBS="$ac_save_LIBS"
 615   else
 616      no_gtk=yes
 617   fi
 618   if test "x$no_gtk" = x ; then
 619      AC_MSG_RESULT(yes)
 620      ifelse([$2], , :, [$2])
 621   else
 622      AC_MSG_RESULT(no)
 623      GTK_CFLAGS=""
 624      GTK_LIBS=""
 625      ifelse([$3], , :, [$3])
 626   fi
 627   CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 628   AC_SUBST(CXXFLAGS)
 629   AC_SUBST(GTK_CFLAGS)
 630   AC_SUBST(GTK_LIBS)
 631 ])
 632
 633
 634 # Configure paths for GTK--
 635 # Erik Andersen 30 May 1998
 636 # Modified by Tero Pulkkinen (added the compiler checks... I hope they work..)
 637
 638 dnl Test for GTK__, and define GTK___CFLAGS and GTK___LIBS
 639 dnl   to be used as follows:
 640 dnl AM_PATH_GTKMM([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 641 dnl
 642
 643 dnl Get the cflags and libraries from the gtkmm-config script
 644 dnl
 645 AC_ARG_WITH(gtkmm-prefix,[  --with-gtkmm-prefix=PREFIX
 646                           Prefix where GTK-- is installed (optional)],
 647             gtkmm_config_prefix="$withval", gtkmm_config_prefix="")
 648 AC_ARG_WITH(gtkmm-exec-prefix,[  --with-gtkmm-exec-prefix=PREFIX
 649                           Exec prefix where GTK-- is installed (optional)],
 650             gtkmm_config_exec_prefix="$withval", gtkmm_config_exec_prefix="")
 651 AC_ARG_ENABLE(gtkmmtest, [  --disable-gtkmmtest     Do not try to compile and run a test GTK-- program],
 652                     , enable_gtkmmtest=yes)
 653
 654   if test x$gtkmm_config_exec_prefix != x ; then
 655      gtkmm_config_args="$gtkmm_config_args --exec-prefix=$gtkmm_config_exec_prefix"
 656      if test x${GTKMM_CONFIG+set} != xset ; then
 657         GTKMM_CONFIG=$gtkmm_config_exec_prefix/bin/gtkmm-config
 658      fi
 659   fi
 660   if test x$gtkmm_config_prefix != x ; then
 661      gtkmm_config_args="$gtkmm_config_args --prefix=$gtkmm_config_prefix"
 662      if test x${GTKMM_CONFIG+set} != xset ; then
 663         GTKMM_CONFIG=$gtkmm_config_prefix/bin/gtkmm-config
 664      fi
 665   fi
 666
 667
 668 AC_DEFUN(AM_PATH_GTKMM,
 669 [dnl
 670
 671 dnl
 672 dnl Check check if the installed GTK-- is sufficiently new.
 673 dnl
 674   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 675   min_gtkmm_version=ifelse([$1], ,0.9.14,$1)
 676
 677   AC_MSG_CHECKING(for GTK-- - version >= $min_gtkmm_version)
 678   no_gtkmm=""
 679   if test "$GTKMM_CONFIG" = "no" ; then
 680     no_gtkmm=yes
 681   else
 682     AC_LANG_SAVE
 683     AC_LANG_CPLUSPLUS
 684
 685     GTK___CFLAGS=`$GTKMM_CONFIG $gtkmm_config_args --cflags`
 686     GTK___LIBS=`$GTKMM_CONFIG $gtkmm_config_args --libs`
 687     gtkmm_config_major_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 688            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 689     gtkmm_config_minor_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 690            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 691     gtkmm_config_micro_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 692            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
 693     if test "x$enable_gtkmmtest" = "xyes" ; then
 694       ac_save_CXXFLAGS="$CXXFLAGS"
 695       ac_save_LIBS="$LIBS"
 696       CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 697       LIBS="$LIBS $GTK___LIBS"
 698 dnl
 699 dnl Now check if the installed GTK-- is sufficiently new. (Also sanity
 700 dnl checks the results of gtkmm-config to some extent
 701 dnl
 702       rm -f conf.gtkmmtest
 703       AC_TRY_RUN([
 704 #include <gtk--.h>
 705 #include <stdio.h>
 706 #include <stdlib.h>
 707
 708 int
 709 main ()
 710 {
 711   int major, minor, micro;
 712   char *tmp_version;
 713
 714   system ("touch conf.gtkmmtest");
 715
 716   /* HP/UX 0 (%@#!) writes to sscanf strings */
 717   tmp_version = g_strdup("$min_gtkmm_version");
 718   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
 719      printf("%s, bad version string\n", "$min_gtkmm_version");
 720      exit(1);
 721    }
 722
 723   if ((gtkmm_major_version != $gtkmm_config_major_version) ||
 724       (gtkmm_minor_version != $gtkmm_config_minor_version) ||
 725       (gtkmm_micro_version != $gtkmm_config_micro_version))
 726     {
 727       printf("\n*** 'gtkmm-config --version' returned %d.%d.%d, but GTK-- (%d.%d.%d)\n",
 728              $gtkmm_config_major_version, $gtkmm_config_minor_version, $gtkmm_config_micro_version,
 729              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 730       printf ("*** was found! If gtkmm-config was correct, then it is best\n");
 731       printf ("*** to remove the old version of GTK--. You may also be able to fix the error\n");
 732       printf("*** by modifying your LD_LIBRARY_PATH enviroment variable, or by editing\n");
 733       printf("*** /etc/ld.so.conf. Make sure you have run ldconfig if that is\n");
 734       printf("*** required on your system.\n");
 735       printf("*** If gtkmm-config was wrong, set the environment variable GTKMM_CONFIG\n");
 736       printf("*** to point to the correct copy of gtkmm-config, and remove the file config.cache\n");
 737       printf("*** before re-running configure\n");
 738     }
 739 /* GTK-- does not have the GTKMM_*_VERSION constants */
 740 /*
 741   else if ((gtkmm_major_version != GTKMM_MAJOR_VERSION) ||
 742            (gtkmm_minor_version != GTKMM_MINOR_VERSION) ||
 743            (gtkmm_micro_version != GTKMM_MICRO_VERSION))
 744     {
 745       printf("*** GTK-- header files (version %d.%d.%d) do not match\n",
 746              GTKMM_MAJOR_VERSION, GTKMM_MINOR_VERSION, GTKMM_MICRO_VERSION);
 747       printf("*** library (version %d.%d.%d)\n",
 748              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 749     }
 750 */
 751   else
 752     {
 753       if ((gtkmm_major_version > major) ||
 754         ((gtkmm_major_version == major) && (gtkmm_minor_version > minor)) ||
 755         ((gtkmm_major_version == major) && (gtkmm_minor_version == minor) && (gtkmm_micro_version >= micro)))
 756       {
 757         return 0;
 758        }
 759      else
 760       {
 761         printf("\n*** An old version of GTK-- (%d.%d.%d) was found.\n",
 762                gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 763         printf("*** You need a version of GTK-- newer than %d.%d.%d. The latest version of\n",
 764                major, minor, micro);
 765         printf("*** GTK-- is always available from ftp://ftp.gtk.org.\n");
 766         printf("***\n");
 767         printf("*** If you have already installed a sufficiently new version, this error\n");
 768         printf("*** probably means that the wrong copy of the gtkmm-config shell script is\n");
 769         printf("*** being found. The easiest way to fix this is to remove the old version\n");
 770         printf("*** of GTK--, but you can also set the GTKMM_CONFIG environment to point to the\n");
 771         printf("*** correct copy of gtkmm-config. (In this case, you will have to\n");
 772         printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
 773         printf("*** so that the correct libraries are found at run-time))\n");
 774       }
 775     }
 776   return 1;
 777 }
 778 ],, no_gtkmm=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 779        CXXFLAGS="$ac_save_CXXFLAGS"
 780        LIBS="$ac_save_LIBS"
 781      fi
 782   fi
 783   if test "x$no_gtkmm" = x ; then
 784      AC_MSG_RESULT(yes)
 785      ifelse([$2], , :, [$2])
 786   else
 787      AC_MSG_RESULT(no)
 788      if test "$GTKMM_CONFIG" = "no" ; then
 789        echo "*** The gtkmm-config script installed by GTK-- could not be found"
 790        echo "*** If GTK-- was installed in PREFIX, make sure PREFIX/bin is in"
 791        echo "*** your path, or set the GTK_CONFIG environment variable to the"
 792        echo "*** full path to gtk-config."
 793        echo "*** The gtkmm-config script was not available in GTK-- versions"
 794        echo "*** prior to 0.9.12. Perhaps you need to update your installed"
 795        echo "*** version to 0.9.12 or later"
 796      else
 797        if test -f conf.gtkmmtest ; then
 798         :
 799        else
 800           echo "*** Could not run GTK-- test program, checking why..."
 801           CXXFLAGS="$CFLAGS $GTKMM_CXXFLAGS"
 802           LIBS="$LIBS $GTK___LIBS"
 803           AC_TRY_LINK([
 804 #include <gtk--.h>
 805 #include <stdio.h>
 806 ],      [ return ((gtkmm_major_version) || (gtkmm_minor_version) || (gtkmm_micro_version)); ],
 807         [ echo "*** The test program compiled, but did not run. This usually means"
 808           echo "*** that the run-time linker is not finding GTK-- or finding the wrong"
 809           echo "*** version of GTK--. If it is not finding GTK--, you'll need to set your"
 810           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 811           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 812           echo "*** is required on your system"
 813           echo "***"
 814           echo "*** If you have an old version installed, it is best to remove it, although"
 815           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH" ],
 816         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 817           echo "*** exact error that occured. This usually means GTK-- was incorrectly installed"
 818           echo "*** or that you have moved GTK-- since it was installed. In the latter case, you"
 819           echo "*** may want to edit the gtkmm-config script: $GTKMM_CONFIG" ])
 820           CXXFLAGS="$ac_save_CXXFLAGS"
 821           LIBS="$ac_save_LIBS"
 822        fi
 823      fi
 824      GTK___CFLAGS=""
 825      GTK__LIBS=""
 826      ifelse([$3], , :, [$3])
 827      AC_LANG_RESTORE
 828   fi
 829   AC_SUBST(GTK___CFLAGS)
 830   AC_SUBST(GTK___LIBS)
 831   rm -f conf.gtkmmtest
 832 ])
 833
 834 # Configure paths for GTK--DRAW
 835 # Derek Quinn Wyatt   98-08-21  (adapted from Jan Nieuwenhuizen's code)
 836
 837 dnl AM_PATH_GTK__DRAW([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 838 dnl Test for GTK--DRAW, and define GTK___CFLAGS and GTK___LIBS
 839 dnl
 840 AC_DEFUN(AM_PATH_GTK__DRAW,
 841 [dnl
 842 dnl Get the cflags and libraries from the gtk__-config script
 843 dnl
 844   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 845   min_gtk___version=ifelse([$1], ,0.0.5,$1)
 846   AC_MSG_CHECKING(for GTK--DRAW - version >= $min_gtk___version)
 847   no_gtk__=""
 848   if test "$GTKMM_CONFIG" != "no" ; then
 849     GTK___CFLAGS=`$GTKMM_CONFIG --cflags`
 850     GTK___LIBS=`$GTKMM_CONFIG --libs`
 851     GTK___DLIBS="$GTK___LIBS -lgtkmmdraw"
 852     GTK___LIBS="$GTK___DLIBS"
 853     ac_save_CFLAGS="$CFLAGS"
 854     ac_save_LIBS="$LIBS"
 855     ac_save_CXXFLAGS="$CXXFLAGS"
 856     CFLAGS="$CFLAGS $GTK___CFLAGS"
 857     CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 858     LIBS="$LIBS $GTK___LIBS"
 859 dnl
 860 dnl Now check if the installed GTK__ is sufficiently new. (Also sanity
 861 dnl checks the results of gtk__-config to some extent
 862 dnl
 863     AC_TRY_RUN([
 864 #include <gtk--.h>
 865 #include <stdio.h>
 866
 867 int
 868 main ()
 869 {
 870   // urg
 871   return 0;
 872 }
 873 ],, no_gtk__=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 874      CFLAGS="$ac_save_CFLAGS"
 875      CXXFLAGS="$ac_save_CXXFLAGS"
 876      LIBS="$ac_save_LIBS"
 877   else
 878      no_gtk__=yes
 879   fi
 880   if test "x$no_gtk__" = x ; then
 881      AC_MSG_RESULT(yes)
 882      ifelse([$2], , :, [$2])
 883   else
 884      AC_MSG_RESULT(no)
 885      GTK___CFLAGS=""
 886      GTK___LIBS=""
 887      ifelse([$3], , :, [$3])
 888   fi
 889   CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 890   AC_SUBST(CXXFLAGS)
 891   AC_SUBST(GTK___CFLAGS)
 892   AC_SUBST(GTK___LIBS)
 893 ])
 894