scm/output-lib.scm

   1 ;;;; output-lib.scm -- implement Scheme output helper functions
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8
   9
  10
  11 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  12 ;; general
  13 (define-public (grob::has-interface grob iface)
  14   (memq iface (ly:grob-interfaces grob)))
  15
  16 (define-public (make-stencil-boxer thickness padding callback)
  17
  18   "Return function that adds a box around the grob passed as argument."
  19   (lambda (grob)
  20
  21     (box-stencil (callback grob) thickness padding)))
  22
  23 (define-public (make-stencil-circler thickness padding callback)
  24   "Return function that adds a circle around the grob passed as argument."
  25
  26   (lambda (grob) (circle-stencil (callback grob) thickness padding)))
  27
  28 (define-public (print-circled-text-callback grob)
  29   (grob-interpret-markup grob (make-circle-markup
  30                    (ly:grob-property grob 'text))
  31              ))
  32
  33 (define-public (event-cause grob)
  34   (let*
  35       ((cause (ly:grob-property  grob 'cause)))
  36
  37     (cond
  38      ((ly:stream-event? cause) cause)
  39      ((ly:grob? cause) (event-cause cause))
  40      (else #f))))
  41
  42 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  43 ;; tablature
  44
  45 ;; The TabNoteHead tablatureFormat callback.
  46 ;; Compute the text grob-property
  47 (define-public (fret-number-tablature-format string
  48                                              context event)
  49   (let*
  50       ((tuning (ly:context-property context 'stringTunings))
  51        (pitch (ly:event-property event 'pitch))
  52        (is-harmonic (apply
  53                      functional-or
  54                      (map
  55                       (lambda (ev)
  56                         (eq? 'harmonic-event (ly:event-property ev 'class)))
  57                       (ly:event-property event 'articulations)))))
  58
  59
  60     (make-whiteout-markup
  61      (make-vcenter-markup
  62       (format
  63        "~a"
  64        (- (ly:pitch-semitones pitch)
  65           (list-ref tuning
  66                     ;; remove 1 because list index starts at 0 and guitar string at 1.
  67                     (- string 1))))))
  68     ))
  69
  70 ;; The 5-string banjo has got a extra string, the fifth (duh), wich
  71 ;; starts at the fifth fret on the neck. Frets on the fifth string
  72 ;; are referred to relative to the other frets:
  73 ;;   the "first fret" on the fifth string is really the sixth fret
  74 ;;   on the banjo neck.
  75 ;; We solve this by defining a new fret-number-tablature function:
  76 (define-public (fret-number-tablature-format-banjo string
  77                                              context event)
  78   (let*
  79       ((tuning (ly:context-property context 'stringTunings))
  80        (pitch (ly:event-property event 'pitch))
  81         )
  82   (make-whiteout-markup
  83    (make-vcenter-markup
  84     (let ((fret (- (ly:pitch-semitones pitch) (list-ref tuning (- string 1)))))
  85       (number->string (cond
  86                        ((and (> fret 0) (= string 5))
  87                         (+ fret 5))
  88                        (else fret))))))
  89   ))
  90
  91
  92 ; default tunings for common string instruments
  93 (define-public guitar-tuning '(4 -1 -5 -10 -15 -20))
  94 (define-public guitar-open-g-tuning '(2 -1 -5 -10 -17 -22))
  95 (define-public bass-tuning '(-17 -22 -27 -32))
  96 (define-public mandolin-tuning '(16 9 2 -5))
  97
  98 ;; tunings for 5-string banjo
  99 (define-public banjo-open-g-tuning '(2 -1 -5 -10 7))
 100 (define-public banjo-c-tuning '(2 -1 -5 -12 7))
 101 (define-public banjo-modal-tuning '(2 0 -5 -10 7))
 102 (define-public banjo-open-d-tuning '(2 -3 -6 -10 9))
 103 (define-public banjo-open-dm-tuning '(2 -3 -6 -10 9))
 104 ;; convert 5-string banjo tuning to 4-string by removing the 5th string
 105 (define-public (four-string-banjo tuning)
 106   (reverse (cdr (reverse tuning))))
 107
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109 ;; note heads
 110
 111
 112 (define-public (stem::calc-duration-log grob)
 113   (ly:duration-log
 114    (ly:event-property (event-cause grob) 'duration)))
 115
 116 (define-public (note-head::calc-duration-log grob)
 117   (min 2
 118        (ly:duration-log
 119         (ly:event-property (event-cause grob) 'duration))))
 120
 121 (define-public (dots::calc-dot-count grob)
 122   (ly:duration-dot-count
 123    (ly:event-property (event-cause grob) 'duration)))
 124
 125 (define-public (dots::calc-staff-position grob)
 126   (let*
 127       ((head (ly:grob-parent grob Y))
 128        (log (ly:grob-property head 'duration-log)))
 129
 130     (cond
 131      ((or (not (grob::has-interface head 'rest-interface))
 132          (not (integer? log))) 0)
 133      ((= log 7) 4)
 134      ((> log 4) 3)
 135      ((= log 0) -1)
 136      ((= log 1) 1)
 137      ((= log -1) 1)
 138      (else 0))))
 139
 140 (define (note-head::calc-tablature-stem-attachment grob)
 141   (cons 0.0 1.35))
 142
 143
 144
 145 ;; silly, use alist?
 146 (define-public (note-head::calc-glyph-name grob)
 147   (let*
 148       ((style (ly:grob-property grob 'style))
 149        (log (min 2 (ly:grob-property grob 'duration-log))))
 150
 151     (case style
 152       ;; "default" style is directly handled in note-head.cc as a
 153       ;; special case (HW says, mainly for performance reasons).
 154       ;; Therefore, style "default" does not appear in this case
 155       ;; statement.  -- jr
 156       ((xcircle) "2xcircle")
 157       ((harmonic) "0harmonic")
 158       ((harmonic-black) "2harmonic")
 159       ((harmonic-mixed) (if (<= log 1) "0harmonic"
 160                                        "2harmonic"))
 161       ((baroque)
 162        ;; Oops, I actually would not call this "baroque", but, for
 163        ;; backwards compatibility to 1.4, this is supposed to take
 164        ;; brevis, longa and maxima from the neo-mensural font and all
 165        ;; other note heads from the default font.  -- jr
 166        (if (< log 0)
 167            (string-append (number->string log) "neomensural")
 168            (number->string log)))
 169       ((mensural)
 170        (string-append (number->string log) (symbol->string style)))
 171       ((petrucci)
 172        (if (< log 0)
 173            (string-append (number->string log) "mensural")
 174            (string-append (number->string log) (symbol->string style))))
 175       ((neomensural)
 176        (string-append (number->string log) (symbol->string style)))
 177       (else
 178        (if (string-match "vaticana*|hufnagel*|medicaea*" (symbol->string style))
 179            (symbol->string style)
 180            (string-append (number->string (max 0 log))
 181                           (symbol->string style)))))))
 182
 183 ;; TODO junk completely?
 184 (define (note-head-style->attachment-coordinates grob axis)
 185   "Return pair (X . Y), containing multipliers for the note head
 186 bounding box, where to attach the stem. e.g.: X==0 means horizontally
 187 centered, X==1 is at the right, X == -1 is at the left."
 188
 189   '(1.0 . 0.0))
 190
 191
 192 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 193 ;; bar numbers
 194
 195 (define-public ((every-nth-bar-number-visible n) barnum) (= 0 (modulo barnum n)))
 196
 197 (define-public ((modulo-bar-number-visible n m) barnum) (and (> barnum 1) (= m (modulo barnum n))))
 198
 199 (define-public ((set-bar-number-visibility n) tr)
 200   (let* ((bn (ly:context-property tr 'currentBarNumber)))
 201     (ly:context-set-property! tr 'barNumberVisibility (modulo-bar-number-visible n (modulo bn n)))))
 202
 203 (define-public (first-bar-number-invisible barnum) (> barnum 1))
 204
 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 206 ;; break visibility
 207
 208 (define-public begin-of-line-visible
 209   #(#f #f #t))
 210 (define-public end-of-line-visible
 211   #(#t #f #f))
 212 (define-public end-of-line-invisible
 213   #(#f #t #t))
 214 (define-public spanbar-begin-of-line-invisible
 215   #(#t #f #f))
 216 (define-public all-visible #(#t #t #t))
 217 (define-public all-invisible #(#f #f #f))
 218 (define-public begin-of-line-invisible
 219   #(#t #t #f))
 220 (define-public center-invisible #(#t #f #t))
 221
 222 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 223 ;; Bar lines.
 224
 225 ;;
 226 ;; How should a  bar line behave at a break?
 227 ;;
 228 ;; Why prepend `default-' to every scm identifier?
 229 (define-public (bar-line::calc-glyph-name grob)
 230   (let* (
 231          (glyph (ly:grob-property grob 'glyph))
 232          (dir (ly:item-break-dir grob))
 233          (result (assoc glyph
 234                        '((":|:" . (":|" . "|:"))
 235                          ("||:" . ("||" . "|:"))
 236                          ("dashed" . ("dashed" . '()))
 237                          ("|" . ("|" . ()))
 238                          ("||:" . ("||" . "|:"))
 239                          ("|s" . (() . "|"))
 240                          ("|:" . ("|" . "|:"))
 241                          ("|." . ("|." . ()))
 242
 243                          ;; hmm... should we end with a bar line here?
 244                          (".|" . ("|" . ".|"))
 245                          (":|" . (":|" . ()))
 246                          ("||" . ("||" . ()))
 247                          (".|." . (".|." . ()))
 248                          ("" . ("" . ""))
 249                          (":" . (":" . ""))
 250                          ("." . ("." . ()))
 251                          ("empty" . (() . ()))
 252                          ("brace" . (() . "brace"))
 253                          ("bracket" . (() . "bracket"))  )))
 254          (glyph-name (if (= dir CENTER)
 255                          glyph
 256                          (if (and result (string? (index-cell (cdr result) dir)))
 257                              (index-cell (cdr result) dir)
 258                              #f)))
 259          )
 260
 261     (if (not glyph-name)
 262         (ly:grob-suicide! grob))
 263
 264     glyph-name))
 265
 266
 267 (define-public (shift-right-at-line-begin g)
 268   "Shift an item to the right, but only at the start of the line."
 269   (if (and (ly:item? g)
 270            (equal? (ly:item-break-dir g) RIGHT))
 271       (ly:grob-translate-axis! g 3.5 X)))
 272
 273
 274 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 275 ;; Tuplets
 276
 277 (define-public (tuplet-number::calc-denominator-text grob)
 278   (number->string (ly:event-property (event-cause grob) 'denominator)))
 279
 280 (define-public (tuplet-number::calc-fraction-text grob)
 281   (let*
 282       ((ev (event-cause grob)))
 283
 284     (format "~a:~a"
 285             (ly:event-property ev 'denominator)
 286             (ly:event-property ev 'numerator))))
 287
 288 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 289 ;; Color
 290
 291 (define-public color? list?)
 292
 293 ; predefined colors
 294 (define-public black       '(0.0 0.0 0.0))
 295 (define-public white       '(1.0 1.0 1.0))
 296 (define-public red         '(1.0 0.0 0.0))
 297 (define-public green       '(0.0 1.0 0.0))
 298 (define-public blue        '(0.0 0.0 1.0))
 299 (define-public cyan        '(0.0 1.0 1.0))
 300 (define-public magenta     '(1.0 0.0 1.0))
 301 (define-public yellow      '(1.0 1.0 0.0))
 302
 303 (define-public grey        '(0.5 0.5 0.5))
 304 (define-public darkred     '(0.5 0.0 0.0))
 305 (define-public darkgreen   '(0.0 0.5 0.0))
 306 (define-public darkblue    '(0.0 0.0 0.5))
 307 (define-public darkcyan    '(0.0 0.5 0.5))
 308 (define-public darkmagenta '(0.5 0.0 0.5))
 309 (define-public darkyellow  '(0.5 0.5 0.0))
 310
 311 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 312 ;; key signature
 313
 314
 315 (define-public (key-signature-interface::alteration-position step alter c0-position)
 316   ;; TODO: memoize - this is mostly constant.
 317
 318   ;; fes, ges, as and bes typeset in lower octave
 319   (define FLAT_TOP_PITCH 2)
 320
 321   ;; ais and bis typeset in lower octave
 322   (define SHARP_TOP_PITCH 4)
 323
 324   (if (pair? step)
 325       (+ (cdr step) (* (car step) 7)  c0-position)
 326       (let*
 327           ((from-bottom-pos (modulo (+ 4 49 c0-position)  7))
 328            (p step)
 329            (c0 (- from-bottom-pos  4)))
 330
 331         (if
 332          (or (and (< alter 0) (or (> p FLAT_TOP_PITCH) (> (+ p c0) 4)) (> (+ p c0) 1))
 333              (and (> alter 0) (or (> p SHARP_TOP_PITCH) (> (+ p c0) 5)) (> (+ p c0) 2))
 334              )
 335
 336          ;; Typeset below c_position
 337          (set! p (- p 7)))
 338
 339         ;; Provide for the four cases in which there's a glitch
 340         ;; it's a hack, but probably not worth
 341         ;; the effort of finding a nicer solution.
 342         ;; --dl.
 343         (cond
 344          ((and (= c0 2) (= p 3) (> alter 0))
 345           (set! p (- p 7)))
 346          ((and (= c0 -3) (= p -1) (> alter 0))
 347           (set! p (+ p 7)))
 348          ((and (= c0 -4) (= p -1) (< alter 0))
 349           (set! p (+ p 7)))
 350          ((and (= c0 -2) (= p -3) (< alter 0))
 351           (set! p (+ p 7))))
 352
 353         (+ c0 p))))
 354
 355
 356 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 357 ;; accidentals
 358
 359 (define-public (accidental-interface::calc-alteration grob)
 360   (ly:pitch-alteration  (ly:event-property (event-cause grob) 'pitch)))
 361
 362
 363 (define-public cancellation-glyph-name-alist
 364   '((0 . "accidentals.natural")))
 365
 366 (define-public standard-alteration-glyph-name-alist
 367      '(
 368        ;; ordered for optimal performance.
 369        (0 . "accidentals.natural")
 370        (-1/2 . "accidentals.flat")
 371        (1/2 . "accidentals.sharp")
 372
 373        (1 . "accidentals.doublesharp")
 374        (-1 . "accidentals.flatflat")
 375
 376        (3/4 . "accidentals.sharp.slashslash.stemstemstem")
 377        (1/4 . "accidentals.sharp.slashslash.stem")
 378        (-1/4 . "accidentals.mirroredflat")
 379        (-3/4 . "accidentals.mirroredflat.flat")
 380        ))
 381
 382 (define-public makam-alteration-glyph-name-alist
 383      '((1 . "accidentals.doublesharp")
 384        (8/9 . "accidentals.sharp.slashslashslash.stemstem")
 385        (5/9 . "accidentals.sharp.slashslashslash.stem")
 386        (4/9 . "accidentals.sharp")
 387        (1/9 . "accidentals.sharp.slashslash.stem")
 388        (0 . "accidentals.natural")
 389        (-1/9 . "accidentals.mirroredflat")
 390        (-4/9 . "accidentals.flat.slash")
 391        (-5/9 . "accidentals.flat")
 392        (-8/9 . "accidentals.flat.slashslash")
 393        (-1 . "accidentals.flatflat")
 394        ))
 395
 396 (define-public alteration-hufnagel-glyph-name-alist
 397    '((1/2 . "accidentals.hufnagel-1")
 398      (0 . "accidentals.vaticana0")
 399      (-1/2 . "accidentals.mensural1")))
 400
 401 (define-public alteration-medicaea-glyph-name-alist
 402    '((1/2 . "accidentals.medicaea-1")
 403      (0 . "accidentals.vaticana0")
 404      (-1/2 . "accidentals.mensural1")))
 405
 406 (define-public alteration-vaticana-glyph-name-alist
 407    '((1/2 . "accidentals.vaticana-1")
 408      (0 . "accidentals.vaticana0")
 409      (-1/2 . "accidentals.mensural1")))
 410
 411 (define-public alteration-mensural-glyph-name-alist
 412    '((1/2 . "accidentals.mensural-1")
 413      (0 . "accidentals.vaticana0")
 414      (-1/2 . "accidentals.mensural1")))
 415
 416
 417 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 418 ;; * Pitch Trill Heads
 419 ;; * Parentheses
 420
 421 (define-public (parentheses-item::calc-parenthesis-stencils grob)
 422   (let* ((font (ly:grob-default-font grob))
 423          (lp (ly:font-get-glyph font "accidentals.leftparen"))
 424          (rp (ly:font-get-glyph font "accidentals.rightparen")))
 425
 426     (list lp rp)))
 427
 428
 429 (define-public (grob-interpret-markup grob text)
 430   (let*
 431       ((layout (ly:grob-layout grob))
 432        (defs (ly:output-def-lookup layout 'text-font-defaults))
 433        (props (ly:grob-alist-chain grob defs)))
 434
 435     (ly:text-interface::interpret-markup
 436      layout props text)))
 437
 438 (define-public (parentheses-item::calc-angled-bracket-stencils grob)
 439   (let* (
 440          (font (ly:grob-default-font grob))
 441          (lp (ly:stencil-aligned-to (ly:stencil-aligned-to (grob-interpret-markup grob (ly:wide-char->utf-8 #x2329))
 442                                                            Y CENTER)  X RIGHT))
 443          (rp (ly:stencil-aligned-to (ly:stencil-aligned-to (grob-interpret-markup grob (ly:wide-char->utf-8 #x232A))
 444                                                            Y CENTER) X LEFT))
 445          )
 446
 447     (list (stencil-whiteout lp)
 448           (stencil-whiteout rp))))
 449
 450 (define (parenthesize-elements grob . rest)
 451   (let*
 452       ((refp (if (null? rest)
 453                  grob
 454                  (car rest)))
 455        (elts (ly:grob-object grob 'elements))
 456        (x-ext (ly:relative-group-extent elts refp X))
 457        (stencils (ly:grob-property grob 'stencils))
 458        (lp (car stencils))
 459        (rp (cadr stencils))
 460        (padding (ly:grob-property grob 'padding 0.1)))
 461
 462     (ly:stencil-add
 463      (ly:stencil-translate-axis lp (- (car x-ext) padding) X)
 464      (ly:stencil-translate-axis rp (+ (cdr x-ext) padding) X))
 465   ))
 466
 467
 468 (define (parentheses-item::print me)
 469   (let*
 470       ((elts (ly:grob-object me 'elements))
 471        (y-ref (ly:grob-common-refpoint-of-array me elts Y))
 472        (x-ref (ly:grob-common-refpoint-of-array me elts X))
 473        (stencil (parenthesize-elements me x-ref))
 474        (elt-y-ext  (ly:relative-group-extent elts y-ref Y))
 475        (y-center (interval-center elt-y-ext)))
 476
 477     (ly:stencil-translate
 478      stencil
 479      (cons
 480       (-
 481        (ly:grob-relative-coordinate me x-ref X))
 482       (-
 483        y-center
 484        (ly:grob-relative-coordinate me y-ref Y))))
 485     ))
 486
 487
 488
 489 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 490 ;;
 491
 492 (define-public (chain-grob-member-functions grob value . funcs)
 493   (for-each
 494    (lambda (func)
 495      (set! value (func grob value)))
 496    funcs)
 497
 498   value)
 499
 500 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 501 ;; falls/doits
 502
 503 (define-public (bend::print spanner)
 504   (define (close  a b)
 505     (< (abs (- a b)) 0.01))
 506
 507   (let*
 508       ((delta-y (* 0.5 (ly:grob-property spanner 'delta-position)))
 509        (left-span (ly:spanner-bound spanner LEFT))
 510        (dots (if (and (grob::has-interface left-span 'note-head-interface)
 511                       (ly:grob? (ly:grob-object left-span 'dot)))
 512                  (ly:grob-object left-span 'dot) #f))
 513
 514        (right-span (ly:spanner-bound spanner RIGHT))
 515        (thickness (* (ly:grob-property spanner 'thickness)
 516                      (ly:output-def-lookup (ly:grob-layout spanner)
 517                                            'line-thickness)))
 518        (padding (ly:grob-property spanner 'padding 0.5))
 519        (common (ly:grob-common-refpoint right-span
 520                                         (ly:grob-common-refpoint spanner
 521                                                                  left-span X)
 522                                         X))
 523        (common-y (ly:grob-common-refpoint spanner left-span Y))
 524        (left-x (+ padding
 525                   (max (interval-end (ly:grob-robust-relative-extent
 526                                       left-span common X))
 527                         (if (and
 528                              dots
 529                              (close (ly:grob-relative-coordinate dots common-y Y)
 530                                         (ly:grob-relative-coordinate spanner common-y Y)))
 531                             (interval-end (ly:grob-robust-relative-extent dots common X))
 532                             -10000) ;; TODO: use real infinity constant.
 533                         )))
 534        (right-x (- (interval-start
 535                     (ly:grob-robust-relative-extent right-span common X))
 536                    padding))
 537        (self-x (ly:grob-relative-coordinate spanner common X))
 538        (dx (- right-x left-x))
 539        (exp (list 'path thickness
 540                   `(quote
 541                     (rmoveto
 542                      ,(- left-x self-x) 0
 543
 544                      rcurveto
 545                      ,(/ dx 3)
 546                      0
 547                      ,dx ,(* 0.66 delta-y)
 548                      ,dx ,delta-y
 549                      )))))
 550
 551     (ly:make-stencil
 552      exp
 553      (cons (- left-x self-x) (- right-x self-x))
 554      (cons (min 0 delta-y)
 555            (max 0 delta-y)))))
 556
 557 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 558 ;; grace spacing
 559
 560
 561 (define-public (grace-spacing::calc-shortest-duration grob)
 562   (let*
 563      ((cols (ly:grob-object grob 'columns))
 564       (get-difference
 565        (lambda (idx)
 566          (ly:moment-sub (ly:grob-property
 567                          (ly:grob-array-ref cols (1+ idx)) 'when)
 568                         (ly:grob-property
 569                          (ly:grob-array-ref cols idx) 'when))))
 570
 571       (moment-min (lambda (x y)
 572                     (cond
 573                      ((and x y)
 574                       (if (ly:moment<? x y)
 575                             x
 576                             y))
 577                      (x x)
 578                      (y y)))))
 579
 580     (fold moment-min #f (map get-difference
 581                              (iota (1- (ly:grob-array-length cols)))))))
 582
 583
 584
 585 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 586 ;; fingering
 587
 588 (define-public (fingering::calc-text grob)
 589   (let*
 590       ((event (event-cause grob))
 591        (digit (ly:event-property event 'digit)))
 592
 593     (if (> digit 5)
 594         (ly:input-message (ly:event-property event 'origin)
 595                           "Warning: Fingering notation for finger number ~a" digit))
 596
 597     (number->string digit 10)
 598   ))
 599
 600 (define-public (string-number::calc-text grob)
 601   (let*
 602       ((digit (ly:event-property (event-cause  grob) 'string-number)))
 603
 604     (number->string digit 10)
 605   ))
 606
 607
 608 (define-public (stroke-finger::calc-text grob)
 609   (let*
 610       ((digit (ly:event-property (event-cause grob) 'digit))
 611        (text (ly:event-property (event-cause grob) 'text)))
 612
 613     (if (string? text)
 614         text
 615         (vector-ref (ly:grob-property grob 'digit-names)  (1- (max (min 5 digit) 1))))))
 616
 617 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 618 ;; dynamics
 619 (define-public (hairpin::calc-grow-direction grob)
 620   (if (eq? (ly:event-property (event-cause grob) 'class) 'decrescendo-event)
 621       START
 622       STOP
 623       ))
 624
 625 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 626 ;; lyrics
 627
 628 (define-public (lyric-text::print grob)
 629   "Allow interpretation of tildes as lyric tieing marks."
 630
 631   (let*
 632       ((text (ly:grob-property grob 'text)))
 633
 634     (grob-interpret-markup grob
 635                (if (string? text)
 636                    (make-tied-lyric-markup text)
 637                    text))))
 638
 639 (define-public ((grob::calc-property-by-copy prop) grob)
 640   (ly:event-property (event-cause grob) prop))
 641
 642 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 643 ;; fret boards
 644
 645 (define (string-frets->description string-frets string-count)
 646   (let*
 647       ((desc (list->vector
 648               (map (lambda (x) (list 'mute  (1+ x)))
 649                    (iota string-count)))))
 650
 651        (for-each (lambda (sf)
 652                    (let*
 653                        ((string (car sf))
 654                         (fret (cadr sf))
 655                         (finger (caddr sf)))
 656
 657
 658                      (vector-set! desc (1- string)
 659                                   (if (= 0 fret)
 660                                       (list 'open string)
 661                                       (if finger
 662                                           (list 'place-fret string fret finger)
 663                                           (list 'place-fret string fret))
 664
 665
 666                                       ))
 667                      ))
 668                  string-frets)
 669
 670        (vector->list desc)))
 671
 672 (define-public (fret-board::calc-stencil grob)
 673   (let* ((string-frets (ly:grob-property grob 'string-fret-finger-combinations))
 674          (string-count (ly:grob-property grob 'string-count)))
 675
 676     (grob-interpret-markup grob
 677                            (make-fret-diagram-verbose-markup
 678                             (string-frets->description string-frets string-count)))))