stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4 AC_DEFUN(AC_STEPMAKE_COMPILE, [
   5     # -O is necessary to get inlining
   6     OPTIMIZE=""
   7     CXXFLAGS=${CXXFLAGS:-""}
   8     checking_b=yes
   9     optimise_b=no
  10     profile_b=no
  11     debug_b=yes
  12
  13     AC_ARG_ENABLE(checking,
  14     [  enable-checking         set runtime checks (assert calls). Default: on],
  15     [checking_b=$enableval] )
  16
  17     # actually, the default is: tja='-O' to get inlining...
  18     # off=''  --jcn
  19
  20     #actually, that sucks.
  21     #  tja looks like a typo.  Default is optimisation off. --hwn
  22
  23     AC_ARG_ENABLE(optimise,
  24     [  enable-optimise         use maximal speed optimisations. Default: off],
  25     [optimise_b=$enableval])
  26
  27     AC_ARG_ENABLE(profiling,
  28     [  enable-profiling        compile with gprof support. Default: off],
  29     [profile_b=$enableval])
  30
  31     AC_ARG_ENABLE(debugging,
  32     [  enable-debugging        set debug info. Default: on],
  33     [debug_b=$enableval])
  34
  35     AC_ARG_ENABLE(mingw-prefix,
  36     [  enable-mingw-prefix=DIR set the mingw32 directory (standalone windows32 exes)],
  37     [MINGWPREFIX=$enableval],
  38     [MINGWPREFIX=no])
  39
  40     if test "$printing_b" = no; then
  41         # ugh
  42         AC_DEFINE(NPRINT)
  43         DEFINES="$DEFINES -DNPRINT"
  44     fi
  45
  46     if test "$checking_b" = no; then
  47         # ugh
  48         AC_DEFINE(NDEBUG)
  49         DEFINES="$DEFINES -DNDEBUG"
  50     fi
  51
  52     if test "$optimise_b" = yes; then
  53         OPTIMIZE="-O2 -finline-functions"
  54     fi
  55
  56     if test "$optimise_b" = no; then
  57         OPTIMIZE=""
  58     fi
  59
  60     if test $profile_b = yes; then
  61         EXTRA_LIBES="-pg"
  62         OPTIMIZE="$OPTIMIZE -pg"
  63     fi
  64
  65     if test $debug_b = yes; then
  66         OPTIMIZE="$OPTIMIZE -g"
  67     fi
  68
  69     # however, C++ support in mingw32 v 0.1.4 is still flaky
  70     if test x$MINGWPREFIX != xno; then
  71         ICFLAGS="-I$MINGWPREFIX/include"
  72         ILDFLAGS="-$MINGWPREFIX/lib"
  73     fi
  74
  75     AC_PROG_CC
  76     LD='$(CC)'
  77     AC_SUBST(LD)
  78
  79     CPPFLAGS=${CPPFLAGS:-""}
  80     AC_SUBST(CPPFLAGS)
  81     AC_SUBST(LDFLAGS)
  82     AC_SUBST(ICFLAGS)
  83     AC_SUBST(ILDFLAGS)
  84     AC_SUBST(DEFINES)
  85     AC_SUBST(EXTRA_LIBES)
  86 ])
  87
  88 AC_DEFUN(AC_STEPMAKE_CXX, [
  89     AC_LANG_CPLUSPLUS
  90     AC_PROG_CXX
  91
  92     AC_CHECK_HEADER(FlexLexer.h, true,
  93         AC_STEPMAKE_WARN(can"\'"t find flex header. Please install Flex headers correctly))
  94
  95     CPPFLAGS="$CPPFLAGS $DEFINES"
  96     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
  97     LDFLAGS=$EXTRA_LIBES
  98
  99     AC_SUBST(CXXFLAGS)
 100     AC_SUBST(CXX)
 101     LD='$(CXX)'
 102     AC_SUBST(LD)
 103 ])
 104
 105 AC_DEFUN(AC_STEPMAKE_CXXTEMPLATE, [
 106     AC_CACHE_CHECK([whether explicit instantiation is needed],
 107         lily_cv_need_explicit_instantiation,
 108         AC_TRY_LINK([
 109     template <class T> struct foo { static int baz; };
 110     template <class T> int foo<T>::baz = 1;
 111     ], [ return foo<int>::baz; ],
 112             lily_cv_need_explicit_instantiation=no,
 113             lily_cv_need_explicit_instantiation=yes))
 114     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 115         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 116     fi
 117 ])
 118
 119 AC_DEFUN(AC_STEPMAKE_DATADIR, [
 120     if test "$datadir" = "\${prefix}/share"; then
 121             datadir='${prefix}/share/'$package
 122     fi
 123     DIR_DATADIR=${datadir}
 124     presome=${prefix}
 125     if test "$prefix" = "NONE"; then
 126             presome=${ac_default_prefix}
 127     fi
 128     DIR_DATADIR=`echo ${DIR_DATADIR} | sed "s!\\\${prefix}!$presome!"`
 129     AC_SUBST(datadir)
 130     AC_SUBST(DIR_DATADIR)
 131     AC_DEFINE_UNQUOTED(DIR_DATADIR, "${DIR_DATADIR}")
 132 ])
 133
 134 AC_DEFUN(AC_STEPMAKE_END, [
 135     AC_OUTPUT($CONFIGFILE.make:config.make.in)
 136
 137     rm -f GNUmakefile
 138     cp make/toplevel.make.in ./GNUmakefile
 139     chmod 444 GNUmakefile
 140 ])
 141
 142 AC_DEFUN(AC_STEPMAKE_GXX, [
 143     # ugh autoconf
 144     changequote(<<, >>)dnl
 145     if $CXX --version | grep '2\.[78]' > /dev/null ||
 146         $CXX --version | grep 'egcs' > /dev/null
 147     changequote([, ])dnl
 148     then
 149             true
 150     else
 151             AC_STEPMAKE_WARN(can\'t find g++ 2.7, 2.8 or egcs)
 152     fi
 153 ])
 154
 155 AC_DEFUN(AC_STEPMAKE_INIT, [
 156
 157     . $srcdir/VERSION
 158     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 159     if test x$MY_PATCH_LEVEL != x; then
 160         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 161     fi
 162
 163     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 164     changequote(<<, >>)dnl
 165     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 166     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 167     changequote([, ])dnl
 168
 169     if test "x$PACKAGE" = "xSTEPMAKE"; then
 170         echo Stepmake package!
 171         (cd stepmake; rm -f stepmake; ln -s ../stepmake .)
 172         (cd stepmake; rm -f bin; ln -s ../bin .)
 173         AC_CONFIG_AUX_DIR(bin)
 174     else
 175         echo Package: $PACKAGE
 176         AC_CONFIG_AUX_DIR(stepmake/bin)
 177     fi
 178
 179     AC_SUBST(package)
 180     AC_SUBST(PACKAGE)
 181     AC_SUBST(PACKAGE_NAME)
 182     AC_DEFINE_UNQUOTED(PACKAGE, "${PACKAGE_NAME}")
 183     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 184
 185     package_depth=`dirname $cache_file`
 186     AC_SUBST(package_depth)
 187
 188     AUTOGENERATE="This file was automatically generated by configure"
 189     AC_SUBST(AUTOGENERATE)
 190     absolute_builddir="`pwd`"
 191     AC_SUBST(absolute_builddir)
 192
 193     # No versioning on directory names of sub-packages
 194     stepmake=stepmake
 195     AC_SUBST(stepmake)
 196
 197     STATE_VECTOR=`ls make/STATE-VECTOR 2>/dev/null`
 198     if test "x$STATE_VECTOR" != "x"; then
 199         STATE_VECTOR="\$(depth)/$STATE_VECTOR"
 200     fi
 201     AC_SUBST(STATE_VECTOR)
 202
 203     CONFIGSUFFIX=
 204     AC_ARG_ENABLE(config,
 205     [  enable-config=FILE      put configure settings in config-FILE.make],
 206     [CONFIGSUFFIX=$enableval])
 207
 208     if test "$CONFIGSUFFIX" != "" ; then
 209         CONFIGFILE=config-$CONFIGSUFFIX
 210     else
 211         CONFIGFILE=config
 212     fi
 213     AC_SUBST(CONFIGSUFFIX)
 214
 215     AC_CANONICAL_HOST
 216     AC_CHECK_PROGS(MAKE, make, error)
 217     AC_CHECK_PROGS(FIND, find, error)
 218
 219
 220 dnl system supplied INSTALL is unsafe; use our own install.
 221 dnl    AC_PROG_INSTALL
 222 dnl    if test "$INSTALL" = "bin/install-sh"; then
 223 dnl     export INSTALL="\$\(depth\)/bin/install-sh"
 224 dnl    fi
 225
 226     AC_CHECK_PROGS(TAR, tar, error)
 227     AC_CHECK_PROGS(BASH, bash, /bin/sh)
 228
 229     AC_PATH_PROG(PYTHON, python, -echo no python)
 230     AC_SUBST(PYTHON)
 231
 232
 233     AC_CHECK_SEARCH_RESULT($MAKE, GNU make,  You should install GNU make)
 234     if test $MAKE != "error" ; then
 235         $MAKE -v| grep GNU > /dev/null
 236         if test "$?" = 1
 237         then
 238                 AC_STEPMAKE_WARN(Please install *GNU* make)
 239         fi
 240     fi
 241
 242     AC_CHECK_SEARCH_RESULT($PYTHON, python, You should install Python)
 243
 244     if test "x$OSTYPE" = "xcygwin32" || test "x$OSTYPE" = "xWindows_NT"; then
 245         LN=cp # hard link does not work under cygnus-nt
 246         LN_S=cp # symbolic link does not work for native nt
 247         ZIP="zip -r -9" #
 248         DOTEXE=.exe
 249        DIRSEP='\\'
 250         PATHSEP=';'
 251        INSTALL="\$(stepdir)/../bin/install-dot-exe.sh -c"
 252     else
 253         DIRSEP='/'
 254         PATHSEP=':'
 255         LN=ln
 256         LN_S='ln -s'
 257         ZIP="zip -r -9"
 258         INSTALL="\$(stepdir)/../bin/install-sh -c"
 259     fi
 260     AC_SUBST(DOTEXE)
 261     AC_SUBST(ZIP)
 262     AC_SUBST(LN)
 263     AC_SUBST(LN_S)
 264     AC_SUBST(INSTALL)
 265     AC_DEFINE_UNQUOTED(DIRSEP, '${DIRSEP}')
 266     AC_SUBST(PATHSEP)
 267     AC_DEFINE_UNQUOTED(PATHSEP, '${PATHSEP}')
 268
 269
 270     AC_STEPMAKE_DATADIR
 271 ])
 272
 273 AC_DEFUN(AC_STEPMAKE_LEXYACC, [
 274     # ugh, automake: we want (and check for) bison
 275     AC_PROG_YACC
 276     # ugh, automake: we want (and check for) flex
 277     # AC_PROG_LEX
 278     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 279
 280     # AC_DECL_YYTEXT
 281     # ugh, ugh
 282     ac_cv_prog_lex_root=lex.yy
 283
 284     AC_CHECK_PROGS(BISON, bison, error)
 285     AC_CHECK_PROGS(FLEX, flex, error)
 286     AC_CHECK_SEARCH_RESULT($BISON, bison,  Please install Bison, 1.25 or better)
 287     AC_CHECK_SEARCH_RESULT($FLEX,  flex, Please install Flex, 2.5 or better)
 288
 289     if test $BISON != "error"; then
 290         bison_version=`$BISON --version| sed 's/^.*version 1.//g' `
 291         if test $bison_version -lt 25; then
 292             AC_STEPMAKE_WARN(Your bison is a bit old (1.$bison_version). You might have to install 1.25)
 293         fi
 294     fi
 295
 296     AC_SUBST(BISON)
 297     AC_SUBST(FLEX)
 298 ])
 299
 300 AC_DEFUN(AC_STEPMAKE_LIB, [
 301     AC_CHECK_PROGS(AR, ar, error)
 302     AC_PROG_RANLIB
 303
 304     AC_SUBST(AR)
 305     AC_SUBST(RANLIB)
 306 ])
 307
 308 AC_DEFUN(AC_STEPMAKE_LIBTOOL, [
 309     # libtool.info ...
 310     # **Never** try to set library version numbers so that they correspond
 311     # to the release number of your package.  This is an abuse that only
 312     # fosters misunderstanding of the purpose of library versions.
 313
 314     REVISION=$PATCH_LEVEL
 315     # CURRENT=$MINOR_VERSION
 316     CURRENT=`expr $MINOR_VERSION + 1`
 317     # AGE=$(expr $MAJOR_VERSION + 1)
 318     AGE=$MAJOR_VERSION
 319     AC_SUBST(CURRENT)
 320     AC_SUBST(REVISION)
 321     AC_SUBST(AGE)
 322 ])
 323
 324 AC_DEFUN(AC_STEPMAKE_LOCALE, [
 325     lang=English
 326     ALL_LINGUAS="en nl"
 327
 328     # with/enable ??
 329     AC_ARG_WITH(localedir,
 330     [  with-localedir=LOCALE   use LOCALE as locale dir. Default: PREFIX/share/locale ],
 331     localedir=$with_localedir,
 332     localedir='${prefix}/share/locale')
 333
 334     AC_ARG_WITH(lang,
 335     [  with-lang=LANG          use LANG as language to emit messages],
 336     language=$with_lang,
 337     language=English)
 338
 339     AC_MSG_CHECKING(language)
 340     case "$language" in
 341       En* | en* | Am* | am* | US* | us*)
 342             lang=English;;
 343       NL | nl | Du* | du* | Ned* | ned*)
 344             lang=Dutch;;
 345       "")
 346             lang=English;;
 347       *)
 348             lang=unknown;;
 349     esac
 350     AC_MSG_RESULT($lang)
 351
 352     if test "$lang" = "unknown" ; then
 353         AC_STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 354     fi
 355
 356 ])
 357
 358 AC_DEFUN(AC_STEPMAKE_GETTEXT, [
 359     DIR_LOCALEDIR=${localedir}
 360     presome=${prefix}
 361     if test "$prefix" = "NONE"; then
 362             presome=${ac_default_prefix}
 363     fi
 364     DIR_LOCALEDIR=`echo ${DIR_LOCALEDIR} | sed "s!\\\${prefix}!$presome!"`
 365     AC_SUBST(localedir)
 366     AC_SUBST(DIR_LOCALEDIR)
 367     AC_DEFINE_UNQUOTED(DIR_LOCALEDIR, "${DIR_LOCALEDIR}")
 368
 369     AC_CHECK_LIB(intl, gettext)
 370     AC_CHECK_FUNCS(gettext)
 371 ])
 372
 373 AC_DEFUN(AC_STEPMAKE_MAN, [
 374     AC_CHECK_PROGS(TROFF, troff, -echo no troff)
 375 ])
 376
 377 AC_DEFUN(AC_STEPMAKE_MSGFMT, [
 378     # AC_CHECK_PROGS(MSGFMT, msgfmt, -echo no msgfmt)
 379     AC_CHECK_PROGS(MSGFMT, msgfmt, \$(SHELL) \$(step-bindir)/fake-msgfmt.sh )
 380     AC_MSG_CHECKING(whether msgfmt accepts -o)
 381     msgfmt_output="`msgfmt -o bla 2>&1 | grep usage`"
 382     if test "$msgfmt_output" = ""; then
 383         AC_MSG_RESULT(yes)
 384     else
 385         # urg
 386         MSGFMT="\$(SHELL) \$(step-bindir)/fake-msgfmt.sh"
 387         AC_MSG_RESULT(no)
 388         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 389     fi
 390     if test ! -n "$MSGFMT"; then
 391         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 392     fi
 393 ])
 394
 395 AC_DEFUN(AC_STEPMAKE_TEXMF, [
 396     AC_ARG_ENABLE(tex-prefix,
 397     [  enable-tex-prefix=DIR   set the tex-directory to find TeX subdirectories. (default: PREFIX)],
 398     [TEXPREFIX=$enableval],
 399     [TEXPREFIX=auto] )
 400
 401     AC_ARG_ENABLE(tex-dir,
 402     [  enable-tex-dir=DIR      set the directory to put $PACKAGE_NAME TeX files in. ],
 403     [TEXDIR=$enableval],
 404     [TEXDIR=auto] )
 405
 406     AC_ARG_ENABLE(mf-dir,
 407     [  enable-mf-dir=DIR       set the directory to put $PACKAGE_NAME MetaFont files in. ],
 408     [MFDIR=$enableval],
 409     [MFDIR=auto])
 410
 411     if test "x$TEXPREFIX" = xauto ; then
 412         AC_TEX_PREFIX(TEXPREFIX)
 413     else
 414      find_texprefix=$TEXPREFIX
 415     fi
 416
 417     if test "x$MFDIR" = xauto; then
 418         AC_MF_SUBDIR(MFDIR)
 419     fi
 420
 421     if test "x$TEXDIR" = xauto ; then
 422         AC_TEX_SUBDIR(TEXDIR)
 423     fi
 424
 425     AC_SUBST(TEXPREFIX)
 426     AC_SUBST(TEXDIR)
 427     AC_SUBST(MFDIR)
 428 ])
 429
 430 AC_DEFUN(AC_STEPMAKE_WARN, [
 431     AC_MSG_WARN($1)
 432     warn_b=yes
 433 ])
 434
 435 AC_DEFUN(AC_STEPMAKE_YODL, [
 436     if test "x$YODL" = "x"; then
 437         AC_CHECK_PROGS(YODL, yodl, -echo no yodl)
 438         AC_CHECK_PROGS(YODL2HTML, yodl2html, -echo no yodl)
 439         AC_CHECK_PROGS(YODL2LATEX, yodl2latex, )
 440         AC_CHECK_PROGS(YODL2MAN, yodl2man, -echo no yodl)
 441         AC_CHECK_PROGS(YODL2MSLESS, yodl2msless, -echo no yodl)
 442         AC_CHECK_PROGS(YODL2TEXINFO, yodl2texinfo, -echo no yodl)
 443         AC_CHECK_PROGS(YODL2TXT, yodl2txt, -echo no yodl)
 444     else
 445         AC_SUBST(YODL)
 446         AC_SUBST(YODL2HTML)
 447         AC_SUBST(YODL2LATEX)
 448         AC_SUBST(YODL2MAN)
 449         AC_SUBST(YODL2MSLESS)
 450         AC_SUBST(YODL2TEXINFO)
 451         AC_SUBST(YODL2TXT)
 452         export YODL YODL2HTML YODL2LATEX YODL2MAN YODL2MSLESS YODL2TEXINFO YODL2TXT
 453     fi
 454     if test "x$YODL" = "-echo no yodl"; then
 455         AC_STEPMAKE_WARN(Did not find YODL (Yodl is Yet Oneother Document Language, see http://www.cs.uu.nl/~hanwen/yodl))
 456     fi
 457 ])
 458
 459 dnl should cache result.
 460 dnl should  look in $prefix first.
 461 dnl should probably assume TDS
 462
 463 AC_DEFUN(AC_TEX_PREFIX, [
 464
 465
 466     AC_MSG_CHECKING(TeX/MF root dir directory)
 467
 468     find_root_prefix="$prefix"
 469
 470
 471     test "x$find_root_prefix" = xNONE && find_root_prefix="$ac_default_prefix"
 472     find_texpostfix="";
 473     for postfix in "/lib/tex/" "/lib/texmf" "/lib" "/tex" "/texmf"; do
 474         find_texprefix="$find_root_prefix$postfix"
 475         if test -d $find_texprefix; then
 476             find_texpostfix=$postfix
 477             break;
 478         fi
 479     done
 480
 481     if test "x$find_texpostfix" = x; then
 482         find_texpostfix='/lib/texmf/tex'
 483         AC_STEPMAKE_WARN(Cannot determine the TeX-directory. Please use --enable-tex-prefix)
 484     fi
 485
 486     find_texprefix="$find_root_prefix/$find_texpostfix"
 487
 488     # only assign if variablename not empty
 489     if test x != "x[$]$1"; then
 490         $1='${prefix}'/"$find_texpostfix"
 491     fi
 492     AC_MSG_RESULT($find_texprefix)
 493
 494 ])
 495
 496
 497 # find a directory inside a prefix,
 498 # $1 the prefix (expanded version)
 499 # $2 variable to assign
 500 # $3 the directory name
 501 # $4 description
 502 AC_DEFUN(AC_FIND_DIR_IN_PREFIX, [
 503
 504     AC_MSG_CHECKING($4 directory)
 505     find_dirdir=`(cd $1;
 506       $FIND ./ -type d -a -name $3 -print |sort|head -1|sed 's#^\./##')`
 507
 508
 509     if test "x$find_dirdir" = x; then
 510        find_dirdir="/$3";
 511        AC_STEPMAKE_WARN(Cannot determine $4 subdirectory. Please set from command-line)
 512         true
 513     fi
 514     $2=$find_dirdir
 515     AC_MSG_RESULT($1/$find_dirdir)
 516 ])
 517
 518 # ugh.  this is hopeless
 519 AC_DEFUN(AC_KPSE_TEX_DIR, [
 520         kpse_paths=`(kpsepath -n latex tex; kpsepath -n tex tex) | sed 's/:/ /g' | tr ' ' '\012' |sort | uniq -d`
 521         kpse_syspaths=`echo $kpse_paths | grep '!'| sed 's/!//g'`
 522         echo $kpse_paths
 523         if test -w "$kpse_syspaths";
 524         then
 525                 dir=`echo $kpse_syspaths | head -1`
 526         else
 527                 dir=`echo $kpse_paths | grep -v '!'| head -1`
 528         fi
 529         if test "$prefix" = "NONE"; then
 530                 local_prefix=$ac_default_prefix
 531                 local_prefix_quote='${prefix}'
 532
 533         else
 534                 local_prefix=$prefix
 535                 local_prefix_quote=$prefix
 536         fi
 537         echo $local_prefix_quote = $local_prefix
 538         echo $dir
 539         echo $dir  | sed 's!'$local_prefix'!\$local_prefix_quote!g'
 540 ])
 541
 542 AC_DEFUN(AC_TEX_SUBDIR, [
 543 dnl    AC_REQUIRE([AC_TEX_PREFIX])
 544     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, tex,TeX input)
 545     $1="$TEXPREFIX/$$1"
 546 ])
 547
 548 AC_DEFUN(AC_MF_SUBDIR, [
 549 dnl     AC_REQUIRE([AC_TEX_PREFIX])
 550     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, source, MF input)
 551     $1="$TEXPREFIX/$$1"
 552 ])
 553
 554 AC_DEFUN(AC_CHECK_SEARCH_RESULT, [
 555         result="`echo \"$1\" | grep echo`"
 556         if test "x$1" = "xerror" -o "x$result" != "x"; then
 557                 AC_STEPMAKE_WARN(can\'t find $2. $3)
 558         fi
 559 ])
 560
 561 # Configure paths for GTK+
 562 # Owen Taylor     97-11-3
 563
 564 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 565 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
 566 dnl
 567 AC_DEFUN(AM_PATH_GTK,
 568 [dnl
 569 dnl Get the cflags and libraries from the gtk-config script
 570 dnl
 571   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
 572   min_gtk_version=ifelse([$1], ,0.99.7,$1)
 573   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
 574   no_gtk=""
 575   if test "$GTK_CONFIG" != "no" ; then
 576     GTK_CFLAGS=`$GTK_CONFIG --cflags`
 577     GTK_LIBS=`$GTK_CONFIG --libs`
 578     ac_save_CFLAGS="$CFLAGS"
 579     ac_save_LIBS="$LIBS"
 580     ac_save_CXXFLAGS="$CXXFLAGS"
 581     CFLAGS="$CFLAGS $GTK_CFLAGS"
 582     CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 583     LIBS="$LIBS $GTK_LIBS"
 584 dnl
 585 dnl Now check if the installed GTK is sufficiently new. (Also sanity
 586 dnl checks the results of gtk-config to some extent
 587 dnl
 588     AC_TRY_RUN([
 589 #include <gtk/gtk.h>
 590 #include <stdio.h>
 591
 592 int
 593 main ()
 594 {
 595   int major, minor, micro;
 596
 597   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
 598      printf("%s, bad version string\n", "$min_gtk_version");
 599      exit(1);
 600    }
 601
 602    return !((gtk_major_version > major) ||
 603             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
 604             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
 605 }
 606 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 607      CFLAGS="$ac_save_CFLAGS"
 608      CXXFLAGS="$ac_save_CXXFLAGS"
 609      LIBS="$ac_save_LIBS"
 610   else
 611      no_gtk=yes
 612   fi
 613   if test "x$no_gtk" = x ; then
 614      AC_MSG_RESULT(yes)
 615      ifelse([$2], , :, [$2])
 616   else
 617      AC_MSG_RESULT(no)
 618      GTK_CFLAGS=""
 619      GTK_LIBS=""
 620      ifelse([$3], , :, [$3])
 621   fi
 622   CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 623   AC_SUBST(CXXFLAGS)
 624   AC_SUBST(GTK_CFLAGS)
 625   AC_SUBST(GTK_LIBS)
 626 ])
 627
 628
 629 # Configure paths for GTK--
 630 # Jan Nieuwenhuizen   98-06-3
 631
 632 dnl AM_PATH_GTK__([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 633 dnl Test for GTK--, and define GTK___CFLAGS and GTK___LIBS
 634 dnl
 635 AC_DEFUN(AM_PATH_GTK__,
 636 [dnl
 637 dnl Get the cflags and libraries from the gtk__-config script
 638 dnl
 639   min_gtk___version=ifelse([$1], ,0.9.4,$1)
 640   AC_MSG_CHECKING(for GTK-- - version >= $min_gtk___version)
 641   no_gtk__=""
 642   if test "$GTK_CONFIG" != "no" ; then
 643     GTK___CFLAGS=`$GTK_CONFIG --cflags`
 644     GTK_LIBS=`$GTK_CONFIG --libs`
 645     GTK___LIBS="$GTK_LIBS -lgtkmm"
 646     ac_save_CFLAGS="$CFLAGS"
 647     ac_save_LIBS="$LIBS"
 648     ac_save_CXXFLAGS="$CXXFLAGS"
 649     CFLAGS="$CFLAGS $GTK___CFLAGS"
 650     CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 651     LIBS="$LIBS $GTK___LIBS"
 652 dnl
 653 dnl Now check if the installed GTK__ is sufficiently new. (Also sanity
 654 dnl checks the results of gtk__-config to some extent
 655 dnl
 656     AC_TRY_RUN([
 657 #include <gtk--.h>
 658 #include <stdio.h>
 659
 660 int
 661 main ()
 662 {
 663   // urg
 664   return 0;
 665 }
 666 ],, no_gtk__=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 667      CFLAGS="$ac_save_CFLAGS"
 668      CXXFLAGS="$ac_save_CXXFLAGS"
 669      LIBS="$ac_save_LIBS"
 670   else
 671      no_gtk__=yes
 672   fi
 673   if test "x$no_gtk__" = x ; then
 674      AC_MSG_RESULT(yes)
 675      ifelse([$2], , :, [$2])
 676   else
 677      AC_MSG_RESULT(no)
 678      GTK___CFLAGS=""
 679      GTK___LIBS=""
 680      ifelse([$3], , :, [$3])
 681   fi
 682   CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 683   AC_SUBST(CXXFLAGS)
 684   AC_SUBST(GTK___CFLAGS)
 685   AC_SUBST(GTK___LIBS)
 686 ])
 687