scm/translation-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; (c) 1998--2012 Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;                 Jan Nieuwenhuizen <janneke@gnu.org>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;; clefs
  22
  23 (define-public (clef-octavation-markup oct style)
  24   "The octavation sign formatting function.  @var{oct} is supposed to be
  25 a string holding the octavation number, @var{style} determines the
  26 way the octavation number is displayed."
  27   (let* ((delim (if (symbol? style)
  28                     (case style
  29                       ((parenthesized) (cons "(" ")"))
  30                       ((bracketed) (cons "[" "]"))
  31                       (else (cons "" "")))
  32                     (cons "" "")))
  33          (text (string-concatenate (list (car delim) oct (cdr delim)))))
  34
  35        (make-vcenter-markup text)))
  36
  37
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39 ;; metronome marks
  40
  41 (define-public (format-metronome-markup event context)
  42   (let ((hide-note (ly:context-property context 'tempoHideNote #f))
  43         (text (ly:event-property event 'text))
  44         (dur (ly:event-property event 'tempo-unit))
  45         (count (ly:event-property event 'metronome-count)))
  46
  47     (metronome-markup text dur count hide-note)))
  48
  49 (define-public (metronome-markup text dur count hide-note)
  50   (let* ((note-mark (if (and (not hide-note) (ly:duration? dur))
  51                         (make-smaller-markup
  52                          (make-note-by-number-markup (ly:duration-log dur)
  53                                                      (ly:duration-dot-count dur)
  54                                                      1))
  55                         #f))
  56          (count-markup (cond ((number? count)
  57                               (if (> count 0)
  58                                   (make-simple-markup (number->string count))
  59                                   #f))
  60                              ((pair? count)
  61                               (make-concat-markup
  62                                (list
  63                                 (make-simple-markup (number->string (car count)))
  64                                 (make-simple-markup " ")
  65                                 (make-simple-markup "–")
  66                                 (make-simple-markup " ")
  67                                 (make-simple-markup (number->string (cdr count))))))
  68                              (else #f)))
  69          (note-markup (if (and (not hide-note) count-markup)
  70                           (make-concat-markup
  71                            (list
  72                             (make-general-align-markup Y DOWN note-mark)
  73                             (make-simple-markup " ")
  74                             (make-simple-markup "=")
  75                             (make-simple-markup " ")
  76                             count-markup))
  77                           #f))
  78          (text-markup (if (not (null? text))
  79                           (make-bold-markup text)
  80                           #f)))
  81     (if text-markup
  82         (if (and note-markup (not hide-note))
  83             (make-line-markup (list text-markup
  84                                     (make-concat-markup
  85                                      (list (make-simple-markup "(")
  86                                            note-markup
  87                                            (make-simple-markup ")")))))
  88             (make-line-markup (list text-markup)))
  89         (if note-markup
  90             (make-line-markup (list note-markup))
  91             (make-null-markup)))))
  92
  93 (define-public (format-mark-alphabet mark context)
  94   (make-bold-markup (make-markalphabet-markup (1- mark))))
  95
  96 (define-public (format-mark-box-alphabet mark context)
  97   (make-bold-markup (make-box-markup (make-markalphabet-markup (1- mark)))))
  98
  99 (define-public (format-mark-circle-alphabet mark context)
 100   (make-bold-markup (make-circle-markup (make-markalphabet-markup (1- mark)))))
 101
 102 (define-public (format-mark-letters mark context)
 103   (make-bold-markup (make-markletter-markup (1- mark))))
 104
 105 (define-public (format-mark-numbers mark context)
 106   (make-bold-markup (number->string mark)))
 107
 108 (define-public (format-mark-barnumbers mark context)
 109   (make-bold-markup (number->string (ly:context-property context
 110                                                          'currentBarNumber))))
 111
 112 (define-public (format-mark-box-letters mark context)
 113   (make-bold-markup (make-box-markup (make-markletter-markup (1- mark)))))
 114
 115 (define-public (format-mark-circle-letters mark context)
 116   (make-bold-markup (make-circle-markup (make-markletter-markup (1- mark)))))
 117
 118 (define-public (format-mark-box-numbers mark context)
 119   (make-bold-markup (make-box-markup (number->string mark))))
 120
 121 (define-public (format-mark-circle-numbers mark context)
 122   (make-bold-markup (make-circle-markup (number->string mark))))
 123
 124 (define-public (format-mark-box-barnumbers mark context)
 125   (make-bold-markup (make-box-markup
 126                      (number->string (ly:context-property context
 127                                                           'currentBarNumber)))))
 128
 129 (define-public (format-mark-circle-barnumbers mark context)
 130   (make-bold-markup (make-circle-markup
 131                      (number->string (ly:context-property context
 132                                                           'currentBarNumber)))))
 133
 134
 135 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 136 ;; Bass figures.
 137
 138 (define-public (format-bass-figure figure event context)
 139   (let* ((fig (ly:event-property event 'figure))
 140          (fig-markup (if (number? figure)
 141
 142                          ;; this is not very elegant, but center-aligning
 143                          ;; all digits is problematic with other markups,
 144                          ;; and shows problems in the (lack of) overshoot
 145                          ;; of feta-alphabet glyphs.
 146                          ((if (<= 10 figure)
 147                               (lambda (y) (make-translate-scaled-markup
 148                                            (cons -0.7 0) y))
 149                               identity)
 150
 151                           (cond
 152                            ((eq? #t (ly:event-property event 'diminished))
 153                             (markup #:slashed-digit figure))
 154                            ((eq? #t (ly:event-property event 'augmented-slash))
 155                             (markup #:backslashed-digit figure))
 156                            (else (markup #:number (number->string figure 10)))))
 157                          #f))
 158
 159          (alt (ly:event-property event 'alteration))
 160          (alt-markup
 161           (if (number? alt)
 162               (markup
 163                #:general-align Y DOWN #:fontsize
 164                (if (not (= alt DOUBLE-SHARP))
 165                    -2 2)
 166                (alteration->text-accidental-markup alt))
 167               #f))
 168
 169          (plus-markup (if (eq? #t (ly:event-property event 'augmented))
 170                           (markup #:number "+")
 171                           #f))
 172
 173          (alt-dir (ly:context-property context 'figuredBassAlterationDirection))
 174          (plus-dir (ly:context-property context 'figuredBassPlusDirection)))
 175
 176     (if (and (not fig-markup) alt-markup)
 177         (begin
 178           (set! fig-markup (markup #:left-align #:pad-around 0.3 alt-markup))
 179           (set! alt-markup #f)))
 180
 181
 182     ;; hmm, how to get figures centered between note, and
 183     ;; lone accidentals too?
 184
 185     ;;    (if (markup? fig-markup)
 186     ;;  (set!
 187     ;;   fig-markup (markup #:translate (cons 1.0 0)
 188     ;;                      #:center-align fig-markup)))
 189
 190     (if alt-markup
 191         (set! fig-markup
 192               (markup #:put-adjacent
 193                       X (if (number? alt-dir)
 194                             alt-dir
 195                             LEFT)
 196                       fig-markup
 197                       #:pad-x 0.2 alt-markup)))
 198
 199     (if plus-markup
 200         (set! fig-markup
 201               (if fig-markup
 202                   (markup #:put-adjacent
 203                           X (if (number? plus-dir)
 204                                 plus-dir
 205                                 LEFT)
 206                           fig-markup
 207                           #:pad-x 0.2 plus-markup)
 208                   plus-markup)))
 209
 210     (if (markup? fig-markup)
 211         (markup #:fontsize -2 fig-markup)
 212         empty-markup)))
 213
 214
 215 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 216 ;; fret diagrams
 217
 218 (define (create-fretboard context grob placement-list)
 219   "Convert @var{placement-list} into a fretboard @var{grob}."
 220
 221   (let* ((tunings (ly:context-property context 'stringTunings))
 222          (my-string-count (length tunings))
 223          (details (ly:grob-property grob 'fret-diagram-details)))
 224
 225     ;; Add string-count from string-tunings to fret-diagram-details.
 226     (set! (ly:grob-property grob 'fret-diagram-details)
 227             (acons 'string-count my-string-count details))
 228     ;; Create the dot-placement list for the grob
 229     (set! (ly:grob-property grob 'dot-placement-list) placement-list)))
 230
 231 (define-public
 232   (determine-frets context notes specified-info . rest)
 233   "Determine string numbers and frets for playing @var{notes}
 234 as a chord, given specified information @var{specified-info}.
 235 @var{specified-info} is a list with two list elements,
 236 specified strings @code{defined-strings} and
 237 specified fingerings @code{defined-fingers}.  Only a fingering of@tie{}0
 238 will affect the fret selection, as it specifies an open string.
 239 If @code{defined-strings} is @code{'()}, the context property
 240 @code{defaultStrings} will be used as a list of defined strings.
 241 Will look for predefined fretboards if @code{predefinedFretboardTable}
 242 is not @code {#f}.  If @var{rest} is present, it contains the
 243 @code{FretBoard} grob, and a fretboard will be
 244 created.  Otherwise, a list of @code{(string fret finger)} lists will
 245 be returned."
 246
 247   ;;  helper functions
 248
 249   (define (string-frets->placement-list string-frets string-count)
 250     "Convert @var{string-frets} to @code{fret-diagram-verbose}
 251 dot placement entries."
 252     (let* ((placements (list->vector
 253                         (map (lambda (x) (list 'mute  x))
 254                              (iota string-count 1)))))
 255
 256       (for-each (lambda (sf)
 257                   (let* ((string (car sf))
 258                          (fret (cadr sf))
 259                          (finger (caddr sf)))
 260                     (vector-set!
 261                       placements
 262                       (1- string)
 263                       (if (= 0 fret)
 264                           (list 'open string)
 265                           (if finger
 266                               (list 'place-fret string fret finger)
 267                               (list 'place-fret string fret))))))
 268                 string-frets)
 269       (vector->list placements)))
 270
 271   (define (placement-list->string-frets placement-list)
 272     "Convert @var{placement-list} to string-fret list."
 273     (map (lambda (x) (if (eq? (car x) 'place-fret)
 274                          (cdr x)
 275                          (list (cadr x) 0)))
 276          (filter (lambda (l) (or (eq? (car l) 'place-fret)
 277                                  (eq? (car l) 'open)))
 278                  placement-list)))
 279
 280   (define (entry-count art-list)
 281     "Count the number of entries in a list of articulations."
 282     (length (filter (lambda (x) (not (null? x)))
 283                     art-list)))
 284
 285   (define (string-number event)
 286     "Get the string-number from @var{event}.  Return @var{#f}
 287 if no string-number is present."
 288     (let ((num (ly:event-property event 'string-number)))
 289       (and (integer? num) (positive? num) num)))
 290
 291   (define (determine-frets-and-strings
 292             notes
 293             defined-strings
 294             defined-fingers
 295             minimum-fret
 296             maximum-stretch
 297             tuning)
 298     "Determine the frets and strings used to play the notes in
 299 @var{notes}, given @var{defined-strings} and @var{defined-fingers}
 300 along with @var{minimum-fret}, @var{maximum-stretch}, and
 301 @var{tuning}.  Returns a list of @code{(string fret finger) lists."
 302
 303
 304     (define restrain-open-strings (ly:context-property context
 305                                                        'restrainOpenStrings
 306                                                        #f))
 307     (define specified-frets '())
 308     (define free-strings (iota (length tuning) 1))
 309
 310     (define (calc-fret pitch string tuning)
 311       "Calculate the fret to play @var{pitch} on @var{string} with
 312 @var{tuning}."
 313       (* 2  (- (ly:pitch-tones pitch) (ly:pitch-tones (list-ref tuning (1- string))))))
 314
 315     (define (note-pitch note)
 316       "Get the pitch (in semitones) from @var{note}."
 317       (ly:event-property note 'pitch))
 318
 319     (define (note-finger ev)
 320       "Get the fingering from @var{ev}.  Return @var{#f}
 321 if no fingering is present."
 322       (let* ((articulations (ly:event-property ev 'articulations))
 323              (finger-found #f))
 324         (map (lambda (art)
 325                (let* ((num (ly:event-property art 'digit)))
 326
 327                  (if (and (ly:in-event-class? art 'fingering-event)
 328                           (number? num)
 329                           (> num 0))
 330                    (set! finger-found num))))
 331              articulations)
 332         finger-found))
 333
 334     (define (delete-free-string string)
 335       (if (number? string)
 336         (set! free-strings
 337           (delete string free-strings))))
 338
 339     (define (close-enough fret)
 340       "Decide if @var{fret} is acceptable, given the already used frets."
 341       (if (null? specified-frets)
 342         #t
 343         (reduce
 344           (lambda (x y)
 345             (and x y))
 346           #t
 347           (map (lambda (specced-fret)
 348                  (or (eq? 0 specced-fret)
 349                      (and (not restrain-open-strings)
 350                      (eq? 0 fret))
 351                      (>= maximum-stretch (abs (- fret specced-fret)))))
 352                specified-frets))))
 353
 354     (define (string-qualifies string pitch)
 355       "Can @var{pitch} be played on @var{string}, given already placed
 356 notes?"
 357       (let* ((fret (calc-fret pitch string tuning)))
 358         (and (or (and (not restrain-open-strings)
 359                       (eq? fret 0))
 360                  (>= fret minimum-fret))
 361              (integer? fret)
 362              (close-enough fret))))
 363
 364     (define (open-string string pitch)
 365       "Is @var{pitch} and open-string note on @var{string}, given
 366 the current tuning?"
 367       (let* ((fret (calc-fret pitch string tuning)))
 368         (eq? fret 0)))
 369
 370     (define (set-fret! pitch-entry string finger)
 371       (let ((this-fret (calc-fret (car pitch-entry)
 372                                   string
 373                                   tuning)))
 374         (if (< this-fret 0)
 375           (ly:warning (_ "Negative fret for pitch ~a on string ~a")
 376                       (car pitch-entry) string)
 377           (if (not (integer? this-fret))
 378               (ly:warning (_ "Missing fret for pitch ~a on string ~a")
 379                           (car pitch-entry) string)))
 380         (delete-free-string string)
 381         (set! specified-frets (cons this-fret specified-frets))
 382         (list-set! string-fret-fingers
 383                    (cdr pitch-entry)
 384                    (list string this-fret finger))))
 385
 386     (define (kill-note! string-fret-fingers note-index)
 387       (list-set! string-fret-fingers note-index (list #f #t)))
 388
 389     (define string-fret-fingers
 390              (map (lambda (string finger)
 391                     (if (null? finger)
 392                         (list string #f)
 393                         (list string #f finger)))
 394                   defined-strings defined-fingers))
 395
 396     ;;; body of determine-frets-and-strings
 397     (let* ((pitches (map note-pitch notes))
 398            (pitch-alist (map cons pitches (iota (length pitches)))))
 399
 400       ;; handle notes with strings assigned and fingering of 0
 401       (for-each
 402         (lambda (pitch-entry string-fret-finger)
 403           (let* ((string (list-ref string-fret-finger 0))
 404                  (finger (if (eq? (length string-fret-finger) 3)
 405                              (list-ref string-fret-finger 2)
 406                              '()))
 407                  (pitch (car pitch-entry))
 408                  (digit (if (null? finger)
 409                             #f
 410                             finger)))
 411             (if (or (not (null? string))
 412                     (eq? digit 0))
 413                 (if (eq? digit 0)
 414                     ;; here we handle fingers of 0 -- open strings
 415                     (let ((fit-string
 416                             (find (lambda (string)
 417                                     (open-string string pitch))
 418                                   free-strings)))
 419                       (if fit-string
 420                           (set-fret! pitch-entry fit-string #f)
 421                           (ly:warning (_ "No open string for pitch ~a")
 422                                       pitch)))
 423                     ;; here we handle assigned strings
 424                     (let ((this-fret
 425                             (calc-fret pitch string tuning))
 426                           (handle-negative
 427                             (ly:context-property context
 428                                                  'handleNegativeFrets
 429                                                  'recalculate)))
 430                       (cond ((or (and (>= this-fret 0) (integer? this-fret))
 431                                  (eq? handle-negative 'include))
 432                              (set-fret! pitch-entry string finger))
 433                             ((eq? handle-negative 'recalculate)
 434                              (begin
 435                                (ly:warning
 436                                  (_ "Requested string for pitch requires negative fret: string ~a pitch ~a")
 437                                  string
 438                                  pitch)
 439                                (ly:warning (_ "Ignoring string request and recalculating."))
 440                                (list-set! string-fret-fingers
 441                                           (cdr pitch-entry)
 442                                           (if (null? finger)
 443                                               (list '() #f)
 444                                               (list '() #f finger)))))
 445                             ((eq? handle-negative 'ignore)
 446                              (begin
 447                                (ly:warning
 448                                  (_ "Requested string for pitch requires negative fret: string ~a pitch ~a")
 449                                  string
 450                                  pitch)
 451                                (ly:warning (_ "Ignoring note in tablature."))
 452                                (kill-note! string-fret-fingers
 453                                            (cdr pitch-entry))))))))))
 454         pitch-alist string-fret-fingers)
 455     ;; handle notes without strings assigned -- sorted by pitch, so
 456     ;; we need to use the alist to have the note number available
 457     (for-each
 458       (lambda (pitch-entry)
 459         (let* ((string-fret-finger (list-ref string-fret-fingers
 460                                              (cdr pitch-entry)))
 461                (string (list-ref string-fret-finger 0))
 462                (finger (if (eq? (length string-fret-finger) 3)
 463                            (list-ref string-fret-finger 2)
 464                            '()))
 465                (pitch (car pitch-entry))
 466                (fit-string
 467                  (find (lambda (string)
 468                          (string-qualifies string pitch))
 469                        free-strings)))
 470           (if (not (list-ref string-fret-finger 1))
 471               (if fit-string
 472                   (set-fret! pitch-entry fit-string finger)
 473                   (begin
 474                     (ly:warning (_ "No string for pitch ~a (given frets ~a)")
 475                                 pitch
 476                                 specified-frets)
 477                     (kill-note! string-fret-fingers
 478                                 (cdr pitch-entry)))))))
 479       (sort pitch-alist (lambda (pitch-entry-a pitch-entry-b)
 480                           (ly:pitch<? (car pitch-entry-b)
 481                                       (car pitch-entry-a)))))
 482     string-fret-fingers)) ;; end of determine-frets-and-strings
 483
 484   (define (get-predefined-fretboard predefined-fret-table tuning pitches)
 485     "Search through @var{predefined-fret-table} looking for a predefined
 486 fretboard with a key of @var{(tuning . pitches)}.  The search will check
 487 both up and down an octave in order to accomodate transposition of the
 488 chords.  Returns a placement-list."
 489
 490     (define (get-fretboard key)
 491       (let ((hash-handle
 492              (hash-get-handle predefined-fret-table key)))
 493         (if hash-handle
 494             (cdr hash-handle)  ; return table entry
 495             '())))
 496
 497     ;; body of get-predefined-fretboard
 498     (let ((test-fretboard (get-fretboard (cons tuning pitches))))
 499       (if (not (null? test-fretboard))
 500           test-fretboard
 501           (let ((test-fretboard
 502                  (get-fretboard
 503                   (cons tuning (map (lambda (x) (shift-octave x 1)) pitches)))))
 504             (if (not (null? test-fretboard))
 505                 test-fretboard
 506                 (get-fretboard
 507                  (cons tuning (map (lambda (x) (shift-octave x -1))
 508                                    pitches))))))))
 509
 510   ;; body of determine-frets
 511   (let* ((predefined-fret-table
 512           (ly:context-property context 'predefinedDiagramTable))
 513          (tunings (ly:context-property context 'stringTunings))
 514          (string-count (length tunings))
 515          (grob (if (null? rest) '() (car rest)))
 516          (pitches (map (lambda (x) (ly:event-property x 'pitch)) notes))
 517          (defined-strings (map (lambda (x)
 518                                  (if (null? x)
 519                                      x
 520                                      (or (string-number x) '())))
 521                                (car specified-info)))
 522          (defined-fingers (map (lambda (x)
 523                                  (if (null? x)
 524                                      x
 525                                      (ly:event-property x 'digit)))
 526                                (cadr specified-info)))
 527          (default-strings (ly:context-property context 'defaultStrings '()))
 528          (strings-used (if (and (zero? (entry-count defined-strings))
 529                                 (not (zero? (entry-count default-strings))))
 530                            default-strings
 531                            defined-strings))
 532          (predefined-fretboard
 533           (if predefined-fret-table
 534               (get-predefined-fretboard
 535                predefined-fret-table
 536                tunings
 537                pitches)
 538               '())))
 539      (if (null? predefined-fretboard)
 540          (let ((string-frets
 541                 (determine-frets-and-strings
 542                  notes
 543                  strings-used
 544                  defined-fingers
 545                  (ly:context-property context 'minimumFret 0)
 546                  (ly:context-property context 'maximumFretStretch 4)
 547                  tunings)))
 548             (if (null? grob)
 549                 string-frets
 550                 (create-fretboard
 551                  context grob (string-frets->placement-list
 552                                 (filter (lambda (entry)
 553                                           (car entry))
 554                                         string-frets)
 555                                 string-count))))
 556          (if (null? grob)
 557              (placement-list->string-frets predefined-fretboard)
 558              (create-fretboard context grob predefined-fretboard)))))
 559
 560
 561
 562 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 563 ;; tablature
 564
 565 ;; The TabNoteHead tablatureFormat callbacks.
 566
 567 ;; Calculate the fret from pitch and string number as letter
 568 ;; The fret letter is taken from 'fretLabels if present
 569 (define-public (fret-letter-tablature-format
 570                 context string-number fret-number)
 571  (let ((labels (ly:context-property context 'fretLabels)))
 572   (make-vcenter-markup
 573    (cond
 574     ((= 0 (length labels))
 575      (string (integer->char (+ fret-number (char->integer #\a)))))
 576     ((and (<= 0 fret-number) (< fret-number (length labels)))
 577      (list-ref labels fret-number))
 578     (else
 579      (ly:warning (_ "No label for fret ~a (on string ~a);
 580 only ~a fret labels provided")
 581                 fret-number string-number (length labels))
 582      ".")))))
 583
 584 ;; Display the fret number as a number
 585 (define-public (fret-number-tablature-format
 586                 context string-number fret-number)
 587   (make-vcenter-markup
 588     (format #f "~a" fret-number)))
 589
 590 ;; The 5-string banjo has got a extra string, the fifth (duh), which
 591 ;; starts at the fifth fret on the neck.  Frets on the fifth string
 592 ;; are referred to relative to the other frets:
 593 ;;   the "first fret" on the fifth string is really the sixth fret
 594 ;;   on the banjo neck.
 595 ;; We solve this by defining a new fret-number-tablature function:
 596 (define-public (fret-number-tablature-format-banjo
 597                 context string-number fret-number)
 598  (make-vcenter-markup
 599   (number->string (cond
 600                    ((and (> fret-number 0) (= string-number 5))
 601                     (+ fret-number 5))
 602                    (else fret-number)))))
 603
 604 ;;  Tab note head staff position functions
 605 ;;
 606 ;;  Define where in the staff to display a given string.  Some forms of
 607 ;;  tablature put the tab note heads in the spaces, rather than on the
 608 ;;  lines
 609
 610 (define-public (tablature-position-on-lines context string-number)
 611  (let* ((string-tunings (ly:context-property context 'stringTunings))
 612         (string-count (length string-tunings))
 613         (string-one-topmost (ly:context-property context 'stringOneTopmost))
 614         (staff-line (- (* 2 string-number) string-count 1)))
 615   (if string-one-topmost
 616       (- staff-line)
 617       staff-line)))
 618
 619 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 620 ;; bar numbers
 621
 622 (define-public ((every-nth-bar-number-visible n) barnum mp)
 623   (= 0 (modulo barnum n)))
 624
 625 (define-public ((modulo-bar-number-visible n m) barnum mp)
 626   (and (> barnum 1) (= m (modulo barnum n))))
 627
 628 (define-public ((set-bar-number-visibility n) tr)
 629   (let ((bn (ly:context-property tr 'currentBarNumber)))
 630     (ly:context-set-property! tr 'barNumberVisibility
 631                               (modulo-bar-number-visible n (modulo bn n)))))
 632
 633 (define-public (first-bar-number-invisible barnum mp)
 634   (> barnum 1))
 635
 636 (define-public (first-bar-number-invisible-save-broken-bars barnum mp)
 637   (or (> barnum 1)
 638       (> (ly:moment-main-numerator mp) 0)))
 639
 640 (define-public (first-bar-number-invisible-and-no-parenthesized-bar-numbers barnum mp)
 641   (and (> barnum 1)
 642        (= (ly:moment-main-numerator mp) 0)))
 643
 644 (define-public (robust-bar-number-function barnum measure-pos alt-number context)
 645   (define (get-number-and-power an pow)
 646     (if (<= an alt-number)
 647         (get-number-and-power (+ an (expt 26 (1+ pow))) (1+ pow))
 648         (cons (+ alt-number (- (expt 26 pow) an)) (1- pow))))
 649   (define (make-letter so-far an pow)
 650     (if (< pow 0)
 651       so-far
 652       (let ((pos (modulo (quotient an (expt 26 pow)) 26)))
 653         (make-letter (string-append so-far
 654                                     (substring "abcdefghijklmnopqrstuvwxyz"
 655                                                pos
 656                                                (1+ pos)))
 657                    an
 658                    (1- pow)))))
 659   (let* ((number-and-power (get-number-and-power 0 0))
 660          (begin-measure (= 0 (ly:moment-main-numerator measure-pos)))
 661          (maybe-open-parenthesis (if begin-measure "" "("))
 662          (maybe-close-parenthesis (if begin-measure "" ")")))
 663     (markup (string-append maybe-open-parenthesis
 664                            (number->string barnum)
 665                            (make-letter ""
 666                                         (car number-and-power)
 667                                         (cdr number-and-power))
 668                            maybe-close-parenthesis))))
 669
 670 (define-public (all-bar-numbers-visible barnum mp) #t)
 671
 672
 673 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 674 ;; percent repeat counters
 675
 676 (define-public ((every-nth-repeat-count-visible n) count context)
 677   (= 0 (modulo count n)))
 678
 679 (define-public (all-repeat-counts-visible count context) #t)
 680
 681 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 682 ;; make-engraver helper macro
 683
 684 (defmacro-public make-engraver forms
 685   "Helper macro for creating Scheme engravers.
 686
 687 The usual form for an engraver is an association list (or alist)
 688 mapping symbols to either anonymous functions or to another such
 689 alist.
 690
 691 @code{make-engraver} accepts forms where the first element is either
 692 an argument list starting with the respective symbol, followed by the
 693 function body (comparable to the way @code{define} is used for
 694 defining functions), or a single symbol followed by subordinate forms
 695 in the same manner.  You can also just make an alist pair
 696 literally (the @samp{car} is quoted automatically) as long as the
 697 unevaluated @samp{cdr} is not a pair.  This is useful if you already
 698 have defined your engraver functions separately.
 699
 700 Symbols mapping to a function would be @code{initialize},
 701 @code{start-translation-timestep}, @code{process-music},
 702 @code{process-acknowledged}, @code{stop-translation-timestep}, and
 703 @code{finalize}.  Symbols mapping to another alist specified in the
 704 same manner are @code{listeners} with the subordinate symbols being
 705 event classes, and @code{acknowledgers} and @code{end-acknowledgers}
 706 with the subordinate symbols being interfaces."
 707   (let loop ((forms forms))
 708     (if (cheap-list? forms)
 709         `(list
 710           ,@(map (lambda (form)
 711                    (if (pair? (car form))
 712                        `(cons ',(caar form) (lambda ,(cdar form) ,@(cdr form)))
 713                        `(cons ',(car form) ,(loop (cdr form)))))
 714                  forms))
 715         forms)))