stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '\(^\| \)[0-9][0-9]*\.[0-9]' \
  36         | head -n 1 \
  37         | tr ' ' '\n' | sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' | grep '\(^\| \)[0-9][0-9]*\.[0-9]' | head -n 1\`\"
  38
  39     if test -z "$_ver"; then
  40         ## If empty, try date [fontforge]
  41         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  42             | head -n 1 \
  43             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  44     fi
  45     echo "$_ver"
  46     changequote([, ])#dnl
  47 ])
  48
  49 # Calculate simplistic numeric version from version string ($1)
  50 # As yet, we have no need for something more elaborate.
  51 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  52     echo "$1" | awk -F. '
  53     {
  54       if ([$]3) {three = [$]3}
  55       else {three = 0}
  56     }
  57     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  58 ])
  59
  60
  61 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  62 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  63     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  64 ])
  65
  66 # Check if tested program ($2) was found ($1).
  67 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  68 # We could abort here if a 'REQUIRED' program is not found
  69 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  70     STEPMAKE_CHECK_SEARCH_RESULT($1)
  71     if test $? -ne 0; then
  72         STEPMAKE_ADD_ENTRY($3, $2)
  73         if test "$3" = "REQUIRED"; then
  74             command="echo ERROR: $2 not found"
  75             # abort configure process here?
  76         else
  77             command="- echo $2 not found"
  78         fi
  79         eval "$1"='$command'
  80         false
  81     else
  82         true
  83     fi
  84 ])
  85
  86
  87 # Return if tested proram ($1) was found (true) or not (false).
  88 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  89     r="`eval echo '$'"$1"`"
  90     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  91         true
  92     else
  93         ##STEPMAKE_WARN(cannot find $2. $3)
  94         false
  95     fi
  96 ])
  97
  98
  99 # Check version of program ($1)
 100 # If version ($4: optional argument, supply if version cannot be
 101 # parsed using --version or -V ) is smaller than requested ($3), add
 102 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 103 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 104     r="`eval echo '$'"$1"`"
 105     AC_MSG_CHECKING([$r version])
 106     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 107     if test -n "$4"; then
 108         ver="$4"
 109     else
 110         ver=`STEPMAKE_GET_VERSION($exe)`
 111     fi
 112     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 113     req=`STEPMAKE_NUMERIC_VERSION($3)`
 114     AC_MSG_RESULT([$ver])
 115     if test "$num" -lt "$req"; then
 116         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 117     fi
 118     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 119     eval `echo $vervar=$num`
 120 ##    AC_SUBST(`eval echo $vervar`)
 121 ])
 122
 123 # Check version of program ($1)
 124 # If version is greater than or equals unsupported ($3),
 125 # add entry to unsupported list ($2, 'UNSUPPORTED')
 126 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 127     r="`eval echo '$'"$1"`"
 128     AC_MSG_CHECKING([$r version])
 129     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 130     ver=`STEPMAKE_GET_VERSION($exe)`
 131     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 132     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 133     AC_MSG_RESULT([$ver])
 134     if test "$num" -ge "$sup"; then
 135         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 136     fi
 137 ])
 138
 139 ### Macros to build configure.in
 140
 141
 142 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 143     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 144     if test "$BIBTEX2HTML" = "bib2html"; then
 145         BIBTEX2HTML_FLAGS='$< $(@)'
 146     else
 147         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 148     fi
 149     AC_SUBST(BIBTEX2HTML)
 150     AC_SUBST(BIBTEX2HTML_FLAGS)
 151 ])
 152
 153
 154 AC_DEFUN(STEPMAKE_BISON, [
 155     # ugh, automake: we want (and check for) bison
 156     AC_PROG_YACC
 157
 158     STEPMAKE_PROGS(BISON, bison, $1)
 159
 160     # urg.  should test functionality rather than version.
 161     if test "$BISON" = "bison" -a -n "$2"; then
 162         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 163     fi
 164 ])
 165
 166
 167 AC_DEFUN(STEPMAKE_COMPILE, [
 168     # -O is necessary to get inlining
 169     CFLAGS=${CFLAGS-""}
 170     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 171     LDFLAGS=${LDFLAGS-""}
 172     optimise_b=yes
 173     profile_b=no
 174     debug_b=yes
 175     pipe_b=yes
 176
 177     AC_ARG_ENABLE(debugging,
 178     [  --enable-debugging      compile with debugging info.  Default: on],
 179     [debug_b=$enableval])
 180
 181     AC_ARG_ENABLE(optimising,
 182     [  --enable-optimising     compile with optimising.  Default: on],
 183     [optimise_b=$enableval])
 184
 185     AC_ARG_ENABLE(profiling,
 186     [  --enable-profiling      compile with gprof support.  Default: off],
 187     [profile_b=$enableval])
 188
 189     AC_ARG_ENABLE(pipe,
 190     [  --enable-pipe           compile with -pipe.  Default: on],
 191     [pipe_b=$enableval])
 192
 193     if test "$optimise_b" = yes; then
 194         AC_DEFINE(NDEBUG)
 195         DEFINES="$DEFINES -DNDEBUG"
 196         OPTIMIZE=" -O2 -finline-functions"
 197     fi
 198
 199     if test $profile_b = yes; then
 200         EXTRA_LIBS="-pg"
 201         OPTIMIZE="$OPTIMIZE -pg"
 202     fi
 203
 204     if test $debug_b = yes; then
 205         OPTIMIZE="$OPTIMIZE -g"
 206     fi
 207
 208     AC_PROG_CC
 209     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 210     LD='$(CC)'
 211     AC_SUBST(LD)
 212
 213     # If -pipe requested, test if it works and add to CFLAGS.
 214     if test "$pipe_b" = yes; then
 215         save_cflags="$CFLAGS"
 216         CFLAGS=" -pipe $CFLAGS";
 217         AC_CACHE_CHECK([whether compiler understands -pipe],
 218             [stepmake_cv_cflags_pipe],
 219             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 220                 [stepmake_cv_cflags_pipe=yes],
 221                 [stepmake_cv_cflags_pipe=no]))
 222         CFLAGS=$save_cflags
 223         if test $stepmake_cv_cflags_pipe = yes; then
 224             OPTIMIZE="$OPTIMIZE -pipe"
 225         fi
 226     fi
 227
 228     CFLAGS="$CFLAGS $OPTIMIZE"
 229     CPPFLAGS=${CPPFLAGS-""}
 230
 231     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 232     save_cflags="$CFLAGS"
 233     case "$host" in
 234         alpha*-*-*)
 235             dnl should do compile test?
 236             AC_MSG_RESULT(-mieee)
 237             CFLAGS=" -mieee $CFLAGS"
 238             ;;
 239         *)
 240             AC_MSG_RESULT([none])
 241             ;;
 242     esac
 243
 244     AC_SUBST(cross_compiling)
 245     AC_SUBST(CFLAGS)
 246     AC_SUBST(CPPFLAGS)
 247     AC_SUBST(LDFLAGS)
 248     AC_SUBST(DEFINES)
 249     AC_SUBST(EXTRA_LIBS)
 250 ])
 251
 252 AC_DEFUN(STEPMAKE_CXX, [
 253     AC_LANG([C++])
 254     AC_PROG_CXX
 255     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 256
 257     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 258     LD='$(CXX)'
 259
 260     AC_SUBST(CXX)
 261     AC_SUBST(CXXFLAGS)
 262     AC_SUBST(LD)
 263 ])
 264
 265
 266 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 267     AC_CACHE_CHECK([whether explicit instantiation is needed],
 268         stepmake_cv_need_explicit_instantiation,
 269         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 270     template <class T> struct foo { static int baz; };
 271     template <class T> int foo<T>::baz = 1;
 272     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 273     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 274         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 275     fi
 276 ])
 277
 278
 279 AC_DEFUN(STEPMAKE_DATADIR, [
 280     if test "$datadir" = "\${prefix}/share"; then
 281             datadir='${prefix}/share'
 282     fi
 283     presome=${prefix}
 284     if test "$prefix" = "NONE"; then
 285         presome=${ac_default_prefix}
 286     fi
 287
 288     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 289
 290     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 291     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 292     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 293
 294     AC_SUBST(datadir)
 295     AC_SUBST(datarootdir)
 296     AC_SUBST(build_package_datadir)
 297     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 298     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 299 ])
 300
 301 ## ugh: cut & paste programming from datadir.
 302 AC_DEFUN(STEPMAKE_LIBDIR, [
 303
 304     if test "$libdir" = "\${exec_prefix}/lib"; then
 305         libdir='${exec_prefix}/lib'
 306     fi
 307     presome=$exec_prefix
 308     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 309
 310     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 311     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 312
 313     AC_SUBST(libdir)
 314     AC_SUBST(build_package_libdir)
 315     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 316     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 317 ])
 318
 319
 320 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 321     # undo expanding of explicit --infodir=/usr/share
 322     # to ease install-time override with prefix=...
 323     strip=`echo $includedir | eval sed s@^$prefix@@`
 324     if test "$includedir" = "`eval echo $prefix$strip`"; then
 325             includedir='${prefix}'$strip''
 326     fi
 327     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 328     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 329             libdir='${exec_prefix}'$strip''
 330     fi
 331     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 332     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 333             infodir='${datarootdir}'$strip''
 334     fi
 335     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 336     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 337             mandir='${datarootdir}'$strip''
 338     fi
 339 ])
 340
 341
 342 AC_DEFUN(STEPMAKE_END, [
 343     STEPMAKE_PREFIX_EXPAND_FIXUP
 344
 345     AC_SUBST(OPTIONAL)
 346     AC_SUBST(REQUIRED)
 347
 348     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 349     AC_OUTPUT
 350
 351     if test -n "$OPTIONAL"; then
 352         echo
 353         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 354     fi
 355
 356     if test -n "$REQUIRED"; then
 357         echo
 358         echo "ERROR: Please install required programs: $REQUIRED"
 359     fi
 360
 361     if test -n "$UNSUPPORTED"; then
 362         echo
 363         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 364     fi
 365
 366     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 367         echo
 368         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 369         if test -f config.cache ; then
 370             echo "Remove config.cache before rerunning ./configure"
 371         fi
 372     fi
 373
 374     if test -n "$REQUIRED$UNSUPPORTED"; then
 375         rm -f $srcdir/GNUmakefile
 376         exit 1
 377     fi
 378
 379     # regular in-place build
 380     # test for srcdir_build = yes ?
 381     if test "$srcdir_build" = "yes"; then
 382         rm -f $srcdir/GNUmakefile
 383         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 384         chmod 444 $srcdir/GNUmakefile
 385     else
 386         if test -f $srcdir/GNUmakefile; then
 387             cat <<EOF
 388 Source directory already configured.  Please clean the source directory
 389
 390      make -C $srcdir distclean
 391
 392 and rerun configure.
 393 EOF
 394             exit 2
 395         fi
 396
 397         for d in 2 3 4 ; do
 398             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name GNUmakefile`; do
 399                 mkdir -p $(dirname $mf)
 400                 cat <<EOF | $PYTHON -  > $mf
 401 print 'depth=' + ('../' * ( $d-1 ) )
 402 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 403 print 'include \$(configure-srcdir)/$mf'
 404 EOF
 405             done
 406             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 407                 mkdir -p $(dirname $mf)
 408                 cat <<EOF | $PYTHON -  > $mf
 409 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 410 print 'include \$(configure-srcdir)/$mf'
 411 EOF
 412             done
 413         done
 414
 415
 416         cat <<EOF > GNUmakefile
 417 depth = ./
 418 include config\$(if \$(conf),-\$(conf),).make
 419 include \$(configure-srcdir)/GNUmakefile.in
 420 EOF
 421         AC_SUBST(VPATH)
 422     fi
 423 ])
 424
 425
 426 AC_DEFUN(STEPMAKE_FLEX, [
 427     # ugh, automake: we want (and check for) flex
 428     # AC_PROG_LEX
 429     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 430
 431     # AC_PROG_LEX()
 432     # ugh, ugh
 433     ac_cv_prog_lex_root=lex.yy
 434     STEPMAKE_PROGS(FLEX, flex, $1)
 435 ])
 436
 437
 438 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 439     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 440     if test $? -ne 0; then
 441         warn='FlexLexer.h (flex package)'
 442         STEPMAKE_ADD_ENTRY($1, $warn)
 443     fi
 444     # check for yyFlexLexer.yy_current_buffer,
 445     # in 2.5.4 <= flex < 2.5.29
 446     AC_LANG_PUSH(C++)
 447     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 448         [stepmake_cv_flexlexer_yy_current_buffer],
 449         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 450 using namespace std;
 451 #include <FlexLexer.h>
 452 class yy_flex_lexer: public yyFlexLexer
 453 {
 454   public:
 455     yy_flex_lexer ()
 456     {
 457       yy_current_buffer = 0;
 458     }
 459 };
 460 ]])],
 461             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 462             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 463     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 464         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 465     fi
 466     AC_LANG_POP(C++)
 467 ])
 468
 469
 470
 471 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 472         AC_MSG_CHECKING([FlexLexer.h location])
 473
 474         # ugh.
 475         cat <<EOF > conftest.cc
 476 using namespace std;
 477 #include <FlexLexer.h>
 478 EOF
 479         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 480           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 481           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 482         rm conftest.cc
 483         AC_SUBST(FLEXLEXER_FILE)
 484         AC_MSG_RESULT($FLEXLEXER_FILE)
 485 ])
 486
 487 AC_DEFUN(STEPMAKE_GCC, [
 488     if test "$GCC" = "yes"; then
 489         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 490     else
 491         warn="$CC (Please install *GNU* cc)"
 492         STEPMAKE_ADD_ENTRY($1, $warn)
 493     fi
 494 ])
 495
 496 AC_DEFUN(STEPMAKE_GETTEXT, [
 497     presome=${prefix}
 498     if test "$prefix" = "NONE"; then
 499             presome=${ac_default_prefix}
 500     fi
 501     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 502
 503     AC_SUBST(localedir)
 504     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 505     # ouch.  autoconf <= 2.57's gettext check fails for
 506     # g++ >= 3.3 (with -std=gnu++98, the default).
 507     # While the check is OK for g++ -std=c++98,
 508     # LilyPond needs GNU g++, so who is to blame here?
 509     # Use a workaround until this is resolved:
 510     # for g++ >= 3.3, select C language.
 511     GCC_UNSUPPORTED=
 512     STEPMAKE_CHECK_VERSION_UNSUPPORTED(CXX, GCC_UNSUPPORTED, 3.3)
 513     if test -n "$GCC_UNSUPPORTED"; then
 514         AC_MSG_WARN([autoconf <= 2.59 with g++ >= 3.3 gettext test broken.])
 515         AC_MSG_WARN([Trying gcc, cross fingers.])
 516         AC_LANG_PUSH(C)
 517     fi
 518     AC_CHECK_LIB(intl, gettext)
 519     AC_CHECK_FUNCS(gettext)
 520     if test -n "$GCC_UNSUPPORTED"; then
 521         AC_LANG_POP(C)
 522     fi
 523 ])
 524
 525
 526 AC_DEFUN(STEPMAKE_GUILE, [
 527     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 528 ])
 529
 530
 531 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 532 #
 533 #   This macro runs the guile-config script, installed with Guile,
 534 #   to find out where Guile's header files and libraries are
 535 #   installed.  It sets two variables, marked for substitution, as
 536 #   by AC_SUBST.
 537 #
 538 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 539 #             code that uses Guile header files.  This is almost
 540 #             always just a -I flag.
 541 #
 542 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 543 #             program against Guile.  This includes -lguile for
 544 #             the Guile library itself, any libraries that Guile
 545 #             itself requires (like -lqthreads), and so on.  It may
 546 #             also include a -L flag to tell the compiler where to
 547 #             find the libraries.
 548
 549 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 550     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 551     if test -x $exe; then
 552         AC_MSG_CHECKING([guile compile flags])
 553         GUILE_CFLAGS="`$guile_config compile`"
 554         AC_MSG_RESULT($GUILE_CFLAGS)
 555         AC_MSG_CHECKING([guile link flags])
 556         GUILE_LDFLAGS="`$guile_config link`"
 557         AC_MSG_RESULT($GUILE_LDFLAGS)
 558     fi
 559     AC_SUBST(GUILE_CFLAGS)
 560     AC_SUBST(GUILE_LDFLAGS)
 561 ])
 562
 563
 564 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 565     ## First, let's just see if we can find Guile at all.
 566     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 567     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 568     AC_MSG_CHECKING([for guile-config])
 569     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config; do
 570         AC_MSG_RESULT([$guile_config])
 571         if ! $guile_config --version > /dev/null 2>&1 ; then
 572             AC_MSG_WARN([cannot execute $guile_config])
 573             AC_MSG_CHECKING([if we are cross compiling])
 574             GUILE_CONFIG='echo no guile-config'
 575         else
 576             GUILE_CONFIG=$guile_config
 577             break
 578         fi
 579     done
 580     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 581     if test $? -ne 0; then
 582         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 583     fi
 584
 585     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 586     # urg.  should test functionality rather than version.
 587     if test $? -eq 0 -a -n "$2"; then
 588         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 589     fi
 590
 591     AC_SUBST(GUILE_CONFIG)
 592
 593     guile_version="$ver"
 594     changequote(<<, >>)#dnl
 595     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 596     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 597     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 598     changequote([, ])#dnl
 599     STEPMAKE_GUILE_FLAGS
 600     save_CPPFLAGS="$CPPFLAGS"
 601     save_LIBS="$LIBS"
 602     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 603     LIBS="$GUILE_LDFLAGS $LIBS"
 604     AC_CHECK_HEADERS([libguile.h])
 605     AC_CHECK_LIB(guile, scm_boot_guile)
 606     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 607     if test "$libguile_b" = "no"; then
 608             warn='libguile (libguile-dev, guile-devel or guile-dev
 609    package).'
 610             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 611     fi
 612     CPPFLAGS="$save_CPPFLAGS"
 613     LIBS="$save_LIBS"
 614     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 615     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 616     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 617 ])
 618
 619
 620 AC_DEFUN(STEPMAKE_DLOPEN, [
 621     AC_CHECK_LIB(dl, dlopen)
 622     AC_CHECK_FUNCS(dlopen)
 623 ])
 624
 625 AC_DEFUN(STEPMAKE_GXX, [
 626     if test "$GXX" = "yes"; then
 627         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 628     else
 629         warn="$CXX (Please install *GNU* c++)"
 630         STEPMAKE_ADD_ENTRY($1, $warn)
 631     fi
 632 ])
 633
 634
 635 AC_DEFUN(STEPMAKE_INIT, [
 636
 637     AC_PREREQ(2.50)
 638     . $srcdir/VERSION
 639     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 640     MICRO_VERSION=$PATCH_LEVEL
 641     TOPLEVEL_VERSION=$FULL_VERSION
 642     if test x$MY_PATCH_LEVEL != x; then
 643         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 644     fi
 645     VERSION=$FULL_VERSION
 646     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 647     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 648     changequote(<<, >>)#dnl
 649     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 650     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 651     changequote([, ])#dnl
 652
 653     # No versioning on directory names of sub-packages
 654     # urg, urg
 655     stepmake=${datadir}/stepmake
 656     presome=${prefix}
 657     if test "$prefix" = "NONE"; then
 658             presome=${ac_default_prefix}
 659     fi
 660     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 661
 662     # urg, how is this supposed to work?
 663     if test "$program_prefix" = "NONE"; then
 664           program_prefix=
 665     fi
 666     if test "$program_suffix" = "NONE"; then
 667           program_suffix=
 668     fi
 669
 670     AC_MSG_CHECKING(Package)
 671     if test "$PACKAGE" = "STEPMAKE"; then
 672         AC_MSG_RESULT(Stepmake package!)
 673
 674         AC_MSG_CHECKING(builddir)
 675
 676         ugh_ugh_autoconf250_builddir="`pwd`"
 677
 678         if test "$srcdir" = "."; then
 679             srcdir_build=yes
 680         else
 681             srcdir_build=no
 682             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 683             package_srcdir="`dirname  $srcdir`"
 684         fi
 685         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 686
 687         (cd stepmake 2>/dev/null || mkdir stepmake)
 688         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 689         stepmake=stepmake
 690     else
 691         AC_MSG_RESULT($PACKAGE)
 692
 693         AC_MSG_CHECKING(builddir)
 694         ugh_ugh_autoconf250_builddir="`pwd`"
 695
 696         here_dir=$(cd . && pwd)
 697         full_src_dir=$(cd $srcdir && pwd)
 698
 699         if test "$full_src_dir" = "$here_dir"; then
 700             srcdir_build=yes
 701         else
 702             srcdir_build=no
 703         fi
 704         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 705
 706         AC_MSG_CHECKING(for stepmake)
 707         # Check for installed stepmake
 708         if test -d $stepmake; then
 709             AC_MSG_RESULT($stepmake)
 710         else
 711             stepmake="`cd $srcdir/stepmake; pwd`"
 712             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 713         fi
 714     fi
 715
 716     AC_SUBST(ugh_ugh_autoconf250_builddir)
 717
 718     # Use absolute directory for non-srcdir builds, so that build
 719     # dir can be moved.
 720     if test "$srcdir_build" = "no" ;  then
 721         srcdir="`cd $srcdir; pwd`"
 722     fi
 723
 724     AC_SUBST(srcdir)
 725     AC_SUBST(stepmake)
 726     AC_SUBST(package)
 727     AC_SUBST(PACKAGE)
 728     AC_SUBST(PACKAGE_NAME)
 729     AC_SUBST(VERSION)
 730     AC_SUBST(MAJOR_VERSION)
 731     AC_SUBST(MINOR_VERSION)
 732     AC_SUBST(MICRO_VERSION)
 733
 734     # stepmake nonstandard names
 735     AC_SUBST(PATCH_LEVEL)
 736     AC_SUBST(TOPLEVEL_VERSION)
 737
 738     # We don't need the upper case variant,
 739     # so stick to macros are uppercase convention.
 740     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 741     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 742     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 743     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 744     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 745
 746     if test -z "$package_depth"; then
 747         package_depth="."
 748     else
 749         package_depth="../$package_depth"
 750     fi
 751     export package_depth
 752     AC_SUBST(package_depth)
 753
 754     AUTOGENERATE="This file was automatically generated by configure"
 755     AC_SUBST(AUTOGENERATE)
 756
 757     CONFIGSUFFIX=
 758     AC_ARG_ENABLE(config,
 759     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 760                             do `make conf=CONF' to get output in ./out-CONF],
 761     [CONFIGURATION=$enableval])
 762
 763     ##'`#
 764
 765     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 766     CONFIGFILE=config$CONFIGSUFFIX
 767     AC_SUBST(CONFIGSUFFIX)
 768
 769     AC_CANONICAL_HOST
 770     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 771     STEPMAKE_PROGS(FIND, find, REQUIRED)
 772
 773     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 774
 775     if test "$(echo 2)" != "2" ||
 776         test "x`uname`" = "xHP-UX"; then
 777         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 778         AC_PATH_PROG(BASH, bash, $KSH)
 779         STEPMAKE_WARN(avoiding buggy /bin/sh)
 780         AC_PATH_PROG(SHELL, bash, $KSH)
 781     else
 782         SHELL=/bin/sh
 783         AC_PATH_PROG(BASH, bash, $SHELL)
 784     fi
 785     AC_SUBST(SHELL)
 786
 787     STEPMAKE_PYTHON(REQUIRED, 1.5)
 788
 789     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 790         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 791         if test "$?" = 1; then
 792             warn='make (Please install *GNU* make)'
 793             # STEPMAKE_WARN($warn)
 794             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 795         fi
 796     fi
 797
 798     ROOTSEP=':'
 799     DIRSEP='/'
 800     PATHSEP=':'
 801     LN=ln
 802     LN_S='ln -s'
 803     ZIP="zip -r -9"
 804
 805     AC_SUBST(program_prefix)
 806     AC_SUBST(program_suffix)
 807     AC_SUBST(ZIP)
 808     AC_SUBST(LN)
 809     AC_SUBST(LN_S)
 810     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 811     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 812     AC_SUBST(DIRSEP)
 813     AC_SUBST(PATHSEP)
 814     AC_SUBST(ROOTSEP)
 815
 816     STEPMAKE_DATADIR
 817     STEPMAKE_LIBDIR
 818 ])
 819
 820
 821 AC_DEFUN(STEPMAKE_LIB, [
 822     STEPMAKE_PROGS(AR, ar, $1)
 823     AC_PROG_RANLIB
 824     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 825 ])
 826
 827
 828 AC_DEFUN(STEPMAKE_LIBTOOL, [
 829     # libtool.info ...
 830     # **Never** try to set library version numbers so that they correspond
 831     # to the release number of your package.  This is an abuse that only
 832     # fosters misunderstanding of the purpose of library versions.
 833
 834     REVISION=$PATCH_LEVEL
 835     # CURRENT=$MINOR_VERSION
 836     CURRENT=`expr $MINOR_VERSION + 1`
 837     # AGE=`expr $MAJOR_VERSION + 1`
 838     AGE=$MAJOR_VERSION
 839     AC_SUBST(CURRENT)
 840     AC_SUBST(REVISION)
 841     AC_SUBST(AGE)
 842 ])
 843
 844
 845 AC_DEFUN(STEPMAKE_LOCALE, [
 846     lang=English
 847     ALL_LINGUAS="en nl"
 848
 849     # with/enable ??
 850     AC_ARG_WITH(localedir,
 851     [  --with-localedir=DIR    location of locales.  Default: PREFIX/share/locale ],
 852     localedir=$with_localedir,
 853     localedir='${prefix}/share/locale')
 854
 855     AC_ARG_WITH(lang,
 856     [  --with-lang=LANG        use LANG as language to emit messages],
 857     language=$with_lang,
 858     language=English)
 859
 860     AC_MSG_CHECKING(language)
 861     case "$language" in
 862       En* | en* | Am* | am* | US* | us*)
 863             lang=English;;
 864       NL | nl | Du* | du* | Ned* | ned*)
 865             lang=Dutch;;
 866       "")
 867             lang=English;;
 868       *)
 869             lang=unknown;;
 870     esac
 871     AC_MSG_RESULT($lang)
 872
 873     if test "$lang" = "unknown" ; then
 874         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 875     fi
 876
 877 ])
 878
 879
 880 AC_DEFUN(STEPMAKE_MAKEINFO, [
 881     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 882 ])
 883
 884
 885 AC_DEFUN(STEPMAKE_MAN, [
 886     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 887     AC_SUBST(GROFF)
 888     STEPMAKE_PROGS(TROFF, troff, $1)
 889     AC_SUBST(TROFF)
 890     STEPMAKE_PROGS(TBL, tbl, $1)
 891     AC_SUBST(TBL)
 892 ])
 893
 894
 895 AC_DEFUN(STEPMAKE_MSGFMT, [
 896     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 897 ])
 898
 899
 900 # Check for program ($2), set full path result to ($1).
 901 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 902 AC_DEFUN(STEPMAKE_PATH_PROG, [
 903     AC_CHECK_PROGS($1, $2, no)
 904     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 905     if test $? -eq 0; then
 906         AC_PATH_PROG($1, $2)
 907         if test -n "$4"; then
 908             STEPMAKE_CHECK_VERSION($1, $3, $4)
 909         fi
 910     fi
 911 ])
 912
 913
 914 # Check for program in set of names ($2), set result to ($1) .
 915 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 916 # If exists, and a minimal version ($4) is required
 917 AC_DEFUN(STEPMAKE_PROGS, [
 918     AC_CHECK_PROGS($1, $2, no)
 919     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 920     if test $? -eq 0 -a -n "$4"; then
 921         STEPMAKE_CHECK_VERSION($1, $3, $4)
 922     fi
 923 ])
 924
 925
 926 AC_DEFUN(STEPMAKE_PERL, [
 927     STEPMAKE_PATH_PROG(PERL, perl, $1)
 928 ])
 929
 930
 931 AC_DEFUN(STEPMAKE_PYTHON, [
 932     unset pv
 933     AC_MSG_CHECKING([for python])
 934     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 935         AC_MSG_RESULT([$python])
 936         if ! $python -V > /dev/null 2>&1 ; then
 937             #AC_MSG_WARN([cannot execute $python])
 938             PYTHON='echo no python'
 939         else
 940             unset pv
 941             STEPMAKE_CHECK_VERSION(python, pv, $2)
 942             if test -z "$pv"; then
 943                 PYTHON=$python
 944                 break
 945             fi
 946         fi
 947     done
 948     if test -n "$pv"; then
 949         STEPMAKE_ADD_ENTRY($1, $pv)
 950     fi
 951     # clear cached value since arg 2 might point us to a new binary
 952     unset ac_cv_path_PYTHON
 953
 954     AC_PATH_PROG(PYTHON, $PYTHON)
 955     AC_SUBST(PYTHON)
 956 ])
 957
 958 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 959     AC_ARG_WITH(python-include,
 960         [  --with-python-include=DIR
 961                           location of the python include dir],[
 962             if test "$withval" = "yes" -o "$withval" = "no"; then
 963                 AC_MSG_WARN(Usage: --with-python-include=includedir)
 964             else
 965                 PYTHON_CFLAGS="-I${withval}"
 966             fi
 967             ])
 968
 969     AC_ARG_WITH(python-lib,
 970         [  --with-python-lib=NAME  name of the python lib],[
 971             if test "$withval" = "yes" -o "$withval" = "no"; then
 972                 AC_MSG_WARN(Usage: --with-python-lib=name)
 973             else
 974                 LDFLAGS="$LDFLAGS -l${withval}"
 975             fi
 976             ])
 977
 978     AC_CHECK_PROGS(PYTHON_CONFIG, python-config, no)
 979
 980     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
 981         # Clean out junk: http://bugs.python.org/issue3290
 982         # Python headers may need some -f* flags, leave them in.
 983         PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/ -\(W\|D\|O\|m\)\(\w\|-\|=\|,\)\+//g'`
 984         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 985     fi
 986
 987     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
 988         changequote(<<, >>)#dnl
 989         # alternatively, for python >= 2.0
 990         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
 991         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
 992         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
 993         changequote([, ])#dnl
 994     fi
 995
 996     if test -z "$PYTHON_HEADER"; then
 997         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
 998         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
 999     fi
