scm/paper.scm

   1 ;;;; paper.scm -- manipulate the paper block.
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7
   8 (define-public (paper-set-staff-size sz)
   9   "Function to be called inside a \\paper{} block to set the staff size."
  10   (let* ((m (current-module))
  11          (ss (/ sz 4))
  12          (pt (eval 'pt m))
  13          (mm (eval 'mm m)))
  14
  15     (module-define! m 'outputscale ss)
  16     (module-define! m 'fonts (make-cmr-tree (/  sz (* 20 pt))))
  17     (module-define! m 'staffheight sz)
  18     (module-define! m 'staff-space ss)
  19     (module-define! m 'staffspace ss)
  20
  21     ;; !! synchronize with feta-params.mf
  22     (module-define! m 'linethickness (+ (* 0.3 pt) (* 0.04 ss)))
  23     (module-define! m 'ledgerlinethickness (+ (* 0.5 pt) (/ ss 10)))
  24     (module-define! m 'blotdiameter (* 0.35 pt))
  25     (module-define! m 'interscoreline (* 4 mm))
  26
  27     (module-define! m 'dimension-variables
  28                     '(pt mm cm in staffheight staff-space
  29                          linewidth indent hsize vsize
  30                          staffspace linethickness ledgerlinethickness
  31                          blotdiameter interscoreline leftmargin rightmargin))
  32     ))
  33
  34 (define-public (set-global-staff-size sz)
  35   "Set the default staff size, where SZ is thought to be in PT."
  36   (let* ((old-mod (current-module))
  37          (pap (eval '$defaultbookpaper old-mod))
  38          (in-paper? (or (module-defined? old-mod 'is-bookpaper)
  39                         (module-defined? old-mod 'is-paper)))
  40
  41          ; maybe not necessary.
  42          ; but let's be paranoid. Maybe someone still refers to the
  43          ; old one.
  44          (new-paper (ly:output-def-clone pap))
  45
  46          (new-scope (ly:output-def-scope new-paper)))
  47
  48     (if in-paper?
  49         (ly:warn "Not in toplevel scope"))
  50     (set-current-module new-scope)
  51     (paper-set-staff-size (* sz (eval 'pt new-scope)))
  52     (set-current-module old-mod)
  53     (module-define! old-mod '$defaultbookpaper new-paper)))
  54
  55 (define paper-alist
  56   '(("a6" . (cons (* 105 mm) (* 148.95 mm)))
  57     ("a5" . (cons (* 148.95 mm) (* 210 mm)))
  58     ("a4" . (cons (* 210 mm) (* 297.9 mm)))
  59     ("a3" . (cons (* 297.9 mm) (* 420 mm)))
  60     ("legal" . (cons (* 8.5 in) (* 14.0 in)))
  61     ("letter" . (cons (* 8.5 in) (* 11.0 in)))
  62     ("tabloid" . (cons (* 11.0 in) (* 17.0 in)))))
  63
  64 ;; todo: take dimension arguments.
  65
  66 (define (set-paper-dimensions m w h)
  67   "M is a module (i.e. paper->scope_ )"
  68   (let* ((mm (eval 'mm m)))
  69     (module-define! m 'hsize w)
  70     (module-define! m 'vsize h)
  71     (module-define! m 'linewidth (- w (* 20 mm)))
  72     (module-define! m 'indent (/ w 14))
  73
  74     ;; page layout - what to do with (printer specific!) margin settings?
  75     (module-define! m 'topmargin (* 5 mm))
  76     (module-define! m 'bottommargin (* 6 mm))
  77     (module-define! m 'headsep (* 4 mm))
  78     (module-define! m 'footsep (* 4 mm))
  79     (module-define! m 'leftmargin (* 10 mm))
  80     (module-define! m 'rightmargin (* 10 mm))))
  81
  82 (define (internal-set-paper-size module name)
  83   (let* ((entry (assoc name paper-alist))
  84          (is-bookpaper? (module-defined? module 'is-bookpaper))
  85          (mm (eval 'mm module)))
  86
  87     (cond
  88      ((not is-bookpaper?)
  89       (ly:warning "This is not a \\paper {} object, ~S"
  90                    module))
  91      ((pair? entry)
  92       (set! entry (eval  (cdr entry) module))
  93           (set-paper-dimensions module (car entry) (cdr entry))
  94           (module-define! module 'papersize name)
  95           (module-define! module 'papersizename name)
  96           (set-paper-dimensions module (car entry) (cdr entry)))
  97      (else
  98       (ly:warn (string-append "Unknown papersize: " name))))
  99
 100     ))
 101
 102 (define-public (set-default-paper-size name)
 103   (internal-set-paper-size (ly:output-def-scope (eval '$defaultbookpaper (current-module)))
 104                            name))
 105
 106 (define-public (set-paper-size name)
 107   (if (module-defined? (current-module) 'is-paper)
 108       (internal-set-paper-size (current-module) name)
 109
 110       ;;; TODO: should raise (generic) exception with throw, and catch
 111       ;;; that in parse-scm.cc
 112       (ly:warn "Must use #(set-paper-size .. ) within \\paper { ... }")))
 113
 114 (define-public (scale-paper pap scale)
 115   (let*
 116       ((new-pap (ly:output-def-clone pap))
 117        (dim-vars (ly:output-def-lookup pap 'dimension-variables))
 118        (scope (ly:output-def-scope new-pap)))
 119
 120     (for-each
 121      (lambda (v)
 122        (define val (ly:output-def-lookup pap v))
 123        (if (number? val)
 124            (module-define! scope v
 125                            (/ val scale))
 126
 127            ;; spurious warnings, eg. for hsize, vsize.
 128 ;          (ly:warn "not a number, ~S = ~S " v  val)
 129            ))
 130
 131      dim-vars)
 132
 133     new-pap
 134   ))