scm/translation-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; (c) 1998--2010 Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;                 Jan Nieuwenhuizen <janneke@gnu.org>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;; metronome marks
  22
  23 (define-public (format-metronome-markup text dur count context)
  24   (let* ((hide-note (eq? #t (ly:context-property context 'tempoHideNote))))
  25     (metronome-markup text dur count hide-note)))
  26
  27 (define-public (metronome-markup text dur count hide-note)
  28   (let* ((note-mark (if (and (not hide-note) (ly:duration? dur))
  29                         (make-smaller-markup
  30                          (make-note-by-number-markup (ly:duration-log dur)
  31                                                      (ly:duration-dot-count dur)
  32                                                      1))
  33                         #f))
  34          (note-markup (if (and (not hide-note) (number? count) (> count 0) )
  35                           (make-concat-markup
  36                            (list
  37                             (make-general-align-markup Y DOWN note-mark)
  38                             (make-simple-markup " ")
  39                             (make-simple-markup "=")
  40                             (make-simple-markup " ")
  41                             (make-simple-markup (number->string count))))
  42                           #f))
  43          (text-markup (if (not (null? text))
  44                           (make-bold-markup text)
  45                           #f)))
  46     (if text-markup
  47         (if (and note-markup (not hide-note))
  48             (make-line-markup (list text-markup
  49                                     (make-concat-markup
  50                                      (list (make-simple-markup "(")
  51                                            note-markup
  52                                            (make-simple-markup ")")))))
  53             (make-line-markup (list text-markup)))
  54         (if note-markup
  55             (make-line-markup (list note-markup))
  56             (make-null-markup)))))
  57
  58 (define-public (format-mark-alphabet mark context)
  59   (make-bold-markup (make-markalphabet-markup (1- mark))))
  60
  61 (define-public (format-mark-box-alphabet mark context)
  62   (make-bold-markup (make-box-markup (make-markalphabet-markup (1- mark)))))
  63
  64 (define-public (format-mark-circle-alphabet mark context)
  65   (make-bold-markup (make-circle-markup (make-markalphabet-markup (1- mark)))))
  66
  67 (define-public (format-mark-letters mark context)
  68   (make-bold-markup (make-markletter-markup (1- mark))))
  69
  70 (define-public (format-mark-numbers mark context)
  71   (make-bold-markup (number->string mark)))
  72
  73 (define-public (format-mark-barnumbers mark context)
  74   (make-bold-markup (number->string (ly:context-property context
  75                                                          'currentBarNumber))))
  76
  77 (define-public (format-mark-box-letters mark context)
  78   (make-bold-markup (make-box-markup (make-markletter-markup (1- mark)))))
  79
  80 (define-public (format-mark-circle-letters mark context)
  81   (make-bold-markup (make-circle-markup (make-markletter-markup (1- mark)))))
  82
  83 (define-public (format-mark-box-numbers mark context)
  84   (make-bold-markup (make-box-markup (number->string mark))))
  85
  86 (define-public (format-mark-circle-numbers mark context)
  87   (make-bold-markup (make-circle-markup (number->string mark))))
  88
  89 (define-public (format-mark-box-barnumbers mark context)
  90   (make-bold-markup (make-box-markup
  91                      (number->string (ly:context-property context
  92                                                           'currentBarNumber)))))
  93
  94 (define-public (format-mark-circle-barnumbers mark context)
  95   (make-bold-markup (make-circle-markup
  96                      (number->string (ly:context-property context
  97                                                           'currentBarNumber)))))
  98
  99
 100 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 101 ;; Bass figures.
 102
 103 (define-public (format-bass-figure figure event context)
 104   (let* ((fig (ly:event-property event 'figure))
 105          (fig-markup (if (number? figure)
 106
 107                          ;; this is not very elegant, but center-aligning
 108                          ;; all digits is problematic with other markups,
 109                          ;; and shows problems in the (lack of) overshoot
 110                          ;; of feta-alphabet glyphs.
 111                          ((if (<= 10 figure)
 112                               (lambda (y) (make-translate-scaled-markup
 113                                            (cons -0.7 0) y))
 114                               identity)
 115
 116                           (cond
 117                            ((eq? #t (ly:event-property event 'diminished))
 118                             (markup #:slashed-digit figure))
 119                            ((eq? #t (ly:event-property event 'augmented-slash))
 120                             (markup #:backslashed-digit figure))
 121                            (else (markup #:number (number->string figure 10)))))
 122                          #f))
 123
 124          (alt (ly:event-property event 'alteration))
 125          (alt-markup
 126           (if (number? alt)
 127               (markup
 128                #:general-align Y DOWN #:fontsize
 129                (if (not (= alt DOUBLE-SHARP))
 130                    -2 2)
 131                (alteration->text-accidental-markup alt))
 132               #f))
 133
 134          (plus-markup (if (eq? #t (ly:event-property event 'augmented))
 135                           (markup #:number "+")
 136                           #f))
 137
 138          (alt-dir (ly:context-property context 'figuredBassAlterationDirection))
 139          (plus-dir (ly:context-property context 'figuredBassPlusDirection)))
 140
 141     (if (and (not fig-markup) alt-markup)
 142         (begin
 143           (set! fig-markup (markup #:left-align #:pad-around 0.3 alt-markup))
 144           (set! alt-markup #f)))
 145
 146
 147     ;; hmm, how to get figures centered between note, and
 148     ;; lone accidentals too?
 149
 150     ;;    (if (markup? fig-markup)
 151     ;;  (set!
 152     ;;   fig-markup (markup #:translate (cons 1.0 0)
 153     ;;                      #:center-align fig-markup)))
 154
 155     (if alt-markup
 156         (set! fig-markup
 157               (markup #:put-adjacent
 158                       X (if (number? alt-dir)
 159                             alt-dir
 160                             LEFT)
 161                       fig-markup
 162                       #:pad-x 0.2 alt-markup)))
 163
 164     (if plus-markup
 165         (set! fig-markup
 166               (if fig-markup
 167                   (markup #:put-adjacent
 168                           X (if (number? plus-dir)
 169                                 plus-dir
 170                                 LEFT)
 171                           fig-markup
 172                           #:pad-x 0.2 plus-markup)
 173                   plus-markup)))
 174
 175     (if (markup? fig-markup)
 176         (markup #:fontsize -2 fig-markup)
 177         empty-markup)))
 178
 179
 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 181 ;; fret diagrams
 182
 183 (define (create-fretboard context grob placement-list)
 184   "Convert @var{placement-list} into a fretboard @var{grob}."
 185
 186   (let* ((tunings (ly:context-property context 'stringTunings))
 187          (my-string-count (length tunings))
 188          (details (ly:grob-property grob 'fret-diagram-details)))
 189
 190     ;; Add string-count from string-tunings to fret-diagram-details.
 191     (set! (ly:grob-property grob 'fret-diagram-details)
 192             (acons 'string-count my-string-count details))
 193     ;; Create the dot-placement list for the grob
 194     (set! (ly:grob-property grob 'dot-placement-list) placement-list)))
 195
 196 (define-public
 197   (determine-frets context notes defined-strings . rest)
 198   "Determine string numbers and frets for playing @var{notes}
 199 as a chord, given specified string numbers @var{defined-strings}.
 200 Will look for predefined fretboards if @code{predefinedFretboardTable}
 201 is not @code {#f}.  If @var{rest} is present, it contains the
 202 FretBoard grob, and a fretboard will be
 203 created.  Otherwise, a list of (string fret finger) lists will
 204 be returned)."
 205
 206   ;;  helper functions
 207
 208   (define (string-frets->placement-list string-frets string-count)
 209     "Convert @var{string-frets} to @code{fret-diagram-verbose}
 210 dot placement entries."
 211     (let* ((placements (list->vector
 212                         (map (lambda (x) (list 'mute  (1+ x)))
 213                              (iota string-count)))))
 214
 215       (for-each (lambda (sf)
 216                   (let* ((string (car sf))
 217                          (fret (cadr sf))
 218                          (finger (caddr sf)))
 219                     (vector-set!
 220                      placements (1- string)
 221                      (if (= 0 fret)
 222                          (list 'open string)
 223                          (if finger
 224                              (list 'place-fret string fret finger)
 225                              (list 'place-fret string fret))))))
 226                 string-frets)
 227       (vector->list placements)))
 228
 229   (define (placement-list->string-frets placement-list)
 230     "Convert @var{placement-list} to string-fret list."
 231     (map (lambda (x) (if (eq? (car x) 'place-fret)
 232                          (cdr x)
 233                          (list (cadr x) 0)))
 234          (filter (lambda (l) (or (eq? (car l) 'place-fret)
 235                                  (eq? (car l) 'open))) placement-list)))
 236
 237
 238   (define (get-predefined-fretboard predefined-fret-table tuning pitches)
 239     "Search through @var{predefined-fret-table} looking for a predefined
 240 fretboard with a key of @var{(tuning . pitches)}.  The search will check
 241 both up and down an octave in order to accomodate transposition of the
 242 chords.  Returns a placement-list."
 243
 244     (define (get-fretboard key)
 245       (let ((hash-handle
 246              (hash-get-handle predefined-fret-table key)))
 247         (if hash-handle
 248             (cdr hash-handle)  ; return table entry
 249             '())))
 250
 251     ;; body of get-predefined-fretboard
 252     (let ((test-fretboard (get-fretboard (cons tuning pitches))))
 253       (if (not (null? test-fretboard))
 254           test-fretboard
 255           (let ((test-fretboard
 256                  (get-fretboard
 257                   (cons tuning (map (lambda (x) (shift-octave x 1)) pitches)))))
 258             (if (not (null? test-fretboard))
 259                 test-fretboard
 260                 (get-fretboard
 261                  (cons tuning (map (lambda (x) (shift-octave x -1))
 262                                    pitches))))))))
 263
 264   ;; body of determine-frets
 265   (let* ((predefined-fret-table
 266           (ly:context-property context 'predefinedDiagramTable))
 267          (tunings (ly:context-property context 'stringTunings))
 268          (string-count (length tunings))
 269          (grob (if (null? rest) '() (car rest)))
 270          (pitches (map (lambda (x) (ly:event-property x 'pitch)) notes))
 271          (predefined-fretboard
 272           (if predefined-fret-table
 273               (get-predefined-fretboard
 274                predefined-fret-table
 275                tunings
 276                pitches)
 277               '())))
 278
 279      (if (null? predefined-fretboard)
 280          (let ((string-frets
 281                 (determine-frets-and-strings
 282                  notes
 283                  defined-strings
 284                  (ly:context-property context 'minimumFret 0)
 285                  (ly:context-property context 'maximumFretStretch 4)
 286                  tunings)))
 287             (if (null? grob)
 288                 string-frets
 289                 (create-fretboard
 290                  context grob (string-frets->placement-list
 291                                 string-frets string-count))))
 292          (if (null? grob)
 293              (placement-list->string-frets predefined-fretboard)
 294              (create-fretboard context grob predefined-fretboard)))))
 295
 296
 297 (define (determine-frets-and-strings
 298           notes defined-strings minimum-fret maximum-stretch tuning)
 299
 300   (define (calc-fret pitch string tuning)
 301     (- (ly:pitch-semitones pitch) (list-ref tuning (1- string))))
 302
 303   (define (note-pitch a)
 304     (ly:event-property a 'pitch))
 305
 306   (define (note-pitch>? a b)
 307     (ly:pitch<? (note-pitch b)
 308                 (note-pitch a)))
 309
 310   (define (note-finger ev)
 311     (let* ((articulations (ly:event-property ev 'articulations))
 312            (finger-found #f))
 313
 314       (map (lambda (art)
 315              (let* ((num (ly:event-property art 'digit)))
 316
 317                (if (and (eq? 'fingering-event (ly:event-property art 'class))
 318                         (number? num))
 319                    (set! finger-found num))))
 320            articulations)
 321
 322       finger-found))
 323
 324   (define (string-number event)
 325     (let ((num (ly:event-property event 'string-number)))
 326       (if (number? num)
 327           num
 328           #f)))
 329
 330
 331   (define (delete-free-string string)
 332     (if (number? string)
 333         (set! free-strings
 334               (delete string free-strings))))
 335
 336   (define free-strings '())
 337   (define unassigned-notes '())
 338   (define specified-frets '())
 339
 340   (define (close-enough fret)
 341     (if (null? specified-frets)
 342         #t
 343         (reduce
 344           (lambda (x y)
 345             (and x y))
 346           #t
 347           (map (lambda (specced-fret)
 348                  (> maximum-stretch (abs (- fret specced-fret))))
 349                specified-frets))))
 350
 351   (define (string-qualifies string pitch)
 352     (let* ((fret (calc-fret pitch string tuning)))
 353       (and (>= fret minimum-fret)
 354            (close-enough fret))))
 355
 356   (define string-fret-fingering-tuples '())
 357
 358   (define (set-fret note string)
 359     (let ((this-fret (calc-fret (ly:event-property note 'pitch)
 360                                 string
 361                                 tuning)))
 362        (set! string-fret-fingering-tuples
 363              (cons (list string
 364                          this-fret
 365                          (note-finger note))
 366                    string-fret-fingering-tuples))
 367        (delete-free-string string)
 368        (set! specified-frets (cons this-fret specified-frets))))
 369
 370   ;;; body of determine-frets-and-strings
 371   (set! free-strings (map 1+ (iota (length tuning))))
 372
 373   ;; get defined-strings same length as notes
 374   (while (< (length defined-strings) (length notes))
 375          (set! defined-strings (append defined-strings '(()))))
 376
 377   ;; handle notes with strings assigned
 378   (for-each
 379     (lambda (note string)
 380       (if (null? string)
 381           (set! unassigned-notes (cons note unassigned-notes))
 382           (let ((this-string (string-number string)))
 383             (delete-free-string this-string)
 384             (set-fret note this-string))))
 385     notes defined-strings)
 386
 387   ;; handle notes without strings assigned
 388   (for-each
 389    (lambda (note)
 390      (let* ((fit-string
 391               (find (lambda (string)
 392                       (string-qualifies string (note-pitch note)))
 393                     free-strings)))
 394         (if fit-string
 395             (set-fret note fit-string)
 396             (ly:warning "No string for pitch ~a (given frets ~a)"
 397                         (note-pitch note)
 398                         specified-frets))))
 399    (sort unassigned-notes note-pitch>?))
 400
 401    string-fret-fingering-tuples)
 402
 403 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 404 ;; tablature
 405
 406 ;; The TabNoteHead tablatureFormat callbacks.
 407
 408 ;; Calculate the fret from pitch and string number as letter
 409 ;; The fret letter is taken from 'fretLabels if present
 410 (define-public (fret-letter-tablature-format
 411                 context string-number fret-number)
 412  (let ((labels (ly:context-property context 'fretLabels)))
 413   (make-vcenter-markup
 414    (cond
 415     ((= 0 (length labels))
 416      (string (integer->char (+ fret-number (char->integer #\a)))))
 417     ((and (<= 0 fret-number) (< fret-number (length labels)))
 418      (list-ref labels fret-number))
 419     (else
 420      (ly:warning "No label for fret ~a (on string ~a);
 421 only ~a fret labels provided"
 422                  fret-number string-number (length labels))
 423        ".")))))
 424
 425 ;; Display the fret number as a number
 426 (define-public (fret-number-tablature-format
 427                 context string-number fret-number)
 428   (make-vcenter-markup
 429     (format "~a" fret-number)))
 430
 431 ;; The 5-string banjo has got a extra string, the fifth (duh), which
 432 ;; starts at the fifth fret on the neck.  Frets on the fifth string
 433 ;; are referred to relative to the other frets:
 434 ;;   the "first fret" on the fifth string is really the sixth fret
 435 ;;   on the banjo neck.
 436 ;; We solve this by defining a new fret-number-tablature function:
 437 (define-public (fret-number-tablature-format-banjo
 438                 context string-number fret-number)
 439  (make-vcenter-markup
 440   (number->string (cond
 441                    ((and (> fret-number 0) (= string-number 5))
 442                     (+ fret-number 5))
 443                    (else fret-number)))))
 444
 445 ;;  Tab note head staff position functions
 446 ;;
 447 ;;  Define where in the staff to display a given string.  Some forms of
 448 ;;  tablature put the tab note heads in the spaces, rather than on the
 449 ;;  lines
 450
 451 (define-public (tablature-position-on-lines context string-number)
 452  (let* ((string-tunings (ly:context-property context 'stringTunings))
 453         (string-count (length string-tunings))
 454         (string-one-topmost (ly:context-property context 'stringOneTopmost))
 455         (staff-line (- (* 2 string-number) string-count 1)))
 456   (if string-one-topmost
 457       (- staff-line)
 458       staff-line)))
 459
 460 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 461 ;; bar numbers
 462
 463 (define-public ((every-nth-bar-number-visible n) barnum)
 464   (= 0 (modulo barnum n)))
 465
 466 (define-public ((modulo-bar-number-visible n m) barnum)
 467   (and (> barnum 1) (= m (modulo barnum n))))
 468
 469 (define-public ((set-bar-number-visibility n) tr)
 470   (let ((bn (ly:context-property tr 'currentBarNumber)))
 471     (ly:context-set-property! tr 'barNumberVisibility
 472                               (modulo-bar-number-visible n (modulo bn n)))))
 473
 474 (define-public (first-bar-number-invisible barnum) (> barnum 1))
 475
 476 (define-public (all-bar-numbers-visible barnum) #t)
 477
 478
 479 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 480 ;; percent repeat counters
 481
 482 (define-public ((every-nth-repeat-count-visible n) count context)
 483   (= 0 (modulo count n)))
 484
 485 (define-public (all-repeat-counts-visible count context) #t)