]> git.donarmstrong.com Git - lilypond.git/blob - scm/page-layout.scm
*** empty log message ***
[lilypond.git] / scm / page-layout.scm
1 ;;;; page-layout.scm -- page layout functions
2 ;;;;
3 ;;;;  source file of the GNU LilyPond music typesetter
4 ;;;; 
5 ;;;; (c) 2004 Jan Nieuwenhuizen <janneke@gnu.org>
6
7 (define (ly:modules-lookup modules sym)
8   (let ((v (module-variable (car modules) sym)))
9     (if (and v (variable-bound? v) (variable-ref v))
10         (variable-ref v)
11         (if (module? (cdr modules)) (ly:modules-lookup (cdr modules) sym)))))
12
13 (define (page-properties paper)
14   (list (append `((linewidth . ,(ly:paper-get-number
15                                  paper 'linewidth)))
16                 (ly:paper-lookup paper 'text-font-defaults))))
17
18 (define-public (book-title paper scopes)
19   "Generate book title from header strings."
20   
21   (define (get sym)
22     (let ((x (ly:modules-lookup scopes sym)))
23       (if (and x (not (unspecified? x))) x "")))
24   
25   (let ((props (page-properties paper)))
26     
27     (interpret-markup
28      paper props
29      (markup
30       #:column
31       (#:override '(baseline-skip . 4)
32       #:column
33       (#:fill-line
34        (#:normalsize (get 'dedication))
35        #:fill-line
36        (#:huge #:bigger #:bigger #:bigger #:bigger #:bold (get 'title))
37        #:override '(baseline-skip . 3)
38        #:column
39        (#:fill-line
40         (#:large #:bigger #:bigger #:bold (get 'subtitle))
41         #:fill-line (#:bigger #:bigger #:bold (get 'subsubtitle)))
42        #:override '(baseline-skip . 5)
43        #:column ("")
44        #:override '(baseline-skip . 2.5)
45        #:column
46        (#:fill-line
47         (#:bigger (get 'poet) #:large #:bigger #:caps (get 'composer))
48         #:fill-line (#:bigger (get 'texttranslator) #:bigger (get 'opus))
49         #:fill-line
50         (#:bigger (get 'meter) #:bigger (get 'arranger))
51         ""
52         #:fill-line (#:large #:bigger (get 'instrument))
53         " "
54         #:fill-line (#:large #:bigger #:caps (get 'piece) ""))))))))
55
56 (define-public (user-title paper markup)
57   "Generate book title from header markup."
58   (if (markup? markup)
59       (let ((props (page-properties paper))
60             (baseline-skip (chain-assoc-get 'baseline-skip props 2)) )
61         (stack-lines DOWN 0 BASELINE-SKIP
62                      (list (interpret-markup paper props markup))))))
63
64 (define-public (score-title paper scopes)
65   "Generate score title from header strings."
66   
67   (define (get sym)
68     (let ((x (ly:modules-lookup scopes sym)))
69       (if (and x (not (unspecified? x))) x "")))
70   
71   (let ((props (page-properties paper)))
72     
73     (interpret-markup
74      paper props
75      (markup
76       #:column
77       (#:override '(baseline-skip . 4)
78       #:column
79       (#:fill-line
80        ("" (get 'opus))
81        #:fill-line (#:large #:bigger #:caps (get 'piece) "")))))))
82
83 (define-public (make-header paper page-number)
84   (let ((props (page-properties paper) ))
85     (interpret-markup paper props
86                       (markup #:fill-line
87                               ("" #:bold (number->string page-number))))))
88
89 (define-public (make-footer paper page-number)
90   (let ((props (page-properties paper)))
91
92     (interpret-markup paper props
93                     (markup #:fill-line ("" (number->string page-number))))))
94
95
96 (define TAGLINE
97   (string-append "Engraved by LilyPond (version " (lilypond-version) ")"))
98
99 (define-public (make-tagline paper scopes)
100   (let* ((props (page-properties paper))
101          (tagline-var (ly:modules-lookup scopes 'tagline))
102          (tagline (if (markup? tagline-var) tagline-var TAGLINE)))
103
104     (cond ((string? tagline)
105            (if (not (equal? tagline ""))
106                (interpret-markup paper props
107                                  (markup #:fill-line (tagline "")))))
108           ((markup? tagline) (interpret-markup paper props tagline)))))
109
110 (define-public (make-copyright paper scopes)
111   (let ((props (page-properties paper))
112         (copyright (ly:modules-lookup scopes 'copyright)))
113     
114     (cond ((string? copyright)
115            (if (not (equal? copyright ""))
116                (interpret-markup paper props
117                                  (markup #:fill-line (copyright "")))))
118           ((markup? copyright) (interpret-markup paper props copyright)))))
119
120
121 ;;; optimal page breaking
122
123 ;;; This is not optimal page breaking, this is optimal distribution of
124 ;;; lines over pages; line breaks are a given.
125
126 ;;; TODO:
127 ;;;    - user tweaking:
128 ;;;       + \pagebreak, \nopagebreak
129 ;;;       + #pages?
130 ;;;    - short circut SCORE=-1 (dismiss path)
131 ;;;    - density scoring
132
133
134 (use-modules (oop goops describe))
135
136 (define-class <break-node> ()
137   (prev #:init-value '() #:accessor node-prev #:init-keyword #:prev)
138   (line #:init-value 'barf #:accessor node-line #:init-keyword #:line)
139   (page #:init-value 0 #:accessor node-page #:init-keyword #:page)
140   (score #:init-value 0 #:accessor node-score #:init-keyword #:score)
141   (height #:init-value 0 #:accessor node-height #:init-keyword #:height))
142
143 (define INFINITY 1e9)
144
145 (define (robust-paper-line-number line)
146   (if (null? line) 0
147       (ly:paper-line-number line)))
148   
149 (define (robust-line-height line)
150   (if (null? line) 0
151       (ly:paper-line-height line)))
152   
153 (define (robust-line-number node)
154   (if (null? node) 0
155       (robust-paper-line-number (node-line node))))
156
157 (define (robust-break-score node)
158   (let ((line (node-line node)))
159     (if (null? line) 0
160         (ly:paper-line-break-score line))))
161
162 (define (make-node prev line page score . height)
163   (make <break-node> #:prev prev #:line line #:page page #:score score
164         #:height (if (null? height) 0 (car height))))
165
166 ;; max density %
167 (define MAX-CRAMP 0.05)
168
169 (define-public (ly:optimal-page-breaks lines book-height text-height
170                                        first-diff last-diff)
171
172   ;; FIXME: may need some tweaking: square, cubic
173   (define (height-score available used)
174     (let* ((empty (- available used))
175            (norm-empty (* empty (/ 100 available))))
176       (if (< norm-empty 0)
177           (if (> (* -1 (/ empty available)) MAX-CRAMP)
178               ;; cannot fill more than MAX-CRAMP
179               -1
180               ;; overfull page is still worse by a power
181               ;; -- which means it never happens
182               ;; let's try a factor 2
183               ;;(* -1 norm-empty norm-empty norm-empty))
184               (* 2 norm-empty norm-empty))
185           (* norm-empty norm-empty))))
186
187   (define (page-height page-number page-count)
188     (let ((h text-height))
189       (if (= page-number 1)
190           (set! h (+ h first-diff)))
191       (if (= page-number page-count)
192           ;;(> page-number (/ book-height text-height))
193        (set! h (+ h last-diff)))
194       h))
195
196   (define (cumulative-height lines)
197     (apply + (map robust-line-height lines)))
198
199   (define (get-path node)
200     (if (null? node) '() (cons node (get-path (node-prev node)))))
201
202   (define (add-scores . lst)
203     (if (null? (filter (lambda (x) (> 0 x)) lst)) (apply + lst) -1))
204
205   (define (density-variance nodes)
206     (define (sqr x) (* x x))
207     (define (density node)
208       (let ((p (page-height (node-page node) (node-page (car nodes))))
209             (h (node-height node)))
210         (if (and p h) (/ h p) 0)))
211     
212     (let* ((height-nodes (reverse
213                           ;; reverse makes for handier debugging
214                           (filter (lambda (x) (> (node-height x) 0)) nodes)))
215            (densities (map density height-nodes))
216            (p-heights (map (lambda (x) (page-height (node-page x)
217                                                     (node-page (car nodes))))
218                            height-nodes))
219            (heights (map node-height height-nodes))
220            (mean (/ (apply + densities) (length densities)))
221            (diff (map (lambda (x) (- x mean)) densities))
222            (var (map sqr (map (lambda (x) (* (car p-heights) x)) diff))))
223       (apply + var)))
224
225   (define (walk-paths best node lines nodes paths)
226     (let* ((height (cumulative-height lines))
227            (next-page (+ (if (null? paths) 0 (node-page (car paths))) 1))
228            (page (page-height (node-page node) next-page))
229            (hh (make-node '() (node-line node) 0 0 height))
230            (break-score (robust-break-score node))
231            (density-score (if (null? paths) 0
232                               ;; TODO: find out why we need density
233                               ;;       use other height-score parameters?
234                               ;; See: input/test/page-breaks.ly
235                               (* 1 (density-variance
236                                     (cons hh (get-path (car paths)))))))
237            (page-score (height-score page height))
238            (this-score (add-scores page-score break-score density-score))
239            (path-score (if (null? paths) 0 (node-score (car paths))))
240            (score (add-scores path-score this-score)))
241
242       (if (and (>= score 0)
243                (or (<= score (node-score best))
244                    (= (node-score best) -1)))
245           (begin
246             (set! (node-score best) score)
247             (set! (node-page best) next-page)
248             (set! (node-height best) height)
249             (set! (node-prev best) (car paths))))
250
251       (if (or (null? nodes)
252               ;; short circuit
253               (and (= path-score -1)
254                    (> (- (/ height page) 1) MAX-CRAMP)))
255           best
256           (walk-paths best (car nodes)
257                       (cons (node-line (car paths)) lines)
258                       (cdr nodes) (cdr paths)))))
259
260   (define (walk-lines lines nodes paths)
261     (if (null? (cdr lines))
262         paths
263         (let* ((prev (node-prev (car nodes)))
264                (this (make-node prev (car lines) 0 INFINITY))
265                (next (make-node this (cadr lines) 0 0))
266                (best (walk-paths this prev (list (node-line (car nodes)))
267                                  (cddr nodes) paths)))
268           (walk-lines (cdr lines) (cons next nodes) (cons best paths)))))
269   
270   (let* ((dummy (make-node '() '() 0 0))
271          (this (make-node dummy (car lines) 0 0))
272          (result (walk-lines lines (list this dummy) (list dummy)))
273          (path (get-path (car result)))
274          ;; CDR: junk dummy node
275          (breaks (cdr (reverse (map robust-line-number path)))))
276
277     (format (current-error-port) "ESTIMATE: ~S\n"
278             (/ book-height text-height))
279     (format (current-error-port) "breaks: ~S\n" breaks)
280     ;; TODO: if solution is bad return no breaks and revert to
281     ;;       ragged bottom
282     (force-output (current-error-port))
283     (list->vector breaks)))