scm/part-combiner.scm

   1 ;;;; part-combiner.scm -- Part combining, staff changes.
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2004  Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 ;; todo: figure out how to make module,
   8 ;; without breaking nested ly scopes
   9
  10 (define-class <Voice-state> ()
  11   (event-list #:init-value '() #:accessor events #:init-keyword #:events)
  12   (when-moment #:accessor when #:init-keyword #:when)
  13   (tuning #:accessor tuning #:init-keyword #:tuning)
  14   (split-index #:accessor split-index)
  15   (vector-index)
  16   (state-vector)
  17   ;;;
  18   ;; spanner-state is an alist
  19   ;; of (SYMBOL . RESULT-INDEX), which indicates where
  20   ;; said spanner was started.
  21   (spanner-state #:init-value '() #:accessor span-state) )
  22
  23 (define-method (write (x <Voice-state> ) file)
  24   (display (when x) file)
  25   (display " evs = " file)
  26   (display (events x) file)
  27   (display " active = " file)
  28   (display (span-state x) file)
  29   (display "\n" file) )
  30
  31 (define-method (note-events (vs <Voice-state>))
  32   (define (f? x)
  33     (equal? (ly:music-property  x 'name) 'NoteEvent))
  34   (filter f? (events vs)))
  35
  36 (define-method (previous-voice-state (vs <Voice-state>))
  37   (let ((i (slot-ref vs 'vector-index))
  38         (v (slot-ref vs 'state-vector)) )
  39     (if (< 0 i)
  40         (vector-ref v (1- i))
  41         #f)))
  42
  43 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  44
  45 (define-class <Split-state> ()
  46   (configuration #:init-value '() #:accessor configuration)
  47   (when-moment #:accessor when #:init-keyword #:when)
  48   ;; voice-states are states starting with the Split-state or later
  49   ;;
  50   (is #:init-keyword #:voice-states #:accessor voice-states)
  51   (synced  #:init-keyword #:synced #:init-value  #f #:getter synced?))
  52
  53
  54 (define-method (write (x <Split-state> ) f)
  55   (display (when x) f)
  56   (display " = " f)
  57   (display (configuration x) f)
  58   (if (synced? x)
  59       (display " synced "))
  60   (display "\n" f) )
  61
  62 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  63
  64
  65 (define (previous-span-state vs)
  66   (let ((p (previous-voice-state vs)))
  67     (if p (span-state p) '())))
  68
  69 (define (make-voice-states evl)
  70   (let ((vec (list->vector (map (lambda (v)
  71                                   (make <Voice-state>
  72                                     #:when (caar v)
  73                                     #:tuning (cdar v)
  74                                     #:events (map car (cdr v))))
  75                                 evl))))
  76     (do ( (i 0 (1+ i)) )
  77         ( (= i (vector-length vec)) vec)
  78       (slot-set! (vector-ref vec i) 'vector-index i)
  79       (slot-set! (vector-ref vec i) 'state-vector vec))))
  80
  81 (define (make-split-state vs1 vs2)
  82   "Merge lists VS1 and VS2, containing Voice-state objects into vector
  83 of Split-state objects, crosslinking the Split-state vector and
  84 Voice-state objects
  85 "
  86   (define (helper ss-idx ss-list idx1 idx2)
  87     (let* ((s1 (if (< idx1 (vector-length vs1)) (vector-ref vs1 idx1) #f))
  88            (s2 (if (< idx2 (vector-length vs2)) (vector-ref vs2 idx2) #f))
  89            (min (cond ((and s1 s2) (moment-min (when s1) (when s2)))
  90                       (s1 (when s1))
  91                       (s2 (when s2))
  92                       (else #f)))
  93            (inc1 (if (and s1 (equal? min (when s1))) 1 0))
  94            (inc2 (if (and s2 (equal? min (when s2))) 1 0))
  95            (ss-object (if min
  96                           (make <Split-state>
  97                             #:when min
  98                             #:voice-states (cons s1 s2)
  99                             #:synced (= inc1 inc2))
 100                           #f)))
 101       (if s1
 102           (set! (split-index s1) ss-idx))
 103       (if s2
 104           (set! (split-index s2) ss-idx))
 105       (if min
 106           (helper (1+ ss-idx)
 107                   (cons ss-object ss-list)
 108                   (+ idx1 inc1)
 109                   (+ idx2 inc2))
 110           ss-list)))
 111   (list->vector (reverse! (helper 0 '() 0  0) '())))
 112
 113
 114 (define (analyse-spanner-states voice-state-vec)
 115
 116   (define (helper index active)
 117     "Analyse EVS at INDEX, given state ACTIVE."
 118
 119     (define (analyse-tie-start active ev)
 120       (if (equal? (ly:music-property ev 'name) 'TieEvent)
 121           (acons 'tie (split-index (vector-ref voice-state-vec index))
 122                  active)
 123           active))
 124
 125     (define (analyse-tie-end active ev)
 126       (if (equal? (ly:music-property ev 'name) 'NoteEvent)
 127           (assoc-remove! active 'tie)
 128           active))
 129
 130     (define (analyse-absdyn-end active ev)
 131       (if (equal? (ly:music-property ev 'name) 'AbsoluteDynamicEvent)
 132           (assoc-remove! (assoc-remove! active 'cresc) 'decr)
 133           active))
 134
 135     (define (active<? a b)
 136       (cond ((symbol<? (car a) (car b)) #t)
 137             ((symbol<? (car b) (car b)) #f)
 138             (else (< (cdr a) (cdr b)))))
 139
 140     (define (analyse-span-event active ev)
 141       (let* ((name (ly:music-property ev 'name))
 142              (key (cond ((equal? name 'SlurEvent) 'slur)
 143                         ((equal? name 'PhrasingSlurEvent) 'tie)
 144                         ((equal? name 'BeamEvent) 'beam)
 145                         ((equal? name 'CrescendoEvent) 'cresc)
 146                         ((equal? name 'DecrescendoEvent) 'decr)
 147                         (else #f)))
 148              (sp (ly:music-property ev 'span-direction)))
 149         (if (and (symbol? key) (ly:dir? sp))
 150             (if (= sp STOP)
 151                 (assoc-remove! active key)
 152                 (acons key
 153                        (split-index (vector-ref voice-state-vec index))
 154                        active))
 155             active)))
 156
 157     (define (analyse-events active evs)
 158       "Run all analyzers on ACTIVE and EVS"
 159       (define (run-analyzer analyzer active evs)
 160         (if (pair? evs)
 161             (run-analyzer analyzer (analyzer active (car evs)) (cdr evs))
 162             active))
 163       (define (run-analyzers analyzers active evs)
 164         (if (pair? analyzers)
 165             (run-analyzers (cdr analyzers)
 166                            (run-analyzer (car analyzers) active evs)
 167                            evs)
 168             active))
 169       (sort ;; todo: use fold or somesuch.
 170        (run-analyzers (list analyse-absdyn-end analyse-span-event
 171                             ;; note: tie-start/span comes after tie-end/absdyn.
 172                             analyse-tie-end analyse-tie-start)
 173                       active evs)
 174        active<?))
 175
 176     ;; must copy, since we use assoc-remove!
 177     (if (< index (vector-length voice-state-vec))
 178         (begin
 179           (set! active (analyse-events active (events (vector-ref voice-state-vec index))))
 180           (set! (span-state (vector-ref voice-state-vec index))
 181                 (list-copy active))
 182           (helper (1+ index) active))))
 183
 184   (helper 0 '()))
 185
 186
 187
 188 (define noticed '())
 189 (define part-combine-listener '())
 190 (define-public (set-part-combine-listener x)
 191   (set! part-combine-listener x))
 192
 193 (define-public (notice-the-events-for-pc context lst)
 194   (set! noticed (acons (ly:context-id context) lst noticed)))
 195
 196 (define-public (make-part-combine-music music-list)
 197   (let ((m (make-music 'PartCombineMusic))
 198         (m1 (make-non-relative-music (context-spec-music (car music-list) 'Voice "one")))
 199         (m2  (make-non-relative-music  (context-spec-music (cadr music-list) 'Voice "two"))))
 200     (set! (ly:music-property m 'elements) (list m1 m2))
 201     (ly:run-translator m2 part-combine-listener)
 202     (ly:run-translator m1 part-combine-listener)
 203     (set! (ly:music-property m 'split-list)
 204           (determine-split-list (reverse! (cdr (assoc "one" noticed)) '())
 205                                 (reverse! (cdr (assoc "two" noticed)) '())))
 206     (set! noticed '())
 207     m))
 208
 209 (define-public (determine-split-list evl1 evl2)
 210   "EVL1 and EVL2 should be ascending"
 211   (let* ((pc-debug #f)
 212          (chord-threshold 8)
 213          (voice-state-vec1 (make-voice-states evl1))
 214          (voice-state-vec2 (make-voice-states evl2))
 215          (result (make-split-state voice-state-vec1 voice-state-vec2)))
 216
 217     (define (analyse-time-step ri)
 218       (define (put x . index)
 219         "Put the result to X, starting from INDEX backwards.
 220
 221 Only set if not set previously.
 222 "
 223         (let ((i (if (pair? index) (car index) ri)))
 224           (if (and (<= 0 i)
 225                    (not (symbol? (configuration (vector-ref result i)))))
 226               (begin
 227                 (set! (configuration (vector-ref result i)) x)
 228                 (put x (1- i))))))
 229
 230       (define (copy-state-from state-vec vs)
 231         (define (copy-one-state key-idx)
 232           (let* ((idx (cdr key-idx))
 233                  (prev-ss (vector-ref result idx))
 234                  (prev (configuration prev-ss)))
 235             (if (symbol? prev)
 236                 (put prev))))
 237         (map copy-one-state (span-state vs)))
 238
 239       (define (analyse-notes now-state)
 240         (let* ((vs1 (car (voice-states now-state)))
 241                (vs2 (cdr (voice-states now-state)))
 242                (notes1 (note-events vs1))
 243                (durs1    (sort (map (lambda (x) (ly:music-property x 'duration))
 244                                     notes1)
 245                                ly:duration<?))
 246                (pitches1 (sort (map (lambda (x) (ly:music-property x 'pitch))
 247                                     notes1)
 248                                ly:pitch<?))
 249                (notes2   (note-events vs2))
 250                (durs2    (sort (map (lambda (x) (ly:music-property x 'duration))
 251                                     notes2)
 252                                ly:duration<?))
 253                (pitches2 (sort (map (lambda (x) (ly:music-property x 'pitch))
 254                                     notes2)
 255                                ly:pitch<?)))
 256           (cond ((> (length notes1) 1) (put 'apart))
 257                 ((> (length notes2) 1) (put 'apart))
 258                 ((not (= (length notes1) (length notes2)))
 259                  (put 'apart))
 260                 ((and (= (length durs1) 1)
 261                       (= (length durs2) 1)
 262                       (not (equal? (car durs1) (car durs2))))
 263                  (put 'apart))
 264                 (else
 265                  (if (and (= (length pitches1) (length pitches2)))
 266                      (if (and (pair? pitches1)
 267                               (pair? pitches2)
 268                               (or
 269                                (< chord-threshold (ly:pitch-steps
 270                                                    (ly:pitch-diff (car pitches1)
 271                                                                   (car pitches2))))
 272
 273                                ;; voice crossings:
 274                                (> 0 (ly:pitch-steps (ly:pitch-diff (car pitches1)
 275                                                                    (car pitches2))))
 276                                ))
 277                          (put 'apart)
 278                          ;; copy previous split state from spanner state
 279                          (begin
 280                            (if (previous-voice-state vs1)
 281                                (copy-state-from voice-state-vec1
 282                                                 (previous-voice-state vs1)))
 283                            (if (previous-voice-state vs2)
 284                                (copy-state-from voice-state-vec2
 285                                                 (previous-voice-state vs2)))
 286                            (if (and (null? (span-state vs1)) (null? (span-state vs2)))
 287                                (put 'chords)))))))))
 288
 289       (if (< ri (vector-length result))
 290           (let* ((now-state (vector-ref result ri))
 291                  (vs1 (car (voice-states now-state)))
 292                  (vs2 (cdr (voice-states now-state))))
 293
 294
 295             (cond ((not vs1) (put 'apart))
 296                   ((not vs2) (put 'apart))
 297                   (else
 298                    (let ((active1 (previous-span-state vs1))
 299                          (active2 (previous-span-state vs2))
 300                          (new-active1 (span-state vs1))
 301                          (new-active2 (span-state vs2)))
 302                      (if pc-debug
 303                          (display (list (when now-state) ri
 304                                         active1 "->" new-active1
 305                                         active2 "->" new-active2
 306                                         "\n")))
 307                      (if (and (synced? now-state)
 308                               (equal? active1 active2)
 309                               (equal? new-active1 new-active2))
 310                     (analyse-notes now-state)
 311                     ;; active states different:
 312                     (put 'apart)))
 313                    ;; go to the next one, if it exists.
 314                    (analyse-time-step (1+ ri)))))))
 315
 316     (define (analyse-a2 ri)
 317       (if (< ri (vector-length result))
 318           (let* ((now-state (vector-ref result ri))
 319                  (vs1 (car (voice-states now-state)))
 320                  (vs2 (cdr (voice-states now-state))))
 321             (if (and (equal? (configuration now-state) 'chords)
 322                      vs1 vs2)
 323                 (let ((notes1 (note-events vs1))
 324                       (notes2 (note-events vs2)))
 325                   (cond ((and (= 1 (length notes1))
 326                               (= 1 (length notes2))
 327                               (equal? (ly:music-property (car notes1) 'pitch)
 328                                       (ly:music-property (car notes2) 'pitch)))
 329                          (set! (configuration now-state) 'unisono))
 330                         ((and (= 0 (length notes1))
 331                               (= 0 (length notes2)))
 332                          (set! (configuration now-state) 'unisilence)))))
 333             (analyse-a2 (1+ ri)))))
 334
 335     (define (analyse-solo12 ri)
 336
 337       (define (previous-config vs)
 338         (let* ((pvs (previous-voice-state vs))
 339                (spi (if pvs (split-index pvs) #f))
 340                (prev-split (if spi (vector-ref result spi) #f)))
 341           (if prev-split
 342               (configuration prev-split)
 343               'apart)))
 344
 345       (define (put-range x a b)
 346         ;; (display (list "put range "  x a b "\n"))
 347         (do ((i a (1+ i)))
 348             ((> i b) b)
 349           (set! (configuration (vector-ref result i)) x)))
 350
 351       (define (put x)
 352         ;; (display (list "putting "  x "\n"))
 353         (set! (configuration (vector-ref result ri)) x))
 354
 355       (define (current-voice-state now-state voice-num)
 356         (define vs ((if (= 1 voice-num) car cdr)
 357                     (voice-states now-state)))
 358         (if (or (not vs) (equal? (when now-state) (when vs)))
 359             vs
 360             (previous-voice-state vs)))
 361
 362       (define (try-solo type start-idx current-idx)
 363         "Find a maximum stretch that can be marked as solo. Only set
 364 the mark when there are no spanners active."
 365         (if (< current-idx (vector-length result))
 366             (let* ((now-state (vector-ref result current-idx))
 367                    (solo-state (current-voice-state now-state (if (equal? type 'solo1) 1 2)))
 368                    (silent-state (current-voice-state now-state (if (equal? type 'solo1) 2 1)))
 369                    (silent-notes (if silent-state (note-events silent-state) '()))
 370                    (solo-notes (if solo-state (note-events solo-state) '()))
 371                    (soln (length solo-notes))
 372                    (siln (length silent-notes)))
 373               ;; (display (list "trying " type " at "  (when now-state) solo-state silent-state  "\n"))
 374               (cond ((not (equal? (configuration now-state) 'apart))
 375                      current-idx)
 376                     ((> siln 0) start-idx)
 377                     ((and (null? (span-state solo-state)))
 378                      ;;
 379                      ;; This includes rests. This isn't a problem: long rests
 380                      ;; will be shared with the silent voice, and be marked
 381                      ;; as unisilence. Therefore, long rests won't
 382                      ;;  accidentally be part of a solo.
 383                      ;;
 384                      (put-range type start-idx current-idx)
 385                      (try-solo type (1+ current-idx) (1+  current-idx)))
 386                     (else
 387                      (try-solo type start-idx (1+ current-idx)))))
 388             start-idx)) ; try-solo
 389
 390       (define (analyse-moment ri)
 391         "Analyse 'apart starting at RI. Return next index. "
 392         (let* ((now-state (vector-ref result ri))
 393                (vs1 (current-voice-state now-state 1))
 394                (vs2 (current-voice-state now-state 2))
 395                ;; (vs1 (car (voice-states now-state)))
 396                ;; (vs2 (cdr (voice-states now-state)))
 397                (notes1 (if vs1 (note-events vs1) '()))
 398                (notes2 (if vs2 (note-events vs2) '()))
 399                (n1 (length notes1))
 400                (n2 (length notes2)))
 401           ;; (display (list "analyzing step " ri "  moment " (when now-state) vs1 vs2  "\n"))
 402           (max                          ; we should always increase.
 403            (cond ((and (= n1 0) (= n2 0))
 404                   (put 'apart-silence)
 405                   (1+ ri))
 406                  ((and (= n2 0)
 407                        (equal? (when vs1) (when now-state))
 408                        (null? (previous-span-state vs1)))
 409                   (try-solo 'solo1 ri ri))
 410                  ((and (= n1 0)
 411                        (equal? (when vs2) (when now-state))
 412                        (null? (previous-span-state vs2)))
 413                   (try-solo 'solo2 ri ri))
 414                  (else (1+ ri)))
 415            (1+ ri)))) ; analyse-moment
 416
 417       (if (< ri (vector-length result))
 418           (if (equal? (configuration (vector-ref result ri)) 'apart)
 419               (analyse-solo12 (analyse-moment ri))
 420               (analyse-solo12 (1+ ri))))) ; analyse-solo12
 421
 422     (analyse-spanner-states voice-state-vec1)
 423     (analyse-spanner-states voice-state-vec2)
 424     (if #f
 425         (begin
 426           (display voice-state-vec1)
 427           (display "***\n")
 428           (display voice-state-vec2)
 429           (display "***\n")
 430           (display result)
 431           (display "***\n")))
 432     (analyse-time-step 0)
 433     ;; (display result)
 434     (analyse-a2 0)
 435     ;; (display result)
 436     (analyse-solo12 0)
 437     ;; (display result)
 438     (set! result (map
 439                   (lambda (x) (cons (when x) (configuration x)))
 440                   (vector->list result)))
 441     ;; (if pc-debug (display result))
 442     result))
 443
 444 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 445 ;; autochange - fairly related to part combining.
 446
 447 (define-public (make-autochange-music music)
 448   (define (generate-split-list change-moment event-list acc)
 449     (if (null? event-list)
 450         acc
 451         (let* ((now-tun (caar event-list))
 452                (evs (map car (cdar event-list)))
 453                (now (car now-tun))
 454                (notes (filter (lambda (x)
 455                                 (equal? (ly:music-property  x 'name) 'NoteEvent))
 456                               evs))
 457                (pitch (if (pair? notes)
 458                           (ly:music-property (car notes) 'pitch)
 459                           #f)))
 460           ;; tail recursive.
 461           (if (and pitch (not (= (ly:pitch-steps pitch) 0)))
 462               (generate-split-list #f
 463                                    (cdr event-list)
 464                                    (cons (cons
 465
 466                                           (if change-moment
 467                                               change-moment
 468                                               now)
 469                                           (sign (ly:pitch-steps pitch))) acc))
 470               (generate-split-list
 471                (if pitch #f now)
 472                (cdr event-list) acc)))))
 473
 474   (set! noticed '())
 475   (let* ((m (make-music 'AutoChangeMusic))
 476          (context (ly:run-translator (make-non-relative-music music) part-combine-listener))
 477          (evs (last-pair noticed))
 478          (split (reverse! (generate-split-list
 479                            #f
 480                            (if (pair? evs)
 481                                (reverse! (cdar evs) '()) '())
 482                            '())
 483                           '())))
 484     (set! (ly:music-property m 'element) music)
 485     (set! (ly:music-property m 'split-list) split)
 486     (set! noticed '())
 487     m))
 488
 489
 490 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 491
 492 (define-public (add-quotable name mus)
 493   (set! noticed '())
 494   (let* ((tab (eval 'musicQuotes (current-module) ))
 495          (context (ly:run-translator (context-spec-music mus 'Voice)
 496                                      part-combine-listener))
 497          (evs (last-pair noticed)))
 498     (if (pair? evs)
 499         (hash-set! tab name
 500                    (list->vector (reverse! (car evs) '()))))))