stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 |
  36                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  37                 head -n 1 |
  38                 tr ' ' '\n' |
  39                 sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' |
  40                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  41                 head -n 1\`\"
  42
  43     if test -z "$_ver"; then
  44         ## If empty, try date [fontforge]
  45         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  46             | head -n 1 \
  47             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  48     fi
  49     echo "$_ver"
  50     changequote([, ])#dnl
  51 ])
  52
  53 # Calculate simplistic numeric version from version string ($1)
  54 # As yet, we have no need for something more elaborate.
  55 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  56     echo "$1" | awk -F. '
  57     {
  58       if ([$]3) {three = [$]3}
  59       else {three = 0}
  60     }
  61     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  62 ])
  63
  64
  65 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  66 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  67     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  68 ])
  69
  70 # Check if tested program ($2) was found ($1).
  71 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  72 # We could abort here if a 'REQUIRED' program is not found
  73 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  74     STEPMAKE_CHECK_SEARCH_RESULT($1)
  75     if test $? -ne 0; then
  76         STEPMAKE_ADD_ENTRY($3, $2)
  77         if test "$3" = "REQUIRED"; then
  78             command="echo ERROR: $2 not found"
  79             # abort configure process here?
  80         else
  81             command="- echo $2 not found"
  82         fi
  83         eval "$1"='$command'
  84         false
  85     else
  86         true
  87     fi
  88 ])
  89
  90
  91 # Return if tested proram ($1) was found (true) or not (false).
  92 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  93     r="`eval echo '$'"$1"`"
  94     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  95         true
  96     else
  97         ##STEPMAKE_WARN(cannot find $2. $3)
  98         false
  99     fi
 100 ])
 101
 102
 103 # Check version of program ($1)
 104 # If version ($4: optional argument, supply if version cannot be
 105 # parsed using --version or -V ) is smaller than requested ($3), add
 106 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 107 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 108     r="`eval echo '$'"$1"`"
 109     AC_MSG_CHECKING([$r version])
 110     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 111     if test -n "$4"; then
 112         ver="$4"
 113     else
 114         ver=`STEPMAKE_GET_VERSION($exe)`
 115     fi
 116     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 117     req=`STEPMAKE_NUMERIC_VERSION($3)`
 118     AC_MSG_RESULT([$ver])
 119     if test "$num" -lt "$req"; then
 120         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 121     fi
 122     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 123     eval `echo $vervar=$num`
 124 ##    AC_SUBST(`eval echo $vervar`)
 125 ])
 126
 127 # Check version of program ($1)
 128 # If version is greater than or equals unsupported ($3),
 129 # add entry to unsupported list ($2, 'UNSUPPORTED')
 130 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 131     r="`eval echo '$'"$1"`"
 132     AC_MSG_CHECKING([$r version])
 133     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 134     ver=`STEPMAKE_GET_VERSION($exe)`
 135     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 136     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 137     AC_MSG_RESULT([$ver])
 138     if test "$num" -ge "$sup"; then
 139         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 140     fi
 141 ])
 142
 143 ### Macros to build configure.in
 144
 145
 146 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 147     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 148     if test "$BIBTEX2HTML" = "bib2html"; then
 149         BIBTEX2HTML_FLAGS='$< $(@)'
 150     else
 151         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 152     fi
 153     AC_SUBST(BIBTEX2HTML)
 154     AC_SUBST(BIBTEX2HTML_FLAGS)
 155 ])
 156
 157
 158 AC_DEFUN(STEPMAKE_BISON, [
 159     # ugh, automake: we want (and check for) bison
 160     AC_PROG_YACC
 161
 162     STEPMAKE_PROGS(BISON, bison, $1)
 163
 164     # urg.  should test functionality rather than version.
 165     if test "$BISON" = "bison" -a -n "$2"; then
 166         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 167     fi
 168 ])
 169
 170 AC_DEFUN(STEPMAKE_COMPILE_BEFORE, [
 171     # -O is necessary to get inlining
 172     CFLAGS=${CFLAGS-""}
 173     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 174     LDFLAGS=${LDFLAGS-""}
 175     optimise_b=yes
 176     profile_b=no
 177     debug_b=yes
 178     pipe_b=yes
 179
 180     AC_ARG_ENABLE(debugging,
 181     [  --enable-debugging      compile with debugging info.  Default: on],
 182     [debug_b=$enableval])
 183
 184     AC_ARG_ENABLE(optimising,
 185     [  --enable-optimising     compile with optimising.  Default: on],
 186     [optimise_b=$enableval])
 187
 188     AC_ARG_ENABLE(profiling,
 189     [  --enable-profiling      compile with gprof support.  Default: off],
 190     [profile_b=$enableval])
 191
 192     AC_ARG_ENABLE(pipe,
 193     [  --enable-pipe           compile with -pipe.  Default: on],
 194     [pipe_b=$enableval])
 195
 196     if test "$optimise_b" = yes; then
 197         AC_DEFINE(NDEBUG)
 198         DEFINES="$DEFINES -DNDEBUG"
 199         OPTIMIZE=" -O2 -finline-functions"
 200     fi
 201
 202     if test $profile_b = yes; then
 203         EXTRA_LIBS="-pg"
 204         OPTIMIZE="$OPTIMIZE -pg"
 205     fi
 206
 207     if test $debug_b = yes; then
 208         OPTIMIZE="$OPTIMIZE -g"
 209     fi
 210 ])
 211
 212 AC_DEFUN(STEPMAKE_COMPILE, [
 213
 214     AC_REQUIRE([STEPMAKE_COMPILE_BEFORE])
 215     AC_REQUIRE([AC_PROG_CC])
 216
 217     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 218     LD='$(CC)'
 219     AC_SUBST(LD)
 220
 221     # If -pipe requested, test if it works and add to CFLAGS.
 222     if test "$pipe_b" = yes; then
 223         save_cflags="$CFLAGS"
 224         CFLAGS=" -pipe $CFLAGS";
 225         AC_CACHE_CHECK([whether compiler understands -pipe],
 226             [stepmake_cv_cflags_pipe],
 227             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 228                 [stepmake_cv_cflags_pipe=yes],
 229                 [stepmake_cv_cflags_pipe=no]))
 230         CFLAGS=$save_cflags
 231         if test $stepmake_cv_cflags_pipe = yes; then
 232             OPTIMIZE="$OPTIMIZE -pipe"
 233         fi
 234     fi
 235
 236     CFLAGS="$CFLAGS $OPTIMIZE"
 237     CPPFLAGS=${CPPFLAGS-""}
 238
 239     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 240     save_cflags="$CFLAGS"
 241     case "$host" in
 242         alpha*-*-*)
 243             dnl should do compile test?
 244             AC_MSG_RESULT(-mieee)
 245             CFLAGS=" -mieee $CFLAGS"
 246             ;;
 247         *)
 248             AC_MSG_RESULT([none])
 249             ;;
 250     esac
 251
 252     AC_SUBST(cross_compiling)
 253     AC_SUBST(CFLAGS)
 254     AC_SUBST(CPPFLAGS)
 255     AC_SUBST(LDFLAGS)
 256     AC_SUBST(DEFINES)
 257     AC_SUBST(EXTRA_LIBS)
 258 ])
 259
 260 AC_DEFUN(STEPMAKE_CXX, [
 261     AC_LANG([C++])
 262     AC_PROG_CXX
 263     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 264
 265     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 266     LD='$(CXX)'
 267
 268     AC_SUBST(CXX)
 269     AC_SUBST(CXXFLAGS)
 270     AC_SUBST(LD)
 271 ])
 272
 273
 274 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 275     AC_CACHE_CHECK([whether explicit instantiation is needed],
 276         stepmake_cv_need_explicit_instantiation,
 277         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 278     template <class T> struct foo { static int baz; };
 279     template <class T> int foo<T>::baz = 1;
 280     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 281     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 282         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 283     fi
 284 ])
 285
 286
 287 AC_DEFUN(STEPMAKE_DATADIR, [
 288     if test "$datadir" = "\${prefix}/share"; then
 289             datadir='${prefix}/share'
 290     fi
 291     presome=${prefix}
 292     if test "$prefix" = "NONE"; then
 293         presome=${ac_default_prefix}
 294     fi
 295
 296     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 297
 298     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 299     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 300     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 301
 302     AC_SUBST(datadir)
 303     AC_SUBST(datarootdir)
 304     AC_SUBST(build_package_datadir)
 305     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 306     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 307 ])
 308
 309 ## ugh: cut & paste programming from datadir.
 310 AC_DEFUN(STEPMAKE_LIBDIR, [
 311
 312     if test "$libdir" = "\${exec_prefix}/lib"; then
 313         libdir='${exec_prefix}/lib'
 314     fi
 315     presome=$exec_prefix
 316     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 317
 318     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 319     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 320
 321     AC_SUBST(libdir)
 322     AC_SUBST(build_package_libdir)
 323     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 324     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 325 ])
 326
 327
 328 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 329     # undo expanding of explicit --infodir=/usr/share
 330     # to ease install-time override with prefix=...
 331     strip=`echo $includedir | eval sed s@^$prefix@@`
 332     if test "$includedir" = "`eval echo $prefix$strip`"; then
 333             includedir='${prefix}'$strip''
 334     fi
 335     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 336     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 337             libdir='${exec_prefix}'$strip''
 338     fi
 339     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 340     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 341             infodir='${datarootdir}'$strip''
 342     fi
 343     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 344     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 345             mandir='${datarootdir}'$strip''
 346     fi
 347 ])
 348
 349
 350 AC_DEFUN(STEPMAKE_END, [
 351     STEPMAKE_PREFIX_EXPAND_FIXUP
 352
 353     AC_SUBST(OPTIONAL)
 354     AC_SUBST(REQUIRED)
 355
 356     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 357     AC_OUTPUT
 358
 359     if test -n "$OPTIONAL"; then
 360         echo
 361         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 362     fi
 363
 364     if test -n "$REQUIRED"; then
 365         echo
 366         echo "ERROR: Please install required programs: $REQUIRED"
 367     fi
 368
 369     if test -n "$UNSUPPORTED"; then
 370         echo
 371         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 372     fi
 373
 374     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 375         echo
 376         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 377         if test -f config.cache ; then
 378             echo "Remove config.cache before rerunning ./configure"
 379         fi
 380     fi
 381
 382     if test -n "$REQUIRED$UNSUPPORTED"; then
 383         rm -f $srcdir/GNUmakefile
 384         exit 1
 385     fi
 386
 387     # regular in-place build
 388     # test for srcdir_build = yes ?
 389     if test "$srcdir_build" = "yes"; then
 390         rm -f $srcdir/GNUmakefile
 391         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 392         chmod 444 $srcdir/GNUmakefile
 393     else
 394         if test -f $srcdir/GNUmakefile; then
 395             cat <<EOF
 396 Source directory already configured.  Please clean the source directory
 397
 398      make -C $srcdir distclean
 399
 400 and rerun configure.
 401 EOF
 402             exit 2
 403         fi
 404
 405         for d in 2 3 4 ; do
 406             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name GNUmakefile`; do
 407                 mkdir -p $(dirname $mf)
 408                 cat <<EOF | $PYTHON -  > $mf
 409 print 'depth=' + ('../' * ( $d-1 ) )
 410 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 411 print 'include \$(configure-srcdir)/$mf'
 412 print 'MODULE_INCLUDES += \$(src-dir)/\$(outbase)'
 413 EOF
 414             done
 415             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 416                 mkdir -p $(dirname $mf)
 417                 cat <<EOF | $PYTHON -  > $mf
 418 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 419 print 'include \$(configure-srcdir)/$mf'
 420 EOF
 421             done
 422         done
 423
 424
 425         cat <<EOF > GNUmakefile
 426 depth = ./
 427 include config\$(if \$(conf),-\$(conf),).make
 428 include \$(configure-srcdir)/GNUmakefile.in
 429 EOF
 430         AC_SUBST(VPATH)
 431     fi
 432 ])
 433
 434
 435 AC_DEFUN(STEPMAKE_FLEX, [
 436     # ugh, automake: we want (and check for) flex
 437     # AC_PROG_LEX
 438     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 439
 440     # AC_PROG_LEX()
 441     # ugh, ugh
 442     ac_cv_prog_lex_root=lex.yy
 443     STEPMAKE_PROGS(FLEX, flex, $1)
 444 ])
 445
 446
 447 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 448     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 449     if test $? -ne 0; then
 450         warn='FlexLexer.h (flex package)'
 451         STEPMAKE_ADD_ENTRY($1, $warn)
 452     fi
 453     # check for yyFlexLexer.yy_current_buffer,
 454     # in 2.5.4 <= flex < 2.5.29
 455     AC_LANG_PUSH(C++)
 456     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 457         [stepmake_cv_flexlexer_yy_current_buffer],
 458         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 459 using namespace std;
 460 #include <FlexLexer.h>
 461 class yy_flex_lexer: public yyFlexLexer
 462 {
 463   public:
 464     yy_flex_lexer ()
 465     {
 466       yy_current_buffer = 0;
 467     }
 468 };
 469 ]])],
 470             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 471             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 472     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 473         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 474     fi
 475     AC_LANG_POP(C++)
 476 ])
 477
 478
 479
 480 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 481         AC_MSG_CHECKING([FlexLexer.h location])
 482
 483         # ugh.
 484         cat <<EOF > conftest.cc
 485 using namespace std;
 486 #include <FlexLexer.h>
 487 EOF
 488         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 489           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 490           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 491         rm conftest.cc
 492         AC_SUBST(FLEXLEXER_FILE)
 493         AC_MSG_RESULT($FLEXLEXER_FILE)
 494 ])
 495
 496 AC_DEFUN(STEPMAKE_GCC, [
 497     if test "$GCC" = "yes"; then
 498         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 499     else
 500         warn="$CC (Please install *GNU* cc)"
 501         STEPMAKE_ADD_ENTRY($1, $warn)
 502     fi
 503 ])
 504
 505 AC_DEFUN(STEPMAKE_GETTEXT, [
 506     presome=${prefix}
 507     if test "$prefix" = "NONE"; then
 508             presome=${ac_default_prefix}
 509     fi
 510     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 511
 512     AC_SUBST(localedir)
 513     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 514     # ouch.  autoconf <= 2.57's gettext check fails for
 515     # g++ >= 3.3 (with -std=gnu++98, the default).
 516     # While the check is OK for g++ -std=c++98,
 517     # LilyPond needs GNU g++, so who is to blame here?
 518     # Use a workaround until this is resolved:
 519     # for g++ >= 3.3, select C language.
 520     GCC_UNSUPPORTED=
 521     STEPMAKE_CHECK_VERSION_UNSUPPORTED(CXX, GCC_UNSUPPORTED, 3.3)
 522     if test -n "$GCC_UNSUPPORTED"; then
 523         AC_MSG_WARN([autoconf <= 2.59 with g++ >= 3.3 gettext test broken.])
 524         AC_MSG_WARN([Trying gcc, cross fingers.])
 525         AC_LANG_PUSH(C)
 526     fi
 527     AC_CHECK_LIB(intl, gettext)
 528     AC_CHECK_FUNCS(gettext)
 529     if test -n "$GCC_UNSUPPORTED"; then
 530         AC_LANG_POP(C)
 531     fi
 532 ])
 533
 534
 535 AC_DEFUN(STEPMAKE_GUILE, [
 536     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 537 ])
 538
 539
 540 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 541 #
 542 #   This macro runs the guile-config script, installed with Guile,
 543 #   to find out where Guile's header files and libraries are
 544 #   installed.  It sets two variables, marked for substitution, as
 545 #   by AC_SUBST.
 546 #
 547 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 548 #             code that uses Guile header files.  This is almost
 549 #             always just a -I flag.
 550 #
 551 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 552 #             program against Guile.  This includes -lguile for
 553 #             the Guile library itself, any libraries that Guile
 554 #             itself requires (like -lqthreads), and so on.  It may
 555 #             also include a -L flag to tell the compiler where to
 556 #             find the libraries.
 557
 558 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 559     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 560     if test -x $exe; then
 561         AC_MSG_CHECKING([guile compile flags])
 562         GUILE_CFLAGS="`$guile_config compile`"
 563         AC_MSG_RESULT($GUILE_CFLAGS)
 564         AC_MSG_CHECKING([guile link flags])
 565         GUILE_LDFLAGS="`$guile_config link`"
 566         AC_MSG_RESULT($GUILE_LDFLAGS)
 567     fi
 568     AC_SUBST(GUILE_CFLAGS)
 569     AC_SUBST(GUILE_LDFLAGS)
 570 ])
 571
 572
 573 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 574     ## First, let's just see if we can find Guile at all.
 575     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 576     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 577     AC_MSG_CHECKING([for guile-config])
 578     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config; do
 579         AC_MSG_RESULT([$guile_config])
 580         if ! $guile_config --version > /dev/null 2>&1 ; then
 581             AC_MSG_WARN([cannot execute $guile_config])
 582             AC_MSG_CHECKING([if we are cross compiling])
 583             GUILE_CONFIG='echo no guile-config'
 584         else
 585             GUILE_CONFIG=$guile_config
 586             break
 587         fi
 588     done
 589     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 590     if test $? -ne 0; then
 591         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 592     fi
 593
 594     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 595     # urg.  should test functionality rather than version.
 596     if test $? -eq 0 -a -n "$2"; then
 597         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 598     fi
 599
 600     AC_SUBST(GUILE_CONFIG)
 601
 602     guile_version="$ver"
 603     changequote(<<, >>)#dnl
 604     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 605     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 606     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 607     changequote([, ])#dnl
 608     STEPMAKE_GUILE_FLAGS
 609     save_CPPFLAGS="$CPPFLAGS"
 610     save_LIBS="$LIBS"
 611     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 612     LIBS="$GUILE_LDFLAGS $LIBS"
 613     AC_CHECK_HEADERS([libguile.h])
 614     AC_CHECK_LIB(guile, scm_boot_guile)
 615     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 616     if test "$libguile_b" = "no"; then
 617             warn='libguile (libguile-dev, guile-devel or guile-dev
 618    package).'
 619             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 620     fi
 621     CPPFLAGS="$save_CPPFLAGS"
 622     LIBS="$save_LIBS"
 623     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 624     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 625     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 626 ])
 627
 628
 629 AC_DEFUN(STEPMAKE_DLOPEN, [
 630     AC_CHECK_LIB(dl, dlopen)
 631     AC_CHECK_FUNCS(dlopen)
 632 ])
 633
 634 AC_DEFUN(STEPMAKE_GXX, [
 635     if test "$GXX" = "yes"; then
 636         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 637     else
 638         warn="$CXX (Please install *GNU* c++)"
 639         STEPMAKE_ADD_ENTRY($1, $warn)
 640     fi
 641 ])
 642
 643
 644 AC_DEFUN(STEPMAKE_INIT, [
 645
 646     . $srcdir/VERSION
 647     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 648     MICRO_VERSION=$PATCH_LEVEL
 649     TOPLEVEL_VERSION=$FULL_VERSION
 650     if test x$MY_PATCH_LEVEL != x; then
 651         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 652     fi
 653     VERSION=$FULL_VERSION
 654     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 655     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 656     changequote(<<, >>)#dnl
 657     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 658     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 659     changequote([, ])#dnl
 660
 661     # No versioning on directory names of sub-packages
 662     # urg, urg
 663     stepmake=${datadir}/stepmake
 664     presome=${prefix}
 665     if test "$prefix" = "NONE"; then
 666             presome=${ac_default_prefix}
 667     fi
 668     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 669
 670     # urg, how is this supposed to work?
 671     if test "$program_prefix" = "NONE"; then
 672           program_prefix=
 673     fi
 674     if test "$program_suffix" = "NONE"; then
 675           program_suffix=
 676     fi
 677
 678     AC_MSG_CHECKING(Package)
 679     if test "$PACKAGE" = "STEPMAKE"; then
 680         AC_MSG_RESULT(Stepmake package!)
 681
 682         AC_MSG_CHECKING(builddir)
 683
 684         ugh_ugh_autoconf250_builddir="`pwd`"
 685
 686         if test "$srcdir" = "."; then
 687             srcdir_build=yes
 688         else
 689             srcdir_build=no
 690             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 691             package_srcdir="`dirname  $srcdir`"
 692         fi
 693         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 694
 695         (cd stepmake 2>/dev/null || mkdir stepmake)
 696         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 697         stepmake=stepmake
 698     else
 699         AC_MSG_RESULT($PACKAGE)
 700
 701         AC_MSG_CHECKING(builddir)
 702         ugh_ugh_autoconf250_builddir="`pwd`"
 703
 704         here_dir=$(cd . && pwd)
 705         full_src_dir=$(cd $srcdir && pwd)
 706
 707         if test "$full_src_dir" = "$here_dir"; then
 708             srcdir_build=yes
 709         else
 710             srcdir_build=no
 711         fi
 712         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 713
 714         AC_MSG_CHECKING(for stepmake)
 715         # Check for installed stepmake
 716         if test -d $stepmake; then
 717             AC_MSG_RESULT($stepmake)
 718         else
 719             stepmake="`cd $srcdir/stepmake; pwd`"
 720             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 721         fi
 722     fi
 723
 724     AC_SUBST(ugh_ugh_autoconf250_builddir)
 725
 726     # Use absolute directory for non-srcdir builds, so that build
 727     # dir can be moved.
 728     if test "$srcdir_build" = "no" ;  then
 729         srcdir="`cd $srcdir; pwd`"
 730     fi
 731
 732     AC_SUBST(srcdir)
 733     AC_SUBST(stepmake)
 734     AC_SUBST(package)
 735     AC_SUBST(PACKAGE)
 736     AC_SUBST(PACKAGE_NAME)
 737     AC_SUBST(VERSION)
 738     AC_SUBST(MAJOR_VERSION)
 739     AC_SUBST(MINOR_VERSION)
 740     AC_SUBST(MICRO_VERSION)
 741
 742     # stepmake nonstandard names
 743     AC_SUBST(PATCH_LEVEL)
 744     AC_SUBST(TOPLEVEL_VERSION)
 745
 746     # We don't need the upper case variant,
 747     # so stick to macros are uppercase convention.
 748     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 749     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 750     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 751     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 752     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 753
 754     if test -z "$package_depth"; then
 755         package_depth="."
 756     else
 757         package_depth="../$package_depth"
 758     fi
 759     export package_depth
 760     AC_SUBST(package_depth)
 761
 762     AUTOGENERATE="This file was automatically generated by configure"
 763     AC_SUBST(AUTOGENERATE)
 764
 765     CONFIGSUFFIX=
 766     AC_ARG_ENABLE(config,
 767     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 768                             do `make conf=CONF' to get output in ./out-CONF],
 769     [CONFIGURATION=$enableval])
 770
 771     ##'`#
 772
 773     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 774     CONFIGFILE=config$CONFIGSUFFIX
 775     AC_SUBST(CONFIGSUFFIX)
 776
 777     AC_CANONICAL_HOST
 778     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 779     STEPMAKE_PROGS(FIND, find, REQUIRED)
 780
 781     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 782
 783     if test "$(echo 2)" != "2" ||
 784         test "x`uname`" = "xHP-UX"; then
 785         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 786         AC_PATH_PROG(BASH, bash, $KSH)
 787         STEPMAKE_WARN(avoiding buggy /bin/sh)
 788         AC_PATH_PROG(SHELL, bash, $KSH)
 789     else
 790         SHELL=/bin/sh
 791         AC_PATH_PROG(BASH, bash, $SHELL)
 792     fi
 793     AC_SUBST(SHELL)
 794
 795     STEPMAKE_PYTHON(REQUIRED, 1.5)
 796
 797     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 798         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 799         if test "$?" = 1; then
 800             warn='make (Please install *GNU* make)'
 801             # STEPMAKE_WARN($warn)
 802             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 803         fi
 804     fi
 805
 806     ROOTSEP=':'
 807     DIRSEP='/'
 808     PATHSEP=':'
 809     LN=ln
 810     LN_S='ln -s'
 811     ZIP="zip -r -9"
 812
 813     AC_SUBST(program_prefix)
 814     AC_SUBST(program_suffix)
 815     AC_SUBST(ZIP)
 816     AC_SUBST(LN)
 817     AC_SUBST(LN_S)
 818     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 819     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 820     AC_SUBST(DIRSEP)
 821     AC_SUBST(PATHSEP)
 822     AC_SUBST(ROOTSEP)
 823
 824     STEPMAKE_DATADIR
 825     STEPMAKE_LIBDIR
 826 ])
 827
 828
 829 AC_DEFUN(STEPMAKE_LIB, [
 830     STEPMAKE_PROGS(AR, ar, $1)
 831     AC_PROG_RANLIB
 832     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 833 ])
 834
 835
 836 AC_DEFUN(STEPMAKE_LIBTOOL, [
 837     # libtool.info ...
 838     # **Never** try to set library version numbers so that they correspond
 839     # to the release number of your package.  This is an abuse that only
 840     # fosters misunderstanding of the purpose of library versions.
 841
 842     REVISION=$PATCH_LEVEL
 843     # CURRENT=$MINOR_VERSION
 844     CURRENT=`expr $MINOR_VERSION + 1`
 845     # AGE=`expr $MAJOR_VERSION + 1`
 846     AGE=$MAJOR_VERSION
 847     AC_SUBST(CURRENT)
 848     AC_SUBST(REVISION)
 849     AC_SUBST(AGE)
 850 ])
 851
 852
 853 AC_DEFUN(STEPMAKE_LOCALE, [
 854     lang=English
 855     ALL_LINGUAS="en nl"
 856
 857     # with/enable ??
 858     AC_ARG_WITH(localedir,
 859     [  --with-localedir=DIR    location of locales.  Default: PREFIX/share/locale ],
 860     localedir=$with_localedir,
 861     localedir='${prefix}/share/locale')
 862
 863     AC_ARG_WITH(lang,
 864     [  --with-lang=LANG        use LANG as language to emit messages],
 865     language=$with_lang,
 866     language=English)
 867
 868     AC_MSG_CHECKING(language)
 869     case "$language" in
 870       En* | en* | Am* | am* | US* | us*)
 871             lang=English;;
 872       NL | nl | Du* | du* | Ned* | ned*)
 873             lang=Dutch;;
 874       "")
 875             lang=English;;
 876       *)
 877             lang=unknown;;
 878     esac
 879     AC_MSG_RESULT($lang)
 880
 881     if test "$lang" = "unknown" ; then
 882         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 883     fi
 884
 885 ])
 886
 887
 888 AC_DEFUN(STEPMAKE_MAKEINFO, [
 889     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 890 ])
 891
 892
 893 AC_DEFUN(STEPMAKE_MAN, [
 894     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 895     AC_SUBST(GROFF)
 896     STEPMAKE_PROGS(TROFF, troff, $1)
 897     AC_SUBST(TROFF)
 898     STEPMAKE_PROGS(TBL, tbl, $1)
 899     AC_SUBST(TBL)
 900 ])
 901
 902
 903 AC_DEFUN(STEPMAKE_MSGFMT, [
 904     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 905 ])
 906
 907
 908 # Check for program ($2), set full path result to ($1).
 909 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 910 AC_DEFUN(STEPMAKE_PATH_PROG, [
 911     AC_CHECK_PROGS($1, $2, no)
 912     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 913     if test $? -eq 0; then
 914         AC_PATH_PROG($1, $2)
 915         if test -n "$4"; then
 916             STEPMAKE_CHECK_VERSION($1, $3, $4)
 917         fi
 918     fi
 919 ])
 920
 921
 922 # Check for program in set of names ($2), set result to ($1) .
 923 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 924 # If exists, and a minimal version ($4) is required
 925 AC_DEFUN(STEPMAKE_PROGS, [
 926     AC_CHECK_PROGS($1, $2, no)
 927     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 928     if test $? -eq 0 -a -n "$4"; then
 929         STEPMAKE_CHECK_VERSION($1, $3, $4)
 930     fi
 931 ])
 932
 933
 934 AC_DEFUN(STEPMAKE_PERL, [
 935     STEPMAKE_PATH_PROG(PERL, perl, $1)
 936 ])
 937
 938
 939 AC_DEFUN(STEPMAKE_PYTHON, [
 940     unset pv
 941     AC_MSG_CHECKING([for python])
 942     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 943         AC_MSG_RESULT([$python])
 944         if ! $python -V > /dev/null 2>&1 ; then
 945             #AC_MSG_WARN([cannot execute $python])
 946             PYTHON='echo no python'
 947         else
 948             unset pv
 949             STEPMAKE_CHECK_VERSION(python, pv, $2)
 950             if test -z "$pv"; then
 951                 PYTHON=$python
 952                 break
 953             fi
 954         fi
 955     done
 956     if test -n "$pv"; then
 957         STEPMAKE_ADD_ENTRY($1, $pv)
 958     fi
 959     # clear cached value since arg 2 might point us to a new binary
 960     unset ac_cv_path_PYTHON
 961
 962     AC_PATH_PROG(PYTHON, $PYTHON)
 963     AC_SUBST(PYTHON)
 964 ])
 965
 966 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 967     AC_ARG_WITH(python-include,
 968         [  --with-python-include=DIR
 969                           location of the python include dir],[
 970             if test "$withval" = "yes" -o "$withval" = "no"; then
 971                 AC_MSG_WARN(Usage: --with-python-include=includedir)
 972             else
 973                 PYTHON_CFLAGS="-I${withval}"
 974             fi
 975             ])
 976
 977     AC_ARG_WITH(python-lib,
 978         [  --with-python-lib=NAME  name of the python lib],[
 979             if test "$withval" = "yes" -o "$withval" = "no"; then
 980                 AC_MSG_WARN(Usage: --with-python-lib=name)
 981             else
 982                 LDFLAGS="$LDFLAGS -l${withval}"
 983             fi
 984             ])
 985
 986     AC_CHECK_PROGS(PYTHON_CONFIG, python-config, no)
 987
 988     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
 989         # Clean out junk: http://bugs.python.org/issue3290
 990         # Python headers may need some -f* flags, leave them in.
 991         # We want the sed commands to look like 's/-[WDOm][[:alnum:][:punct:]][[:alnum:][:punct:]]*//g' and 's/-arch [^[:space:]]*//g', but automake eats brackets.
 992         PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
 993         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 994     fi
 995
 996     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
 997         changequote(<<, >>)#dnl
 998         # alternatively, for python >= 2.0
 999         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
