scm/translation-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; (c) 1998--2015 Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;                 Jan Nieuwenhuizen <janneke@gnu.org>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;; clefs
  22
  23 (define-public (clef-transposition-markup oct style)
  24   "The transposition sign formatting function.  @var{oct} is supposed to be
  25 a string holding the transposition number, @var{style} determines the
  26 way the transposition number is displayed."
  27   (let* ((delim (if (symbol? style)
  28                     (case style
  29                       ((parenthesized) (cons "(" ")"))
  30                       ((bracketed) (cons "[" "]"))
  31                       (else (cons "" "")))
  32                     (cons "" "")))
  33          (text (string-concatenate (list (car delim) oct (cdr delim)))))
  34
  35     (make-vcenter-markup text)))
  36
  37
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39 ;; metronome marks
  40
  41 (define-public (format-metronome-markup event context)
  42    (let ((hide-note (ly:context-property context 'tempoHideNote #f))
  43          (text (ly:event-property event 'text))
  44          (dur (ly:event-property event 'tempo-unit))
  45          (count (ly:event-property event 'metronome-count)))
  46    (metronome-markup text dur count hide-note)))
  47 (export format-metronome-markup)
  48
  49 (define (metronome-markup text dur count hide-note)
  50   (let* ((note-mark
  51             (if (and (not hide-note) (ly:duration? dur))
  52                 (make-smaller-markup
  53                   (make-note-by-number-markup
  54                     (ly:duration-log dur)
  55                     (ly:duration-dot-count dur)
  56                     UP))
  57                 #f))
  58          (count-markup (cond ((number? count)
  59                               (if (> count 0)
  60                                   (make-simple-markup
  61                                           (number->string count))
  62                                   #f))
  63                              ((pair? count)
  64                               (make-concat-markup
  65                                (list
  66                                 (make-simple-markup
  67                                         (number->string (car count)))
  68                                 (make-simple-markup " ")
  69                                 (make-simple-markup "–")
  70                                 (make-simple-markup " ")
  71                                 (make-simple-markup
  72                                         (number->string (cdr count))))))
  73                              (else #f)))
  74          (note-markup (if (and (not hide-note) count-markup)
  75                           (make-concat-markup
  76                            (list
  77                             (make-general-align-markup Y DOWN note-mark)
  78                             (make-simple-markup " ")
  79                             (make-simple-markup "=")
  80                             (make-simple-markup " ")
  81                             count-markup))
  82                           #f))
  83          (text-markup (if (not (null? text))
  84                           (make-bold-markup text)
  85                           #f)))
  86     (if text-markup
  87         (if (and note-markup (not hide-note))
  88             (make-line-markup (list text-markup
  89                                     (make-concat-markup
  90                                      (list (make-simple-markup "(")
  91                                            note-markup
  92                                            (make-simple-markup ")")))))
  93             (make-line-markup (list text-markup)))
  94         (if note-markup
  95             (make-line-markup (list note-markup))
  96             (make-null-markup)))))
  97
  98 (define-public (format-mark-alphabet mark context)
  99   (make-bold-markup (make-markalphabet-markup (1- mark))))
 100
 101 (define-public (format-mark-box-alphabet mark context)
 102   (make-bold-markup (make-box-markup (make-markalphabet-markup (1- mark)))))
 103
 104 (define-public (format-mark-circle-alphabet mark context)
 105   (make-bold-markup (make-circle-markup (make-markalphabet-markup (1- mark)))))
 106
 107 (define-public (format-mark-letters mark context)
 108   (make-bold-markup (make-markletter-markup (1- mark))))
 109
 110 (define-public (format-mark-numbers mark context)
 111   (make-bold-markup (number->string mark)))
 112
 113 (define-public (format-mark-barnumbers mark context)
 114   (make-bold-markup (number->string (ly:context-property context
 115                                                          'currentBarNumber))))
 116
 117 (define-public (format-mark-box-letters mark context)
 118   (make-bold-markup (make-box-markup (make-markletter-markup (1- mark)))))
 119
 120 (define-public (format-mark-circle-letters mark context)
 121   (make-bold-markup (make-circle-markup (make-markletter-markup (1- mark)))))
 122
 123 (define-public (format-mark-box-numbers mark context)
 124   (make-bold-markup (make-box-markup (number->string mark))))
 125
 126 (define-public (format-mark-circle-numbers mark context)
 127   (make-bold-markup (make-circle-markup (number->string mark))))
 128
 129 (define-public (format-mark-box-barnumbers mark context)
 130   (make-bold-markup (make-box-markup
 131                      (number->string (ly:context-property context
 132                                                           'currentBarNumber)))))
 133
 134 (define-public (format-mark-circle-barnumbers mark context)
 135   (make-bold-markup (make-circle-markup
 136                      (number->string (ly:context-property context
 137                                                           'currentBarNumber)))))
 138
 139
 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 141 ;; Bass figures.
 142
 143 (define-public (format-bass-figure figure event context)
 144   (let* ((fig (ly:event-property event 'figure))
 145          (fig-markup (if (number? figure)
 146
 147                          ;; this is not very elegant, but center-aligning
 148                          ;; all digits is problematic with other markups,
 149                          ;; and shows problems in the (lack of) overshoot
 150                          ;; of feta-alphabet glyphs.
 151                          ((if (<= 10 figure)
 152                               (lambda (y) (make-translate-scaled-markup
 153                                            (cons -0.7 0) y))
 154                               identity)
 155
 156                           (cond
 157                            ((eq? #t (ly:event-property event 'diminished))
 158                             (markup #:slashed-digit figure))
 159                            ((eq? #t (ly:event-property event 'augmented-slash))
 160                             (markup #:backslashed-digit figure))
 161                            (else (markup #:number (number->string figure 10)))))
 162                          #f))
 163
 164          (alt (ly:event-property event 'alteration))
 165          (alt-markup
 166           (if (number? alt)
 167               (markup
 168                #:general-align Y DOWN #:fontsize
 169                (if (not (= alt DOUBLE-SHARP))
 170                    -2 2)
 171                (alteration->text-accidental-markup alt))
 172               #f))
 173
 174          (plus-markup (if (eq? #t (ly:event-property event 'augmented))
 175                           (markup #:number "+")
 176                           #f))
 177
 178          (alt-dir (ly:context-property context 'figuredBassAlterationDirection))
 179          (plus-dir (ly:context-property context 'figuredBassPlusDirection)))
 180
 181     (if (and (not fig-markup) alt-markup)
 182         (begin
 183           (set! fig-markup (markup #:left-align #:pad-around 0.3 alt-markup))
 184           (set! alt-markup #f)))
 185
 186
 187     ;; hmm, how to get figures centered between note, and
 188     ;; lone accidentals too?
 189
 190     ;;    (if (markup? fig-markup)
 191     ;;  (set!
 192     ;;   fig-markup (markup #:translate (cons 1.0 0)
 193     ;;                      #:center-align fig-markup)))
 194
 195     (if alt-markup
 196         (set! fig-markup
 197               (markup #:put-adjacent
 198                       X (if (number? alt-dir)
 199                             alt-dir
 200                             LEFT)
 201                       fig-markup
 202                       #:pad-x 0.2 alt-markup)))
 203
 204     (if plus-markup
 205         (set! fig-markup
 206               (if fig-markup
 207                   (markup #:put-adjacent
 208                           X (if (number? plus-dir)
 209                                 plus-dir
 210                                 LEFT)
 211                           fig-markup
 212                           #:pad-x 0.2 plus-markup)
 213                   plus-markup)))
 214
 215     (if (markup? fig-markup)
 216         (markup #:fontsize -2 fig-markup)
 217         empty-markup)))
 218
 219
 220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 221 ;; fret diagrams
 222
 223 (define (create-fretboard context grob placement-list)
 224   "Convert @var{placement-list} into a fretboard @var{grob}."
 225
 226   (let* ((tunings (ly:context-property context 'stringTunings))
 227          (my-string-count (length tunings))
 228          (details (ly:grob-property grob 'fret-diagram-details)))
 229
 230     ;; Add string-count from string-tunings to fret-diagram-details.
 231     (set! (ly:grob-property grob 'fret-diagram-details)
 232           (acons 'string-count my-string-count details))
 233     ;; Create the dot-placement list for the grob
 234     (set! (ly:grob-property grob 'dot-placement-list) placement-list)))
 235
 236 (define*-public
 237   ((determine-frets #:optional (support-non-integer-fret? #f))
 238                     context notes specified-info . rest)
 239   "Determine string numbers and frets for playing @var{notes}
 240 as a chord, given specified information @var{specified-info}.
 241 @var{specified-info} is a list with two list elements,
 242 specified strings @code{defined-strings} and
 243 specified fingerings @code{defined-fingers}.  Only a fingering of@tie{}0
 244 will affect the fret selection, as it specifies an open string.
 245 If @code{defined-strings} is @code{'()}, the context property
 246 @code{defaultStrings} will be used as a list of defined strings.
 247 Will look for predefined fretboards if @code{predefinedFretboardTable}
 248 is not @code {#f}.  If @var{rest} is present, it contains the
 249 @code{FretBoard} grob, and a fretboard will be
 250 created.  Otherwise, a list of @code{(string fret finger)} lists will
 251 be returned.
 252 If the optional @var{support-non-integer-fret?} is set @code{#t}, micro-tones
 253 are supported for TabStaff, but not not for FretBoards."
 254
 255   ;;  helper functions
 256
 257   (define (string-frets->placement-list string-frets string-count)
 258     "Convert @var{string-frets} to @code{fret-diagram-verbose}
 259 dot placement entries."
 260     (let* ((placements (list->vector
 261                         (map (lambda (x) (list 'mute  x))
 262                              (iota string-count 1)))))
 263
 264       (for-each (lambda (sf)
 265                   (let* ((string (car sf))
 266                          (fret (cadr sf))
 267                          (finger (caddr sf)))
 268                     (vector-set!
 269                      placements
 270                      (1- string)
 271                      (if (= 0 fret)
 272                          (list 'open string)
 273                          (if finger
 274                              (list 'place-fret string fret finger)
 275                              (list 'place-fret string fret))))))
 276                 string-frets)
 277       (vector->list placements)))
 278
 279   (define (placement-list->string-frets placement-list)
 280     "Convert @var{placement-list} to string-fret list."
 281     (map (lambda (x) (if (eq? (car x) 'place-fret)
 282                          (cdr x)
 283                          (list (cadr x) 0)))
 284          (filter (lambda (l) (or (eq? (car l) 'place-fret)
 285                                  (eq? (car l) 'open)))
 286                  placement-list)))
 287
 288   (define (entry-count art-list)
 289     "Count the number of entries in a list of articulations."
 290     (length (filter (lambda (x) (not (null? x)))
 291                     art-list)))
 292
 293   (define (string-number event)
 294     "Get the string-number from @var{event}.  Return @var{#f}
 295 if no string-number is present."
 296     (let ((num (ly:event-property event 'string-number)))
 297       (and (integer? num) (positive? num) num)))
 298
 299   (define (determine-frets-and-strings
 300            notes
 301            defined-strings
 302            defined-fingers
 303            minimum-fret
 304            maximum-stretch
 305            tuning)
 306     "Determine the frets and strings used to play the notes in
 307 @var{notes}, given @var{defined-strings} and @var{defined-fingers}
 308 along with @var{minimum-fret}, @var{maximum-stretch}, and
 309 @var{tuning}.  Returns a list of @code{(string fret finger) lists."
 310
 311
 312     (define restrain-open-strings (ly:context-property context
 313                                                        'restrainOpenStrings
 314                                                        #f))
 315     (define specified-frets '())
 316     (define free-strings (iota (length tuning) 1))
 317
 318     (define (calc-fret pitch string tuning)
 319       "Calculate the fret to play @var{pitch} on @var{string} with
 320 @var{tuning}."
 321       (* 2  (- (ly:pitch-tones pitch) (ly:pitch-tones (list-ref tuning (1- string))))))
 322
 323     (define (note-pitch note)
 324       "Get the pitch (in semitones) from @var{note}."
 325       (ly:event-property note 'pitch))
 326
 327     (define (note-finger ev)
 328       "Get the fingering from @var{ev}.  Return @var{#f}
 329 if no fingering is present."
 330       (let* ((articulations (ly:event-property ev 'articulations))
 331              (finger-found #f))
 332         (for-each (lambda (art)
 333                     (let* ((num (ly:event-property art 'digit)))
 334
 335                       (if (and (ly:in-event-class? art 'fingering-event)
 336                                (number? num)
 337                                (> num 0))
 338                           (set! finger-found num))))
 339                   articulations)
 340         finger-found))
 341
 342     (define (delete-free-string string)
 343       (if (number? string)
 344           (set! free-strings
 345                 (delete string free-strings))))
 346
 347     (define (close-enough fret)
 348       "Decide if @var{fret} is acceptable, given the already used frets."
 349       (every (lambda (specced-fret)
 350                (or (zero? specced-fret)
 351                    (zero? fret)
 352                    (>= maximum-stretch (abs (- fret specced-fret)))))
 353              specified-frets))
 354
 355     (define (string-qualifies string pitch)
 356       "Can @var{pitch} be played on @var{string}, given already placed
 357 notes?"
 358       (let* ((fret (calc-fret pitch string tuning)))
 359         (and (or (and (not restrain-open-strings)
 360                       (zero? fret))
 361                  (>= fret minimum-fret))
 362              (if (and support-non-integer-fret? (null? rest))
 363                  (integer? (truncate fret))
 364                  (integer? fret))
 365              (close-enough fret))))
 366
 367     (define (open-string string pitch)
 368       "Is @var{pitch} and open-string note on @var{string}, given
 369 the current tuning?"
 370       (let* ((fret (calc-fret pitch string tuning)))
 371         (zero? fret)))
 372
 373     (define (set-fret! pitch-entry string finger)
 374       (let ((this-fret (calc-fret (car pitch-entry)
 375                                   string
 376                                   tuning)))
 377         (if (< this-fret 0)
 378             (ly:warning (_ "Negative fret for pitch ~a on string ~a")
 379                         (car pitch-entry) string)
 380             (if (and (not (integer? this-fret)) (not support-non-integer-fret?))
 381                 (ly:warning (_ "Missing fret for pitch ~a on string ~a")
 382                             (car pitch-entry) string)))
 383         (delete-free-string string)
 384         (set! specified-frets (cons this-fret specified-frets))
 385         (list-set! string-fret-fingers
 386                    (cdr pitch-entry)
 387                    (list string this-fret finger))))
 388
 389     (define (kill-note! string-fret-fingers note-index)
 390       (list-set! string-fret-fingers note-index (list #f #t)))
 391
 392     (define string-fret-fingers
 393       (map (lambda (string finger)
 394              (if (null? finger)
 395                  (list string #f)
 396                  (list string #f finger)))
 397            defined-strings defined-fingers))
 398
 399     ;;; body of determine-frets-and-strings
 400     (let* ((pitches (map note-pitch notes))
 401            (pitch-alist (map cons pitches (iota (length pitches)))))
 402
 403       ;; handle notes with strings assigned and fingering of 0
 404       (for-each
 405        (lambda (pitch-entry string-fret-finger)
 406          (let* ((string (list-ref string-fret-finger 0))
 407                 (finger (if (= (length string-fret-finger) 3)
 408                             (list-ref string-fret-finger 2)
 409                             '()))
 410                 (pitch (car pitch-entry))
 411                 (digit (if (null? finger)
 412                            #f
 413                            finger)))
 414            (if (or (not (null? string))
 415                    (eqv? digit 0))
 416                (if (eqv? digit 0)
 417                    ;; here we handle fingers of 0 -- open strings
 418                    (let ((fit-string
 419                           (find (lambda (string)
 420                                   (open-string string pitch))
 421                                 free-strings)))
 422                      (if fit-string
 423                          (set-fret! pitch-entry fit-string #f)
 424                          (ly:warning (_ "No open string for pitch ~a")
 425                                      pitch)))
 426                    ;; here we handle assigned strings
 427                    (let ((this-fret
 428                           (calc-fret pitch string tuning))
 429                          (handle-negative
 430                           (ly:context-property context
 431                                                'handleNegativeFrets
 432                                                'recalculate)))
 433                      (cond ((or (and (>= this-fret 0) (integer? this-fret))
 434                                 (eq? handle-negative 'include))
 435                             (set-fret! pitch-entry string finger))
 436                            ((eq? handle-negative 'recalculate)
 437                             (begin
 438                               (ly:warning
 439                                (_ "Requested string for pitch requires negative fret: string ~a pitch ~a")
 440                                string
 441                                pitch)
 442                               (ly:warning (_ "Ignoring string request and recalculating."))
 443                               (list-set! string-fret-fingers
 444                                          (cdr pitch-entry)
 445                                          (if (null? finger)
 446                                              (list '() #f)
 447                                              (list '() #f finger)))))
 448                            ((eq? handle-negative 'ignore)
 449                             (begin
 450                               (ly:warning
 451                                (_ "Requested string for pitch requires negative fret: string ~a pitch ~a")
 452                                string
 453                                pitch)
 454                               (ly:warning (_ "Ignoring note in tablature."))
 455                               (kill-note! string-fret-fingers
 456                                           (cdr pitch-entry))))))))))
 457        pitch-alist string-fret-fingers)
 458       ;; handle notes without strings assigned -- sorted by pitch, so
 459       ;; we need to use the alist to have the note number available
 460       (for-each
 461        (lambda (pitch-entry)
 462          (let* ((string-fret-finger (list-ref string-fret-fingers
 463                                               (cdr pitch-entry)))
 464                 (string (list-ref string-fret-finger 0))
 465                 (finger (if (= (length string-fret-finger) 3)
 466                             (list-ref string-fret-finger 2)
 467                             '()))
 468                 (pitch (car pitch-entry))
 469                 (fit-string
 470                  (find (lambda (string)
 471                          (string-qualifies string pitch))
 472                        free-strings)))
 473            (if (not (list-ref string-fret-finger 1))
 474                (if fit-string
 475                    (set-fret! pitch-entry fit-string finger)
 476                    (begin
 477                      (ly:event-warning
 478                       (list-ref notes (cdr pitch-entry))
 479                       (_ "No string for pitch ~a (given frets ~a)")
 480                       pitch
 481                       specified-frets)
 482                      (kill-note! string-fret-fingers
 483                                  (cdr pitch-entry)))))))
 484        (sort pitch-alist (lambda (pitch-entry-a pitch-entry-b)
 485                            (ly:pitch<? (car pitch-entry-b)
 486                                        (car pitch-entry-a)))))
 487       string-fret-fingers)) ;; end of determine-frets-and-strings
 488
 489   (define (get-predefined-fretboard predefined-fret-table tuning pitches)
 490     "Search through @var{predefined-fret-table} looking for a predefined
 491 fretboard with a key of @var{(tuning . pitches)}.  The search will check
 492 both up and down an octave in order to accomodate transposition of the
 493 chords.  Returns a placement-list."
 494
 495     (define (get-fretboard key)
 496       (let ((hash-handle
 497              (hash-get-handle predefined-fret-table key)))
 498         (if hash-handle
 499             (cdr hash-handle)  ; return table entry
 500             '())))
 501
 502     ;; body of get-predefined-fretboard
 503     (let ((test-fretboard (get-fretboard (cons tuning pitches))))
 504       (if (not (null? test-fretboard))
 505           test-fretboard
 506           (let ((test-fretboard
 507                  (get-fretboard
 508                   (cons tuning (map (lambda (x) (shift-octave x 1)) pitches)))))
 509             (if (not (null? test-fretboard))
 510                 test-fretboard
 511                 (get-fretboard
 512                  (cons tuning (map (lambda (x) (shift-octave x -1))
 513                                    pitches))))))))
 514
 515   ;; body of determine-frets
 516   (let* ((predefined-fret-table
 517           (ly:context-property context 'predefinedDiagramTable))
 518          (tunings (ly:context-property context 'stringTunings))
 519          (string-count (length tunings))
 520          (grob (if (null? rest) '() (car rest)))
 521          (pitches (map (lambda (x) (ly:event-property x 'pitch)) notes))
 522          (defined-strings (map (lambda (x)
 523                                  (if (null? x)
 524                                      x
 525                                      (or (string-number x) '())))
 526                                (car specified-info)))
 527          (defined-fingers (map (lambda (x)
 528                                  (if (null? x)
 529                                      x
 530                                      (ly:event-property x 'digit)))
 531                                (cadr specified-info)))
 532          (default-strings (ly:context-property context 'defaultStrings '()))
 533          (strings-used (if (and (zero? (entry-count defined-strings))
 534                                 (not (zero? (entry-count default-strings))))
 535                            default-strings
 536                            defined-strings))
 537          (predefined-fretboard
 538           (if predefined-fret-table
 539               (get-predefined-fretboard
 540                predefined-fret-table
 541                tunings
 542                pitches)
 543               '())))
 544     (if (null? predefined-fretboard)
 545         (let ((string-frets
 546                (determine-frets-and-strings
 547                 notes
 548                 strings-used
 549                 defined-fingers
 550                 (ly:context-property context 'minimumFret 0)
 551                 (ly:context-property context 'maximumFretStretch 4)
 552                 tunings)))
 553           (if (null? grob)
 554               string-frets
 555               (create-fretboard
 556                context grob (string-frets->placement-list
 557                              (filter (lambda (entry)
 558                                        (car entry))
 559                                      string-frets)
 560                              string-count))))
 561         (if (null? grob)
 562             (placement-list->string-frets predefined-fretboard)
 563             (create-fretboard context grob predefined-fretboard)))))
 564
 565
 566
 567 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 568 ;; tablature
 569
 570 ;; The TabNoteHead tablatureFormat callbacks.
 571
 572 ;; Calculate the fret from pitch and string number as letter
 573 ;; The fret letter is taken from 'fretLabels if present
 574 (define-public (fret-letter-tablature-format
 575                 context string-number fret-number)
 576   (let ((labels (ly:context-property context 'fretLabels)))
 577     (make-translate-scaled-markup '(0 . -0.5)
 578      (cond
 579       ((= 0 (length labels))
 580        (string (integer->char (+ fret-number (char->integer #\a)))))
 581       ((and (<= 0 fret-number) (< fret-number (length labels)))
 582        (list-ref labels fret-number))
 583       (else
 584        (ly:warning (_ "No label for fret ~a (on string ~a);
 585 only ~a fret labels provided")
 586                    fret-number string-number (length labels))
 587        ".")))))
 588
 589 ;; Display the fret number as a number
 590 (define-public (fret-number-tablature-format
 591                 context string-number fret-number)
 592   (if (integer? fret-number)
 593       (make-vcenter-markup
 594         (format #f "~a" fret-number))
 595       ;; for non-integer fret-number print p.e. "2½"
 596       (let* ((whole-part (truncate fret-number))
 597              (remaining (- fret-number whole-part))
 598              (fret
 599                (if (and (zero? whole-part) (not (zero? remaining)))
 600                    ""
 601                    (format #f "~a" whole-part)))
 602              (frac
 603                (if (zero? remaining)
 604                    ""
 605                    (format #f "~a" remaining))))
 606         (make-concat-markup
 607           (list (make-vcenter-markup fret)
 608                 (make-vcenter-markup
 609                   ;; the value `-2.5' is my choice
 610                   (make-fontsize-markup -2.5 frac)))))))
 611
 612 ;; The 5-string banjo has got an extra string, the fifth (duh), which
 613 ;; starts at the fifth fret on the neck.  Frets on the fifth string
 614 ;; are referred to relative to the other frets:
 615 ;;   the "first fret" on the fifth string is really the sixth fret
 616 ;;   on the banjo neck.
 617 ;; We solve this by defining a new fret-number-tablature function:
 618 (define-public (fret-number-tablature-format-banjo
 619                 context string-number fret-number)
 620   (make-vcenter-markup
 621    (number->string (cond
 622                     ((and (> fret-number 0) (= string-number 5))
 623                      (+ fret-number 5))
 624                     (else fret-number)))))
 625
 626 ;;  Tab note head staff position functions
 627 ;;
 628 ;;  Define where in the staff to display a given string.  Some forms of
 629 ;;  tablature put the tab note heads in the spaces, rather than on the
 630 ;;  lines
 631
 632 (define-public (tablature-position-on-lines context string-number)
 633   (let* ((string-tunings (ly:context-property context 'stringTunings))
 634          (string-count (length string-tunings))
 635          (string-one-topmost (ly:context-property context 'stringOneTopmost))
 636          (staff-line (- (* 2 string-number) string-count 1)))
 637     (if string-one-topmost
 638         (- staff-line)
 639         staff-line)))
 640
 641 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 642 ;; bar numbers
 643
 644 (define ((every-nth-bar-number-visible n) barnum mp)
 645   (= 0 (modulo barnum n)))
 646 (export every-nth-bar-number-visible)
 647
 648 (define ((modulo-bar-number-visible n m) barnum mp)
 649   (and (> barnum 1) (= m (modulo barnum n))))
 650 (export modulo-bar-number-visible)
 651
 652 (define ((set-bar-number-visibility n) tr)
 653   (let ((bn (ly:context-property tr 'currentBarNumber)))
 654     (ly:context-set-property! tr 'barNumberVisibility
 655                               (modulo-bar-number-visible n (modulo bn n)))))
 656 (export set-bar-number-visibility)
 657
 658 (define-public (first-bar-number-invisible barnum mp)
 659   (> barnum 1))
 660
 661 (define-public (first-bar-number-invisible-save-broken-bars barnum mp)
 662   (or (> barnum 1)
 663       (> (ly:moment-main-numerator mp) 0)))
 664
 665 (define-public (first-bar-number-invisible-and-no-parenthesized-bar-numbers barnum mp)
 666   (and (> barnum 1)
 667        (= (ly:moment-main-numerator mp) 0)))
 668
 669 (define-public (robust-bar-number-function barnum measure-pos alt-number context)
 670   (define (get-number-and-power an pow)
 671     (if (<= an alt-number)
 672         (get-number-and-power (+ an (expt 26 (1+ pow))) (1+ pow))
 673         (cons (+ alt-number (- (expt 26 pow) an)) (1- pow))))
 674   (define (make-letter so-far an pow)
 675     (if (< pow 0)
 676         so-far
 677         (let ((pos (modulo (quotient an (expt 26 pow)) 26)))
 678           (make-letter (string-append so-far
 679                                       (substring "abcdefghijklmnopqrstuvwxyz"
 680                                                  pos
 681                                                  (1+ pos)))
 682                        an
 683                        (1- pow)))))
 684   (let* ((number-and-power (get-number-and-power 0 0))
 685          (begin-measure (= 0 (ly:moment-main-numerator measure-pos)))
 686          (maybe-open-parenthesis (if begin-measure "" "("))
 687          (maybe-close-parenthesis (if begin-measure "" ")")))
 688     (markup (string-append maybe-open-parenthesis
 689                            (number->string barnum)
 690                            (make-letter ""
 691                                         (car number-and-power)
 692                                         (cdr number-and-power))
 693                            maybe-close-parenthesis))))
 694
 695 (define-public (all-bar-numbers-visible barnum mp) #t)
 696
 697
 698 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 699 ;; percent repeat counters
 700
 701 (define ((every-nth-repeat-count-visible n) count context)
 702   (= 0 (modulo count n)))
 703 (export every-nth-repeat-count-visible)
 704
 705 (define-public (all-repeat-counts-visible count context) #t)