scm/paper.scm

   1 ;;;; paper.scm -- manipulate the paper block.
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7
   8 (define-public (paper-set-staff-size sz)
   9   "Function to be called inside a \\paper{} block to set the staff size."
  10   (let* ((m (current-module))
  11          (ss (/ sz 4))
  12          (pt (eval 'pt m))
  13          (mm (eval 'mm m)))
  14
  15     (module-define! m 'fonts (make-cmr-tree (/  sz (* 20 pt))))
  16     (module-define! m 'staffheight sz)
  17     (module-define! m 'staff-space ss)
  18     (module-define! m 'staffspace ss)
  19
  20
  21     ;; !! synchronize with feta-params.mf
  22     (module-define! m 'linethickness (+ (* 0.3 pt) (* 0.04 ss)))
  23     (module-define! m 'ledgerlinethickness (+ (* 0.5 pt) (/ ss 10)))
  24     (module-define! m 'blotdiameter (* 0.35 pt))
  25     (module-define! m 'interscoreline (* 4 mm))
  26
  27     (module-define! m 'dimension-variables
  28                     '(pt mm cm in staffheight staff-space
  29                          linewidth indent hsize vsize
  30                          staffspace linethickness ledgerlinethickness
  31                          blotdiameter interscoreline))
  32     ))
  33
  34 (define-public (set-global-staff-size sz)
  35   "Set the default staff size, where SZ is thought to be in PT."
  36   (let* ((old-mod (current-module))
  37          (pap (eval '$defaultpaper old-mod))
  38          (is-paper? (module-defined? old-mod '$defaultpaper))
  39
  40
  41          ;; Huh? Why is it necessary to clone object?
  42          (new-paper (ly:output-def-clone pap))
  43          (new-scope (ly:output-def-scope new-paper)))
  44     (if (not is-paper?)
  45         (ly:warn "Not in toplevel scope"))
  46     (set-current-module new-scope)
  47     (paper-set-staff-size (* sz (eval 'pt new-scope)))
  48     (set-current-module old-mod)
  49     (module-define! old-mod '$defaultpaper new-paper)))
  50
  51 (define paper-alist
  52   '(("a6" . (cons (* 105 mm) (* 148.95 mm)))
  53     ("a5" . (cons (* 148.95 mm) (* 210 mm)))
  54     ("a4" . (cons (* 210 mm) (* 297.9 mm)))
  55     ("a3" . (cons (* 297.9 mm) (* 420 mm)))
  56     ("legal" . (cons (* 8.5 in) (* 14.0 in)))
  57     ("letter" . (cons (* 8.5 in) (* 11.0 in)))
  58     ("tabloid" . (cons (* 11.0 in) (* 17.0 in)))))
  59
  60 ;; todo: take dimension arguments.
  61
  62 (define (set-paper-dimensions m w h)
  63   "M is a module (i.e. paper->scope_ )"
  64   (let* ((mm (eval 'mm m)))
  65     (module-define! m 'hsize w)
  66     (module-define! m 'vsize h)
  67     (module-define! m 'linewidth (- w (* 20 mm)))
  68     (module-define! m 'indent (/ w 14))
  69
  70     ;; page layout - what to do with (printer specific!) margin settings?
  71     (module-define! m 'top-margin (* 5 mm))
  72     (module-define! m 'bottom-margin (* 6 mm))
  73     (module-define! m 'head-sep (* 4 mm))
  74     (module-define! m 'foot-sep (* 4 mm))))
  75
  76 (define (internal-set-paper-size module name)
  77   (let* ((entry (assoc name paper-alist))
  78          (is-paper? (module-defined? module '$is-paper))
  79          (mm (eval 'mm module)))
  80
  81     (cond
  82      ((not is-paper?)
  83       (ly:warning "This is not a \\paper {} object:")
  84       (display module))
  85      ((pair? entry)
  86       (set! entry (eval  (cdr entry) module))
  87           (set-paper-dimensions module (car entry) (cdr entry))
  88           (module-define! module 'papersize name)
  89           (module-define! module 'papersizename name)
  90           (set-paper-dimensions module (car entry) (cdr entry)))
  91      (else
  92       (ly:warn (string-append "Unknown papersize: " name))))
  93
  94     ))
  95
  96 (define-public (set-default-paper-size name)
  97   (internal-set-paper-size (ly:output-def-scope (eval '$defaultpaper (current-module)))
  98                            name))
  99
 100 (define-public (set-paper-size name)
 101   (if (module-defined? (current-module) '$is-paper)
 102       (internal-set-paper-size (current-module) name)
 103
 104       ;;; TODO: should raise (generic) exception with throw, and catch
 105       ;;; that in parse-scm.cc
 106       (ly:warn "Must use #(set-paper-size .. ) within \\paper { ... }")))
 107
 108 (define-public (scale-paper pap bookpap)
 109   (let*
 110       ((scale (ly:bookpaper-outputscale bookpap))
 111        (new-pap (ly:output-def-clone pap))
 112        (dim-vars (ly:paper-lookup pap 'dimension-variables))
 113        (scope (ly:output-def-scope new-pap)))
 114
 115     (for-each
 116      (lambda (v)
 117        (module-define! scope v
 118                        (/ (ly:paper-lookup pap v) scale)))
 119
 120      dim-vars)
 121
 122     new-pap
 123   ))