1000         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
1001         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
1002         changequote([, ])#dnl
1003     fi
1004
1005     if test -z "$PYTHON_HEADER"; then
1006         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
1007         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
1008     fi
1009
1010     if test -z "$PYTHON_HEADER"; then
1011         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1012         STEPMAKE_ADD_ENTRY($1, $warn)
1013     fi
1014 ])
1015
1016
1017
1018 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1019     AC_LANG_PUSH(C++)
1020     AC_CACHE_CHECK([for stl.data () method],
1021         [stepmake_cv_stl_data_method],
1022         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1023 #include <vector>
1024 using namespace std;
1025 vector <int> v;
1026 void *p = v.data ();
1027 ]])],
1028             [stepmake_cv_stl_data_method=yes],
1029             [stepmake_cv_stl_data_method=no]))
1030     if test $stepmake_cv_stl_data_method = yes; then
1031         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1032     fi
1033     AC_LANG_POP(C++)
1034 ])
1035
1036
1037 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1038     # ugh
1039     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1040 ])
1041
1042 AC_DEFUN(STEPMAKE_TEXMF, [
1043     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1044     STEPMAKE_PROGS(METAPOST, mpost, $1)
1045     # STEPMAKE_PROGS(INIMETAFONT, inimf inimfont "$METAFONT -ini", $1)
1046
1047     AC_MSG_CHECKING(for working metafont mode)
1048     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1049     for MFMODE in $modelist; do
1050         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1051         if test -f mfput.tfm; then
1052             break;
1053         fi
1054     done
1055     AC_MSG_RESULT($MFMODE)
1056
1057     rm -f mfput.*
1058
1059     AC_SUBST(MFMODE)
1060 ])
1061
1062
1063 AC_DEFUN(STEPMAKE_WARN, [
1064     AC_MSG_WARN($1)
1065     warn_b=yes
1066 ])
1067
1068
1069 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1070 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1071 dnl also defines GSTUFF_PKG_ERRORS on error
1072 AC_DEFUN(PKG_CHECK_MODULES, [
1073   succeeded=no
1074
1075   if test -z "$PKG_CONFIG"; then
1076     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1077   fi
1078
1079   if test "$PKG_CONFIG" = "no" ; then
1080      echo "*** The pkg-config script could not be found. Make sure it is"
1081      echo "*** in your path, or set the PKG_CONFIG environment variable"
1082      echo "*** to the full path to pkg-config."
1083      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1084   else
1085      PKG_CONFIG_MIN_VERSION=0.9.0
1086      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1087         AC_MSG_CHECKING(for $2)
1088
1089         if $PKG_CONFIG --exists "$2" ; then
1090             AC_MSG_RESULT(yes)
1091             succeeded=yes
1092
1093             AC_MSG_CHECKING($1_CFLAGS)
1094             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1095             AC_MSG_RESULT($$1_CFLAGS)
1096
1097             AC_MSG_CHECKING($1_LIBS)
1098             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1099             AC_MSG_RESULT($$1_LIBS)
1100         else
1101             $1_CFLAGS=""
1102             $1_LIBS=""
1103             ## If we have a custom action on failure, don't print errors, but
1104             ## do set a variable so people can do so.
1105             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1106             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1107         fi
1108
1109         AC_SUBST($1_CFLAGS)
1110         AC_SUBST($1_LIBS)
1111      fi
1112   fi
1113
1114   if test $succeeded = yes; then
1115      ifelse([$3], , :, [$3])
1116   else
1117      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1118   fi
1119 ])
1120
1121 AC_DEFUN(STEPMAKE_FREETYPE2, [
1122     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1123     if test "$have_freetype2" = yes; then
1124         AC_DEFINE(HAVE_FREETYPE2)
1125         save_CPPFLAGS="$CPPFLAGS"
1126         save_LIBS="$LIBS"
1127         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1128         LIBS="$FREETYPE2_LIBS $LIBS"
1129         AC_SUBST(FREETYPE2_CFLAGS)
1130         AC_SUBST(FREETYPE2_LIBS)
1131         CPPFLAGS="$save_CPPFLAGS"
1132         LIBS="$save_LIBS"
1133     else
1134         # UGR
1135         #r="lib$1-dev or $1-devel"
1136         r="libfreetype6-dev or freetype?-devel"
1137         ver="`pkg-config --modversion $1`"
1138         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1139     fi
1140 ])
1141
1142 AC_DEFUN(STEPMAKE_PANGO, [
1143     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1144     if test "$have_pango16" = yes ; then
1145         AC_DEFINE(HAVE_PANGO16)
1146         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1147         save_CPPFLAGS="$CPPFLAGS"
1148         save_LIBS="$LIBS"
1149         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1150         LIBS="$PANGO_LIBS $LIBS"
1151         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1152         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1153         AC_SUBST(PANGO_CFLAGS)
1154         AC_SUBST(PANGO_LIBS)
1155         CPPFLAGS="$save_CPPFLAGS"
1156         LIBS="$save_LIBS"
1157     else
1158         # UGR
1159         #r="lib$1-dev or $1-devel"
1160         r="libpango1.0-dev or pango1.0-devel"
1161         ver="`pkg-config --modversion $1`"
1162         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1163     fi
1164 ])
1165
1166 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1167     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1168     if test "$have_pangoft2" = yes ; then
1169         AC_DEFINE(HAVE_PANGO16)
1170         AC_DEFINE(HAVE_PANGO_FT2)
1171         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1172         save_CPPFLAGS="$CPPFLAGS"
1173         save_LIBS="$LIBS"
1174         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1175         LIBS="$PANGO_FT2_LIBS $LIBS"
1176         AC_CHECK_HEADERS([pango/pangoft2.h])
1177         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1178         AC_SUBST(PANGO_FT2_CFLAGS)
1179         AC_SUBST(PANGO_FT2_LIBS)
1180         CPPFLAGS="$save_CPPFLAGS"
1181         LIBS="$save_LIBS"
1182     else
1183         # UGR
1184         #r="lib$1-dev or $1-devel"e
1185         r="libpango1.0-dev or pango?-devel"
1186         ver="`pkg-config --modversion $1`"
1187         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1188     fi
1189 ])
1190
1191 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1192     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1193     if test "$have_fontconfig" = yes ; then
1194         AC_DEFINE(HAVE_FONTCONFIG)
1195         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1196         save_CPPFLAGS="$CPPFLAGS"
1197         save_LIBS="$LIBS"
1198         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1199         LIBS="$FONTCONFIG_LIBS $LIBS"
1200         AC_SUBST(FONTCONFIG_CFLAGS)
1201         AC_SUBST(FONTCONFIG_LIBS)
1202         CPPFLAGS="$save_CPPFLAGS"
1203         LIBS="$save_LIBS"
1204     else
1205         r="lib$1-dev or $1-devel"
1206         ver="`pkg-config --modversion $1`"
1207         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1208     fi
1209 ])
1210
1211 AC_DEFUN(STEPMAKE_WINDOWS, [
1212     AC_CYGWIN
1213     AC_MINGW32
1214
1215     if test "$CYGWIN" = "yes"; then
1216         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1217         program_suffix=.exe
1218         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1219     elif test "$MINGW32" = "yes"; then
1220         LN='cp -r'
1221         LN_S='cp -r'
1222         program_suffix=.exe
1223         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1224         PATHSEP=';'
1225     fi
1226
1227     AC_SUBST(LN)
1228     AC_SUBST(LN_S)
1229     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1230     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1231     AC_SUBST(DIRSEP)
1232     AC_SUBST(PATHSEP)
1233     AC_SUBST(program_suffix)
1234
1235     AC_MSG_CHECKING([for some flavor of Windows])
1236     if test "$CYGWIN$MINGW32" = "nono"; then
1237         PLATFORM_WINDOWS=no
1238     else
1239         PLATFORM_WINDOWS=yes
1240     fi
1241     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1242     AC_SUBST(PLATFORM_WINDOWS)
1243     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1244     AC_SUBST(WINDRES)
1245 ])