1000
1001     if test -z "$PYTHON_HEADER"; then
1002         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1003         STEPMAKE_ADD_ENTRY($1, $warn)
1004     fi
1005 ])
1006
1007
1008
1009 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1010     AC_LANG_PUSH(C++)
1011     AC_CACHE_CHECK([for stl.data () method],
1012         [stepmake_cv_stl_data_method],
1013         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1014 #include <vector>
1015 using namespace std;
1016 vector <int> v;
1017 void *p = v.data ();
1018 ]])],
1019             [stepmake_cv_stl_data_method=yes],
1020             [stepmake_cv_stl_data_method=no]))
1021     if test $stepmake_cv_stl_data_method = yes; then
1022         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1023     fi
1024     AC_LANG_POP(C++)
1025 ])
1026
1027
1028 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1029     # ugh
1030     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1031 ])
1032
1033 AC_DEFUN(STEPMAKE_TEXMF, [
1034     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1035     STEPMAKE_PROGS(METAPOST, mpost, $1)
1036     # STEPMAKE_PROGS(INIMETAFONT, inimf inimfont "$METAFONT -ini", $1)
1037
1038     AC_MSG_CHECKING(for working metafont mode)
1039     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1040     for MFMODE in $modelist; do
1041         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1042         if test -f mfput.tfm; then
1043             break;
1044         fi
1045     done
1046     AC_MSG_RESULT($MFMODE)
1047
1048     rm -f mfput.*
1049
1050     AC_SUBST(MFMODE)
1051 ])
1052
1053
1054 AC_DEFUN(STEPMAKE_WARN, [
1055     AC_MSG_WARN($1)
1056     warn_b=yes
1057 ])
1058
1059
1060 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1061 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1062 dnl also defines GSTUFF_PKG_ERRORS on error
1063 AC_DEFUN(PKG_CHECK_MODULES, [
1064   succeeded=no
1065
1066   if test -z "$PKG_CONFIG"; then
1067     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1068   fi
1069
1070   if test "$PKG_CONFIG" = "no" ; then
1071      echo "*** The pkg-config script could not be found. Make sure it is"
1072      echo "*** in your path, or set the PKG_CONFIG environment variable"
1073      echo "*** to the full path to pkg-config."
1074      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1075   else
1076      PKG_CONFIG_MIN_VERSION=0.9.0
1077      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1078         AC_MSG_CHECKING(for $2)
1079
1080         if $PKG_CONFIG --exists "$2" ; then
1081             AC_MSG_RESULT(yes)
1082             succeeded=yes
1083
1084             AC_MSG_CHECKING($1_CFLAGS)
1085             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1086             AC_MSG_RESULT($$1_CFLAGS)
1087
1088             AC_MSG_CHECKING($1_LIBS)
1089             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1090             AC_MSG_RESULT($$1_LIBS)
1091         else
1092             $1_CFLAGS=""
1093             $1_LIBS=""
1094             ## If we have a custom action on failure, don't print errors, but
1095             ## do set a variable so people can do so.
1096             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1097             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1098         fi
1099
1100         AC_SUBST($1_CFLAGS)
1101         AC_SUBST($1_LIBS)
1102      fi
1103   fi
1104
1105   if test $succeeded = yes; then
1106      ifelse([$3], , :, [$3])
1107   else
1108      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1109   fi
1110 ])
1111
1112 AC_DEFUN(STEPMAKE_FREETYPE2, [
1113     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1114     if test "$have_freetype2" = yes; then
1115         AC_DEFINE(HAVE_FREETYPE2)
1116         save_CPPFLAGS="$CPPFLAGS"
1117         save_LIBS="$LIBS"
1118         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1119         LIBS="$FREETYPE2_LIBS $LIBS"
1120         AC_SUBST(FREETYPE2_CFLAGS)
1121         AC_SUBST(FREETYPE2_LIBS)
1122         CPPFLAGS="$save_CPPFLAGS"
1123         LIBS="$save_LIBS"
1124     else
1125         # UGR
1126         #r="lib$1-dev or $1-devel"
1127         r="libfreetype6-dev or freetype?-devel"
1128         ver="`pkg-config --modversion $1`"
1129         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1130     fi
1131 ])
1132
1133 AC_DEFUN(STEPMAKE_GTK2, [
1134     PKG_CHECK_MODULES(GTK2, $1 >= $3, have_gtk2=yes, true)
1135     if test "$have_gtk2" = yes ; then
1136         AC_DEFINE(HAVE_GTK2)
1137         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1138         save_CPPFLAGS="$CPPFLAGS"
1139         save_LIBS="$LIBS"
1140         CPPFLAGS="$GTK2_CFLAGS $CPPFLAGS"
1141         LIBS="$GTK2_LIBS $LIBS"
1142         AC_SUBST(GTK2_CFLAGS)
1143         AC_SUBST(GTK2_LIBS)
1144         CPPFLAGS="$save_CPPFLAGS"
1145         LIBS="$save_LIBS"
1146     else
1147         # UGR
1148         # r="lib$1-dev or $1-devel"
1149         r="libgtk2.0-dev or gtk2-devel"
1150         ver="`pkg-config --modversion $1`"
1151         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1152     fi
1153 ])
1154
1155 AC_DEFUN(STEPMAKE_PANGO, [
1156     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1157     if test "$have_pango16" = yes ; then
1158         AC_DEFINE(HAVE_PANGO16)
1159         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1160         save_CPPFLAGS="$CPPFLAGS"
1161         save_LIBS="$LIBS"
1162         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1163         LIBS="$PANGO_LIBS $LIBS"
1164         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1165         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1166         AC_SUBST(PANGO_CFLAGS)
1167         AC_SUBST(PANGO_LIBS)
1168         CPPFLAGS="$save_CPPFLAGS"
1169         LIBS="$save_LIBS"
1170     else
1171         # UGR
1172         #r="lib$1-dev or $1-devel"
1173         r="libpango1.0-dev or pango1.0-devel"
1174         ver="`pkg-config --modversion $1`"
1175         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1176     fi
1177 ])
1178
1179 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1180     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1181     if test "$have_pangoft2" = yes ; then
1182         AC_DEFINE(HAVE_PANGO16)
1183         AC_DEFINE(HAVE_PANGO_FT2)
1184         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1185         save_CPPFLAGS="$CPPFLAGS"
1186         save_LIBS="$LIBS"
1187         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1188         LIBS="$PANGO_FT2_LIBS $LIBS"
1189         AC_CHECK_HEADERS([pango/pangoft2.h])
1190         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1191         AC_SUBST(PANGO_FT2_CFLAGS)
1192         AC_SUBST(PANGO_FT2_LIBS)
1193         CPPFLAGS="$save_CPPFLAGS"
1194         LIBS="$save_LIBS"
1195     else
1196         # UGR
1197         #r="lib$1-dev or $1-devel"e
1198         r="libpango1.0-dev or pango?-devel"
1199         ver="`pkg-config --modversion $1`"
1200         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1201     fi
1202 ])
1203
1204 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1205     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1206     if test "$have_fontconfig" = yes ; then
1207         AC_DEFINE(HAVE_FONTCONFIG)
1208         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1209         save_CPPFLAGS="$CPPFLAGS"
1210         save_LIBS="$LIBS"
1211         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1212         LIBS="$FONTCONFIG_LIBS $LIBS"
1213         AC_SUBST(FONTCONFIG_CFLAGS)
1214         AC_SUBST(FONTCONFIG_LIBS)
1215         CPPFLAGS="$save_CPPFLAGS"
1216         LIBS="$save_LIBS"
1217     else
1218         r="lib$1-dev or $1-devel"
1219         ver="`pkg-config --modversion $1`"
1220         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1221     fi
1222 ])
1223
1224 AC_DEFUN(STEPMAKE_WINDOWS, [
1225     AC_CYGWIN
1226     AC_MINGW32
1227
1228     if test "$CYGWIN" = "yes"; then
1229         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1230         program_suffix=.exe
1231         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1232     elif test "$MINGW32" = "yes"; then
1233         LN='cp -r'
1234         LN_S='cp -r'
1235         program_suffix=.exe
1236         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1237         PATHSEP=';'
1238     fi
1239
1240     AC_SUBST(LN)
1241     AC_SUBST(LN_S)
1242     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1243     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1244     AC_SUBST(DIRSEP)
1245     AC_SUBST(PATHSEP)
1246     AC_SUBST(program_suffix)
1247
1248     AC_MSG_CHECKING([for some flavor of Windows])
1249     if test "$CYGWIN$MINGW32" = "nono"; then
1250         PLATFORM_WINDOWS=no
1251     else
1252         PLATFORM_WINDOWS=yes
1253     fi
1254     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1255     AC_SUBST(PLATFORM_WINDOWS)
1256     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1257     AC_SUBST(WINDRES)
1258 ])