scm/output-svg.scm

   1 ;;;; output-svg.scm -- implement Scheme output routines for SVG1
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2002--2005 Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7 ;;;; http://www.w3.org/TR/SVG11
   8 ;;;; http://www.w3.org/TR/SVG12/ -- page, pageSet in draft
   9
  10 ;;;; TODO:
  11 ;;;;  * .cff MUST NOT be in fc's fontpath.
  12 ;;;;    - workaround: remove mf/out from ~/.fonts.conf,
  13 ;;;;      instead add ~/.fonts and symlink all /mf/out/*otf there.
  14 ;;;;    - bug in fontconfig/freetype/pango?
  15
  16 ;;;;  * inkscape page/pageSet support
  17 ;;;;  * inkscape SVG-font support
  18 ;;;;    - use fontconfig/fc-cache for now, see output-gnome.scm
  19
  20 (define-module (scm output-svg))
  21 (define this-module (current-module))
  22
  23 (use-modules
  24  (guile)
  25  (ice-9 regex)
  26  (lily)
  27  (srfi srfi-13))
  28
  29
  30 (define lily-unit-length 1.75)
  31
  32 (define (dispatch expr)
  33   (let ((keyword (car expr)))
  34     (cond
  35      ((eq? keyword 'some-func) "")
  36      ;;((eq? keyword 'placebox) (dispatch (cadddr expr)))
  37      (else
  38       (if (module-defined? this-module keyword)
  39           (apply (eval keyword this-module) (cdr expr))
  40           (begin
  41             (ly:warning (_ "undefined: ~S") keyword)
  42             ""))))))
  43
  44 ;; Helper functions
  45 (define-public (attributes attributes-alist)
  46   (apply string-append
  47          (map (lambda (x) (format #f " ~s=\"~a\"" (car x) (cdr x)))
  48               attributes-alist)))
  49
  50 (define-public (eo entity . attributes-alist)
  51   "o = open"
  52   (format #f "<~S~a>\n" entity (attributes attributes-alist)))
  53
  54 (define-public (eoc entity . attributes-alist)
  55   " oc = open/close"
  56   (format #f "<~S~a/>\n" entity (attributes attributes-alist)))
  57
  58 (define-public (ec entity)
  59   "c = close"
  60   (format #f "</~S>\n" entity))
  61
  62
  63
  64 (define-public (entity entity string . attributes-alist)
  65   (if (equal? string "")
  66       (apply eoc entity attributes-alist)
  67       (string-append
  68        (apply eo (cons entity attributes-alist)) string (ec entity))))
  69
  70 (define (offset->point o)
  71   (format #f " ~S,~S" (car o)  (- (cdr o))))
  72
  73 (define (svg-bezier lst close)
  74   (let* ((c0 (car (list-tail lst 3)))
  75          (c123 (list-head lst 3)))
  76     (string-append
  77      (if (not close) "M " "L ")
  78      (offset->point c0)
  79      "C " (apply string-append (map offset->point c123))
  80      (if (not close) "" (string-append
  81                          "L " (offset->point close))))))
  82
  83 (define (sqr x)
  84   (* x x))
  85
  86 (define (integer->entity integer)
  87   (format #f "&#x~x;" integer))
  88
  89 (define (char->entity char)
  90   (integer->entity (char->integer char)))
  91
  92 (define (string->entities string)
  93   (apply string-append
  94          (map (lambda (x) (char->entity x)) (string->list string))))
  95
  96 (define pango-description-regexp-comma
  97   (make-regexp "^([^,]+), ?([-a-zA-Z_]*) ([0-9.]+)$"))
  98
  99 (define pango-description-regexp-nocomma
 100   (make-regexp "^([^ ]+) ([-a-zA-Z_]*) ?([0-9.]+)$"))
 101
 102 (define (pango-description-to-svg-font str)
 103   (let*
 104       ((size 4.0)
 105        (family "Helvetica")
 106        (style #f)
 107        (match-1 (regexp-exec pango-description-regexp-comma str))
 108        (match-2 (regexp-exec pango-description-regexp-nocomma str))
 109        (match (if match-1
 110                   match-1
 111                   match-2)))
 112
 113     (if (regexp-match? match)
 114         (begin
 115           (set! family (match:substring match 1))
 116           (if (< 0 (string-length (match:substring match 2)))
 117               (set! style (match:substring match 2)))
 118           (set! size
 119                 (string->number (match:substring match 3))))
 120
 121         (ly:warning (_ "can't decypher Pango description: ~a") str))
 122
 123     (set! style
 124           (if (string? style)
 125               (format "font-style:~a;" style)
 126               ""))
 127
 128     (format "font-family:~a;~afont-size:~a;text-anchor:west"
 129             family
 130             style
 131             (/ size lily-unit-length))
 132     ))
 133
 134 ;;; FONT may be font smob, or pango font string
 135 (define (svg-font font)
 136   (if (string? font)
 137       (pango-description-to-svg-font font)
 138       (let ((name-style (font-name-style font))
 139             (size (modified-font-metric-font-scaling font))
 140             (anchor "west"))
 141
 142         (format #f "font-family:~a;font-style:~a;font-size:~a;text-anchor:~a;"
 143                 (car name-style) (cadr name-style)
 144                 size anchor))))
 145
 146 (define (fontify font expr)
 147   (entity 'text expr
 148           `(style . ,(svg-font font))
 149           '(fill . "currentColor")
 150           ))
 151
 152 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 153 ;;; stencil outputters
 154 ;;;
 155
 156 ;;; catch-all for missing stuff
 157 ;;; comment this out to see find out what functions you miss :-)
 158
 159 (if #f
 160     (begin
 161       (define (dummy . foo) "")
 162       (map (lambda (x) (module-define! this-module x dummy))
 163            (append
 164             (ly:all-stencil-expressions)
 165             (ly:all-output-backend-commands)))
 166       ))
 167
 168 (define (url-link url x y)
 169   (string-append
 170    (eo 'a `(xlink:href . ,url))
 171    (eoc 'rect
 172         `(x . ,(car x))
 173         `(y . ,(car y))
 174         `(width . ,(- (cdr x) (car x)))
 175         `(height . ,(- (cdr y) (car y)))
 176         '(fill . "none")
 177         '(stroke . "none")
 178         '(stroke-width . "0.0"))
 179    (ec 'a)))
 180
 181 (define (grob-cause offset grob)
 182   "")
 183
 184 (define (no-origin)
 185   "")
 186
 187
 188 (define (rect-beam width slope thick blot-diameter)
 189   (let* ((x width)
 190          (y (* slope width))
 191          (z (/ y x)))
 192     (entity 'rect ""
 193             ;; The stroke will stick out.  To use stroke,
 194             ;; the stroke-width must be subtracted from all other dimensions.
 195             ;;'(stroke-linejoin . "round")
 196             ;;'(stroke-linecap . "round")
 197             ;;`(stroke-width . ,blot-diameter)
 198             ;;'(stroke . "red")
 199             ;;'(fill . "orange")
 200
 201             `(x . 0)
 202             `(y . ,(- (/ thick 2)))
 203             `(width . ,width)
 204             `(height . ,(+ thick (* (abs z) (/ thick 2))))
 205             `(rx . ,(/ blot-diameter 2))
 206             `(transform . ,(format #f "matrix (1, ~f, 0, 1, 0, 0)"  z)
 207                         ))))
 208
 209 (define (beam width slope thick blot-diameter)
 210   (let* ((b blot-diameter)
 211          (t (- thick b))
 212          (w (- width b))
 213          (h (* w slope)))
 214     (entity 'polygon ""
 215             '(stroke-linejoin . "round")
 216             '(stroke-linecap . "round")
 217             `(stroke-width . ,blot-diameter)
 218             '(stroke . "currentColor")
 219             '(fill . "currentColor")
 220             `(points . ,(string-join
 221                          (map offset->point
 222                               (list (cons (/ b 2) (/ t 2))
 223                                     (cons (+ w (/ b 2)) (+ h (/ t 2)))
 224                                     (cons (+ w (/ b 2)) (+ h (- (/ t 2))))
 225                                     (cons (/ b 2) (- (/ t 2)))))))
 226             )))
 227
 228 (define (path-beam width slope thick blot-diameter)
 229   (let* ((b blot-diameter)
 230          (t (- thick b))
 231          (w (- width b))
 232          (h (* w slope)))
 233     (entity 'path ""
 234             '(stroke-linejoin . "round")
 235             '(stroke-linecap . "round")
 236             `(stroke-width . ,blot-diameter)
 237             '(stroke . "currentColor")
 238             '(fill . "currentColor")
 239             `(d . ,(format #f "M ~S,~S l ~S,~S l ~S,~S l ~S,~S l ~S,~S"
 240                            (/ b 2) (/ t 2)
 241                            w (- h)
 242                            0 (- t)
 243                            (- w) h
 244                            0 t))
 245             )))
 246
 247 (define (bezier-sandwich lst thick)
 248   (let* ((first (list-tail lst 4))
 249          (first-c0 (car (list-tail first 3)))
 250          (second (list-head lst 4)))
 251     (entity 'path ""
 252             '(stroke-linejoin . "round")
 253             '(stroke-linecap . "round")
 254             `(stroke-width . ,thick)
 255             '(stroke . "currentColor")
 256             '(fill . "currentColor")
 257             `(d . ,(string-append (svg-bezier first #f)
 258                                   (svg-bezier second first-c0)))
 259             )))
 260
 261 (define (char font i)
 262   (dispatch
 263    `(fontify ,font ,(entity 'tspan (char->entity (integer->char i))))))
 264
 265 (define-public (comment s)
 266   (string-append "<!-- " s " !-->\n"))
 267
 268 (define (draw-line thick x1 y1 x2 y2 . alist)
 269
 270   (apply entity 'line ""
 271          (append
 272           `((stroke-linejoin . "round")
 273             (stroke-linecap . "round")
 274             (stroke-width . ,thick)
 275             (stroke . "currentColor")
 276             (x1 . ,x1)
 277             (y1 . ,(- y1))
 278             (x2 . ,x2)
 279             (y2 . ,(- y2)))
 280           alist)))
 281
 282 (define (dashed-line thick on off dx dy)
 283   (draw-line thick 0 0 dx dy `(style . ,(format "stroke-dasharray:~a,~a;" on off))))
 284
 285 (define (filledbox breapth width depth height)
 286   (round-filled-box breapth width depth height 0))
 287
 288 (define (named-glyph font name)
 289   (dispatch
 290    `(fontify ,font ,(entity 'tspan
 291                             (integer->entity
 292                              (ly:font-glyph-name-to-charcode font name))))))
 293
 294 (define (placebox x y expr)
 295   (entity 'g
 296           ;; FIXME -- JCN
 297           ;;(dispatch expr)
 298           expr
 299           `(transform . ,(format #f "translate (~f, ~f)"
 300                                  x (- y)))))
 301
 302 (define (polygon coords blot-diameter is-filled)
 303   (entity
 304    'polygon ""
 305    '(stroke-linejoin . "round")
 306    '(stroke-linecap . "round")
 307    `(stroke-width . ,blot-diameter)
 308    `(fill . ,(if is-filled "currentColor" "none"))
 309    '(stroke . "currentColor")
 310    `(points . ,(string-join
 311                 (map offset->point (ly:list->offsets '() coords))))
 312    ))
 313
 314 (define (round-filled-box breapth width depth height blot-diameter)
 315   (entity 'rect ""
 316           ;; The stroke will stick out.  To use stroke,
 317           ;; the stroke-width must be subtracted from all other dimensions.
 318           ;;'(stroke-linejoin . "round")
 319           ;;'(stroke-linecap . "round")
 320           ;;`(stroke-width . ,blot)
 321           ;;'(stroke . "red")
 322           ;;'(fill . "orange")
 323
 324           `(x . ,(- breapth))
 325           `(y . ,(- height))
 326           `(width . ,(+ breapth width))
 327           `(height . ,(+ depth height))
 328           `(ry . ,(/ blot-diameter 2))
 329           ))
 330
 331 (define (circle radius thick is-filled)
 332   (entity
 333    'circle ""
 334    '(stroke-linejoin . "round")
 335    '(stroke-linecap . "round")
 336    `(fill . ,(if is-filled "currentColor" "none"))
 337    `(stroke . "currentColor")
 338    `(stroke-width . ,thick)
 339    `(r . ,radius)))
 340
 341 (define (text font string)
 342   (dispatch `(fontify ,font ,(entity 'tspan (string->entities string)))))
 343
 344 (define (utf8-string pango-font-description string)
 345   (dispatch `(fontify ,pango-font-description ,(entity 'tspan string))))
 346
 347
 348
 349 (define (setcolor r g b)
 350   (format "<g color=\"rgb(~a%,~a%,~a%)\">"
 351           (* 100 r) (* 100 g) (* 100 b)
 352           ))
 353
 354 (define (resetcolor)
 355   "</g>")