stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4 AC_DEFUN(AC_STEPMAKE_COMPILE, [
   5     # -O is necessary to get inlining
   6     OPTIMIZE=""
   7     CXXFLAGS=${CXXFLAGS:-""}
   8     CFLAGS=${CFLAGS:-""}
   9     checking_b=yes
  10     optimise_b=no
  11     profile_b=no
  12     debug_b=yes
  13
  14     AC_ARG_ENABLE(checking,
  15     [  enable-checking         set runtime checks (assert calls). Default: on],
  16     [checking_b=$enableval] )
  17
  18     # actually, the default is: tja='-O' to get inlining...
  19     # off=''  --jcn
  20
  21     #actually, that sucks.
  22     #  tja looks like a typo.  Default is optimisation off. --hwn
  23
  24     AC_ARG_ENABLE(optimise,
  25     [  enable-optimise         use maximal speed optimisations. Default: off],
  26     [optimise_b=$enableval])
  27
  28     AC_ARG_ENABLE(profiling,
  29     [  enable-profiling        compile with gprof support. Default: off],
  30     [profile_b=$enableval])
  31
  32     AC_ARG_ENABLE(debugging,
  33     [  enable-debugging        set debug info. Default: on],
  34     [debug_b=$enableval])
  35
  36     AC_ARG_ENABLE(mingw-prefix,
  37     [  enable-mingw-prefix=DIR set the mingw32 directory (standalone windows32 exes)],
  38     [MINGWPREFIX=$enableval],
  39     [MINGWPREFIX=no])
  40
  41     if test "$printing_b" = no; then
  42         # ugh
  43         AC_DEFINE(NPRINT)
  44         DEFINES="$DEFINES -DNPRINT"
  45     fi
  46
  47     if test "$checking_b" = no; then
  48         # ugh
  49         AC_DEFINE(NDEBUG)
  50         DEFINES="$DEFINES -DNDEBUG"
  51     fi
  52
  53     if test "$optimise_b" = yes; then
  54         OPTIMIZE="-O2 -finline-functions"
  55     fi
  56
  57     if test "$optimise_b" = no; then
  58         OPTIMIZE=""
  59     fi
  60
  61     if test $profile_b = yes; then
  62         EXTRA_LIBES="-pg"
  63         OPTIMIZE="$OPTIMIZE -pg"
  64     fi
  65
  66     if test $debug_b = yes; then
  67         OPTIMIZE="$OPTIMIZE -g"
  68     fi
  69
  70     # however, C++ support in mingw32 v 0.1.4 is still flaky
  71     if test x$MINGWPREFIX != xno; then
  72         ICFLAGS="-I$MINGWPREFIX/include"
  73         ILDFLAGS="-$MINGWPREFIX/lib"
  74     fi
  75
  76     AC_PROG_CC
  77     LD='$(CC)'
  78     AC_SUBST(LD)
  79
  80     CFLAGS="$CFLAGS $OPTIMIZE"
  81     CPPFLAGS=${CPPFLAGS:-""}
  82     AC_SUBST(CFLAGS)
  83     AC_SUBST(CPPFLAGS)
  84     AC_SUBST(LDFLAGS)
  85     AC_SUBST(ICFLAGS)
  86     AC_SUBST(ILDFLAGS)
  87     AC_SUBST(DEFINES)
  88     AC_SUBST(EXTRA_LIBES)
  89 ])
  90
  91 AC_DEFUN(AC_STEPMAKE_CXX, [
  92     AC_LANG_CPLUSPLUS
  93     AC_PROG_CXX
  94
  95     AC_CHECK_HEADER(FlexLexer.h, true,
  96         AC_STEPMAKE_WARN(can"\'"t find flex header. Please install Flex headers correctly))
  97
  98     CPPFLAGS="$CPPFLAGS $DEFINES"
  99     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 100     LDFLAGS=$EXTRA_LIBES
 101
 102     AC_SUBST(CXXFLAGS)
 103     AC_SUBST(CXX)
 104     LD='$(CXX)'
 105     AC_SUBST(LD)
 106 ])
 107
 108 AC_DEFUN(AC_STEPMAKE_CXXTEMPLATE, [
 109     AC_CACHE_CHECK([whether explicit instantiation is needed],
 110         lily_cv_need_explicit_instantiation,
 111         AC_TRY_LINK([
 112     template <class T> struct foo { static int baz; };
 113     template <class T> int foo<T>::baz = 1;
 114     ], [ return foo<int>::baz; ],
 115             lily_cv_need_explicit_instantiation=no,
 116             lily_cv_need_explicit_instantiation=yes))
 117     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 118         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 119     fi
 120 ])
 121
 122 AC_DEFUN(AC_STEPMAKE_DATADIR, [
 123     if test "$datadir" = "\${prefix}/share"; then
 124             datadir='${prefix}/share/'$package
 125     fi
 126     DIR_DATADIR=${datadir}
 127     presome=${prefix}
 128     if test "$prefix" = "NONE"; then
 129             presome=${ac_default_prefix}
 130     fi
 131     DIR_DATADIR=`echo ${DIR_DATADIR} | sed "s!\\\${prefix}!$presome!"`
 132     AC_SUBST(datadir)
 133     AC_SUBST(DIR_DATADIR)
 134     AC_DEFINE_UNQUOTED(DIR_DATADIR, "${DIR_DATADIR}")
 135 ])
 136
 137 AC_DEFUN(AC_STEPMAKE_END, [
 138     AC_OUTPUT($CONFIGFILE.make:config.make.in)
 139
 140     rm -f GNUmakefile
 141     cp make/toplevel.make.in ./GNUmakefile
 142     chmod 444 GNUmakefile
 143 ])
 144
 145 AC_DEFUN(AC_STEPMAKE_GXX, [
 146     # ugh autoconf
 147     # urg, egcs: how to check for egcs >= 1.1?
 148     changequote(<<, >>)dnl
 149     if $CXX --version | grep '2\.8' > /dev/null ||
 150         $CXX --version | grep 'egcs' > /dev/null
 151     changequote([, ])dnl
 152     then
 153             true
 154     else
 155             AC_STEPMAKE_WARN(can\'t find g++ 2.8 or egcs 1.1)
 156     fi
 157 ])
 158
 159 AC_DEFUN(AC_STEPMAKE_GUILE, [
 160     # on some systems, -lguile succeeds for guile-1.3
 161     # others need readline, dl (or even more)
 162     # urg, must check for different functions in libguile
 163     # to force new check iso reading from cache
 164
 165     # gh_scm2doubles,gh_doubles2scm are new in 1.3
 166     GUILE_FLAGS
 167     AC_CHECK_LIB(guile, gh_scm2doubles,
 168       LIBS="`echo $GUILE_LDFLAGS | sed -e 's/-L[[[/-_a-zA-Z0-9]]]\+ //g'` $LIBS";
 169       AC_DEFINE(HAVE_LIBGUILE), , $GUILE_LDFLAGS dnl
 170     )
 171     if test "$ac_cv_lib_guile_gh_scm2doubles" != yes ; then
 172         AC_STEPMAKE_WARN(You should install guile 1.3 or newer)
 173     fi
 174 ])
 175
 176 AC_DEFUN(AC_STEPMAKE_INIT, [
 177
 178     . $srcdir/VERSION
 179     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 180     if test x$MY_PATCH_LEVEL != x; then
 181         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 182     fi
 183
 184     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 185     changequote(<<, >>)dnl
 186     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 187     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 188     changequote([, ])dnl
 189
 190     # No versioning on directory names of sub-packages
 191     # urg, urg
 192     stepmake=${datadir}/stepmake
 193     presome=${prefix}
 194     if test "$prefix" = "NONE"; then
 195             presome=${ac_default_prefix}
 196     fi
 197     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 198
 199     if test "x$PACKAGE" = "xSTEPMAKE"; then
 200         echo Stepmake package!
 201         (cd stepmake; rm -f stepmake; ln -s ../stepmake .)
 202         (cd stepmake; rm -f bin; ln -s ../bin .)
 203         AC_CONFIG_AUX_DIR(bin)
 204         stepmake=stepmake
 205     else
 206         echo Package: $PACKAGE
 207         # Check for installed stepmake
 208         if test -d $stepmake; then
 209             echo Using installed stepmake: $stepmake
 210         else
 211             stepmake='$(depth)'/stepmake
 212             echo Using local stepmake: $datadir/stepmake not found
 213         fi
 214         AC_CONFIG_AUX_DIR(\
 215           $HOME/usr/local/share/stepmake/bin\
 216           $HOME/usr/local/lib/stepmake/bin\
 217           $HOME/usr/share/stepmake/bin\
 218           $HOME/usr/lib/stepmake/bin\
 219           /usr/local/share/stepmake/bin\
 220           /usr/local/lib/stepmake/bin\
 221           /usr/share/stepmake/bin\
 222           /usr/lib/stepmake/bin\
 223           stepmake/bin\
 224         )
 225     fi
 226
 227     AC_SUBST(stepmake)
 228     AC_SUBST(package)
 229     AC_SUBST(PACKAGE)
 230     AC_SUBST(PACKAGE_NAME)
 231     AC_DEFINE_UNQUOTED(PACKAGE, "${PACKAGE_NAME}")
 232     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 233
 234     if test "$package_depth" = "" ; then
 235         package_depth="."
 236     else
 237         package_depth="../$package_depth"
 238     fi
 239     export package_depth
 240     AC_SUBST(package_depth)
 241
 242     AUTOGENERATE="This file was automatically generated by configure"
 243     AC_SUBST(AUTOGENERATE)
 244     absolute_builddir="`pwd`"
 245     AC_SUBST(absolute_builddir)
 246
 247     STATE_VECTOR=`ls make/STATE-VECTOR 2>/dev/null`
 248     if test "x$STATE_VECTOR" != "x"; then
 249         STATE_VECTOR="\$(depth)/$STATE_VECTOR"
 250     fi
 251     AC_SUBST(STATE_VECTOR)
 252
 253     CONFIGSUFFIX=
 254     AC_ARG_ENABLE(config,
 255     [  enable-config=FILE      put configure settings in config-FILE.make],
 256     [CONFIGSUFFIX=$enableval])
 257
 258     if test "$CONFIGSUFFIX" != "" ; then
 259         CONFIGFILE=config-$CONFIGSUFFIX
 260     else
 261         CONFIGFILE=config
 262     fi
 263     AC_SUBST(CONFIGSUFFIX)
 264
 265     AC_CANONICAL_HOST
 266     AC_CHECK_PROGS(MAKE, gmake make, error)
 267     AC_CHECK_PROGS(FIND, find, error)
 268
 269 dnl system supplied INSTALL is unsafe; use our own install.
 270 dnl    AC_PROG_INSTALL
 271 dnl    if test "$INSTALL" = "bin/install-sh"; then
 272 dnl     export INSTALL="\$\(depth\)/bin/install-sh"
 273 dnl    fi
 274
 275     AC_CHECK_PROGS(TAR, tar, error)
 276     AC_CHECK_PROGS(BASH, bash, /bin/sh)
 277
 278     AC_PATH_PROG(PYTHON, ${PYTHON:-python}, -echo no python)
 279     AC_SUBST(PYTHON)
 280
 281     if test $MAKE != "error" ; then
 282         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 283         if test "$?" = 1
 284         then
 285                 AC_STEPMAKE_WARN(Please install *GNU* make)
 286         fi
 287     fi
 288
 289     AC_CHECK_SEARCH_RESULT($PYTHON, python, You should install Python)
 290
 291     if test "x$OSTYPE" = "xcygwin32" || test "x$OSTYPE" = "xWindows_NT"; then
 292         LN=cp # hard link does not work under cygnus-nt
 293         LN_S=cp # symbolic link does not work for native nt
 294         ZIP="zip -r -9" #
 295         DOTEXE=.exe
 296         # urg
 297         # DIRSEP='\\'
 298         # PATHSEP=';'
 299         #
 300         # cygwin fixes all these things.
 301         # it seems these were used because of dos-style TEXINPUTS and
 302         # MFINPUTS needed for miktex.
 303         # but this breaks parsing of all other cygwin/unix style paths.
 304         #
 305         # if your (mik)tex breaks, make a:
 306         #    /usr/local/bin/tex:
 307         #    #!/bin/sh
 308         #    TEXINPUTS=`cygpath -pw $TEXINPUTS` /texmf/miktex/bin/tex $*
 309         #
 310         # and
 311         #
 312         #    /usr/local/bin/mf:
 313         #    #!/bin/sh
 314         #    MFINPUTS=`cygpath -pw $MFINPUTS` /texmf/miktex/bin/mf $*
 315         #
 316         # this way, you may have buildscripts/out/lilypond-profile
 317         # 'automatically' sourced from /usr/etc/profile.d/ too.
 318         #
 319         DIRSEP='/'
 320         PATHSEP=':'
 321         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
 322     else
 323         DIRSEP='/'
 324         PATHSEP=':'
 325         LN=ln
 326         LN_S='ln -s'
 327         ZIP="zip -r -9"
 328         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-sh -c"
 329     fi
 330     AC_SUBST(DOTEXE)
 331     AC_SUBST(ZIP)
 332     AC_SUBST(LN)
 333     AC_SUBST(LN_S)
 334     AC_SUBST(INSTALL)
 335     AC_DEFINE_UNQUOTED(DIRSEP, '${DIRSEP}')
 336     AC_DEFINE_UNQUOTED(PATHSEP, '${PATHSEP}')
 337     AC_SUBST(PATHSEP)
 338     AC_SUBST(DIRSEP)
 339
 340
 341     AC_STEPMAKE_DATADIR
 342 ])
 343
 344 AC_DEFUN(AC_STEPMAKE_LEXYACC, [
 345     # ugh, automake: we want (and check for) bison
 346     AC_PROG_YACC
 347     # ugh, automake: we want (and check for) flex
 348     # AC_PROG_LEX
 349     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 350
 351     # AC_DECL_YYTEXT
 352     # ugh, ugh
 353     ac_cv_prog_lex_root=lex.yy
 354
 355     AC_CHECK_PROGS(BISON, bison, error)
 356     AC_CHECK_PROGS(FLEX, flex, error)
 357     AC_CHECK_SEARCH_RESULT($BISON, bison,  Please install Bison, 1.25 or newer)
 358     AC_CHECK_SEARCH_RESULT($FLEX,  flex, Please install Flex, 2.5 or newer)
 359
 360     if test $BISON != "error"; then
 361         bison_version=`$BISON --version| sed 's/^.*version 1.//g' `
 362         if test $bison_version -lt 25; then
 363             AC_STEPMAKE_WARN(Your bison is a bit old (1.$bison_version). You might have to install 1.25)
 364         fi
 365     fi
 366
 367     AC_SUBST(BISON)
 368     AC_SUBST(FLEX)
 369 ])
 370
 371 AC_DEFUN(AC_STEPMAKE_LIB, [
 372     AC_CHECK_PROGS(AR, ar, error)
 373     AC_PROG_RANLIB
 374
 375     AC_SUBST(AR)
 376     AC_SUBST(RANLIB)
 377 ])
 378
 379 AC_DEFUN(AC_STEPMAKE_LIBTOOL, [
 380     # libtool.info ...
 381     # **Never** try to set library version numbers so that they correspond
 382     # to the release number of your package.  This is an abuse that only
 383     # fosters misunderstanding of the purpose of library versions.
 384
 385     REVISION=$PATCH_LEVEL
 386     # CURRENT=$MINOR_VERSION
 387     CURRENT=`expr $MINOR_VERSION + 1`
 388     # AGE=$(expr $MAJOR_VERSION + 1)
 389     AGE=$MAJOR_VERSION
 390     AC_SUBST(CURRENT)
 391     AC_SUBST(REVISION)
 392     AC_SUBST(AGE)
 393 ])
 394
 395 AC_DEFUN(AC_STEPMAKE_LOCALE, [
 396     lang=English
 397     ALL_LINGUAS="en nl"
 398
 399     # with/enable ??
 400     AC_ARG_WITH(localedir,
 401     [  with-localedir=LOCALE   use LOCALE as locale dir. Default: PREFIX/share/locale ],
 402     localedir=$with_localedir,
 403     localedir='${prefix}/share/locale')
 404
 405     AC_ARG_WITH(lang,
 406     [  with-lang=LANG          use LANG as language to emit messages],
 407     language=$with_lang,
 408     language=English)
 409
 410     AC_MSG_CHECKING(language)
 411     case "$language" in
 412       En* | en* | Am* | am* | US* | us*)
 413             lang=English;;
 414       NL | nl | Du* | du* | Ned* | ned*)
 415             lang=Dutch;;
 416       "")
 417             lang=English;;
 418       *)
 419             lang=unknown;;
 420     esac
 421     AC_MSG_RESULT($lang)
 422
 423     if test "$lang" = "unknown" ; then
 424         AC_STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 425     fi
 426
 427 ])
 428
 429 AC_DEFUN(AC_STEPMAKE_GETTEXT, [
 430     DIR_LOCALEDIR=${localedir}
 431     presome=${prefix}
 432     if test "$prefix" = "NONE"; then
 433             presome=${ac_default_prefix}
 434     fi
 435     DIR_LOCALEDIR=`echo ${DIR_LOCALEDIR} | sed "s!\\\${prefix}!$presome!"`
 436     AC_SUBST(localedir)
 437     AC_SUBST(DIR_LOCALEDIR)
 438     AC_DEFINE_UNQUOTED(DIR_LOCALEDIR, "${DIR_LOCALEDIR}")
 439
 440     AC_CHECK_LIB(intl, gettext)
 441     AC_CHECK_FUNCS(gettext)
 442 ])
 443
 444 AC_DEFUN(AC_STEPMAKE_MAN, [
 445     AC_CHECK_PROGS(TROFF, troff, -echo no troff)
 446     AC_CHECK_PROGS(TBL, tbl, cat)
 447 ])
 448
 449 AC_DEFUN(AC_STEPMAKE_MSGFMT, [
 450     # AC_CHECK_PROGS(MSGFMT, msgfmt, -echo no msgfmt)
 451     AC_CHECK_PROGS(MSGFMT, msgfmt, \$(SHELL) \$(step-bindir)/fake-msgfmt.sh )
 452     AC_MSG_CHECKING(whether msgfmt accepts -o)
 453     msgfmt_output="`msgfmt -o bla 2>&1 | grep usage`"
 454     if test "$msgfmt_output" = ""; then
 455         AC_MSG_RESULT(yes)
 456     else
 457         # urg
 458         MSGFMT="\$(SHELL) \$(step-bindir)/fake-msgfmt.sh"
 459         AC_MSG_RESULT(no)
 460         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 461     fi
 462     if test ! -n "$MSGFMT"; then
 463         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 464     fi
 465 ])
 466
 467 AC_DEFUN(AC_STEPMAKE_TEXMF_DIRS, [
 468     AC_ARG_ENABLE(tex-prefix,
 469     [  enable-tex-prefix=DIR   set the tex-directory to find TeX subdirectories. (default: PREFIX)],
 470     [TEXPREFIX=$enableval],
 471     [TEXPREFIX=auto] )
 472
 473     AC_ARG_ENABLE(tex-dir,
 474     [  enable-tex-dir=DIR      set the directory to put $PACKAGE_NAME TeX files in. ],
 475     [TEXDIR=$enableval],
 476     [TEXDIR=auto] )
 477
 478     AC_ARG_ENABLE(mf-dir,
 479     [  enable-mf-dir=DIR       set the directory to put $PACKAGE_NAME MetaFont files in. ],
 480     [MFDIR=$enableval],
 481     [MFDIR=auto])
 482
 483     if test "x$TEXPREFIX" = xauto ; then
 484         AC_TEX_PREFIX(TEXPREFIX)
 485     else
 486      find_texprefix=$TEXPREFIX
 487     fi
 488
 489     if test "x$MFDIR" = xauto; then
 490         AC_MF_SUBDIR(MFDIR)
 491     fi
 492
 493     if test "x$TEXDIR" = xauto ; then
 494         AC_TEX_SUBDIR(TEXDIR)
 495     fi
 496     AC_SUBST(TEXPREFIX)
 497     AC_SUBST(TEXDIR)
 498     AC_SUBST(MFDIR)
 499 ])
 500
 501 AC_DEFUN(AC_STEPMAKE_TEXMF, [
 502     # urg, never know what names these teTeX guys will think up
 503     AC_CHECK_PROGS(METAFONT, mf, no)
 504     if test "x$METAFONT" = "xno"; then
 505         AC_CHECK_PROGS(MFONT, mfont, -echo no mf or mfont)
 506         METAFONT=$MFONT
 507     fi
 508
 509     AC_CHECK_PROGS(METAPOST, mp, no)
 510     if test "x$METAPOST" = "xno"; then
 511         AC_CHECK_PROGS(MPOST, mpost, -echo no mp or mpost)
 512         METAPOST=$MPOST
 513     fi
 514
 515     AC_SUBST(METAFONT)
 516     AC_SUBST(METAPOST)
 517 ])
 518
 519 AC_DEFUN(AC_STEPMAKE_WARN, [
 520     AC_MSG_WARN($1)
 521     warn_b=yes
 522 ])
 523
 524 AC_DEFUN(AC_STEPMAKE_YODL, [
 525     if test "x$YODL" = "x"; then
 526         AC_CHECK_PROGS(STRIPROFF, striproff, -echo no striproff)
 527         AC_CHECK_PROGS(YODL, yodl, -echo no yodl)
 528         AC_CHECK_PROGS(YODL2HTML, yodl2html, -echo no yodl)
 529         AC_CHECK_PROGS(YODL2LATEX, yodl2latex, )
 530         AC_CHECK_PROGS(YODL2MAN, yodl2man, -echo no yodl)
 531         AC_CHECK_PROGS(YODL2MSLESS, yodl2msless, -echo no yodl)
 532         AC_CHECK_PROGS(YODL2TEXINFO, yodl2texinfo, -echo no yodl)
 533         AC_CHECK_PROGS(YODL2TXT, yodl2txt, -echo no yodl)
 534         YODL2LESS_DIR='$(bindir)/'
 535     else
 536         AC_SUBST(STRIPROFF)
 537         AC_SUBST(YODL)
 538         AC_SUBST(YODL2HTML)
 539         AC_SUBST(YODL2LATEX)
 540         AC_SUBST(YODL2LESS_DIR)
 541         AC_SUBST(YODL2MAN)
 542         AC_SUBST(YODL2MSLESS)
 543         AC_SUBST(YODL2TEXINFO)
 544         AC_SUBST(YODL2TXT)
 545         export STRIPROFF YODL YODL2HTML YODL2LATEX YODL2MAN YODL2MSLESS YODL2TEXINFO YODL2TXT
 546     fi
 547     if test "x$YODL" = "-echo no yodl"; then
 548         AC_STEPMAKE_WARN(Did not find YODL (Yodl is Yet Oneother Document Language, see http://www.cs.uu.nl/~hanwen/yodl))
 549     fi
 550 ])
 551
 552 dnl should cache result.
 553 dnl should  look in $prefix first.
 554 dnl should probably assume TDS
 555
 556 AC_DEFUN(AC_TEX_PREFIX, [
 557
 558
 559     AC_MSG_CHECKING(TeX/MF root dir directory)
 560
 561     find_root_prefix="$prefix"
 562
 563
 564     test "x$find_root_prefix" = xNONE && find_root_prefix="$ac_default_prefix"
 565     find_texpostfix="";
 566     for postfix in "/lib/tex/" "/lib/texmf" "/lib" "/tex" "/texmf"; do
 567         find_texprefix="$find_root_prefix$postfix"
 568         if test -d $find_texprefix; then
 569             find_texpostfix=$postfix
 570             break;
 571         fi
 572     done
 573
 574     if test "x$find_texpostfix" = x; then
 575         find_texpostfix='/lib/texmf/tex'
 576         AC_STEPMAKE_WARN(Cannot determine the TeX-directory. Please use --enable-tex-prefix)
 577     fi
 578
 579     find_texprefix="$find_root_prefix/$find_texpostfix"
 580
 581     # only assign if variablename not empty
 582     if test x != "x[$]$1"; then
 583         $1='${prefix}'/"$find_texpostfix"
 584     fi
 585     AC_MSG_RESULT($find_texprefix)
 586
 587 ])
 588
 589
 590 # find a directory inside a prefix,
 591 # $1 the prefix (expanded version)
 592 # $2 variable to assign
 593 # $3 the directory name
 594 # $4 description
 595 AC_DEFUN(AC_FIND_DIR_IN_PREFIX, [
 596
 597     AC_MSG_CHECKING($4 directory)
 598     find_dirdir=`(cd $1;
 599       $FIND ./ -type d -a -name $3 -print |sort|head -1|sed 's#^\./##')`
 600
 601
 602     if test "x$find_dirdir" = x; then
 603        find_dirdir="/$3";
 604        AC_STEPMAKE_WARN(Cannot determine $4 subdirectory. Please set from command-line)
 605         true
 606     fi
 607     $2=$find_dirdir
 608     AC_MSG_RESULT($1/$find_dirdir)
 609 ])
 610
 611 # ugh.  this is hopeless
 612 AC_DEFUN(AC_KPSE_TEX_DIR, [
 613         kpse_paths=`(kpsepath -n latex tex; kpsepath -n tex tex) | sed 's/:/ /g' | tr ' ' '\012' |sort | uniq -d`
 614         kpse_syspaths=`echo $kpse_paths | grep '!'| sed 's/!//g'`
 615         echo $kpse_paths
 616         if test -w "$kpse_syspaths";
 617         then
 618                 dir=`echo $kpse_syspaths | head -1`
 619         else
 620                 dir=`echo $kpse_paths | grep -v '!'| head -1`
 621         fi
 622         if test "$prefix" = "NONE"; then
 623                 local_prefix=$ac_default_prefix
 624                 local_prefix_quote='${prefix}'
 625
 626         else
 627                 local_prefix=$prefix
 628                 local_prefix_quote=$prefix
 629         fi
 630         echo $local_prefix_quote = $local_prefix
 631         echo $dir
 632         echo $dir  | sed 's!'$local_prefix'!\$local_prefix_quote!g'
 633 ])
 634
 635 AC_DEFUN(AC_TEX_SUBDIR, [
 636 dnl    AC_REQUIRE([AC_TEX_PREFIX])
 637     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, tex,TeX input)
 638     $1="$TEXPREFIX/$$1"
 639 ])
 640
 641 AC_DEFUN(AC_MF_SUBDIR, [
 642 dnl     AC_REQUIRE([AC_TEX_PREFIX])
 643     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, source, MF input)
 644     $1="$TEXPREFIX/$$1"
 645 ])
 646
 647 AC_DEFUN(AC_CHECK_SEARCH_RESULT, [
 648         result="`echo \"$1\" | grep echo`"
 649         if test "x$1" = "xerror" -o "x$result" != "x"; then
 650                 AC_STEPMAKE_WARN(can\'t find $2. $3)
 651         fi
 652 ])
 653
 654
 655 # Configure paths for GTK+
 656 # Owen Taylor     97-11-3
 657
 658 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 659 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
 660 dnl
 661 AC_DEFUN(AM_PATH_GTK,
 662 [dnl
 663 dnl Get the cflags and libraries from the gtk-config script
 664 dnl
 665   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
 666   min_gtk_version=ifelse([$1], ,1.1.1,$1)
 667   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
 668   no_gtk=""
 669   if test "$GTK_CONFIG" != "no" ; then
 670     GTK_CFLAGS=`$GTK_CONFIG --cflags`
 671     GTK_LIBS=`$GTK_CONFIG --libs`
 672     ac_save_CFLAGS="$CFLAGS"
 673     ac_save_LIBS="$LIBS"
 674     ac_save_CXXFLAGS="$CXXFLAGS"
 675     CFLAGS="$CFLAGS $GTK_CFLAGS"
 676     CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 677     LIBS="$LIBS $GTK_LIBS"
 678 dnl
 679 dnl Now check if the installed GTK is sufficiently new. (Also sanity
 680 dnl checks the results of gtk-config to some extent
 681 dnl
 682     AC_TRY_RUN([
 683 #include <gtk/gtk.h>
 684 #include <stdio.h>
 685
 686 int
 687 main ()
 688 {
 689   int major, minor, micro;
 690
 691   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
 692      printf("%s, bad version string\n", "$min_gtk_version");
 693      exit(1);
 694    }
 695
 696    return !((gtk_major_version > major) ||
 697             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
 698             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
 699 }
 700 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 701      CFLAGS="$ac_save_CFLAGS"
 702      CXXFLAGS="$ac_save_CXXFLAGS"
 703      LIBS="$ac_save_LIBS"
 704   else
 705      no_gtk=yes
 706   fi
 707   if test "x$no_gtk" = x ; then
 708      AC_MSG_RESULT(yes)
 709      ifelse([$2], , :, [$2])
 710   else
 711      AC_MSG_RESULT(no)
 712      GTK_CFLAGS=""
 713      GTK_LIBS=""
 714      ifelse([$3], , :, [$3])
 715   fi
 716   CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 717   AC_SUBST(CXXFLAGS)
 718   AC_SUBST(GTK_CFLAGS)
 719   AC_SUBST(GTK_LIBS)
 720 ])
 721
 722
 723 # Configure paths for GTK--
 724 # Erik Andersen 30 May 1998
 725 # Modified by Tero Pulkkinen (added the compiler checks... I hope they work..)
 726
 727 dnl Test for GTK__, and define GTK___CFLAGS and GTK___LIBS
 728 dnl   to be used as follows:
 729 dnl AM_PATH_GTKMM([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 730 dnl
 731
 732 dnl Get the cflags and libraries from the gtkmm-config script
 733 dnl
 734 AC_ARG_WITH(gtkmm-prefix,[  --with-gtkmm-prefix=PREFIX
 735                           Prefix where GTK-- is installed (optional)],
 736             gtkmm_config_prefix="$withval", gtkmm_config_prefix="")
 737 AC_ARG_WITH(gtkmm-exec-prefix,[  --with-gtkmm-exec-prefix=PREFIX
 738                           Exec prefix where GTK-- is installed (optional)],
 739             gtkmm_config_exec_prefix="$withval", gtkmm_config_exec_prefix="")
 740 AC_ARG_ENABLE(gtkmmtest, [  --disable-gtkmmtest     Do not try to compile and run a test GTK-- program],
 741                     , enable_gtkmmtest=yes)
 742
 743   if test x$gtkmm_config_exec_prefix != x ; then
 744      gtkmm_config_args="$gtkmm_config_args --exec-prefix=$gtkmm_config_exec_prefix"
 745      if test x${GTKMM_CONFIG+set} != xset ; then
 746         GTKMM_CONFIG=$gtkmm_config_exec_prefix/bin/gtkmm-config
 747      fi
 748   fi
 749   if test x$gtkmm_config_prefix != x ; then
 750      gtkmm_config_args="$gtkmm_config_args --prefix=$gtkmm_config_prefix"
 751      if test x${GTKMM_CONFIG+set} != xset ; then
 752         GTKMM_CONFIG=$gtkmm_config_prefix/bin/gtkmm-config
 753      fi
 754   fi
 755
 756
 757 AC_DEFUN(AM_PATH_GTKMM,
 758 [dnl
 759
 760 dnl
 761 dnl Check check if the installed GTK-- is sufficiently new.
 762 dnl
 763   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 764   min_gtkmm_version=ifelse([$1], ,0.9.14,$1)
 765
 766   AC_MSG_CHECKING(for GTK-- - version >= $min_gtkmm_version)
 767   no_gtkmm=""
 768   if test "$GTKMM_CONFIG" = "no" ; then
 769     no_gtkmm=yes
 770   else
 771     AC_LANG_SAVE
 772     AC_LANG_CPLUSPLUS
 773
 774     GTK___CFLAGS=`$GTKMM_CONFIG $gtkmm_config_args --cflags`
 775     GTK___LIBS=`$GTKMM_CONFIG $gtkmm_config_args --libs`
 776     gtkmm_config_major_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 777            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 778     gtkmm_config_minor_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 779            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 780     gtkmm_config_micro_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 781            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
 782     if test "x$enable_gtkmmtest" = "xyes" ; then
 783       ac_save_CXXFLAGS="$CXXFLAGS"
 784       ac_save_LIBS="$LIBS"
 785       CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 786       LIBS="$LIBS $GTK___LIBS"
 787 dnl
 788 dnl Now check if the installed GTK-- is sufficiently new. (Also sanity
 789 dnl checks the results of gtkmm-config to some extent
 790 dnl
 791       rm -f conf.gtkmmtest
 792       AC_TRY_RUN([
 793 #include <gtk--.h>
 794 #include <stdio.h>
 795 #include <stdlib.h>
 796
 797 int
 798 main ()
 799 {
 800   int major, minor, micro;
 801   char *tmp_version;
 802
 803   system ("touch conf.gtkmmtest");
 804
 805   /* HP/UX 0 (%@#!) writes to sscanf strings */
 806   tmp_version = g_strdup("$min_gtkmm_version");
 807   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
 808      printf("%s, bad version string\n", "$min_gtkmm_version");
 809      exit(1);
 810    }
 811
 812   if ((gtkmm_major_version != $gtkmm_config_major_version) ||
 813       (gtkmm_minor_version != $gtkmm_config_minor_version) ||
 814       (gtkmm_micro_version != $gtkmm_config_micro_version))
 815     {
 816       printf("\n*** 'gtkmm-config --version' returned %d.%d.%d, but GTK-- (%d.%d.%d)\n",
 817              $gtkmm_config_major_version, $gtkmm_config_minor_version, $gtkmm_config_micro_version,
 818              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 819       printf ("*** was found! If gtkmm-config was correct, then it is best\n");
 820       printf ("*** to remove the old version of GTK--. You may also be able to fix the error\n");
 821       printf("*** by modifying your LD_LIBRARY_PATH enviroment variable, or by editing\n");
 822       printf("*** /etc/ld.so.conf. Make sure you have run ldconfig if that is\n");
 823       printf("*** required on your system.\n");
 824       printf("*** If gtkmm-config was wrong, set the environment variable GTKMM_CONFIG\n");
 825       printf("*** to point to the correct copy of gtkmm-config, and remove the file config.cache\n");
 826       printf("*** before re-running configure\n");
 827     }
 828 /* GTK-- does not have the GTKMM_*_VERSION constants */
 829 /*
 830   else if ((gtkmm_major_version != GTKMM_MAJOR_VERSION) ||
 831            (gtkmm_minor_version != GTKMM_MINOR_VERSION) ||
 832            (gtkmm_micro_version != GTKMM_MICRO_VERSION))
 833     {
 834       printf("*** GTK-- header files (version %d.%d.%d) do not match\n",
 835              GTKMM_MAJOR_VERSION, GTKMM_MINOR_VERSION, GTKMM_MICRO_VERSION);
 836       printf("*** library (version %d.%d.%d)\n",
 837              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 838     }
 839 */
 840   else
 841     {
 842       if ((gtkmm_major_version > major) ||
 843         ((gtkmm_major_version == major) && (gtkmm_minor_version > minor)) ||
 844         ((gtkmm_major_version == major) && (gtkmm_minor_version == minor) && (gtkmm_micro_version >= micro)))
 845       {
 846         return 0;
 847        }
 848      else
 849       {
 850         printf("\n*** An old version of GTK-- (%d.%d.%d) was found.\n",
 851                gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 852         printf("*** You need a version of GTK-- newer than %d.%d.%d. The latest version of\n",
 853                major, minor, micro);
 854         printf("*** GTK-- is always available from ftp://ftp.gtk.org.\n");
 855         printf("***\n");
 856         printf("*** If you have already installed a sufficiently new version, this error\n");
 857         printf("*** probably means that the wrong copy of the gtkmm-config shell script is\n");
 858         printf("*** being found. The easiest way to fix this is to remove the old version\n");
 859         printf("*** of GTK--, but you can also set the GTKMM_CONFIG environment to point to the\n");
 860         printf("*** correct copy of gtkmm-config. (In this case, you will have to\n");
 861         printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
 862         printf("*** so that the correct libraries are found at run-time))\n");
 863       }
 864     }
 865   return 1;
 866 }
 867 ],, no_gtkmm=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 868        CXXFLAGS="$ac_save_CXXFLAGS"
 869        LIBS="$ac_save_LIBS"
 870      fi
 871   fi
 872   if test "x$no_gtkmm" = x ; then
 873      AC_MSG_RESULT(yes)
 874      ifelse([$2], , :, [$2])
 875   else
 876      AC_MSG_RESULT(no)
 877      if test "$GTKMM_CONFIG" = "no" ; then
 878        echo "*** The gtkmm-config script installed by GTK-- could not be found"
 879        echo "*** If GTK-- was installed in PREFIX, make sure PREFIX/bin is in"
 880        echo "*** your path, or set the GTK_CONFIG environment variable to the"
 881        echo "*** full path to gtk-config."
 882        echo "*** The gtkmm-config script was not available in GTK-- versions"
 883        echo "*** prior to 0.9.12. Perhaps you need to update your installed"
 884        echo "*** version to 0.9.12 or newer"
 885      else
 886        if test -f conf.gtkmmtest ; then
 887         :
 888        else
 889           echo "*** Could not run GTK-- test program, checking why..."
 890           CXXFLAGS="$CFLAGS $GTKMM_CXXFLAGS"
 891           LIBS="$LIBS $GTK___LIBS"
 892           AC_TRY_LINK([
 893 #include <gtk--.h>
 894 #include <stdio.h>
 895 ],      [ return ((gtkmm_major_version) || (gtkmm_minor_version) || (gtkmm_micro_version)); ],
 896         [ echo "*** The test program compiled, but did not run. This usually means"
 897           echo "*** that the run-time linker is not finding GTK-- or finding the wrong"
 898           echo "*** version of GTK--. If it is not finding GTK--, you'll need to set your"
 899           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 900           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 901           echo "*** is required on your system"
 902           echo "***"
 903           echo "*** If you have an old version installed, it is best to remove it, although"
 904           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH" ],
 905         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 906           echo "*** exact error that occured. This usually means GTK-- was incorrectly installed"
 907           echo "*** or that you have moved GTK-- since it was installed. In the latter case, you"
 908           echo "*** may want to edit the gtkmm-config script: $GTKMM_CONFIG" ])
 909           CXXFLAGS="$ac_save_CXXFLAGS"
 910           LIBS="$ac_save_LIBS"
 911        fi
 912      fi
 913      GTK___CFLAGS=""
 914      GTK__LIBS=""
 915      ifelse([$3], , :, [$3])
 916      AC_LANG_RESTORE
 917   fi
 918   AC_SUBST(GTK___CFLAGS)
 919   AC_SUBST(GTK___LIBS)
 920   rm -f conf.gtkmmtest
 921 ])
 922
 923 # Configure paths for GTK--DRAW
 924 # Derek Quinn Wyatt   98-08-21  (adapted from Jan Nieuwenhuizen's code)
 925
 926 dnl AM_PATH_GTK__DRAW([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 927 dnl Test for GTK--DRAW, and define GTK___CFLAGS and GTK___LIBS
 928 dnl
 929 AC_DEFUN(AM_PATH_GTK__DRAW,
 930 [dnl
 931 dnl Get the cflags and libraries from the gtk__-config script
 932 dnl
 933   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 934   min_gtk___version=ifelse([$1], ,0.0.5,$1)
 935   AC_MSG_CHECKING(for GTK--DRAW - version >= $min_gtk___version)
 936   no_gtk__=""
 937   if test "$GTKMM_CONFIG" != "no" ; then
 938     GTK___CFLAGS=`$GTKMM_CONFIG --cflags`
 939     GTK___LIBS=`$GTKMM_CONFIG --libs`
 940     GTK___DLIBS="$GTK___LIBS -lgtkmmdraw"
 941     GTK___LIBS="$GTK___DLIBS"
 942     ac_save_CFLAGS="$CFLAGS"
 943     ac_save_LIBS="$LIBS"
 944     ac_save_CXXFLAGS="$CXXFLAGS"
 945     CFLAGS="$CFLAGS $GTK___CFLAGS"
 946     CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 947     LIBS="$LIBS $GTK___LIBS"
 948 dnl
 949 dnl Now check if the installed GTK__ is sufficiently new. (Also sanity
 950 dnl checks the results of gtk__-config to some extent
 951 dnl
 952     AC_TRY_RUN([
 953 #include <gtk--.h>
 954 #include <stdio.h>
 955
 956 int
 957 main ()
 958 {
 959   // urg
 960   return 0;
 961 }
 962 ],, no_gtk__=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 963      CFLAGS="$ac_save_CFLAGS"
 964      CXXFLAGS="$ac_save_CXXFLAGS"
 965      LIBS="$ac_save_LIBS"
 966   else
 967      no_gtk__=yes
 968   fi
 969   if test "x$no_gtk__" = x ; then
 970      AC_MSG_RESULT(yes)
 971      ifelse([$2], , :, [$2])
 972   else
 973      AC_MSG_RESULT(no)
 974      GTK___CFLAGS=""
 975      GTK___LIBS=""
 976      ifelse([$3], , :, [$3])
 977   fi
 978   CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 979   AC_SUBST(CXXFLAGS)
 980   AC_SUBST(GTK___CFLAGS)
 981   AC_SUBST(GTK___LIBS)
 982 ])
 983
 984 dnl   GUILE_FLAGS --- set flags for compiling and linking with Guile
 985 dnl
 986 dnl   This macro runs the `guile-config' script, installed with Guile,
 987 dnl   to find out where Guile's header files and libraries are
 988 dnl   installed.  It sets two variables, marked for substitution, as
 989 dnl   by AC_SUBST.
 990 dnl
 991 dnl     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 992 dnl             code that uses Guile header files.  This is almost
 993 dnl             always just a -I flag.
 994 dnl
 995 dnl     GUILE_LDFLAGS --- flags to pass to the linker to link a
 996 dnl             program against Guile.  This includes `-lguile' for
 997 dnl             the Guile library itself, any libraries that Guile
 998 dnl             itself requires (like -lqthreads), and so on.  It may
 999 dnl             also include a -L flag to tell the compiler where to
1000 dnl             find the libraries.
1001
1002 AC_DEFUN([GUILE_FLAGS],[
1003 ## The GUILE_FLAGS macro.
1004   ## First, let's just see if we can find Guile at all.
1005   AC_MSG_CHECKING(for Guile)
1006   guile-config link > /dev/null || {
1007     echo "configure: cannot find guile-config; is Guile installed?" 1>&2
1008     exit 1
1009   }
1010   GUILE_CFLAGS="`guile-config compile`"
1011   GUILE_LDFLAGS="`guile-config link`"
1012   AC_SUBST(GUILE_CFLAGS)
1013   AC_SUBST(GUILE_LDFLAGS)
1014   AC_MSG_RESULT(yes)
1015 ])
1016