scm/page.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2006--2014 Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 (define-module (scm page)
  19
  20   #:export (make-page
  21             page-property
  22             page-set-property!
  23             page-prev
  24             page-printable-height
  25             layout->page-init
  26             page-force
  27             page-penalty
  28             page-configuration
  29             page-lines
  30             page-page-number
  31             page-system-numbers
  32             page-stencil
  33             page-free-height
  34             page?
  35             ))
  36
  37 (use-modules (lily)
  38              (scm paper-system)
  39              (srfi srfi-1))
  40
  41
  42 (define (annotate? layout)
  43   (eq? #t (ly:output-def-lookup layout 'annotate-spacing)))
  44
  45
  46 (define page-module (current-module))
  47
  48 (define (make-page paper-book  . args)
  49   (let*
  50       ((p (apply ly:make-prob (append
  51                                (list 'page (layout->page-init (ly:paper-book-paper paper-book))
  52                                      'paper-book paper-book)
  53                                args))))
  54
  55     (page-set-property! p 'head-stencil (page-header p))
  56     (page-set-property! p 'foot-stencil (page-footer p))
  57
  58     p))
  59
  60 (define page-property ly:prob-property)
  61 (define page-set-property! ly:prob-set-property!)
  62 (define (page-property? page sym)
  63   (eq? #t (page-property page sym)))
  64 (define (page? x)  (ly:prob-type? x 'page))
  65
  66
  67 ;; define accessors.
  68 (for-each
  69  (lambda (j)
  70    (module-define!
  71     page-module
  72     (string->symbol (format #f "page-~a" j))
  73     (lambda (pg)
  74       (page-property pg j))))
  75
  76  '(page-number prev lines force penalty lines))
  77
  78 (define (page-system-numbers page)
  79   (map (lambda (ps) (ly:prob-property ps 'number))
  80        (page-lines page)))
  81
  82 (define (page-translate-systems page)
  83   (for-each
  84
  85    (lambda (sys off)
  86      (if (not (number? (ly:prob-property sys 'Y-offset)))
  87          (ly:prob-set-property! sys 'Y-offset off)))
  88
  89    (page-property page 'lines)
  90    (page-property page 'configuration)))
  91
  92 (define (annotate-top-space first-system layout header-stencil stencil)
  93   (let* ((top-margin (ly:output-def-lookup layout 'top-margin))
  94          (sym (if (paper-system-title? first-system)
  95                   'top-markup-spacing
  96                   'top-system-spacing))
  97          (spacing-spec (ly:output-def-lookup layout sym))
  98          (X-offset (ly:prob-property first-system 'X-offset 5))
  99          (header-extent (ly:stencil-extent header-stencil Y)))
 100
 101     (set! stencil
 102           (ly:stencil-add stencil
 103                           (ly:stencil-translate-axis
 104                            (annotate-spacing-spec layout
 105                                                   spacing-spec
 106                                                   (- top-margin)
 107                                                   (car header-extent)
 108                                                   #:base-color red)
 109                            X-offset X)))
 110     stencil))
 111
 112
 113 (define (annotate-page layout stencil)
 114   (let ((top-margin (ly:output-def-lookup layout 'top-margin))
 115         (paper-height (ly:output-def-lookup layout 'paper-height))
 116         (bottom-margin (ly:output-def-lookup layout 'bottom-margin))
 117         (add-stencil (lambda (y)
 118                        (set! stencil
 119                              (ly:stencil-add stencil
 120                                              (ly:stencil-translate-axis y 6 X))))))
 121     (add-stencil
 122      (ly:stencil-translate-axis
 123       (annotate-y-interval layout "paper-height"
 124                            (cons (- paper-height) 0)
 125                            #t)
 126       1 X))
 127     (add-stencil
 128      (ly:stencil-translate-axis
 129       (annotate-y-interval layout "top-margin"
 130                            (cons (- top-margin) 0)
 131                            #t)
 132       2 X))
 133     (add-stencil
 134      (ly:stencil-translate-axis
 135       (annotate-y-interval layout "bottom-margin"
 136                            (cons (- paper-height) (- bottom-margin paper-height))
 137                            #t)
 138       2 X))
 139     stencil))
 140
 141 (define (annotate-space-left page)
 142   (let*
 143       ((paper-book (page-property page 'paper-book))
 144        (layout (ly:paper-book-paper paper-book))
 145        (arrow (annotate-y-interval layout
 146                                    "space left"
 147                                    (cons (- 0.0
 148                                             (page-property page 'bottom-edge)
 149                                             (let ((foot (page-property page 'foot-stencil)))
 150                                               (if (and (ly:stencil? foot)
 151                                                        (not (ly:stencil-empty? foot)))
 152                                                   (car (ly:stencil-extent foot Y))
 153                                                   0.0)))
 154                                          (page-property page  'bottom-system-edge))
 155                                    #t)))
 156
 157     (set! arrow (ly:stencil-translate-axis arrow 8 X))
 158
 159     arrow))
 160
 161
 162 (define (page-header-or-footer page dir)
 163   (let*
 164       ((paper-book (page-property page 'paper-book))
 165        (layout (ly:paper-book-paper paper-book))
 166        (scopes (ly:paper-book-scopes paper-book))
 167        (number (page-page-number page))
 168        (is-last-bookpart (page-property page 'is-last-bookpart))
 169        (is-bookpart-last-page (page-property page 'is-bookpart-last-page))
 170        (sym (if (= dir UP)
 171                 'make-header
 172                 'make-footer))
 173        (header-proc (ly:output-def-lookup layout sym)))
 174
 175     (if (procedure? header-proc)
 176         (header-proc layout scopes number is-last-bookpart is-bookpart-last-page)
 177         #f)))
 178
 179
 180 (define (page-header page)
 181   (page-header-or-footer page UP))
 182
 183 (define (page-footer page)
 184   (page-header-or-footer page DOWN))
 185
 186 (define (layout->page-init layout)
 187   "Alist of settings for page layout"
 188   (let*
 189       ((paper-height (ly:output-def-lookup layout 'paper-height))
 190        (paper-width (ly:output-def-lookup layout 'paper-width))
 191        (left-margin (ly:output-def-lookup layout 'left-margin))
 192        (right-margin (ly:output-def-lookup layout 'right-margin))
 193        (bottom-edge (- paper-height
 194                        (ly:output-def-lookup layout 'bottom-margin)) )
 195        (top-margin (ly:output-def-lookup layout 'top-margin))
 196        )
 197
 198     `((paper-height . ,paper-height)
 199       (paper-width . ,paper-width)
 200       (left-margin . ,left-margin)
 201       (right-margin . ,right-margin)
 202       (top-margin . ,top-margin)
 203       (bottom-edge . ,bottom-edge)
 204       )))
 205
 206 (define (make-page-stencil page)
 207   "Construct a stencil representing the page from PAGE."
 208
 209
 210   (page-translate-systems page)
 211   (let*
 212       ((paper-book (page-property page 'paper-book))
 213        (prop (lambda (sym) (page-property page sym)))
 214        (layout (ly:paper-book-paper paper-book))
 215        (scopes (ly:paper-book-scopes paper-book))
 216        (lines (page-lines page))
 217        (number (page-page-number page))
 218
 219        ;; TODO: naming paper-height/paper-width not analogous to TeX.
 220
 221        (system-xoffset (ly:output-def-lookup layout 'horizontal-shift 0.0))
 222        (system-separator-markup (ly:output-def-lookup layout 'system-separator-markup))
 223        (system-separator-stencil (if (markup? system-separator-markup)
 224                                      (interpret-markup layout
 225                                                        (layout-extract-page-properties layout)
 226                                                        system-separator-markup)
 227                                      #f))
 228
 229        (page-stencil (ly:make-stencil '()))
 230
 231        (last-system #f)
 232        (last-y 0.0)
 233        (add-to-page (lambda (stencil x y)
 234                       (set! page-stencil
 235                             (ly:stencil-add page-stencil
 236                                             (ly:stencil-translate stencil
 237                                                                   (cons
 238                                                                    (+ system-xoffset x)
 239                                                                    (- 0 y (prop 'top-margin)))
 240
 241                                                                   )))))
 242        (add-system
 243         (lambda (system)
 244           (let* ((stencil (paper-system-stencil system))
 245                  (y (ly:prob-property system 'Y-offset 0))
 246                  (is-title (paper-system-title?
 247                             system)))
 248             (add-to-page stencil
 249                          (ly:prob-property system 'X-offset 0.0)
 250                          y)
 251             (if (and (ly:stencil? system-separator-stencil)
 252                      last-system
 253                      (not (paper-system-title? system))
 254                      (not (paper-system-title? last-system)))
 255                 (add-to-page
 256                  system-separator-stencil
 257                  0
 258                  (average (- last-y
 259                              (car (paper-system-staff-extents last-system)))
 260                           (- y
 261                              (cdr (paper-system-staff-extents system))))))
 262             (set! last-system system)
 263             (set! last-y y))))
 264        (head (prop 'head-stencil))
 265        (foot (prop 'foot-stencil))
 266        )
 267
 268     (if (and
 269          (ly:stencil? head)
 270          (not (ly:stencil-empty? head)))
 271         (begin
 272           ;; Ensure that the top of the header just touches the top margin.
 273           (set! head (ly:stencil-translate-axis head
 274                                                 (- 0 (cdr (ly:stencil-extent head Y)) (prop 'top-margin)) Y))
 275           (set! page-stencil (ly:stencil-add page-stencil head))))
 276
 277     (if (and
 278          (annotate? layout)
 279          (pair? lines))
 280
 281         (begin
 282           (set! page-stencil (annotate-top-space (car lines) layout head page-stencil))
 283
 284           (for-each (lambda (sys next-sys)
 285                       (paper-system-annotate sys next-sys layout))
 286                     lines
 287                     (append (cdr lines) (list #f)))
 288           (paper-system-annotate-last (car (last-pair lines)) layout)))
 289
 290     (for-each add-system lines)
 291
 292
 293     (ly:prob-set-property! page 'bottom-system-edge
 294                            (car (ly:stencil-extent page-stencil Y)))
 295     (ly:prob-set-property! page 'space-left
 296                            (+ (prop 'bottom-edge)
 297                               (prop 'bottom-system-edge)
 298                               (if (and (ly:stencil? foot)
 299                                        (not (ly:stencil-empty? foot)))
 300                                   (car (ly:stencil-extent foot Y))
 301                                   0.0)))
 302
 303     (if (annotate? layout)
 304         (set! page-stencil
 305               (ly:stencil-add page-stencil
 306                               (annotate-space-left page))))
 307
 308     (if (and (ly:stencil? foot)
 309              (not (ly:stencil-empty? foot)))
 310         (set! page-stencil
 311               (ly:stencil-add
 312                page-stencil
 313                (ly:stencil-translate
 314                 foot
 315                 (cons 0
 316                       (+ (- (prop 'bottom-edge))
 317                          (- (car (ly:stencil-extent foot Y)))))))))
 318
 319     (if (ly:output-def-lookup layout 'two-sided #f)
 320         (set! page-stencil
 321               (ly:stencil-translate page-stencil
 322                                     (cons (prop (if (even? number)
 323                                                     'left-margin
 324                                                     'right-margin))
 325                                           0)))
 326         (set! page-stencil
 327               (ly:stencil-translate page-stencil (cons (prop 'left-margin) 0))))
 328
 329     ;; annotation.
 330     (if (annotate? layout)
 331         (set! page-stencil (annotate-page layout page-stencil)))
 332
 333     page-stencil))
 334
 335
 336 (define-public (page-stencil page)
 337   (if (not (ly:stencil? (page-property page 'stencil)))
 338
 339       ;; todo: make tweakable.
 340       ;; via property + callbacks.
 341
 342       (page-set-property! page 'stencil (make-page-stencil page)))
 343   (page-property page 'stencil))
 344
 345 (define (calc-printable-height page)
 346   "Printable area for music and titles; matches default-page-make-stencil."
 347   (let*
 348       ((paper-book (page-property page 'paper-book))
 349        (layout (ly:paper-book-paper paper-book))
 350        (h (- (ly:output-def-lookup layout 'paper-height)
 351              (ly:output-def-lookup layout 'top-margin)
 352              (ly:output-def-lookup layout 'bottom-margin)))
 353
 354        (head (page-property page 'head-stencil))
 355        (foot (page-property page 'foot-stencil))
 356        (available
 357         (- h (if (ly:stencil? head)
 358                  (interval-length (ly:stencil-extent head Y))
 359                  0)
 360            (if (ly:stencil? foot)
 361                (interval-length (ly:stencil-extent foot Y))
 362                0))))
 363
 364     ;; (display (list "\n available" available head foot))
 365     available))
 366
 367 (define (page-printable-height page)
 368   (if (not (number? (page-property page 'printable-height)))
 369       (page-set-property! page 'printable-height (calc-printable-height page)))
 370
 371   (page-property page 'printable-height))