scm/paper.scm

   1 ;;;; paper.scm -- manipulate the paper and layout block.
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6
   7 (define-public (set-paper-dimension-variables mod)
   8   (module-define! mod 'dimension-variables
   9                   '(pt mm cm in staff-height staff-space
  10                        page-top-space
  11                        between-system-space between-system-padding
  12                        line-width indent paper-width paper-height horizontal-shift
  13                        staff-space line-thickness ledgerline-thickness
  14                        blot-diameter left-margin right-margin)))
  15
  16 (define (calc-line-thickness staff-space pt)
  17   ;; linear interpolation.
  18
  19   ;; !! synchronize with feta-params.mf
  20   (let*
  21     ((x1 (* 4.125 pt))
  22      (x0 (* 5 pt))
  23      (f1 (* 0.47 pt))
  24      (f0 (* 0.50 pt)))
  25
  26     (/
  27      (+
  28       (* f1 (- staff-space x0))
  29            (* f0 (- x1 staff-space)))
  30      (- x1 x0))))
  31
  32 (define-public (layout-set-absolute-staff-size-in-module m staff-height)
  33   (let*
  34       ((pt (eval 'pt m))
  35        (ss (/ staff-height 4))
  36        (factor (/ staff-height (* 20 pt))))
  37
  38     (module-define! m 'text-font-size (* 12 factor))
  39
  40     (module-define! m 'output-scale ss)
  41     (module-define! m 'fonts
  42                     (if tex-backend?
  43                         (make-cmr-tree factor)
  44                         (make-century-schoolbook-tree factor)))
  45     (module-define! m 'staff-height staff-height)
  46     (module-define! m 'staff-space ss)
  47
  48     (module-define! m 'line-thickness (calc-line-thickness ss pt))
  49
  50     ;;  sync with feta
  51     (module-define! m 'ledgerline-thickness (+ (* 0.5 pt) (/ ss 10)))
  52
  53     ;;  sync with feta
  54     (module-define! m 'blot-diameter (* 0.4 pt))
  55     ))
  56
  57  (define-public (layout-set-absolute-staff-size sz)
  58   "Function to be called inside a \\layout{} block to set the staff size. SZ is in
  59 points"
  60
  61   (layout-set-absolute-staff-size-in-module (current-module) sz))
  62
  63 (define-public (layout-set-staff-size sz)
  64   "Function to be called inside a \\layout{} block to set the staff size. SZ is in
  65 points"
  66
  67   (layout-set-absolute-staff-size (* (eval 'pt (current-module)) sz)))
  68
  69 (define-safe-public (set-global-staff-size sz)
  70   "Set the default staff size, where SZ is thought to be in PT."
  71   (let* ((current-mod (current-module))
  72          (pap (eval '$defaultpaper current-mod))
  73          (in-layout? (or (module-defined? current-mod 'is-paper)
  74                          (module-defined? current-mod 'is-layout)))
  75
  76          ; maybe not necessary.
  77          ; but let's be paranoid. Maybe someone still refers to the
  78          ; old one.
  79          (new-paper (ly:output-def-clone pap))
  80
  81          (new-scope (ly:output-def-scope new-paper)))
  82
  83     (if in-layout?
  84         (ly:warning (_ "set-global-staff-size: not in toplevel scope")))
  85
  86     (layout-set-absolute-staff-size-in-module new-scope
  87                                               (* sz (eval 'pt new-scope)))
  88     (module-define! current-mod '$defaultpaper new-paper)))
  89
  90 (define-public paper-alist
  91
  92   ;; don't use decimals.
  93   ;; ISO 216 has a tolerance of +- 2mm
  94
  95   '(("a7" . (cons (* 74 mm) (* 105 mm)))
  96     ("a6" . (cons (* 105 mm) (* 148 mm)))
  97     ("a5" . (cons (* 148 mm) (* 210 mm)))
  98     ("a4" . (cons (* 210 mm) (* 297 mm)))
  99     ("a3" . (cons (* 297 mm) (* 420 mm)))
 100     ("legal" . (cons (* 8.5 in) (* 14.0 in)))
 101     ("letter" . (cons (* 8.5 in) (* 11.0 in)))
 102     ("11x17" . (cons (* 11.0 in) (* 17.0 in)))
 103     ))
 104
 105 ;; todo: take dimension arguments.
 106
 107 (define (set-paper-dimensions m w h)
 108   "M is a module (i.e. layout->scope_ )"
 109   (let* ((mm (eval 'mm m)))
 110     (module-define! m 'paper-width w)
 111     (module-define! m 'paper-height h)
 112     (module-define! m 'line-width (- w
 113                                      (ly:modules-lookup (list m) 'left-margin (* 10 mm))
 114                                      (ly:modules-lookup (list m) 'right-margin (* 10 mm))))
 115
 116     (module-define! m 'indent (/ w 14))
 117
 118     ;; page layout - what to do with (printer specific!) margin settings?
 119
 120     ))
 121
 122 (define (internal-set-paper-size module name landscape?)
 123   (define (swap x)
 124     (cons (cdr x) (car x)))
 125
 126   (let* ((entry (assoc name paper-alist))
 127          (is-paper? (module-defined? module 'is-paper))
 128          (mm (eval 'mm module)))
 129
 130     (cond
 131      ((not is-paper?)
 132       (ly:warning (_ "This is not a \\layout {} object, ~S" module)))
 133      ((pair? entry)
 134
 135       (set! entry (eval (cdr entry) module))
 136       (if landscape?
 137           (set! entry (swap entry)))
 138       (set-paper-dimensions module (car entry) (cdr entry))
 139
 140       (module-define! module 'papersizename name)
 141       (module-define! module 'landscape
 142                       (if landscape? #t #f)))
 143      (else
 144       (ly:warning (_ "Unknown papersize: ~a" name))))))
 145
 146 (define-safe-public (set-default-paper-size name . rest)
 147   (internal-set-paper-size
 148    (ly:output-def-scope (eval '$defaultpaper (current-module)))
 149    name
 150    (memq 'landscape rest)))
 151
 152 (define-public (set-paper-size name . rest)
 153   (if (module-defined? (current-module) 'is-paper)
 154       (internal-set-paper-size (current-module) name
 155                                (memq 'landscape rest))
 156
 157       ;;; TODO: should raise (generic) exception with throw, and catch
 158       ;;; that in parse-scm.cc
 159       (ly:warning (_ "Must use #(set-paper-size .. ) within \\paper { ... }"))))
 160
 161 (define-public (scale-layout pap scale)
 162   (let* ((new-pap (ly:output-def-clone pap))
 163          (dim-vars (ly:output-def-lookup pap 'dimension-variables))
 164          (old-scope (ly:output-def-scope pap))
 165          (scope (ly:output-def-scope new-pap)))
 166
 167     (for-each
 168      (lambda (v)
 169        (let* ((var (module-variable old-scope v))
 170               (val (if (variable? var) (variable-ref var) #f)))
 171
 172          (if (number? val)
 173              (module-define! scope v
 174                              (/ val scale))
 175
 176              ;; spurious warnings, eg. for paper-width, paper-height.
 177              ;; (ly:warning (_ "not a number, ~S = ~S " v  val))
 178              )))
 179
 180      dim-vars)
 181
 182     new-pap))