stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4 AC_DEFUN(AC_STEPMAKE_COMPILE, [
   5     # -O is necessary to get inlining
   6     OPTIMIZE=""
   7     CXXFLAGS=${CXXFLAGS:-""}
   8     CFLAGS=${CFLAGS:-""}
   9     checking_b=yes
  10     optimise_b=no
  11     profile_b=no
  12     debug_b=yes
  13
  14     AC_ARG_ENABLE(checking,
  15     [  enable-checking         set runtime checks (assert calls). Default: on],
  16     [checking_b=$enableval] )
  17
  18     # actually, the default is: tja='-O' to get inlining...
  19     # off=''  --jcn
  20
  21     #actually, that sucks.
  22     #  tja looks like a typo.  Default is optimisation off. --hwn
  23
  24     AC_ARG_ENABLE(optimise,
  25     [  enable-optimise         use maximal speed optimisations. Default: off],
  26     [optimise_b=$enableval])
  27
  28     AC_ARG_ENABLE(profiling,
  29     [  enable-profiling        compile with gprof support. Default: off],
  30     [profile_b=$enableval])
  31
  32     AC_ARG_ENABLE(debugging,
  33     [  enable-debugging        set debug info. Default: on],
  34     [debug_b=$enableval])
  35
  36     AC_ARG_ENABLE(mingw-prefix,
  37     [  enable-mingw-prefix=DIR set the mingw32 directory (standalone windows32 exes)],
  38     [MINGWPREFIX=$enableval],
  39     [MINGWPREFIX=no])
  40
  41     if test "$printing_b" = no; then
  42         # ugh
  43         AC_DEFINE(NPRINT)
  44         DEFINES="$DEFINES -DNPRINT"
  45     fi
  46
  47     if test "$checking_b" = no; then
  48         # ugh
  49         AC_DEFINE(NDEBUG)
  50         DEFINES="$DEFINES -DNDEBUG"
  51     fi
  52
  53     if test "$optimise_b" = yes; then
  54         OPTIMIZE="-O2 -finline-functions"
  55     fi
  56
  57     if test "$optimise_b" = no; then
  58         OPTIMIZE=""
  59     fi
  60
  61     if test $profile_b = yes; then
  62         EXTRA_LIBES="-pg"
  63         OPTIMIZE="$OPTIMIZE -pg"
  64     fi
  65
  66     if test $debug_b = yes; then
  67         OPTIMIZE="$OPTIMIZE -g"
  68     fi
  69
  70     # however, C++ support in mingw32 v 0.1.4 is still flaky
  71     if test x$MINGWPREFIX != xno; then
  72         ICFLAGS="-I$MINGWPREFIX/include"
  73         ILDFLAGS="-$MINGWPREFIX/lib"
  74     fi
  75
  76     AC_PROG_CC
  77     LD='$(CC)'
  78     AC_SUBST(LD)
  79
  80     CFLAGS="$CFLAGS $OPTIMIZE"
  81     CPPFLAGS=${CPPFLAGS:-""}
  82     AC_SUBST(CFLAGS)
  83     AC_SUBST(CPPFLAGS)
  84     AC_SUBST(LDFLAGS)
  85     AC_SUBST(ICFLAGS)
  86     AC_SUBST(ILDFLAGS)
  87     AC_SUBST(DEFINES)
  88     AC_SUBST(EXTRA_LIBES)
  89 ])
  90
  91 AC_DEFUN(AC_STEPMAKE_CXX, [
  92     AC_LANG_CPLUSPLUS
  93     AC_PROG_CXX
  94
  95     AC_CHECK_HEADER(FlexLexer.h, true,
  96         AC_STEPMAKE_WARN(can"\'"t find flex header. Please install Flex headers correctly))
  97
  98     CPPFLAGS="$CPPFLAGS $DEFINES"
  99     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 100     LDFLAGS=$EXTRA_LIBES
 101
 102     AC_SUBST(CXXFLAGS)
 103     AC_SUBST(CXX)
 104     LD='$(CXX)'
 105     AC_SUBST(LD)
 106 ])
 107
 108 AC_DEFUN(AC_STEPMAKE_CXXTEMPLATE, [
 109     AC_CACHE_CHECK([whether explicit instantiation is needed],
 110         lily_cv_need_explicit_instantiation,
 111         AC_TRY_LINK([
 112     template <class T> struct foo { static int baz; };
 113     template <class T> int foo<T>::baz = 1;
 114     ], [ return foo<int>::baz; ],
 115             lily_cv_need_explicit_instantiation=no,
 116             lily_cv_need_explicit_instantiation=yes))
 117     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 118         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 119     fi
 120 ])
 121
 122 AC_DEFUN(AC_STEPMAKE_DATADIR, [
 123     if test "$datadir" = "\${prefix}/share"; then
 124             datadir='${prefix}/share/'$package
 125     fi
 126     DIR_DATADIR=${datadir}
 127     presome=${prefix}
 128     if test "$prefix" = "NONE"; then
 129             presome=${ac_default_prefix}
 130     fi
 131     DIR_DATADIR=`echo ${DIR_DATADIR} | sed "s!\\\${prefix}!$presome!"`
 132     AC_SUBST(datadir)
 133     AC_SUBST(DIR_DATADIR)
 134     AC_DEFINE_UNQUOTED(DIR_DATADIR, "${DIR_DATADIR}")
 135 ])
 136
 137 AC_DEFUN(AC_STEPMAKE_END, [
 138     AC_OUTPUT($CONFIGFILE.make:config.make.in)
 139
 140     rm -f GNUmakefile
 141     cp make/toplevel.make.in ./GNUmakefile
 142     chmod 444 GNUmakefile
 143 ])
 144
 145 AC_DEFUN(AC_STEPMAKE_GXX, [
 146     # ugh autoconf
 147     # urg, egcs: how to check for egcs >= 1.1?
 148     changequote(<<, >>)dnl
 149     if $CXX --version | grep '2\.8' > /dev/null ||
 150         $CXX --version | grep 'egcs' > /dev/null
 151     changequote([, ])dnl
 152     then
 153             true
 154     else
 155             AC_STEPMAKE_WARN(can\'t find g++ 2.8 or egcs 1.1)
 156     fi
 157 ])
 158
 159 AC_DEFUN(AC_STEPMAKE_GUILE, [
 160     # on some systems, -lguile succeeds for guile-1.3
 161     # others need readline, dl (or even more)
 162     # urg, must check for different functions in libguile
 163     # to force new check iso reading from cache
 164
 165     # gh_scm2doubles,gh_doubles2scm are new in 1.3
 166     GUILE_FLAGS
 167     AC_CHECK_LIB(guile, gh_scm2doubles,
 168       LIBS="`echo $GUILE_LDFLAGS | sed -e 's/-L[[[/-_a-zA-Z0-9]]]\+ //g'` $LIBS";
 169       AC_DEFINE(HAVE_LIBGUILE), , $GUILE_LDFLAGS dnl
 170     )
 171     if test "$ac_cv_lib_guile_gh_scm2doubles" != yes ; then
 172         AC_STEPMAKE_WARN(You should install guile 1.3 or newer)
 173     fi
 174 ])
 175
 176 AC_DEFUN(AC_STEPMAKE_INIT, [
 177
 178     . $srcdir/VERSION
 179     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 180     if test x$MY_PATCH_LEVEL != x; then
 181         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 182     fi
 183
 184     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 185     changequote(<<, >>)dnl
 186     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 187     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 188     changequote([, ])dnl
 189
 190     # No versioning on directory names of sub-packages
 191     # urg, urg
 192     stepmake=${datadir}/stepmake
 193     presome=${prefix}
 194     if test "$prefix" = "NONE"; then
 195             presome=${ac_default_prefix}
 196     fi
 197     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 198
 199     if test "x$PACKAGE" = "xSTEPMAKE"; then
 200         echo Stepmake package!
 201         (cd stepmake; rm -f stepmake; ln -s ../stepmake .)
 202         (cd stepmake; rm -f bin; ln -s ../bin .)
 203         AC_CONFIG_AUX_DIR(bin)
 204         stepmake=stepmake
 205     else
 206         echo Package: $PACKAGE
 207         # Check for installed stepmake
 208         if test -d $stepmake; then
 209             echo Using installed stepmake: $stepmake
 210         else
 211             stepmake='$(depth)'/stepmake
 212             echo Using local stepmake: $datadir/stepmake not found
 213         fi
 214         AC_CONFIG_AUX_DIR(\
 215           $HOME/usr/local/share/stepmake/bin\
 216           $HOME/usr/local/lib/stepmake/bin\
 217           $HOME/usr/share/stepmake/bin\
 218           $HOME/usr/lib/stepmake/bin\
 219           /usr/local/share/stepmake/bin\
 220           /usr/local/lib/stepmake/bin\
 221           /usr/share/stepmake/bin\
 222           /usr/lib/stepmake/bin\
 223           stepmake/bin\
 224         )
 225     fi
 226
 227     AC_SUBST(stepmake)
 228     AC_SUBST(package)
 229     AC_SUBST(PACKAGE)
 230     AC_SUBST(PACKAGE_NAME)
 231     AC_DEFINE_UNQUOTED(PACKAGE, "${PACKAGE_NAME}")
 232     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 233
 234     if test "$package_depth" = "" ; then
 235         package_depth="."
 236     else
 237         package_depth="../$package_depth"
 238     fi
 239     export package_depth
 240     AC_SUBST(package_depth)
 241
 242     AUTOGENERATE="This file was automatically generated by configure"
 243     AC_SUBST(AUTOGENERATE)
 244     absolute_builddir="`pwd`"
 245     AC_SUBST(absolute_builddir)
 246
 247     STATE_VECTOR=`ls make/STATE-VECTOR 2>/dev/null`
 248     if test "x$STATE_VECTOR" != "x"; then
 249         STATE_VECTOR="\$(depth)/$STATE_VECTOR"
 250     fi
 251     AC_SUBST(STATE_VECTOR)
 252
 253     CONFIGSUFFIX=
 254     AC_ARG_ENABLE(config,
 255     [  enable-config=FILE      put configure settings in config-FILE.make],
 256     [CONFIGSUFFIX=$enableval])
 257
 258     if test "$CONFIGSUFFIX" != "" ; then
 259         CONFIGFILE=config-$CONFIGSUFFIX
 260     else
 261         CONFIGFILE=config
 262     fi
 263     AC_SUBST(CONFIGSUFFIX)
 264
 265     AC_CANONICAL_HOST
 266     AC_CHECK_PROGS(MAKE, gmake make, error)
 267     AC_CHECK_PROGS(FIND, find, error)
 268
 269 dnl system supplied INSTALL is unsafe; use our own install.
 270 dnl    AC_PROG_INSTALL
 271 dnl    if test "$INSTALL" = "bin/install-sh"; then
 272 dnl     export INSTALL="\$\(depth\)/bin/install-sh"
 273 dnl    fi
 274
 275     AC_CHECK_PROGS(TAR, tar, error)
 276     AC_CHECK_PROGS(BASH, bash, /bin/sh)
 277
 278     AC_PATH_PROG(PYTHON, ${PYTHON:-python}, -echo no python)
 279     AC_SUBST(PYTHON)
 280
 281     if test $MAKE != "error" ; then
 282         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 283         if test "$?" = 1
 284         then
 285                 AC_STEPMAKE_WARN(Please install *GNU* make)
 286         fi
 287     fi
 288
 289     AC_CHECK_SEARCH_RESULT($PYTHON, python, You should install Python)
 290
 291     if test "x$OSTYPE" = "xcygwin32" || test "x$OSTYPE" = "xWindows_NT"; then
 292         LN=cp # hard link does not work under cygnus-nt
 293         LN_S=cp # symbolic link does not work for native nt
 294         ZIP="zip -r -9" #
 295         DOTEXE=.exe
 296         # urg
 297         # DIRSEP='\\'
 298         # PATHSEP=';'
 299         #
 300         # cygwin fixes all these things.
 301         # it seems these were used because of dos-style TEXINPUTS and
 302         # MFINPUTS needed for miktex.
 303         # but this breaks parsing of all other cygwin/unix style paths.
 304         #
 305         # if your (mik)tex breaks, make a:
 306         #    /usr/local/bin/tex:
 307         #    #!/bin/sh
 308         #    TEXINPUTS=`cygpath -pw $TEXINPUTS` /texmf/miktex/bin/tex $*
 309         #
 310         # and
 311         #
 312         #    /usr/local/bin/mf:
 313         #    #!/bin/sh
 314         #    MFINPUTS=`cygpath -pw $MFINPUTS` /texmf/miktex/bin/mf $*
 315         #
 316         # this way, you may have buildscripts/out/lilypond-profile
 317         # 'automatically' sourced from /usr/etc/profile.d/ too.
 318         #
 319         DIRSEP='/'
 320         PATHSEP=':'
 321         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
 322     else
 323         DIRSEP='/'
 324         PATHSEP=':'
 325         LN=ln
 326         LN_S='ln -s'
 327         ZIP="zip -r -9"
 328         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-sh -c"
 329     fi
 330     AC_SUBST(DOTEXE)
 331     AC_SUBST(ZIP)
 332     AC_SUBST(LN)
 333     AC_SUBST(LN_S)
 334     AC_SUBST(INSTALL)
 335     AC_DEFINE_UNQUOTED(DIRSEP, '${DIRSEP}')
 336     AC_DEFINE_UNQUOTED(PATHSEP, '${PATHSEP}')
 337     AC_SUBST(PATHSEP)
 338     AC_SUBST(DIRSEP)
 339
 340
 341     AC_STEPMAKE_DATADIR
 342 ])
 343
 344 AC_DEFUN(AC_STEPMAKE_LEXYACC, [
 345     # ugh, automake: we want (and check for) bison
 346     AC_PROG_YACC
 347     # ugh, automake: we want (and check for) flex
 348     # AC_PROG_LEX
 349     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 350
 351     # AC_DECL_YYTEXT
 352     # ugh, ugh
 353     ac_cv_prog_lex_root=lex.yy
 354
 355     AC_CHECK_PROGS(BISON, bison, error)
 356     AC_CHECK_PROGS(FLEX, flex, error)
 357     AC_CHECK_SEARCH_RESULT($BISON, bison,  Please install Bison, 1.25 or newer)
 358     AC_CHECK_SEARCH_RESULT($FLEX,  flex, Please install Flex, 2.5 or newer)
 359
 360     if test $BISON != "error"; then
 361         bison_version=`$BISON --version| sed 's/^.*version 1.//g' `
 362         if test $bison_version -lt 25; then
 363             AC_STEPMAKE_WARN(Your bison is a bit old (1.$bison_version). You might have to install 1.25)
 364         fi
 365     fi
 366
 367     AC_SUBST(BISON)
 368     AC_SUBST(FLEX)
 369 ])
 370
 371 AC_DEFUN(AC_STEPMAKE_LIB, [
 372     AC_CHECK_PROGS(AR, ar, error)
 373     AC_PROG_RANLIB
 374
 375     AC_SUBST(AR)
 376     AC_SUBST(RANLIB)
 377 ])
 378
 379 AC_DEFUN(AC_STEPMAKE_LIBTOOL, [
 380     # libtool.info ...
 381     # **Never** try to set library version numbers so that they correspond
 382     # to the release number of your package.  This is an abuse that only
 383     # fosters misunderstanding of the purpose of library versions.
 384
 385     REVISION=$PATCH_LEVEL
 386     # CURRENT=$MINOR_VERSION
 387     CURRENT=`expr $MINOR_VERSION + 1`
 388     # AGE=$(expr $MAJOR_VERSION + 1)
 389     AGE=$MAJOR_VERSION
 390     AC_SUBST(CURRENT)
 391     AC_SUBST(REVISION)
 392     AC_SUBST(AGE)
 393 ])
 394
 395 AC_DEFUN(AC_STEPMAKE_LOCALE, [
 396     lang=English
 397     ALL_LINGUAS="en nl"
 398
 399     # with/enable ??
 400     AC_ARG_WITH(localedir,
 401     [  with-localedir=LOCALE   use LOCALE as locale dir. Default: PREFIX/share/locale ],
 402     localedir=$with_localedir,
 403     localedir='${prefix}/share/locale')
 404
 405     AC_ARG_WITH(lang,
 406     [  with-lang=LANG          use LANG as language to emit messages],
 407     language=$with_lang,
 408     language=English)
 409
 410     AC_MSG_CHECKING(language)
 411     case "$language" in
 412       En* | en* | Am* | am* | US* | us*)
 413             lang=English;;
 414       NL | nl | Du* | du* | Ned* | ned*)
 415             lang=Dutch;;
 416       "")
 417             lang=English;;
 418       *)
 419             lang=unknown;;
 420     esac
 421     AC_MSG_RESULT($lang)
 422
 423     if test "$lang" = "unknown" ; then
 424         AC_STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 425     fi
 426
 427 ])
 428
 429 AC_DEFUN(AC_STEPMAKE_GETTEXT, [
 430     DIR_LOCALEDIR=${localedir}
 431     presome=${prefix}
 432     if test "$prefix" = "NONE"; then
 433             presome=${ac_default_prefix}
 434     fi
 435     DIR_LOCALEDIR=`echo ${DIR_LOCALEDIR} | sed "s!\\\${prefix}!$presome!"`
 436     AC_SUBST(localedir)
 437     AC_SUBST(DIR_LOCALEDIR)
 438     AC_DEFINE_UNQUOTED(DIR_LOCALEDIR, "${DIR_LOCALEDIR}")
 439
 440     AC_CHECK_LIB(intl, gettext)
 441     AC_CHECK_FUNCS(gettext)
 442 ])
 443
 444 AC_DEFUN(AC_STEPMAKE_MAN, [
 445     AC_CHECK_PROGS(GROFF, groff ditroff, -echo no groff)
 446     AC_CHECK_PROGS(TROFF, troff, -echo no troff)
 447     AC_CHECK_PROGS(TBL, tbl, cat)
 448 ])
 449
 450 AC_DEFUN(AC_STEPMAKE_MSGFMT, [
 451     # AC_CHECK_PROGS(MSGFMT, msgfmt, -echo no msgfmt)
 452     AC_CHECK_PROGS(MSGFMT, msgfmt, \$(SHELL) \$(step-bindir)/fake-msgfmt.sh )
 453     AC_MSG_CHECKING(whether msgfmt accepts -o)
 454     msgfmt_output="`msgfmt -o bla 2>&1 | grep usage`"
 455     if test "$msgfmt_output" = ""; then
 456         AC_MSG_RESULT(yes)
 457     else
 458         # urg
 459         MSGFMT="\$(SHELL) \$(step-bindir)/fake-msgfmt.sh"
 460         AC_MSG_RESULT(no)
 461         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 462     fi
 463     if test ! -n "$MSGFMT"; then
 464         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 465     fi
 466 ])
 467
 468 AC_DEFUN(AC_STEPMAKE_TEXMF_DIRS, [
 469     AC_ARG_ENABLE(tex-prefix,
 470     [  enable-tex-prefix=DIR   set the tex-directory to find TeX subdirectories. (default: PREFIX)],
 471     [TEXPREFIX=$enableval],
 472     [TEXPREFIX=auto] )
 473
 474     AC_ARG_ENABLE(tex-dir,
 475     [  enable-tex-dir=DIR      set the directory to put $PACKAGE_NAME TeX files in. ],
 476     [TEXDIR=$enableval],
 477     [TEXDIR=auto] )
 478
 479     AC_ARG_ENABLE(mf-dir,
 480     [  enable-mf-dir=DIR       set the directory to put $PACKAGE_NAME MetaFont files in. ],
 481     [MFDIR=$enableval],
 482     [MFDIR=auto])
 483
 484     if test "x$TEXPREFIX" = xauto ; then
 485         AC_TEX_PREFIX(TEXPREFIX)
 486     else
 487      find_texprefix=$TEXPREFIX
 488     fi
 489
 490     if test "x$MFDIR" = xauto; then
 491         AC_MF_SUBDIR(MFDIR)
 492     fi
 493
 494     if test "x$TEXDIR" = xauto ; then
 495         AC_TEX_SUBDIR(TEXDIR)
 496     fi
 497     AC_SUBST(TEXPREFIX)
 498     AC_SUBST(TEXDIR)
 499     AC_SUBST(MFDIR)
 500 ])
 501
 502 AC_DEFUN(AC_STEPMAKE_TEXMF, [
 503     # urg, never know what names these teTeX guys will think up
 504     AC_CHECK_PROGS(METAFONT, mf, no)
 505     if test "x$METAFONT" = "xno"; then
 506         AC_CHECK_PROGS(MFONT, mfont, -echo no mf or mfont)
 507         METAFONT=$MFONT
 508     fi
 509
 510     AC_CHECK_PROGS(METAPOST, mp, no)
 511     if test "x$METAPOST" = "xno"; then
 512         AC_CHECK_PROGS(MPOST, mpost, -echo no mp or mpost)
 513         METAPOST=$MPOST
 514     fi
 515
 516     AC_SUBST(METAFONT)
 517     AC_SUBST(METAPOST)
 518 ])
 519
 520 AC_DEFUN(AC_STEPMAKE_WARN, [
 521     AC_MSG_WARN($1)
 522     warn_b=yes
 523 ])
 524
 525 AC_DEFUN(AC_STEPMAKE_YODL, [
 526     if test "x$YODL" = "x"; then
 527         AC_CHECK_PROGS(STRIPROFF, striproff, -echo no striproff)
 528         AC_CHECK_PROGS(YODL, yodl, -echo no yodl)
 529         AC_CHECK_PROGS(YODL2HTML, yodl2html, -echo no yodl)
 530         AC_CHECK_PROGS(YODL2LATEX, yodl2latex, )
 531         AC_CHECK_PROGS(YODL2MAN, yodl2man, -echo no yodl)
 532         AC_CHECK_PROGS(YODL2MSLESS, yodl2msless, -echo no yodl)
 533         AC_CHECK_PROGS(YODL2TEXINFO, yodl2texinfo, -echo no yodl)
 534         AC_CHECK_PROGS(YODL2TXT, yodl2txt, -echo no yodl)
 535         YODL2LESS_DIR='$(bindir)/'
 536     else
 537         AC_SUBST(STRIPROFF)
 538         AC_SUBST(YODL)
 539         AC_SUBST(YODL2HTML)
 540         AC_SUBST(YODL2LATEX)
 541         AC_SUBST(YODL2LESS_DIR)
 542         AC_SUBST(YODL2MAN)
 543         AC_SUBST(YODL2MSLESS)
 544         AC_SUBST(YODL2TEXINFO)
 545         AC_SUBST(YODL2TXT)
 546         export STRIPROFF YODL YODL2HTML YODL2LATEX YODL2MAN YODL2MSLESS YODL2TEXINFO YODL2TXT
 547     fi
 548     if test "x$YODL" = "-echo no yodl"; then
 549         AC_STEPMAKE_WARN(Did not find YODL (Yodl is Yet Oneother Document Language, see http://www.cs.uu.nl/~hanwen/yodl))
 550     fi
 551 ])
 552
 553 dnl should cache result.
 554 dnl should  look in $prefix first.
 555 dnl should probably assume TDS
 556
 557 AC_DEFUN(AC_TEX_PREFIX, [
 558
 559
 560     AC_MSG_CHECKING(TeX/MF root dir directory)
 561
 562     find_root_prefix="$prefix"
 563
 564
 565     test "x$find_root_prefix" = xNONE && find_root_prefix="$ac_default_prefix"
 566     find_texpostfix="";
 567     for postfix in "/lib/tex/" "/lib/texmf" "/lib" "/tex" "/texmf"; do
 568         find_texprefix="$find_root_prefix$postfix"
 569         if test -d $find_texprefix; then
 570             find_texpostfix=$postfix
 571             break;
 572         fi
 573     done
 574
 575     if test "x$find_texpostfix" = x; then
 576         find_texpostfix='/lib/texmf/tex'
 577         AC_STEPMAKE_WARN(Cannot determine the TeX-directory. Please use --enable-tex-prefix)
 578     fi
 579
 580     find_texprefix="$find_root_prefix/$find_texpostfix"
 581
 582     # only assign if variablename not empty
 583     if test x != "x[$]$1"; then
 584         $1='${prefix}'/"$find_texpostfix"
 585     fi
 586     AC_MSG_RESULT($find_texprefix)
 587
 588 ])
 589
 590
 591 # find a directory inside a prefix,
 592 # $1 the prefix (expanded version)
 593 # $2 variable to assign
 594 # $3 the directory name
 595 # $4 description
 596 AC_DEFUN(AC_FIND_DIR_IN_PREFIX, [
 597
 598     AC_MSG_CHECKING($4 directory)
 599     find_dirdir=`(cd $1;
 600       $FIND ./ -type d -a -name $3 -print |sort|head -1|sed 's#^\./##')`
 601
 602
 603     if test "x$find_dirdir" = x; then
 604        find_dirdir="/$3";
 605        AC_STEPMAKE_WARN(Cannot determine $4 subdirectory. Please set from command-line)
 606         true
 607     fi
 608     $2=$find_dirdir
 609     AC_MSG_RESULT($1/$find_dirdir)
 610 ])
 611
 612 # ugh.  this is hopeless
 613 AC_DEFUN(AC_KPSE_TEX_DIR, [
 614         kpse_paths=`(kpsepath -n latex tex; kpsepath -n tex tex) | sed 's/:/ /g' | tr ' ' '\012' |sort | uniq -d`
 615         kpse_syspaths=`echo $kpse_paths | grep '!'| sed 's/!//g'`
 616         echo $kpse_paths
 617         if test -w "$kpse_syspaths";
 618         then
 619                 dir=`echo $kpse_syspaths | head -1`
 620         else
 621                 dir=`echo $kpse_paths | grep -v '!'| head -1`
 622         fi
 623         if test "$prefix" = "NONE"; then
 624                 local_prefix=$ac_default_prefix
 625                 local_prefix_quote='${prefix}'
 626
 627         else
 628                 local_prefix=$prefix
 629                 local_prefix_quote=$prefix
 630         fi
 631         echo $local_prefix_quote = $local_prefix
 632         echo $dir
 633         echo $dir  | sed 's!'$local_prefix'!\$local_prefix_quote!g'
 634 ])
 635
 636 AC_DEFUN(AC_TEX_SUBDIR, [
 637 dnl    AC_REQUIRE([AC_TEX_PREFIX])
 638     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, tex,TeX input)
 639     $1="$TEXPREFIX/$$1"
 640 ])
 641
 642 AC_DEFUN(AC_MF_SUBDIR, [
 643 dnl     AC_REQUIRE([AC_TEX_PREFIX])
 644     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, source, MF input)
 645     $1="$TEXPREFIX/$$1"
 646 ])
 647
 648 AC_DEFUN(AC_CHECK_SEARCH_RESULT, [
 649         result="`echo \"$1\" | grep echo`"
 650         if test "x$1" = "xerror" -o "x$result" != "x"; then
 651                 AC_STEPMAKE_WARN(can\'t find $2. $3)
 652         fi
 653 ])
 654
 655
 656 # Configure paths for GTK+
 657 # Owen Taylor     97-11-3
 658
 659 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 660 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
 661 dnl
 662 AC_DEFUN(AM_PATH_GTK,
 663 [dnl
 664 dnl Get the cflags and libraries from the gtk-config script
 665 dnl
 666   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
 667   min_gtk_version=ifelse([$1], ,1.1.1,$1)
 668   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
 669   no_gtk=""
 670   if test "$GTK_CONFIG" != "no" ; then
 671     GTK_CFLAGS=`$GTK_CONFIG --cflags`
 672     GTK_LIBS=`$GTK_CONFIG --libs`
 673     ac_save_CFLAGS="$CFLAGS"
 674     ac_save_LIBS="$LIBS"
 675     ac_save_CXXFLAGS="$CXXFLAGS"
 676     CFLAGS="$CFLAGS $GTK_CFLAGS"
 677     CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 678     LIBS="$LIBS $GTK_LIBS"
 679 dnl
 680 dnl Now check if the installed GTK is sufficiently new. (Also sanity
 681 dnl checks the results of gtk-config to some extent
 682 dnl
 683     AC_TRY_RUN([
 684 #include <gtk/gtk.h>
 685 #include <stdio.h>
 686
 687 int
 688 main ()
 689 {
 690   int major, minor, micro;
 691
 692   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
 693      printf("%s, bad version string\n", "$min_gtk_version");
 694      exit(1);
 695    }
 696
 697    return !((gtk_major_version > major) ||
 698             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
 699             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
 700 }
 701 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 702      CFLAGS="$ac_save_CFLAGS"
 703      CXXFLAGS="$ac_save_CXXFLAGS"
 704      LIBS="$ac_save_LIBS"
 705   else
 706      no_gtk=yes
 707   fi
 708   if test "x$no_gtk" = x ; then
 709      AC_MSG_RESULT(yes)
 710      ifelse([$2], , :, [$2])
 711   else
 712      AC_MSG_RESULT(no)
 713      GTK_CFLAGS=""
 714      GTK_LIBS=""
 715      ifelse([$3], , :, [$3])
 716   fi
 717   CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 718   AC_SUBST(CXXFLAGS)
 719   AC_SUBST(GTK_CFLAGS)
 720   AC_SUBST(GTK_LIBS)
 721 ])
 722
 723
 724 # Configure paths for GTK--
 725 # Erik Andersen 30 May 1998
 726 # Modified by Tero Pulkkinen (added the compiler checks... I hope they work..)
 727
 728 dnl Test for GTK__, and define GTK___CFLAGS and GTK___LIBS
 729 dnl   to be used as follows:
 730 dnl AM_PATH_GTKMM([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 731 dnl
 732
 733 dnl Get the cflags and libraries from the gtkmm-config script
 734 dnl
 735 AC_ARG_WITH(gtkmm-prefix,[  --with-gtkmm-prefix=PREFIX
 736                           Prefix where GTK-- is installed (optional)],
 737             gtkmm_config_prefix="$withval", gtkmm_config_prefix="")
 738 AC_ARG_WITH(gtkmm-exec-prefix,[  --with-gtkmm-exec-prefix=PREFIX
 739                           Exec prefix where GTK-- is installed (optional)],
 740             gtkmm_config_exec_prefix="$withval", gtkmm_config_exec_prefix="")
 741 AC_ARG_ENABLE(gtkmmtest, [  --disable-gtkmmtest     Do not try to compile and run a test GTK-- program],
 742                     , enable_gtkmmtest=yes)
 743
 744   if test x$gtkmm_config_exec_prefix != x ; then
 745      gtkmm_config_args="$gtkmm_config_args --exec-prefix=$gtkmm_config_exec_prefix"
 746      if test x${GTKMM_CONFIG+set} != xset ; then
 747         GTKMM_CONFIG=$gtkmm_config_exec_prefix/bin/gtkmm-config
 748      fi
 749   fi
 750   if test x$gtkmm_config_prefix != x ; then
 751      gtkmm_config_args="$gtkmm_config_args --prefix=$gtkmm_config_prefix"
 752      if test x${GTKMM_CONFIG+set} != xset ; then
 753         GTKMM_CONFIG=$gtkmm_config_prefix/bin/gtkmm-config
 754      fi
 755   fi
 756
 757
 758 AC_DEFUN(AM_PATH_GTKMM,
 759 [dnl
 760
 761 dnl
 762 dnl Check check if the installed GTK-- is sufficiently new.
 763 dnl
 764   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 765   min_gtkmm_version=ifelse([$1], ,0.9.14,$1)
 766
 767   AC_MSG_CHECKING(for GTK-- - version >= $min_gtkmm_version)
 768   no_gtkmm=""
 769   if test "$GTKMM_CONFIG" = "no" ; then
 770     no_gtkmm=yes
 771   else
 772     AC_LANG_SAVE
 773     AC_LANG_CPLUSPLUS
 774
 775     GTK___CFLAGS=`$GTKMM_CONFIG $gtkmm_config_args --cflags`
 776     GTK___LIBS=`$GTKMM_CONFIG $gtkmm_config_args --libs`
 777     gtkmm_config_major_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 778            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 779     gtkmm_config_minor_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 780            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 781     gtkmm_config_micro_version=`$GTKMM_CONFIG $gtkmm_config_args --version | \
 782            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
 783     if test "x$enable_gtkmmtest" = "xyes" ; then
 784       ac_save_CXXFLAGS="$CXXFLAGS"
 785       ac_save_LIBS="$LIBS"
 786       CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 787       LIBS="$LIBS $GTK___LIBS"
 788 dnl
 789 dnl Now check if the installed GTK-- is sufficiently new. (Also sanity
 790 dnl checks the results of gtkmm-config to some extent
 791 dnl
 792       rm -f conf.gtkmmtest
 793       AC_TRY_RUN([
 794 #include <gtk--.h>
 795 #include <stdio.h>
 796 #include <stdlib.h>
 797
 798 int
 799 main ()
 800 {
 801   int major, minor, micro;
 802   char *tmp_version;
 803
 804   system ("touch conf.gtkmmtest");
 805
 806   /* HP/UX 0 (%@#!) writes to sscanf strings */
 807   tmp_version = g_strdup("$min_gtkmm_version");
 808   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
 809      printf("%s, bad version string\n", "$min_gtkmm_version");
 810      exit(1);
 811    }
 812
 813   if ((gtkmm_major_version != $gtkmm_config_major_version) ||
 814       (gtkmm_minor_version != $gtkmm_config_minor_version) ||
 815       (gtkmm_micro_version != $gtkmm_config_micro_version))
 816     {
 817       printf("\n*** 'gtkmm-config --version' returned %d.%d.%d, but GTK-- (%d.%d.%d)\n",
 818              $gtkmm_config_major_version, $gtkmm_config_minor_version, $gtkmm_config_micro_version,
 819              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 820       printf ("*** was found! If gtkmm-config was correct, then it is best\n");
 821       printf ("*** to remove the old version of GTK--. You may also be able to fix the error\n");
 822       printf("*** by modifying your LD_LIBRARY_PATH enviroment variable, or by editing\n");
 823       printf("*** /etc/ld.so.conf. Make sure you have run ldconfig if that is\n");
 824       printf("*** required on your system.\n");
 825       printf("*** If gtkmm-config was wrong, set the environment variable GTKMM_CONFIG\n");
 826       printf("*** to point to the correct copy of gtkmm-config, and remove the file config.cache\n");
 827       printf("*** before re-running configure\n");
 828     }
 829 /* GTK-- does not have the GTKMM_*_VERSION constants */
 830 /*
 831   else if ((gtkmm_major_version != GTKMM_MAJOR_VERSION) ||
 832            (gtkmm_minor_version != GTKMM_MINOR_VERSION) ||
 833            (gtkmm_micro_version != GTKMM_MICRO_VERSION))
 834     {
 835       printf("*** GTK-- header files (version %d.%d.%d) do not match\n",
 836              GTKMM_MAJOR_VERSION, GTKMM_MINOR_VERSION, GTKMM_MICRO_VERSION);
 837       printf("*** library (version %d.%d.%d)\n",
 838              gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 839     }
 840 */
 841   else
 842     {
 843       if ((gtkmm_major_version > major) ||
 844         ((gtkmm_major_version == major) && (gtkmm_minor_version > minor)) ||
 845         ((gtkmm_major_version == major) && (gtkmm_minor_version == minor) && (gtkmm_micro_version >= micro)))
 846       {
 847         return 0;
 848        }
 849      else
 850       {
 851         printf("\n*** An old version of GTK-- (%d.%d.%d) was found.\n",
 852                gtkmm_major_version, gtkmm_minor_version, gtkmm_micro_version);
 853         printf("*** You need a version of GTK-- newer than %d.%d.%d. The latest version of\n",
 854                major, minor, micro);
 855         printf("*** GTK-- is always available from ftp://ftp.gtk.org.\n");
 856         printf("***\n");
 857         printf("*** If you have already installed a sufficiently new version, this error\n");
 858         printf("*** probably means that the wrong copy of the gtkmm-config shell script is\n");
 859         printf("*** being found. The easiest way to fix this is to remove the old version\n");
 860         printf("*** of GTK--, but you can also set the GTKMM_CONFIG environment to point to the\n");
 861         printf("*** correct copy of gtkmm-config. (In this case, you will have to\n");
 862         printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
 863         printf("*** so that the correct libraries are found at run-time))\n");
 864       }
 865     }
 866   return 1;
 867 }
 868 ],, no_gtkmm=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 869        CXXFLAGS="$ac_save_CXXFLAGS"
 870        LIBS="$ac_save_LIBS"
 871      fi
 872   fi
 873   if test "x$no_gtkmm" = x ; then
 874      AC_MSG_RESULT(yes)
 875      ifelse([$2], , :, [$2])
 876   else
 877      AC_MSG_RESULT(no)
 878      if test "$GTKMM_CONFIG" = "no" ; then
 879        echo "*** The gtkmm-config script installed by GTK-- could not be found"
 880        echo "*** If GTK-- was installed in PREFIX, make sure PREFIX/bin is in"
 881        echo "*** your path, or set the GTK_CONFIG environment variable to the"
 882        echo "*** full path to gtk-config."
 883        echo "*** The gtkmm-config script was not available in GTK-- versions"
 884        echo "*** prior to 0.9.12. Perhaps you need to update your installed"
 885        echo "*** version to 0.9.12 or newer"
 886      else
 887        if test -f conf.gtkmmtest ; then
 888         :
 889        else
 890           echo "*** Could not run GTK-- test program, checking why..."
 891           CXXFLAGS="$CFLAGS $GTKMM_CXXFLAGS"
 892           LIBS="$LIBS $GTK___LIBS"
 893           AC_TRY_LINK([
 894 #include <gtk--.h>
 895 #include <stdio.h>
 896 ],      [ return ((gtkmm_major_version) || (gtkmm_minor_version) || (gtkmm_micro_version)); ],
 897         [ echo "*** The test program compiled, but did not run. This usually means"
 898           echo "*** that the run-time linker is not finding GTK-- or finding the wrong"
 899           echo "*** version of GTK--. If it is not finding GTK--, you'll need to set your"
 900           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 901           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 902           echo "*** is required on your system"
 903           echo "***"
 904           echo "*** If you have an old version installed, it is best to remove it, although"
 905           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH" ],
 906         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 907           echo "*** exact error that occured. This usually means GTK-- was incorrectly installed"
 908           echo "*** or that you have moved GTK-- since it was installed. In the latter case, you"
 909           echo "*** may want to edit the gtkmm-config script: $GTKMM_CONFIG" ])
 910           CXXFLAGS="$ac_save_CXXFLAGS"
 911           LIBS="$ac_save_LIBS"
 912        fi
 913      fi
 914      GTK___CFLAGS=""
 915      GTK__LIBS=""
 916      ifelse([$3], , :, [$3])
 917      AC_LANG_RESTORE
 918   fi
 919   AC_SUBST(GTK___CFLAGS)
 920   AC_SUBST(GTK___LIBS)
 921   rm -f conf.gtkmmtest
 922 ])
 923
 924 # Configure paths for GTK--DRAW
 925 # Derek Quinn Wyatt   98-08-21  (adapted from Jan Nieuwenhuizen's code)
 926
 927 dnl AM_PATH_GTK__DRAW([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 928 dnl Test for GTK--DRAW, and define GTK___CFLAGS and GTK___LIBS
 929 dnl
 930 AC_DEFUN(AM_PATH_GTK__DRAW,
 931 [dnl
 932 dnl Get the cflags and libraries from the gtk__-config script
 933 dnl
 934   AC_PATH_PROG(GTKMM_CONFIG, gtkmm-config, no)
 935   min_gtk___version=ifelse([$1], ,0.0.5,$1)
 936   AC_MSG_CHECKING(for GTK--DRAW - version >= $min_gtk___version)
 937   no_gtk__=""
 938   if test "$GTKMM_CONFIG" != "no" ; then
 939     GTK___CFLAGS=`$GTKMM_CONFIG --cflags`
 940     GTK___LIBS=`$GTKMM_CONFIG --libs`
 941     GTK___DLIBS="$GTK___LIBS -lgtkmmdraw"
 942     GTK___LIBS="$GTK___DLIBS"
 943     ac_save_CFLAGS="$CFLAGS"
 944     ac_save_LIBS="$LIBS"
 945     ac_save_CXXFLAGS="$CXXFLAGS"
 946     CFLAGS="$CFLAGS $GTK___CFLAGS"
 947     CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 948     LIBS="$LIBS $GTK___LIBS"
 949 dnl
 950 dnl Now check if the installed GTK__ is sufficiently new. (Also sanity
 951 dnl checks the results of gtk__-config to some extent
 952 dnl
 953     AC_TRY_RUN([
 954 #include <gtk--.h>
 955 #include <stdio.h>
 956
 957 int
 958 main ()
 959 {
 960   // urg
 961   return 0;
 962 }
 963 ],, no_gtk__=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 964      CFLAGS="$ac_save_CFLAGS"
 965      CXXFLAGS="$ac_save_CXXFLAGS"
 966      LIBS="$ac_save_LIBS"
 967   else
 968      no_gtk__=yes
 969   fi
 970   if test "x$no_gtk__" = x ; then
 971      AC_MSG_RESULT(yes)
 972      ifelse([$2], , :, [$2])
 973   else
 974      AC_MSG_RESULT(no)
 975      GTK___CFLAGS=""
 976      GTK___LIBS=""
 977      ifelse([$3], , :, [$3])
 978   fi
 979   CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 980   AC_SUBST(CXXFLAGS)
 981   AC_SUBST(GTK___CFLAGS)
 982   AC_SUBST(GTK___LIBS)
 983 ])
 984
 985 dnl   GUILE_FLAGS --- set flags for compiling and linking with Guile
 986 dnl
 987 dnl   This macro runs the `guile-config' script, installed with Guile,
 988 dnl   to find out where Guile's header files and libraries are
 989 dnl   installed.  It sets two variables, marked for substitution, as
 990 dnl   by AC_SUBST.
 991 dnl
 992 dnl     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 993 dnl             code that uses Guile header files.  This is almost
 994 dnl             always just a -I flag.
 995 dnl
 996 dnl     GUILE_LDFLAGS --- flags to pass to the linker to link a
 997 dnl             program against Guile.  This includes `-lguile' for
 998 dnl             the Guile library itself, any libraries that Guile
 999 dnl             itself requires (like -lqthreads), and so on.  It may
1000 dnl             also include a -L flag to tell the compiler where to
1001 dnl             find the libraries.
1002
1003 AC_DEFUN([GUILE_FLAGS],[
1004 ## The GUILE_FLAGS macro.
1005   ## First, let's just see if we can find Guile at all.
1006   AC_MSG_CHECKING(for Guile)
1007   guile-config link > /dev/null || {
1008     echo "configure: cannot find guile-config; is Guile installed?" 1>&2
1009     exit 1
1010   }
1011   GUILE_CFLAGS="`guile-config compile`"
1012   GUILE_LDFLAGS="`guile-config link`"
1013   AC_SUBST(GUILE_CFLAGS)
1014   AC_SUBST(GUILE_LDFLAGS)
1015   AC_MSG_RESULT(yes)
1016 ])
1017